package cf;

use Symbol;
use List::Util;
use Storable;

use strict;

our %COMMAND;
our @EVENT;
our %PROP_TYPE;
our %PROP_IDX;

BEGIN {
   @EVENT = map lc, @EVENT;

   *CORE::GLOBAL::warn = sub {
      my $msg = join "", @_;
      $msg .= "\n"
         unless $msg =~ /\n$/;

      print STDERR "cfperl: $msg";
      LOG llevError, "cfperl: $msg";
   };
}

my %ignore_set = (MAP_PROP_PATH => 1); # I hate the plug-in api. Deeply!

# generate property mutators
sub prop_gen {
   my ($prefix, $class) = @_;

   no strict 'refs';

   for my $prop (keys %PROP_TYPE) {
      $prop =~ /^\Q$prefix\E_(.*$)/ or next;
      my $sub = lc $1;

      my $type = $PROP_TYPE{$prop};
      my $idx  = $PROP_IDX {$prop};

      *{"$class\::get_$sub"} = *{"$class\::$sub"} = sub {
         $_[0]->get_property ($type, $idx)
      };

      *{"$class\::set_$sub"} = sub {
         $_[0]->set_property ($type, $idx, $_[1]);
      } unless $ignore_set{$prop};
   }
}

# auto-generate most of the API

prop_gen OBJECT_PROP => "cf::object";
# CFAPI_OBJECT_ANIMATION?
prop_gen PLAYER_PROP => "cf::object::player";

prop_gen MAP_PROP    => "cf::map";
prop_gen ARCH_PROP   => "cf::arch";

# guessed hierarchies

@cf::object::player::ISA = 'cf::object';
@cf::object::map::ISA    = 'cf::object';

my %ext_pkg;
my @exts;
my @hook;
my %command;

sub inject_event {
   my ($data) = @_;

   my $cb = $hook[$data->{event_code}]{$data->{extension}}
      or return;

   $cb->($data)
}

sub inject_global_event {
   my ($data) = @_;

   my $cb = $hook[$data->{event_code}]
      or return;

   List::Util::max map $_->($data), values %$cb
}

sub inject_command {
   my ($name, $obj, $params) = @_;

   for my $cmd (@{ $command{$name} }) {
      $cmd->[1]->($obj, $params);
   }

   -1
}

sub register_command {
   my ($name, $time, $cb) = @_;

   my $caller = caller;

   warn "registering command '$name/$time' to '$caller'";

   push @{ $command{$name} }, [$time, $cb, $caller];
   $COMMAND{"$name\000"} = List::Util::max map $_->[0], @{ $command{$name} };
}

sub register {
   my ($base, $pkg) = @_;

   for my $idx (0 .. $#EVENT) {
      if (my $ref = $pkg->can ("on_$EVENT[$idx]")) {
         warn "registering $EVENT[$idx] hook to '$pkg'\n";
         $hook[$idx]{$base} = $ref;
      }
   }
}

sub load_extension {
   my ($path) = @_;

   $path =~ /([^\/\\]+)\.ext$/ or die "$path";
   my $base = $1;
   my $pkg = $1;
   $pkg =~ s/[^[:word:]]/_/g;
   $pkg = "cf::ext::$pkg";

   warn "loading '$path' into '$pkg'\n";

   open my $fh, "<:utf8", $path
      or die "$path: $!";

   my $source =
      "package $pkg; use strict; use utf8;\n"
      . "#line 1 \"$path\"\n{\n"
      . (do { local $/; <$fh> })
      . "\n};\n1";

   eval $source
      or die "$path: $@";

   push @exts, $pkg;
   $ext_pkg{$base} = $pkg;

#   no strict 'refs';
#   @{"$pkg\::ISA"} = cf::ext::;

   register $base, $pkg;
}

sub unload_extension {
   my ($pkg) = @_;

   warn "removing extension $pkg\n";

   # remove hooks
   for my $idx (0 .. $#EVENT) {
      delete $hook[$idx]{$pkg};
   }

   # remove commands
   for my $name (keys %command) {
      my @cb = grep $_->[2] ne $pkg, @{ $command{$name} };

      if (@cb) {
         $command{$name} = \@cb;
         $COMMAND{"$name\000"} = List::Util::max map $_->[0], @cb;
      } else {
         delete $command{$name};
         delete $COMMAND{"$name\000"};
      }
   }

   Symbol::delete_package $pkg;
}

sub load_extensions {
   my $LIBDIR = maps_directory "perl";

   for my $ext (<$LIBDIR/*.ext>) {
      next unless -r $ext;
      eval {
         load_extension $ext;
         1
      } or warn "$ext not loaded: $@";
   }
}

register_command "perl-reload", 0, sub {
   my ($who, $arg) = @_;

   if ($who->flag (FLAG_WIZ)) {
      $who->message ("reloading...");

      warn "reloading...\n";
      eval {
         unload_extension $_ for @exts;
         delete $INC{"cf.pm"};

         # don't, removes xs symbols, too
         #Symbol::delete_package $pkg;

         require cf;
      };
      warn $@ if $@;
      $who->message ($@) if $@;
      warn "reloaded\n";

      $who->message ("reloaded");
   } else {
      $who->message ("Intruder Alert!");
   }
};

#############################################################################
# load/save/clean perl data associated with a map

*on_mapclean = sub {
   my $map = shift->{map};

   my $path = $map->tmpname;
   defined $path or return;

   unlink "$path.cfperl";
};

*on_mapin =
*on_mapload = sub {
   my $map = shift->{map};

   my $path = $map->tmpname;
   $path = $map->path unless defined $path;

   open my $fh, "<:raw", "$path.cfperl"
      or return; # no perl data

   my $data = Storable::thaw do { local $/; <$fh> };

   $data->{version} <= 1
      or return; # too new

   $map->_set_obs ($data->{obs});
};

*on_mapout = sub {
   my $map = shift->{map};

   my $path = $map->tmpname;
   $path = $map->path unless defined $path;

   my $obs = $map->_get_obs;

   if (defined $obs) {
      open my $fh, ">:raw", "$path.cfperl"
         or die "$path.cfperl: $!";

      stat $path;

      print $fh Storable::nfreeze {
         size    => (stat _)[7],
         time    => (stat _)[9],
         version => 1,
         obs     => $obs,
      };

      chmod SAVE_MODE, "$path.cfperl"; # very racy, but cf-compatible *g*
   } else {
      unlink "$path.cfperl";
   }
};

#############################################################################
# load/save perl data associated with player->ob objects

*on_player_load = sub {
   my ($event) = @_;
   my $path = $event->{message};
   my $ob = $event->{who};

   open my $fh, "<:raw", "$path.cfperl"
      or return; # no perl data

   my $data = Storable::thaw do { local $/; <$fh> };

   $data->{version} <= 1
      or return; # too new

   %$ob = %{$data->{ob}};
};

*on_player_save = sub {
   my ($event) = @_;
   my $path = $event->{message};
   my $ob = $event->{who};

   if (keys %$ob) {
      open my $fh, ">:raw", "$path.cfperl"
         or die "$path.cfperl: $!";

      stat $path;

      print $fh Storable::nfreeze {
         size    => (stat _)[7],
         time    => (stat _)[9],
         version => 1,
         ob      => $ob,
      };

      chmod SAVE_MODE, "$path.cfperl"; # very racy, but cf-compatible *g*
   } else {
      unlink "$path.cfperl";
   }
};

register "<global>", __PACKAGE__;

load_extensions;

1