#! perl # depends=irc

use Fcntl;
use Coro::AIO;

our $UPDATE_LOGINS = EV::idle sub {
   $_[0]->stop;

   cf::async {
      my ($status, @pl) = ext::commands::who_listing;

      my $fh = aio_open "$LOCALDIR/usercount", O_WRONLY | O_CREAT | O_TRUNC, 0644
         or return;
      aio_write $fh, 0, undef, scalar @pl, 0;
      aio_close $fh;

      my $who;
      for ($status, @pl) {
         s/[<&]//g;
         $who .= "$_<br />\n";
      }

      my $fh = aio_open "$LOCALDIR/userlisting.html", O_WRONLY | O_CREAT | O_TRUNC, 0644
         or return;
      aio_write $fh, 0, undef, $who, 0;
      aio_close $fh;
   };
};

cf::player->attach (
   on_login => sub {
      my ($pl) = @_;
      $pl->ob->set_ob_key_value (schmorplog_last_login => time);

      $pl->ob->set_ob_key_value (schmorplog_login_count =>
         1 + $pl->ob->get_ob_key_value ("schmorplog_login_count"));

      (my $client = $pl->ns->version) =~ s/\n/\\n/g;

      $pl->ob->set_ob_key_value (schmorplog_client => $client);

      ext::irc::do_notice (sprintf "%s logged in", $pl->ob->name);

      $UPDATE_LOGINS->start;

      warn "LOGIN: ", $pl->ob->name, " from ", $pl->ns->host;
   },
   on_logout => sub {
      my ($pl, $cleanly) = @_;
      $pl->ob->set_ob_key_value (schmorplog_last_logout => time);
      ext::irc::do_notice (sprintf "%s left", $pl->ob->name);

      $UPDATE_LOGINS->start;

      warn "LOGOUT: ", $pl->ob->name, " from ", $pl->ns->host, " ($cleanly)";
   },
   on_birth => sub {
      my ($pl) = @_;
      ext::irc::do_notice (sprintf "%s was just born", $pl->ob->name);
      $pl->ob->set_ob_key_value (schmorplog_birthdate => time);

      warn "BIRTH: ", $pl->ob->name, " from ", $pl->ns->host;
   },
   on_quit => sub {
      my ($pl) = @_;
      ext::irc::do_notice (sprintf "%s quit the game", $pl->ob->name);

      warn "QUIT: ", $pl->ob->name, " from ", $pl->ns->host;
   },
   on_death => sub {
      my ($pl) = @_;
      ext::irc::do_notice (sprintf "%s was killed by %s", $pl->ob->name, $pl->killer_name);

      $pl->ob->set_ob_key_value (schmorplog_death_count =>
         1 + $pl->ob->get_ob_key_value ("schmorplog_death_count"));
   },
   on_load => sub {
      my ($pl, $path) = @_;
      $pl->ob->set_ob_key_value (schmorplog_last_load => time);
   },
   on_save => sub {
      my ($pl, $path) = @_;
      $pl->ob->set_ob_key_value (schmorplog_last_save => time);
   },
);