#! perl # MANDATORY

# this extension swaps out maps and resets them, in essence managing
# the reset/swap policy of the server.
# it also contains the map prefetching logic

#our $DEACTIVATE_TIMEOUT =   20; # number of seconds after which maps get deactivated to save cpu
our $SWAP_TIMEOUT       = $cf::CFG{swap_timeout}      || 35; # number of seconds after which maps inactive get swapped out
our $SCHEDULE_INTERVAL  = $cf::CFG{schedule_interval} || 10; # time the map scheduler sleeps between runs
our $SAVE_TIMEOUT       = $cf::CFG{save_timeout}      || 20; # save maps every n seconds
our $MAX_ACTIVES        = $cf::CFG{max_actives}       || 200000; # swap aggressively when > this many objects are active

cf::async_ext {
   $Coro::current->prio (Coro::PRIO_MIN);
   # load the header of swapped-out maps.
   # this is not a correctness issue, it simply saves diskspace
   # because old files will get cleaned up on reset time
   Coro::Timer::sleep 1;

   my $files = Coro::AIO::aio_readdir cf::localdir . "/" . cf::tmpdir;

   for my $map (@$files) {
      utf8::decode $map;
      next if $map =~ /\.(?:pst|meta)$/;
      cf::map::find $map;
      $cf::WAIT_FOR_TICK_ONE->wait;
   }

   #TODO: should also preload random maps...
};

our $SCHEDULER = cf::async_ext {
   my $schedule_interval = Coro::Event->timer (after => 1, interval => $SCHEDULE_INTERVAL);
   while () {
      $schedule_interval->next unless cf::object::actives_size > $MAX_ACTIVES;

      # this weird form of iteration over values is used because
      # the hash changes underneath us frequently, and for
      # keeps a direct reference to the value without (in 5.8 perls)
      # keeping a reference, so this is prone to crashes or worse.
      my @maps = keys %cf::MAP;
      for (@maps) {
         my $map = $cf::MAP{$_}
            or next;
         $map->valid or next;

         eval {
            # not yet, because maps might become visible to players nearby
            # we need to remove the map from %cf::MAP and all tiled map links
#         if ($last_access + $DEACTIVATE_TIMEOUT <= $cf::RUNTIME) {
#            $map->deactivate;
#            delete $map->{active};
#         }
            if ($map->should_reset) {
               $map->reset;
            } elsif ($map->in_memory == cf::MAP_IN_MEMORY) {
               my $max_idle = cf::object::actives_size > $MAX_ACTIVES ? 1 : $SWAP_TIMEOUT;
               if ($map->last_access + $max_idle <= $cf::RUNTIME && !$map->players) {
                  $map->swap_out;
                  $cf::WAIT_FOR_TICK_ONE->wait unless $max_idle == 1;
               } elsif ($map->{last_save} + $SAVE_TIMEOUT <= $cf::RUNTIME) {
                  $map->save;
                  $cf::WAIT_FOR_TICK_ONE->wait unless $max_idle == 1;
               }
            }
         };
         warn $@ if $@;
         Coro::cede;
      };
   }
};

$SCHEDULER->prio (-2);