--- deliantra/server/lib/cf.pm	2006/02/04 20:38:29	1.3
+++ deliantra/server/lib/cf.pm	2006/08/24 14:05:22	1.37
@@ -2,6 +2,14 @@
 
 use Symbol;
 use List::Util;
+use Storable;
+use Opcode;
+use Safe;
+use Safe::Hole;
+
+use Time::HiRes;
+use Event;
+$Event::Eval = 1; # no idea why this is required, but it is
 
 use strict;
 
@@ -9,6 +17,11 @@
 our @EVENT;
 our %PROP_TYPE;
 our %PROP_IDX;
+our $LIBDIR = maps_directory "perl";
+
+our $TICK = MAX_TIME * 1e-6;
+our $TICK_WATCHER;
+our $NEXT_TICK;
 
 BEGIN {
    @EVENT = map lc, @EVENT;
@@ -23,6 +36,8 @@
    };
 }
 
+my %ignore_set = (MAP_PROP_PATH => 1); # I hate the plug-in api. Deeply!
+
 # generate property mutators
 sub prop_gen {
    my ($prefix, $class) = @_;
@@ -42,7 +57,7 @@
 
       *{"$class\::set_$sub"} = sub {
          $_[0]->set_property ($type, $idx, $_[1]);
-      };
+      } unless $ignore_set{$prop};
    }
 }
 
@@ -57,22 +72,43 @@
 
 # guessed hierarchies
 
-@cf::object::player::ISA = 'cf::object';
-@cf::object::map::ISA    = 'cf::object';
+@ext::cf::object::player::ISA = @cf::object::player::ISA = 'cf::object';
+@ext::cf::object::map::ISA    = @cf::object::map::ISA    = 'cf::object';
 
+# we bless all objects into derived classes to force a method lookup
+# within the Safe compartment.
+for my $pkg (qw(cf::object cf::object::map cf::object::player cf::player cf::map cf::party cf::region cf::arch)) {
+   no strict 'refs';
+   @{"ext::$pkg\::wrap::ISA"} = @{"$pkg\::wrap::ISA"} = $pkg;
+}
+
+$Event::DIED = sub {
+   warn "error in event callback: @_";
+};
+
+my %ext_pkg;
 my @exts;
 my @hook;
 my %command;
+my %extcmd;
 
 sub inject_event {
-   my ($data) = @_;
+   my $extension = shift;
+   my $event_code = shift;
 
-   my $cb = $hook[$data->{event_code}]
+   my $cb = $hook[$event_code]{$extension}
       or return;
 
-   $_->($data) for values %$cb;
+   &$cb
+}
+
+sub inject_global_event {
+   my $event = shift;
+
+   my $cb = $hook[$event]
+      or return;
 
-   ()
+   List::Util::max map &$_, values %$cb
 }
 
 sub inject_command {
@@ -89,15 +125,37 @@
    my ($name, $time, $cb) = @_;
 
    my $caller = caller;
+   #warn "registering command '$name/$time' to '$caller'";
 
    push @{ $command{$name} }, [$time, $cb, $caller];
    $COMMAND{"$name\000"} = List::Util::max map $_->[0], @{ $command{$name} };
 }
 
+sub register_extcmd {
+   my ($name, $cb) = @_;
+
+   my $caller = caller;
+   #warn "registering extcmd '$name' to '$caller'";
+
+   $extcmd{$name} = [$cb, $caller];
+}
+
+sub register {
+   my ($base, $pkg) = @_;
+
+   for my $idx (0 .. $#EVENT) {
+      if (my $ref = $pkg->can ("on_$EVENT[$idx]")) {
+         #warn "registering $EVENT[$idx] hook to '$pkg'\n";
+         $hook[$idx]{$base} = $ref;
+      }
+   }
+}
+
 sub load_extension {
    my ($path) = @_;
 
    $path =~ /([^\/\\]+)\.ext$/ or die "$path";
+   my $base = $1;
    my $pkg = $1;
    $pkg =~ s/[^[:word:]]/_/g;
    $pkg = "cf::ext::$pkg";
@@ -117,17 +175,12 @@
       or die "$path: $@";
 
    push @exts, $pkg;
+   $ext_pkg{$base} = $pkg;
 
-   no strict 'refs';
-
-#   @{"$pkg\::ISA"} = cf::ext::;
+#   no strict 'refs';
+#   @{"$pkg\::ISA"} = ext::;
 
-   for my $idx (0 .. $#EVENT) {
-      if (my $ref = $pkg->can ("on_$EVENT[$idx]")) {
-         warn "registering $EVENT[$idx] hook\n";
-         $hook[$idx]{$pkg} = $ref;
-      }
-   }
+   register $base, $pkg;
 }
 
 sub unload_extension {
@@ -153,6 +206,18 @@
       }
    }
 
+   # remove extcmds
+   for my $name (grep $extcmd{$_}[1] eq $pkg, keys %extcmd) {
+      delete $extcmd{$name};
+   }
+
+   if (my $cb = $pkg->can ("on_unload")) {
+      eval {
+         $cb->($pkg);
+         1
+      } or warn "$pkg unloaded, but with errors: $@";
+   }
+
    Symbol::delete_package $pkg;
 }
 
@@ -168,25 +233,336 @@
    }
 }
 
+sub _perl_reload(&) {
+   my ($msg) = @_;
+
+   $msg->("reloading...");
+
+   eval {
+      # 1. cancel all watchers
+      $_->cancel for Event::all_watchers;
+
+      # 2. unload all extensions
+      for (@exts) {
+         $msg->("unloading <$_>");
+         unload_extension $_;
+      }
+
+      # 3. unload all modules loaded from $LIBDIR
+      while (my ($k, $v) = each %INC) {
+         next unless $v =~ /^\Q$LIBDIR\E\/.*\.pm$/;
+
+         $msg->("removing <$k>");
+         delete $INC{$k};
+
+         $k =~ s/\.pm$//;
+         $k =~ s/\//::/g;
+
+         if (my $cb = $k->can ("unload_module")) {
+            $cb->();
+         }
+
+         Symbol::delete_package $k;
+      }
+
+      # 4. get rid of ext::, as good as possible
+      Symbol::delete_package "ext::$_"
+         for qw(cf::object cf::object::map cf::object::player cf::player cf::map cf::party cf::region);
+
+      # 5. remove register_script_function callbacks
+      # TODO
+      
+      # 6. unload cf.pm "a bit"
+      delete $INC{"cf.pm"};
+
+      # don't, removes xs symbols, too
+      #Symbol::delete_package __PACKAGE__;
+
+      # 7. reload cf.pm
+      $msg->("reloading cf.pm");
+      require cf;
+   };
+   $msg->($@) if $@;
+
+   $msg->("reloaded");
+};
+
+sub perl_reload() {
+   _perl_reload {
+      warn $_[0];
+      print "$_[0]\n";
+   };
+}
+
 register_command "perl-reload", 0, sub {
    my ($who, $arg) = @_;
 
    if ($who->flag (FLAG_WIZ)) {
-      $who->message ("reloading...");
+      _perl_reload {
+         warn $_[0];
+         $who->message ($_[0]);
+      };
+   }
+};
+
+#############################################################################
+# utility functions
 
-      warn "reloading...\n";
-      unload_extension $_ for @exts;
-      @exts = 0;
-      load_extensions;
-      warn "reloaded\n";
+use JSON::Syck (); # TODO# replace by JSON::PC once working
+
+sub from_json($) {
+   $JSON::Syck::ImplicitUnicode = 1; # work around JSON::Syck bugs
+   JSON::Syck::Load $_[0]
+}
 
-      $who->message ("reloaded");
+sub to_json($) {
+   $JSON::Syck::ImplicitUnicode = 0;  # work around JSON::Syck bugs
+   JSON::Syck::Dump $_[0]
+}
+
+#############################################################################
+# extcmd framework, basically convert ext <msg>
+# into pkg::->on_extcmd_arg1 (...) while shortcutting a few
+
+sub on_extcmd {
+   my ($pl, $buf) = @_;
+
+   my $msg = eval { from_json $buf };
+
+   if (ref $msg) {
+      if (my $cb = $extcmd{$msg->{msgtype}}) {
+         if (my %reply = $cb->[0]->($pl, $msg)) {
+            $pl->ext_reply ($msg->{msgid}, %reply);
+         }
+      }
    } else {
-      $who->message ("Intruder Alert!");
+      warn "player " . ($pl->ob->name) . " sent unparseable ext message: <$buf>\n";
    }
+
+   1
+}
+
+#############################################################################
+# load/save/clean perl data associated with a map
+
+*on_mapclean = sub {
+   my ($map) = @_;
+
+   my $path = $map->tmpname;
+   defined $path or return;
+
+   unlink "$path.cfperl";
 };
 
+*on_mapin =
+*on_mapload = sub {
+   my ($map) = @_;
+
+   my $path = $map->tmpname;
+   $path = $map->path unless defined $path;
+
+   open my $fh, "<:raw", "$path.cfperl"
+      or return; # no perl data
+
+   my $data = Storable::thaw do { local $/; <$fh> };
+
+   $data->{version} <= 1
+      or return; # too new
+
+   $map->_set_obs ($data->{obs});
+};
+
+*on_mapout = sub {
+   my ($map) = @_;
+
+   my $path = $map->tmpname;
+   $path = $map->path unless defined $path;
+
+   my $obs = $map->_get_obs;
+
+   if (defined $obs) {
+      open my $fh, ">:raw", "$path.cfperl"
+         or die "$path.cfperl: $!";
+
+      stat $path;
+
+      print $fh Storable::nfreeze {
+         size    => (stat _)[7],
+         time    => (stat _)[9],
+         version => 1,
+         obs     => $obs,
+      };
+
+      chmod SAVE_MODE, "$path.cfperl"; # very racy, but cf-compatible *g*
+   } else {
+      unlink "$path.cfperl";
+   }
+};
+
+#############################################################################
+# load/save perl data associated with player->ob objects
+
+sub all_objects(@) {
+   @_, map all_objects ($_->inv), @_
+}
+
+*on_player_load = sub {
+   my ($ob, $path) = @_;
+
+   for my $o (all_objects $ob) {
+      if (my $value = $o->get_ob_key_value ("_perl_data")) {
+         $o->set_ob_key_value ("_perl_data");
+
+         %$o = %{ Storable::thaw pack "H*", $value };
+      }
+   }
+};
+
+*on_player_save = sub {
+   my ($ob, $path) = @_;
+
+   $_->set_ob_key_value (_perl_data => unpack "H*", Storable::nfreeze $_)
+      for grep %$_, all_objects $ob;
+};
+
+#############################################################################
+# core extensions - in perl
+
+=item cf::player::exists $login
+
+Returns true when the given account exists.
+
+=cut
+
+sub cf::player::exists($) {
+   cf::player::find $_[0]
+      or -f sprintf "%s/%s/%s/%s.pl", cf::localdir, cf::playerdir, ($_[0]) x 2;
+}
+
+=item $player->reply ($npc, $msg[, $flags])
+
+Sends a message to the player, as if the npc C<$npc> replied. C<$npc>
+can be C<undef>. Does the right thing when the player is currently in a
+dialogue with the given NPC character.
+
+=cut
+
+# rough implementation of a future "reply" method that works
+# with dialog boxes.
+sub cf::object::player::reply($$$;$) {
+   my ($self, $npc, $msg, $flags) = @_;
+
+   $flags = cf::NDI_BROWN | cf::NDI_UNIQUE unless @_ >= 4;
+
+   if ($self->{record_replies}) {
+      push @{ $self->{record_replies} }, [$npc, $msg, $flags];
+   } else {
+      $msg = $npc->name . " says: $msg" if $npc;
+      $self->message ($msg, $flags);
+   }
+}
+
+=item $player->ext_reply ($msgid, $msgtype, %msg)
+
+Sends an ext reply to the player.
+
+=cut
+
+sub cf::player::ext_reply($$$%) {
+   my ($self, $id, %msg) = @_;
+
+   $msg{msgid} = $id;
+
+   $self->send ("ext " . to_json \%msg);
+}
+
+#############################################################################
+# map scripting support
+
+our $safe = new Safe "ext";
+our $safe_hole = new Safe::Hole;
+
+$SIG{FPE} = 'IGNORE';
+
+$safe->permit_only (Opcode::opset qw(:base_core :base_mem :base_orig :base_math sort time));
+
+# here we export the classes and methods available to script code
+
+for (
+   ["cf::object"         => qw(contr pay_amount pay_player)],
+   ["cf::object::player" => qw(player)],
+   ["cf::player"         => qw(peaceful)],
+) {
+   no strict 'refs';
+   my ($pkg, @funs) = @$_;
+   *{"ext::$pkg\::$_"} = $safe_hole->wrap (\&{"$pkg\::$_"})
+      for @funs;
+}
+
+sub safe_eval($;@) {
+   my ($code, %vars) = @_;
+
+   my $qcode = $code;
+   $qcode =~ s/"/‟/g; # not allowed in #line filenames
+   $qcode =~ s/\n/\\n/g;
+
+   local $_;
+   local @ext::cf::_safe_eval_args = values %vars;
+
+   $code =
+      "do {\n"
+      . "my (" . (join ",", map "\$$_", keys %vars) . ") = \@cf::_safe_eval_args;\n"
+      . "#line 0 \"{$qcode}\"\n"
+      . $code
+      . "\n}"
+   ;
+
+   sub_generation_inc;
+   my @res = wantarray ? $safe->reval ($code) : scalar $safe->reval ($code);
+   sub_generation_inc;
+
+   wantarray ? @res : $res[0]
+}
+
+sub register_script_function {
+   my ($fun, $cb) = @_;
+
+   no strict 'refs';
+   *{"ext::$fun"} = $safe_hole->wrap ($cb);
+}
+
+#############################################################################
+# the server's main()
+
+sub run {
+   Event::loop;
+}
+
+#############################################################################
+# initialisation
+
+register "<global>", __PACKAGE__;
+
+unshift @INC, $LIBDIR;
+
 load_extensions;
 
+$TICK_WATCHER = Event->timer (
+   prio => 1,
+   at   => $NEXT_TICK || 1,
+   cb   => sub {
+      cf::server_tick; # one server iteration
+
+      my $NOW = Event::time;
+      $NEXT_TICK += $TICK;
+
+      # if we are delayed by four ticks, skip them all
+      $NEXT_TICK = $NOW if $NOW >= $NEXT_TICK + $TICK * 4;
+
+      $TICK_WATCHER->at ($NEXT_TICK);
+      $TICK_WATCHER->start;
+   },
+);
+
 1