server/ext/map-scheduler.ext

#! perl # mandatory

# this extension swaps out maps and resets them, in essence managing
# the reset/swap policy of the server.
# it also contains the map prefetching logic

#our $DEACTIVATE_TIMEOUT =   20; # number of seconds after which maps get deactivated to save cpu
our $SWAP_TIMEOUT       = $cf::CFG{swap_timeout}      || 300; # number of seconds after which inactive maps get swapped out
our $SCHEDULE_INTERVAL  = $cf::CFG{schedule_interval} ||   2; # time the map scheduler sleeps between runs
our $SAVE_TIMEOUT       = $cf::CFG{save_timeout}      ||  30; # save maps every n seconds
our $SWAP_LOAD1         = $cf::CFG{swap_load1}        ||  .1; # start aggressively swapping at this load
our $SWAP_LOAD2         = $cf::CFG{swap_load2}        ||  .4; # swap as fast as possible at this load

cf::async_ext {
   $Coro::current->{desc} = "startup map scanner";
   $Coro::current->prio (Coro::PRIO_MIN);

   # load the header of swapped-out maps.
   # this is not a correctness issue, it simply saves diskspace
   # because old files will get cleaned up on reset time
   Coro::Timer::sleep 0.25;

   for my $path (@{ cf::map::tmp_maps or [] }, @{ cf::map::random_maps or [] }) {
      cf::cede_to_tick;
      cf::map::find $path;
   }

   # now hunt for resettable per-player maps
   for my $login (@{ cf::player::list_logins or [] }) {
      for my $path (@{ cf::player::maps $login or [] }) {
         cf::cede_to_tick;

         $path =~ /^~[^\/]+(\/.*)$/
            or next; # doh

         my $base = cf::map::find $1;

         # skip maps without base maps on the assumption
         # that those are old, unresettable maps
         next unless $base;

         # skip unresettable maps, for speed
         next if $base->{deny_reset};

         my $map = cf::map::find $path;

         if ($map->{deny_reset}) {
            warn "found noreset map with resettable base map, resetting: $path\n";
            delete $map->{deny_reset};
         }
      }
   }
};

our $SCHEDULER = cf::async_ext {
   $Coro::current->{desc} = "map scheduler";
   $Coro::current->prio (Coro::PRIO_MAX);
   my $timer = Coro::Event->timer (data => cf::WF_AUTOCANCEL);

   while () {
      if ($cf::LOADAVG > $SWAP_LOAD2) {
         $timer->interval (0.05);
         $timer->next;
         cf::wait_for_tick;
      } else {
         $timer->interval ($SCHEDULE_INTERVAL);
         $timer->next;
      }

      # this weird form of iteration over values is used because
      # the hash changes underneath us frequently, and for
      # keeps a direct reference to the value without (in 5.8 perls)
      # keeping a reference, so this is prone to crashes or worse.
      my @maps = keys %cf::MAP;
      for (@maps) {
         my $map = $cf::MAP{$_}
            or next;
         $map->valid or next;

         eval {
            # not yet, because maps might become visible to players nearby
            # we need to remove the map from %cf::MAP and all tiled map links
#         if ($last_access + $DEACTIVATE_TIMEOUT <= $cf::RUNTIME) {
#            $map->deactivate;
#            delete $map->{active};
#         }
            if ($map->should_reset) {
               $map->reset;
            } elsif ($map->in_memory == cf::MAP_IN_MEMORY) {
               my $max_idle = cf::clamp +(cf::lerp $cf::LOADAVG, $SWAP_LOAD1, $SWAP_LOAD2, $SWAP_TIMEOUT, $cf::TICK * 1.5),
                                        $cf::TICK * 1.5, $SWAP_TIMEOUT;

               if ($map->last_access + $max_idle <= $cf::RUNTIME && !$map->players) {
                  $map->swap_out;
               } elsif ($map->{last_save} + $SAVE_TIMEOUT <= $cf::RUNTIME) {
                  $map->save;
                  $map->{last_save} -= rand; # randomise map save times a bit
               }
            }
         };
         warn $@ if $@;
         cf::cede_to_tick;
      };
   }
};

$SCHEDULER->prio (-2);

Revision:	1.45
Committed:	Thu Oct 11 00:34:31 2007 UTC (16 years, 7 months ago) by root
Branch:	MAIN
CVS Tags:	rel-2_3
Changes since 1.44:	+10 -4 lines
Log Message:	- rewrite follow to use a coroutine and make it generally safer. - the map scheduler, under duress, tried to swap out maps fast, but when a sync job was entered it also entered and andless loop causing a freeze. hack around this temporairly by always sleeping 50ms.
#	Content
1	#! perl # mandatory
2
3	# this extension swaps out maps and resets them, in essence managing
4	# the reset/swap policy of the server.
5	# it also contains the map prefetching logic
6
7	#our $DEACTIVATE_TIMEOUT = 20; # number of seconds after which maps get deactivated to save cpu
8	our $SWAP_TIMEOUT = $cf::CFG{swap_timeout} \|\| 300; # number of seconds after which inactive maps get swapped out
9	our $SCHEDULE_INTERVAL = $cf::CFG{schedule_interval} \|\| 2; # time the map scheduler sleeps between runs
10	our $SAVE_TIMEOUT = $cf::CFG{save_timeout} \|\| 30; # save maps every n seconds
11	our $SWAP_LOAD1 = $cf::CFG{swap_load1} \|\| .1; # start aggressively swapping at this load
12	our $SWAP_LOAD2 = $cf::CFG{swap_load2} \|\| .4; # swap as fast as possible at this load
13
14	cf::async_ext {
15	$Coro::current->{desc} = "startup map scanner";
16	$Coro::current->prio (Coro::PRIO_MIN);
17
18	# load the header of swapped-out maps.
19	# this is not a correctness issue, it simply saves diskspace
20	# because old files will get cleaned up on reset time
21	Coro::Timer::sleep 0.25;
22
23	for my $path (@{ cf::map::tmp_maps or [] }, @{ cf::map::random_maps or [] }) {
24	cf::cede_to_tick;
25	cf::map::find $path;
26	}
27
28	# now hunt for resettable per-player maps
29	for my $login (@{ cf::player::list_logins or [] }) {
30	for my $path (@{ cf::player::maps $login or [] }) {
31	cf::cede_to_tick;
32
33	$path =~ /^~[^\/]+(\/.*)$/
34	or next; # doh
35
36	my $base = cf::map::find $1;
37
38	# skip maps without base maps on the assumption
39	# that those are old, unresettable maps
40	next unless $base;
41
42	# skip unresettable maps, for speed
43	next if $base->{deny_reset};
44
45	my $map = cf::map::find $path;
46
47	if ($map->{deny_reset}) {
48	warn "found noreset map with resettable base map, resetting: $path\n";
49	delete $map->{deny_reset};
50	}
51	}
52	}
53	};
54
55	our $SCHEDULER = cf::async_ext {
56	$Coro::current->{desc} = "map scheduler";
57	$Coro::current->prio (Coro::PRIO_MAX);
58	my $timer = Coro::Event->timer (data => cf::WF_AUTOCANCEL);
59
60	while () {
61	if ($cf::LOADAVG > $SWAP_LOAD2) {
62	$timer->interval (0.05);
63	$timer->next;
64	cf::wait_for_tick;
65	} else {
66	$timer->interval ($SCHEDULE_INTERVAL);
67	$timer->next;
68	}
69
70	# this weird form of iteration over values is used because
71	# the hash changes underneath us frequently, and for
72	# keeps a direct reference to the value without (in 5.8 perls)
73	# keeping a reference, so this is prone to crashes or worse.
74	my @maps = keys %cf::MAP;
75	for (@maps) {
76	my $map = $cf::MAP{$_}
77	or next;
78	$map->valid or next;
79
80	eval {
81	# not yet, because maps might become visible to players nearby
82	# we need to remove the map from %cf::MAP and all tiled map links
83	# if ($last_access + $DEACTIVATE_TIMEOUT <= $cf::RUNTIME) {
84	# $map->deactivate;
85	# delete $map->{active};
86	# }
87	if ($map->should_reset) {
88	$map->reset;
89	} elsif ($map->in_memory == cf::MAP_IN_MEMORY) {
90	my $max_idle = cf::clamp +(cf::lerp $cf::LOADAVG, $SWAP_LOAD1, $SWAP_LOAD2, $SWAP_TIMEOUT, $cf::TICK * 1.5),
91	$cf::TICK * 1.5, $SWAP_TIMEOUT;
92
93	if ($map->last_access + $max_idle <= $cf::RUNTIME && !$map->players) {
94	$map->swap_out;
95	} elsif ($map->{last_save} + $SAVE_TIMEOUT <= $cf::RUNTIME) {
96	$map->save;
97	$map->{last_save} -= rand; # randomise map save times a bit
98	}
99	}
100	};
101	warn $@ if $@;
102	cf::cede_to_tick;
103	};
104	}
105	};
106
107	$SCHEDULER->prio (-2);
108