#! perl # depends=irc mandatory

# statistics-package

use Fcntl;
use Coro::AIO;

our $UPDATE_LOGINS = EV::idle sub {
   $_[0]->stop;

   cf::async {
      my ($status, @pl) = ext::commands::who_listing;

      my $fh = aio_open "$LOCALDIR/usercount", O_WRONLY | O_CREAT | O_TRUNC, 0644
         or return;
      aio_write $fh, 0, undef, scalar @pl, 0;
      aio_close $fh;

      my $who;
      for ($status, @pl) {
         s/[<&]//g;
         $who .= "$_<br />\n";
      }

      my $fh = aio_open "$LOCALDIR/userlisting.html", O_WRONLY | O_CREAT | O_TRUNC, 0644
         or return;
      aio_write $fh, 0, undef, $who, 0;
      aio_close $fh;
   };
};

cf::object->attach (
   on_kill => sub {
      my ($ob, $hitter) = @_;

      return unless $hitter;
      $hitter = $hitter->outer_owner;
      my $pl = $hitter->contr
         or return;

      ++$hitter->{stats_kill}{$ob->name};
   },
);

cf::player->attach (
   on_login => sub {
      my ($pl) = @_;
      $pl->ob->kv_set (schmorplog_last_login => time);

      $pl->ob->kv_set (schmorplog_login_count =>
         1 + $pl->ob->kv_get ("schmorplog_login_count"));

      (my $client = $pl->ns->version) =~ s/\n/\\n/g;

      $pl->ob->kv_set (schmorplog_client => $client);

      ext::irc::do_notice (sprintf "%s logged in", $pl->ob->name);

      $UPDATE_LOGINS->start;

      warn "LOGIN: ", $pl->ob->name, " from ", $pl->ns->host;
   },
   on_logout => sub {
      my ($pl, $cleanly) = @_;
      $pl->ob->kv_set (schmorplog_last_logout => time);
      ext::irc::do_notice (sprintf "%s left", $pl->ob->name);

      $UPDATE_LOGINS->start;

      warn "LOGOUT: ", $pl->ob->name, " from ", $pl->ns->host, " ($cleanly)";
   },
   on_birth => sub {
      my ($pl) = @_;
      ext::irc::do_notice (sprintf "%s was just born", $pl->ob->name);
      $pl->ob->kv_set (schmorplog_birthdate => time);

      warn "BIRTH: ", $pl->ob->name, " from ", $pl->ns->host;
   },
   on_quit => sub {
      my ($pl) = @_;
      ext::irc::do_notice (sprintf "%s quit the game", $pl->ob->name);

      warn "QUIT: ", $pl->ob->name, " from ", $pl->ns->host;
   },
   on_death => sub {
      my ($pl) = @_;

      my $msg = $pl->expand_cfpod (sprintf "%s was killed by %s.", $pl->ob->name, $pl->killer_name);
      ext::irc::do_notice ($msg);

      ++$pl->ob->{stats_death}{$pl->killer_name};

      $pl->ob->kv_set (schmorplog_death_count =>
         1 + $pl->ob->kv_get ("schmorplog_death_count"));

      $_->send_msg ("" => $msg, cf::NDI_VERBATIM)
         for cf::player::list;
   },
   on_load => sub {
      my ($pl, $path) = @_;
      $pl->ob->kv_set (schmorplog_last_load => time);
   },
   on_save => sub {
      my ($pl, $path) = @_;
      $pl->ob->kv_set (schmorplog_last_save => time);
   },
);

cf::register_script_function "statistician::talk" => sub {
   my ($who, $msg, $npc) = @_;

   my ($cmd, $args) = split /\s+/, $msg, 2;

   $args ||= $who->name;

   if ($cmd eq "deaths") {
      cf::async {
         my $pl = cf::player::find $args
            or return $who->reply ($npc, "I don't know any person named '$args'.");

         my $s = $pl->ob->{stats_death}
            or return $who->reply ($npc, "$args didn't die even once.");

         my $rep = "$args died a total of " . $pl->ob->kv_get ("schmorplog_death_count") . " times, among them:\n\n\n\n";

         for (sort { $s->{$b} <=> $s->{$a} } keys %$s) {
            $rep .= "$s->{$_} time(s) due to $_.\n\n";
         }

         $who->reply ($npc, $rep);
      };
   } elsif ($cmd eq "kills") {
      cf::async {
         my $pl = cf::player::find $args
            or return $who->reply ($npc, "I don't know any person named '$args'.");

         my $s = $pl->ob->{stats_kill}
            or return $who->reply ($npc, "I don't know of I<anything> that $args has killed so far.");

         my $rep = sprintf "\n\nC<%6s> %s\n\n", "Kills", "Name";
         for (sort { $s->{$a} <=> $s->{$b} } keys %$s) {
            $rep .= sprintf "C<%6s> %s\n\n", $s->{$_}, $_;
         }

         $who->reply ($npc, $rep);
      };
   } elsif ($cmd eq "hi") {
      $who->reply ($npc, "Hello!\n\n"
                   . "I am a statistician, I keep statistics about all people here.\n\n"
                   . "To know how often somebody died, ask C<deaths> I<playername>\n\n"
                   . "To know how many kills somebody scored, ask C<kills> I<playername>");
   } else {
      $who->reply ($npc, "No idea what you want of me, how about saying 'hi' first?");
   }

   $cmd = lc $cmd;
};

# log "crash" messages, i.e. client exit reasons
cf::register_exticmd clientlog => sub {
   my ($ns, $msg) = @_;

   my $name = $ns->pl && $ns->pl->ob ? $ns->pl->ob->name : "<unknown>";

   $msg =~ y/\x0a\x20-\x7f//cd;
   $msg =~ s/\s+$//;

   warn sprintf "clientlog [%s/%s]: %s\n", $ns->host, $name, $msg;

   ()
};