#!perl # mandatory

sub ob2info {
   my ($item, $rval) = @_;
   sprintf "[%s from %s (%d:%d%s) nrof: %d uuid: %s]",
      $item->name, $item->kv_get ('ext_reseller_seller'),
      $item->kv_get ('ext_reseller_orig_value'), $item->value,
      (defined $rval ? ":$rval" : ""), $item->nrof, $item->uuid;
}

sub audit_log {
   my ($who, $action, $info) = @_;
   warn
      sprintf "RESELLER_AUDIT(%s) %s %s: %s\n",
         $who->map->path, $who->name, $action, $info;
}

sub find_rec;

sub find_rec {
   my ($ob, $cb) = @_;

   my @found;
   for my $i ($ob->inv) {
      push @found, $i if $cb->($i);
      push @found, find_rec $i, $cb if $i->inv;
   }

   return @found;
}

sub find_unpaid {
   my ($ob) = @_;
   find_rec $ob, sub { $_[0]->flag (cf::FLAG_UNPAID) };
}

sub find_traded {
   my ($ob) = @_;
   find_rec $ob, sub { $_[0]->kv_get ('ext_reseller_seller') ne '' };
}

cf::register_script_function "reseller::list_sells" => sub {
   my ($who, $msg, $npc) = @_;
   my $ext_re_sales = $npc->kv_get ('ext_reseller_sales');
   my $sells = $ext_re_sales && cf::decode_json $ext_re_sales;
   my $hissells = $sells->{$who->name};

   unless (keys %{$hissells || {}}) {
      $who->reply ($npc, "I'm sorry, but you sold nothing.\n");
      return 0;
   }

   my $reply = "You sold:\n\n";

   for (keys %$hissells) {
      my $n = $_;
      $n =~ s/\s*\(unpaid\)//g;
      $reply .= "   B<$n> (for " . cf::cost_string_from_value ($hissells->{$_}) . ")\n";
   }

   $who->reply ($npc, $reply);

   0
};

cf::register_script_function "reseller::pay_player" => sub {
   my ($who, $msg, $npc) = @_;
   my $ext_re_sales = $npc->kv_get ('ext_reseller_sales');
   my $sells = $ext_re_sales && cf::decode_json $ext_re_sales;
   my $hissells = $sells->{$who->name};

   unless (keys %{$hissells || {}}) {
      $who->reply ($npc, "I'm sorry, but you sold nothing.\n");
      return 0;
   }

   my $sum = 0;
   $sum += $_ for values %$hissells;

   $who->pay_player ($sum);
   $who->reply ($npc, "Here are the " . cf::cost_string_from_value ($sum) . " for your sales.");

   audit_log ($who, 'collects', "$sum silver");

   $sells->{$who->name} = {};

   $npc->kv_set (ext_reseller_sales => cf::encode_json $sells)
      if $sells;

   0
};

cf::object::attachment "reseller_shopmat",
   on_move_trigger => sub {
      my ($self, $who_caused, $who) = @_;

      my @obs = grep { $_->name eq $self->{reseller_shopmat}{npc_name} }
                     $who->map->at ($self->{reseller_shopmat}{npc_x}, $self->{reseller_shopmat}{npc_y});

      unless (@obs) {
         warn "Couldn't find shop keeper in " . $who->map->path . "\n";
         return cf::override;
      }

      my $ext_re_sales = $obs[0]->kv_get ('ext_reseller_sales');
      my $sells = $ext_re_sales && cf::decode_json $ext_re_sales;

      my $unpaid_items = {};

      for my $item (find_unpaid ($who)) {
         if ($item->kv_get ('ext_reseller_seller') eq $who->name) {
            audit_log ($who, 'removes', ob2info ($item));
            $item->flag (cf::FLAG_UNPAID, 0);
            $item->remove;
            give_back ($who, $item);
            next;
         }

         my $value = $item->query_cost ($who, cf::F_BUY | cf::F_SHOP);

         warn "Object " . $item->name . " bought by " . $who->name . " on map " 
              . $who->map->path . " for $value silver has no seller set\n"
            if $item->kv_get ('ext_reseller_seller') eq '';

         $unpaid_items->{$item} = [$value, $item];
      }

      audit_log ($who, 'wants', (join ",", map { ob2info ($_->[1], $_->[0]) } values %$unpaid_items))
         if %$unpaid_items;

      $self->apply_shop_mat ($who);

      my @seller_noted;

      for my $item (find_traded ($who)) {
         next if $item->flag (cf::FLAG_UNPAID);
         if (my $value = $unpaid_items->{$item}[0]) {
            push @seller_noted, ob2info ($item, $value)."P";
            $sells->{$item->kv_get ('ext_reseller_seller')}->{$item->name} += $value;
         } else {
            push @seller_noted, ob2info ($item)."T";
         }

         $item->value ($item->kv_get ('ext_reseller_orig_value'));
         $item->kv_del ("ext_reseller_seller");
      }

      audit_log ($who, 'removed', (join ",", @seller_noted))
         if @seller_noted;

      $obs[0]->kv_set (ext_reseller_sales => cf::encode_json $sells)
         if $sells;

      cf::override;
   },
;

sub give_back {
   my ($who, $what) = @_;
   $who->insert ($what);
   $who->esrv_send_item ($what);
}

sub give_back_with_message {
   my ($who, $what, $msg) = @_;
   $who->message ($msg, cf::NDI_BROWN);
   give_back ($who, $what);
}

cf::object::attachment "reseller_floor",
   on_drop_on => sub {
      my ($on, $what, $who) = @_;
      my $name = $what->custom_name;

      return if $what->flag (cf::FLAG_UNPAID);

      if ($what->type == cf::MONEY) {
         give_back_with_message ($who, $what,
            "The shopkeeper says: Sorry, you can't sell money here.");
         return cf::override;
      }

      if (!$what->flag (cf::FLAG_IDENTIFIED) && $what->need_identify) {
         give_back_with_message ($who, $what,
            "The shopkeeper says: Sorry, you can't sell unidentified stuff here.");
         return cf::override;
      }

      my $orig_value = $what->value;
      my $value = 0;

      if ($name =~ m/\S/) {
         unless ($name =~ m/\d+\s*\S+/) {
            give_back_with_message ($who, $what,
               "The shopkeeper says: Sorry, I don't recognize '$name' as currency. "
               . "Please name your item like '17 platinum' or '10 gold 8 silver.'");
            return cf::override;
         }

         while ($name =~ s/^\s*(\d+)\s*(\S+)//) {
            my ($v, $c) = ($1, $2);
            if (my $coin = cf::coin_from_name $c) {
               $value += $v * $coin->value;
            } else {
               give_back_with_message ($who, $what,
                  "The shopkeeper says: I don't know the currency '$c', you can use one of these currencies: "
                  . (join ", ", cf::coin_names)
               );
               return cf::override;
            }
         }
      } else {
         # commented out the following line because too many just use the 
         # reseller shop as dumpyard:
         # $value = $what->query_cost ($who, cf::F_SELL | cf::F_SHOP) / ($what->nrof || 1);
         give_back_with_message ($who, $what,
            "Sorry, you can't just sell stuff without assigning a price to it! "
            . "Please name your item like '17 platinum' or '10 gold 8 silver' "
            . "and drop it again. (To rename the item use the B<rename> "
            . "entry in the inventory item popup menu)."
         );
         return cf::override;
      }

      if ($value < 0) {
         give_back_with_message ($who, $what,
            "The shopkeeper says: You can't sell something for a negative value: $value.");
         return cf::override;
      }

      my $fee = $value / 100; # 1% selling fee

      unless ($who->pay_amount ($fee)) {
         give_back_with_message ($who, $what,
            "The shopkeeper says: You need " . cf::cost_string_from_value ($fee)
            . " to pay the 1% fee for this item.");
         return cf::override;
      } else {
         $who->message (
            "The shopkeeper says: Ok, got the fee of " . cf::cost_string_from_value ($fee)
            . " for the item.",
            cf::NDI_BROWN
         );
      }

      $what->value ($value);
      my $cost = $what->query_cost ($who, cf::F_BUY | cf::F_SHOP) / ($what->nrof || 1);

      my $fact = 0;
      if ($cost) {
         $fact = $value / $cost;
         $what->value (cf::ceil ($value * $fact));
      }

#  warn "END VALUE: $value * $fact => " . $what->value . "\n";

#   my $cost = $what->query_cost ($who, cf::F_BUY | cf::F_SHOP) / $what->nrof;
#  warn "COSTS NOW: $cost\n";

      $who->message (
         "The shopkeeper says: Ok, I marked " 
         . ($what->nrof || 1) . " " . $what->name . " to be sold for at least " 
         . cf::cost_string_from_value ($value)
         . ($what->nrof > 1 ? " each" : ""), cf::NDI_BROWN
      );

      $what->kv_set (ext_reseller_seller => $who->name);
      $what->kv_set (ext_reseller_orig_value => $orig_value);
#  warn "SET SELLER ON " . $what->name . " + " . $what->{seller}->[0] . "\n";
      $what->custom_name ($what->name . " (by " . $who->name . ")");
      $what->flag (cf::FLAG_UNPAID, 1);
      $what->insert_ob_in_map_at ($who->map, $who, cf::INS_BELOW_ORIGINATOR, $who->x, $who->y);

      audit_log ($who, 'sells', ob2info ($what));

      cf::override;
   },
;