package cf;

use Symbol;
use List::Util;
use Storable;
use Opcode;
use Safe;
use Safe::Hole;

use Time::HiRes;
use Event;
$Event::Eval = 1; # no idea why this is required, but it is

use strict;

our %COMMAND = ();
our @EVENT;
our @PLUGIN_EVENT;
our %PROP_TYPE;
our %PROP_IDX;
our $LIBDIR = maps_directory "perl";

our $TICK = MAX_TIME * 1e-6;
our $TICK_WATCHER;
our $NEXT_TICK;

BEGIN {
   @PLUGIN_EVENT = map lc, @PLUGIN_EVENT;

   *CORE::GLOBAL::warn = sub {
      my $msg = join "", @_;
      $msg .= "\n"
         unless $msg =~ /\n$/;

      print STDERR "cfperl: $msg";
      LOG llevError, "cfperl: $msg";
   };
}

my %ignore_set = (MAP_PROP_PATH => 1); # I hate the plug-in api. Deeply!

# generate property mutators
sub prop_gen {
   my ($prefix, $class) = @_;

   no strict 'refs';

   for my $prop (keys %PROP_TYPE) {
      $prop =~ /^\Q$prefix\E_(.*$)/ or next;
      my $sub = lc $1;

      my $type = $PROP_TYPE{$prop};
      my $idx  = $PROP_IDX {$prop};

      *{"$class\::get_$sub"} = *{"$class\::$sub"} = sub {
         $_[0]->get_property ($type, $idx)
      };

      *{"$class\::set_$sub"} = sub {
         $_[0]->set_property ($type, $idx, $_[1]);
      } unless $ignore_set{$prop};
   }
}

# auto-generate most of the API

prop_gen OBJECT_PROP => "cf::object";
# CFAPI_OBJECT_ANIMATION?
prop_gen PLAYER_PROP => "cf::object::player";

prop_gen MAP_PROP    => "cf::map";
prop_gen ARCH_PROP   => "cf::arch";

# guessed hierarchies

@safe::cf::object::player::ISA = @cf::object::player::ISA = 'cf::object';
@safe::cf::object::map::ISA    = @cf::object::map::ISA    = 'cf::object';

# we bless all objects into (empty) derived classes to force a method lookup
# within the Safe compartment.
for my $pkg (qw(cf::object cf::object::map cf::object::player cf::player cf::map cf::party cf::region cf::arch)) {
   no strict 'refs';
   @{"safe::$pkg\::wrap::ISA"} = @{"$pkg\::wrap::ISA"} = $pkg;
}

$Event::DIED = sub {
   warn "error in event callback: @_";
};

my %ext_pkg;
my @exts;
my @hook;
my %command;
my %extcmd;

#############################################################################
# "new" plug-in system

=item cf::object::attach ... # NYI

=item cf::attach_global ...

=item cf::attach_to_type ...

=item cf::attach_to_objects ...

=item cf::attach_to_players ...

=item cf::attach_to_maps ...

   prio    => $number, # lower is earlier
   on_xxx  => \&cb,
   package => package::,

=cut

# the following variables are defined in .xs and must not be re-created
our @CB_GLOBAL = (); # registry for all global events
our @CB_OBJECT = ();
our @CB_PLAYER = ();
our @CB_TYPE   = (); # registry for type (cf-object class) based events
our @CB_MAP    = ();

sub _attach_cb($\%$$$) {
   my ($registry, $undo, $event, $prio, $cb) = @_;

   use sort 'stable';

   $cb = [$prio, $cb];

   @{$registry->[$event]} = sort
                           { $a->[0] cmp $b->[0] }
                           @{$registry->[$event] || []}, $cb;

   push @{$undo->{cb}}, [$event, $cb];
}

# attach handles attaching event callbacks
# the only thing the caller has to do is pass the correct
# registry (== where the callback attaches to).
sub _attach(\@$\@) {
   my ($registry, $klass, $arg) = @_;

   my $prio = 0;

   my %undo = (
      registry => $registry,
      cb       => [],
   );

   my %cb_id = map +("on_" . lc $EVENT[$_][0], $_) , grep $EVENT[$_][1] == $klass, 0 .. $#EVENT;

   while (@$arg) {
      my $type = shift @$arg;

      if ($type eq "prio") {
         $prio = shift @$arg;

      } elsif ($type eq "package") {
         my $pkg = shift @$arg;

         while (my ($name, $id) = each %cb_id) {
            if (my $cb = $pkg->can ($name)) {
               _attach_cb $registry, %undo, $id, $prio, $cb;
            }
         }

      } elsif (exists $cb_id{$type}) {
         _attach_cb $registry, %undo, $cb_id{$type}, $prio, shift @$arg;

      } elsif (ref $type) {
         warn "attaching objects not supported, ignoring.\n";

      } else {
         shift @$arg;
         warn "attach argument '$type' not supported, ignoring.\n";
      }
   }

   \%undo
}

sub cf::object::attach {
   die;
}

sub attach_global {
   _attach @CB_GLOBAL, KLASS_GLOBAL, @_
}

sub attach_to_type {
   my $type = shift;
   _attach @{$CB_TYPE[$type]}, KLASS_OBJECT, @_
}

sub attach_to_objects {
   _attach @CB_OBJECT, KLASS_OBJECT, @_
}

sub attach_to_players {
   _attach @CB_PLAYER, KLASS_PLAYER, @_
}

sub attach_to_maps {
   _attach @CB_MAP, KLASS_MAP, @_
}

our $override;

sub override() {
   $override = 1
}

sub invoke {
   my $event = shift;
   my $callbacks = shift;

   local $override;

   for (@$callbacks) {
      eval { &{$_->[1]} };

      if ($@) {
         warn "$@";
         warn "... while processing $EVENT[$event][0] event, skipping processing altogether.\n";
         override;
      }

      return 1 if $override;
   }

   0
}

#############################################################################
# old plug-in events

sub inject_event {
   my $extension = shift;
   my $event_code = shift;

   my $cb = $hook[$event_code]{$extension}
      or return;

   &$cb
}

sub inject_global_event {
   my $event = shift;

   my $cb = $hook[$event]
      or return;

   List::Util::max map &$_, values %$cb
}

sub inject_command {
   my ($name, $obj, $params) = @_;

   for my $cmd (@{ $command{$name} }) {
      $cmd->[1]->($obj, $params);
   }

   -1
}

sub register_command {
   my ($name, $time, $cb) = @_;

   my $caller = caller;
   #warn "registering command '$name/$time' to '$caller'";

   push @{ $command{$name} }, [$time, $cb, $caller];
   $COMMAND{"$name\000"} = List::Util::max map $_->[0], @{ $command{$name} };
}

sub register_extcmd {
   my ($name, $cb) = @_;

   my $caller = caller;
   #warn "registering extcmd '$name' to '$caller'";

   $extcmd{$name} = [$cb, $caller];
}

sub register {
   my ($base, $pkg) = @_;

   for my $idx (0 .. $#PLUGIN_EVENT) {
      if (my $ref = $pkg->can ("on_$PLUGIN_EVENT[$idx]")) {
         #warn "registering $PLUGIN_EVENT[$idx] hook to '$pkg'\n";
         $hook[$idx]{$base} = $ref;
      }
   }
}

sub load_extension {
   my ($path) = @_;

   $path =~ /([^\/\\]+)\.ext$/ or die "$path";
   my $base = $1;
   my $pkg = $1;
   $pkg =~ s/[^[:word:]]/_/g;
   $pkg = "ext::$pkg";

   warn "loading '$path' into '$pkg'\n";

   open my $fh, "<:utf8", $path
      or die "$path: $!";

   my $source =
      "package $pkg; use strict; use utf8;\n"
      . "#line 1 \"$path\"\n{\n"
      . (do { local $/; <$fh> })
      . "\n};\n1";

   eval $source
      or die "$path: $@";

   push @exts, $pkg;
   $ext_pkg{$base} = $pkg;

#   no strict 'refs';
#   @{"$pkg\::ISA"} = ext::;

   register $base, $pkg;
}

sub unload_extension {
   my ($pkg) = @_;

   warn "removing extension $pkg\n";

   # remove hooks
   for my $idx (0 .. $#PLUGIN_EVENT) {
      delete $hook[$idx]{$pkg};
   }

   # remove commands
   for my $name (keys %command) {
      my @cb = grep $_->[2] ne $pkg, @{ $command{$name} };

      if (@cb) {
         $command{$name} = \@cb;
         $COMMAND{"$name\000"} = List::Util::max map $_->[0], @cb;
      } else {
         delete $command{$name};
         delete $COMMAND{"$name\000"};
      }
   }

   # remove extcmds
   for my $name (grep $extcmd{$_}[1] eq $pkg, keys %extcmd) {
      delete $extcmd{$name};
   }

   if (my $cb = $pkg->can ("on_unload")) {
      eval {
         $cb->($pkg);
         1
      } or warn "$pkg unloaded, but with errors: $@";
   }

   Symbol::delete_package $pkg;
}

sub load_extensions {
   my $LIBDIR = maps_directory "perl";

   for my $ext (<$LIBDIR/*.ext>) {
      next unless -r $ext;
      eval {
         load_extension $ext;
         1
      } or warn "$ext not loaded: $@";
   }
}

sub _perl_reload(&) {
   my ($msg) = @_;

   $msg->("reloading...");

   eval {
      # 1. cancel all watchers
      $_->cancel for Event::all_watchers;

      # 2. unload all extensions
      for (@exts) {
         $msg->("unloading <$_>");
         unload_extension $_;
      }

      # 3. unload all modules loaded from $LIBDIR
      while (my ($k, $v) = each %INC) {
         next unless $v =~ /^\Q$LIBDIR\E\/.*\.pm$/;

         $msg->("removing <$k>");
         delete $INC{$k};

         $k =~ s/\.pm$//;
         $k =~ s/\//::/g;

         if (my $cb = $k->can ("unload_module")) {
            $cb->();
         }

         Symbol::delete_package $k;
      }

      # 4. get rid of safe::, as good as possible
      Symbol::delete_package "safe::$_"
         for qw(cf::object cf::object::map cf::object::player cf::player cf::map cf::party cf::region);

      # 5. remove register_script_function callbacks
      # TODO
      
      # 6. unload cf.pm "a bit"
      delete $INC{"cf.pm"};

      # don't, removes xs symbols, too,
      # and global variables created in xs
      #Symbol::delete_package __PACKAGE__;

      # 7. reload cf.pm
      $msg->("reloading cf.pm");
      require cf;
   };
   $msg->($@) if $@;

   $msg->("reloaded");
};

sub perl_reload() {
   _perl_reload {
      warn $_[0];
      print "$_[0]\n";
   };
}

register_command "perl-reload", 0, sub {
   my ($who, $arg) = @_;

   if ($who->flag (FLAG_WIZ)) {
      _perl_reload {
         warn $_[0];
         $who->message ($_[0]);
      };
   }
};

#############################################################################
# utility functions

use JSON::Syck (); # TODO# replace by JSON::PC once working

sub from_json($) {
   $JSON::Syck::ImplicitUnicode = 1; # work around JSON::Syck bugs
   JSON::Syck::Load $_[0]
}

sub to_json($) {
   $JSON::Syck::ImplicitUnicode = 0;  # work around JSON::Syck bugs
   JSON::Syck::Dump $_[0]
}

#############################################################################
# extcmd framework, basically convert ext <msg>
# into pkg::->on_extcmd_arg1 (...) while shortcutting a few

sub on_extcmd {
   my ($pl, $buf) = @_;

   my $msg = eval { from_json $buf };

   if (ref $msg) {
      if (my $cb = $extcmd{$msg->{msgtype}}) {
         if (my %reply = $cb->[0]->($pl, $msg)) {
            $pl->ext_reply ($msg->{msgid}, %reply);
         }
      }
   } else {
      warn "player " . ($pl->ob->name) . " sent unparseable ext message: <$buf>\n";
   }

   1
}

#############################################################################
# load/save/clean perl data associated with a map

*cf::mapsupport::on_clean = sub {
   my ($map) = @_;

   my $path = $map->tmpname;
   defined $path or return;

   unlink "$path.cfperl";
};

*cf::mapsupport::on_swapin =
*cf::mapsupport::on_load = sub {
   my ($map) = @_;

   my $path = $map->tmpname;
   $path = $map->path unless defined $path;

   open my $fh, "<:raw", "$path.cfperl"
      or return; # no perl data

   my $data = Storable::thaw do { local $/; <$fh> };

   $data->{version} <= 1
      or return; # too new

   $map->_set_obs ($data->{obs});
};

*cf::mapsupport::on_swapout = sub {
   my ($map) = @_;

   my $path = $map->tmpname;
   $path = $map->path unless defined $path;

   my $obs = $map->_get_obs;

   if (defined $obs) {
      open my $fh, ">:raw", "$path.cfperl"
         or die "$path.cfperl: $!";

      stat $path;

      print $fh Storable::nfreeze {
         size    => (stat _)[7],
         time    => (stat _)[9],
         version => 1,
         obs     => $obs,
      };

      chmod SAVE_MODE, "$path.cfperl"; # very racy, but cf-compatible *g*
   } else {
      unlink "$path.cfperl";
   }
};

attach_to_maps prio => -10000, package => cf::mapsupport::;

#############################################################################
# load/save perl data associated with player->ob objects

sub all_objects(@) {
   @_, map all_objects ($_->inv), @_
}

attach_to_players
   on_load => sub {
      my ($pl, $path) = @_;

      for my $o (all_objects $pl->ob) {
         if (my $value = $o->get_ob_key_value ("_perl_data")) {
            $o->set_ob_key_value ("_perl_data");

            %$o = %{ Storable::thaw pack "H*", $value };
         }
      }
   },
   on_save => sub {
      my ($pl, $path) = @_;

      $_->set_ob_key_value (_perl_data => unpack "H*", Storable::nfreeze $_)
         for grep %$_, all_objects $pl->ob;
   },
;

#############################################################################
# core extensions - in perl

=item cf::player::exists $login

Returns true when the given account exists.

=cut

sub cf::player::exists($) {
   cf::player::find $_[0]
      or -f sprintf "%s/%s/%s/%s.pl", cf::localdir, cf::playerdir, ($_[0]) x 2;
}

=item $player->reply ($npc, $msg[, $flags])

Sends a message to the player, as if the npc C<$npc> replied. C<$npc>
can be C<undef>. Does the right thing when the player is currently in a
dialogue with the given NPC character.

=cut

# rough implementation of a future "reply" method that works
# with dialog boxes.
sub cf::object::player::reply($$$;$) {
   my ($self, $npc, $msg, $flags) = @_;

   $flags = cf::NDI_BROWN | cf::NDI_UNIQUE unless @_ >= 4;

   if ($self->{record_replies}) {
      push @{ $self->{record_replies} }, [$npc, $msg, $flags];
   } else {
      $msg = $npc->name . " says: $msg" if $npc;
      $self->message ($msg, $flags);
   }
}

=item $player->ext_reply ($msgid, $msgtype, %msg)

Sends an ext reply to the player.

=cut

sub cf::player::ext_reply($$$%) {
   my ($self, $id, %msg) = @_;

   $msg{msgid} = $id;

   $self->send ("ext " . to_json \%msg);
}

#############################################################################
# map scripting support

our $safe = new Safe "ext";
our $safe_hole = new Safe::Hole;

$SIG{FPE} = 'IGNORE';

$safe->permit_only (Opcode::opset qw(:base_core :base_mem :base_orig :base_math sort time));

# here we export the classes and methods available to script code

for (
   ["cf::object"         => qw(contr pay_amount pay_player)],
   ["cf::object::player" => qw(player)],
   ["cf::player"         => qw(peaceful)],
) {
   no strict 'refs';
   my ($pkg, @funs) = @$_;
   *{"safe::$pkg\::$_"} = $safe_hole->wrap (\&{"$pkg\::$_"})
      for @funs;
}

sub safe_eval($;@) {
   my ($code, %vars) = @_;

   my $qcode = $code;
   $qcode =~ s/"/‟/g; # not allowed in #line filenames
   $qcode =~ s/\n/\\n/g;

   local $_;
   local @safe::cf::_safe_eval_args = values %vars;

   $code =
      "do {\n"
      . "my (" . (join ",", map "\$$_", keys %vars) . ") = \@cf::_safe_eval_args;\n"
      . "#line 0 \"{$qcode}\"\n"
      . $code
      . "\n}"
   ;

   sub_generation_inc;
   my @res = wantarray ? $safe->reval ($code) : scalar $safe->reval ($code);
   sub_generation_inc;

   wantarray ? @res : $res[0]
}

sub register_script_function {
   my ($fun, $cb) = @_;

   no strict 'refs';
   *{"safe::$fun"} = $safe_hole->wrap ($cb);
}

#############################################################################
# the server's main()

sub main {
   Event::loop;
}

#############################################################################
# initialisation

register "<global>", __PACKAGE__;

unshift @INC, $LIBDIR;

load_extensions;

$TICK_WATCHER = Event->timer (
   prio => 1,
   at   => $NEXT_TICK || 1,
   cb   => sub {
      cf::server_tick; # one server iteration

      my $NOW = Event::time;
      $NEXT_TICK += $TICK;

      # if we are delayed by four ticks, skip them all
      $NEXT_TICK = $NOW if $NOW >= $NEXT_TICK + $TICK * 4;

      $TICK_WATCHER->at ($NEXT_TICK);
      $TICK_WATCHER->start;
   },
);

1