package cf;

use Symbol;
use List::Util;
use Storable;
use Opcode;
use Safe;
use Safe::Hole;

use Time::HiRes;
use Event;
$Event::Eval = 1; # no idea why this is required, but it is

use strict;

_reload_1;

our %COMMAND = ();
our @EVENT;
our %PROP_TYPE;
our %PROP_IDX;
our $LIBDIR = maps_directory "perl";

our $TICK = MAX_TIME * 1e-6;
our $TICK_WATCHER;
our $NEXT_TICK;

BEGIN {
   *CORE::GLOBAL::warn = sub {
      my $msg = join "", @_;
      $msg .= "\n"
         unless $msg =~ /\n$/;

      print STDERR "cfperl: $msg";
      LOG llevError, "cfperl: $msg";
   };
}

my %ignore_set = (MAP_PROP_PATH => 1); # I hate the plug-in api. Deeply!

# generate property mutators
sub prop_gen {
   my ($prefix, $class) = @_;

   no strict 'refs';

   for my $prop (keys %PROP_TYPE) {
      $prop =~ /^\Q$prefix\E_(.*$)/ or next;
      my $sub = lc $1;

      my $type = $PROP_TYPE{$prop};
      my $idx  = $PROP_IDX {$prop};

      *{"$class\::get_$sub"} = *{"$class\::$sub"} = sub {
         $_[0]->get_property ($type, $idx)
      };

      *{"$class\::set_$sub"} = sub {
         $_[0]->set_property ($type, $idx, $_[1]);
      } unless $ignore_set{$prop};
   }
}

# auto-generate most of the API

prop_gen OBJECT_PROP => "cf::object";
# CFAPI_OBJECT_ANIMATION?
prop_gen PLAYER_PROP => "cf::object::player";

prop_gen MAP_PROP    => "cf::map";
prop_gen ARCH_PROP   => "cf::arch";

@safe::cf::object::player::ISA = @cf::object::player::ISA = 'cf::object';

# we bless all objects into (empty) derived classes to force a method lookup
# within the Safe compartment.
for my $pkg (qw(cf::object cf::object::player cf::player cf::map cf::party cf::region cf::arch cf::living)) {
   no strict 'refs';
   @{"safe::$pkg\::wrap::ISA"} = @{"$pkg\::wrap::ISA"} = $pkg;
}

$Event::DIED = sub {
   warn "error in event callback: @_";
};

my %ext_pkg;
my @exts;
my @hook;
my %command;
my %extcmd;

#############################################################################
# utility functions

use JSON::Syck (); # TODO# replace by JSON::PC once working

sub from_json($) {
   $JSON::Syck::ImplicitUnicode = 1; # work around JSON::Syck bugs
   JSON::Syck::Load $_[0]
}

sub to_json($) {
   $JSON::Syck::ImplicitUnicode = 0;  # work around JSON::Syck bugs
   JSON::Syck::Dump $_[0]
}

#############################################################################
# "new" plug-in system

=head3 EVENTS AND OBJECT ATTACHMENTS

=over 4

=item $object->attach ($attachment, key => $value...)

=item $object->detach ($attachment)

Attach/detach a pre-registered attachment to an object.

=item $player->attach ($attachment, key => $value...)

=item $player->detach ($attachment)

Attach/detach a pre-registered attachment to a player.

=item $map->attach ($attachment, key => $value...)

=item $map->detach ($attachment)

Attach/detach a pre-registered attachment to a map.

=item $bool = $object->attached ($name)

=item $bool = $player->attached ($name)

=item $bool = $map->attached ($name)

Checks wether the named attachment is currently attached to the object.

=item cf::attach_global ...

Attach handlers for global events.

This and all following C<attach_*>-functions expect any number of the
following handler/hook descriptions:

=over 4

=item prio => $number

Set the priority for all following handlers/hooks (unless overwritten
by another C<prio> setting). Lower priority handlers get executed
earlier. The default priority is C<0>, and many built-in handlers are
registered at priority C<-1000>, so lower priorities should not be used
unless you know what you are doing.

=item on_I<event> => \&cb

Call the given code reference whenever the named event happens (event is
something like C<instantiate>, C<apply>, C<use_skill> and so on, and which
handlers are recognised generally depends on the type of object these
handlers attach to).

See F<include/eventinc.h> for the full list of events supported, and their
class.

=item package => package::

Look for sub functions of the name C<< on_I<event> >> in the given
package and register them.  Only handlers for eevents supported by the
object/class are recognised.

=back

=item cf::attach_to_type $object_type, $subtype, ...

Attach handlers for a specific object type (e.g. TRANSPORT) and
subtype. If C<$subtype> is zero or undef, matches all objects of the given
type.

=item cf::attach_to_objects ...

Attach handlers to all objects. Do not use this except for debugging or
very rare events, as handlers are (obviously) called for I<all> objects in
the game.

=item cf::attach_to_players ...

Attach handlers to all players.

=item cf::attach_to_maps ...

Attach handlers to all maps.

=item cf:register_attachment $name, ...

Register an attachment by name through which objects can refer to this
attachment.

=item cf:register_player_attachment $name, ...

Register an attachment by name through which players can refer to this
attachment.

=item cf:register_map_attachment $name, ...

Register an attachment by name through which maps can refer to this
attachment.

=cut

# the following variables are defined in .xs and must not be re-created
our @CB_GLOBAL = (); # registry for all global events
our @CB_OBJECT = (); # all objects (should not be used except in emergency)
our @CB_PLAYER = ();
our @CB_TYPE   = (); # registry for type (cf-object class) based events
our @CB_MAP    = ();

my %attachment;

sub _attach_cb($\%$$$) {
   my ($registry, $undo, $event, $prio, $cb) = @_;

   use sort 'stable';

   $cb = [$prio, $cb];

   @{$registry->[$event]} = sort
                           { $a->[0] cmp $b->[0] }
                           @{$registry->[$event] || []}, $cb;

   push @{$undo->{cb}}, [$event, $cb];
}

# attach handles attaching event callbacks
# the only thing the caller has to do is pass the correct
# registry (== where the callback attaches to).
sub _attach(\@$@) {
   my ($registry, $klass, @arg) = @_;

   my $prio = 0;

   my %undo = (
      registry => $registry,
      cb       => [],
   );

   my %cb_id = map +("on_" . lc $EVENT[$_][0], $_) , grep $EVENT[$_][1] == $klass, 0 .. $#EVENT;

   while (@arg) {
      my $type = shift @arg;

      if ($type eq "prio") {
         $prio = shift @arg;

      } elsif ($type eq "package") {
         my $pkg = shift @arg;

         while (my ($name, $id) = each %cb_id) {
            if (my $cb = $pkg->can ($name)) {
               _attach_cb $registry, %undo, $id, $prio, $cb;
            }
         }

      } elsif (exists $cb_id{$type}) {
         _attach_cb $registry, %undo, $cb_id{$type}, $prio, shift @arg;

      } elsif (ref $type) {
         warn "attaching objects not supported, ignoring.\n";

      } else {
         shift @arg;
         warn "attach argument '$type' not supported, ignoring.\n";
      }
   }

   \%undo
}

sub _attach_attachment {
   my ($obj, $name, %arg) = @_;

   return if exists $obj->{_attachment}{$name};

   my $res;

   if (my $attach = $attachment{$name}) {
      my $registry = $obj->registry;

      for (@$attach) {
         my ($klass, @attach) = @$_;
         $res = _attach @$registry, $klass, @attach;
      }

      $obj->{$name} = \%arg;
   } else {
      warn "object uses attachment '$name' that is not available, postponing.\n";
   }

   $obj->{_attachment}{$name} = undef;

   $res->{attachment} = $name;
   $res
}

*cf::object::attach =
*cf::player::attach =
*cf::map::attach = sub {
   my ($obj, $name, %arg) = @_;

   _attach_attachment $obj, $name, %arg;
};

# all those should be optimised
*cf::object::detach =
*cf::player::detach =
*cf::map::detach = sub {
   my ($obj, $name) = @_;

   delete $obj->{_attachment}{$name};
   reattach ($obj);
};

*cf::object::attached =
*cf::player::attached =
*cf::map::attached = sub {
   my ($obj, $name) = @_;

   exists $obj->{_attachment}{$name}
};

sub attach_global {
   _attach @CB_GLOBAL, KLASS_GLOBAL, @_
}

sub attach_to_type {
   my $type = shift;
   my $subtype = shift;

   _attach @{$CB_TYPE[$type + $subtype * NUM_SUBTYPES]}, KLASS_OBJECT, @_
}

sub attach_to_objects {
   _attach @CB_OBJECT, KLASS_OBJECT, @_
}

sub attach_to_players {
   _attach @CB_PLAYER, KLASS_PLAYER, @_
}

sub attach_to_maps {
   _attach @CB_MAP, KLASS_MAP, @_
}

sub register_attachment {
   my $name = shift;

   $attachment{$name} = [[KLASS_OBJECT, @_]];
}

sub register_player_attachment {
   my $name = shift;

   $attachment{$name} = [[KLASS_PLAYER, @_]];
}

sub register_map_attachment {
   my $name = shift;

   $attachment{$name} = [[KLASS_MAP, @_]];
}

our $override;
our @invoke_results = (); # referenced from .xs code. TODO: play tricks with reify and mortals?

sub override {
   $override = 1;
   @invoke_results = ();
}

sub do_invoke {
   my $event = shift;
   my $callbacks = shift;

   @invoke_results = ();

   local $override;

   for (@$callbacks) {
      eval { &{$_->[1]} };

      if ($@) {
         warn "$@";
         warn "... while processing $EVENT[$event][0] event, skipping processing altogether.\n";
         override;
      }

      return 1 if $override;
   }

   0
}

=item $bool = cf::invoke EVENT_GLOBAL_XXX, ...

=item $bool = $object->invoke (EVENT_OBJECT_XXX, ...)

=item $bool = $player->invoke (EVENT_PLAYER_XXX, ...)

=item $bool = $map->invoke (EVENT_MAP_XXX, ...)

Generate a global/object/player/map-specific event with the given arguments.

This API is preliminary (most likely, the EVENT_KLASS_xxx prefix will be
removed in future versions), and there is no public API to access override
results (if you must, access C<@cf::invoke_results> directly).

=back

=head2 methods valid for all pointers

=over 4

=item $object->valid

=item $player->valid

=item $map->valid

Just because you have a perl object does not mean that the corresponding
C-level object still exists. If you try to access an object that has no
valid C counterpart anymore you get an exception at runtime. This method
can be used to test for existence of the C object part without causing an
exception.

=back

=cut

*cf::object::valid =
*cf::player::valid =
*cf::map::valid = \&cf::_valid;

#############################################################################
# object support

sub instantiate {
   my ($obj, $data) = @_;

   $data = from_json $data;

   for (@$data) {
      my ($name, $args) = @$_;

      $obj->attach ($name, %{$args || {} });
   }
}

# basically do the same as instantiate, without calling instantiate
sub reattach {
   my ($obj) = @_;
   my $registry = $obj->registry;

   @$registry = ();

   delete $obj->{_attachment} unless scalar keys %{ $obj->{_attachment} || {} };

   for my $name (keys %{ $obj->{_attachment} || {} }) {
      if (my $attach = $attachment{$name}) {
         for (@$attach) {
            my ($klass, @attach) = @$_;
            _attach @$registry, $klass, @attach;
         }
      } else {
         warn "object uses attachment '$name' that is not available, postponing.\n";
      }
   }
}

sub object_freezer_save {
   my ($filename, $objs) = @_;

   if (@$objs) {
      open my $fh, ">:raw", "$filename.pst~";
      syswrite $fh, Storable::nfreeze { version => 1, objs => $objs };
      close $fh;
      chmod SAVE_MODE, "$filename.pst~";
      rename "$filename.pst~", "$filename.pst";
   } else {
      unlink "$filename.pst";
   }

   chmod SAVE_MODE, "$filename~";
   rename "$filename~", $filename;
}

sub object_thawer_load {
   my ($filename) = @_;

   open my $fh, "<:raw:perlio", "$filename.pst"
      or return;

   eval { local $/; (Storable::thaw <$fh>)->{objs} }
}

attach_to_objects
   prio     => -1000000,
   on_clone => sub {
      my ($src, $dst) = @_;

      @{$dst->registry} = @{$src->registry};

      %$dst = %$src;

      %{$dst->{_attachment}} = %{$src->{_attachment}}
         if exists $src->{_attachment};
   },
;

#############################################################################
# old plug-in events

sub inject_event {
   my $extension = shift;
   my $event_code = shift;

   my $cb = $hook[$event_code]{$extension}
      or return;

   &$cb
}

sub inject_global_event {
   my $event = shift;

   my $cb = $hook[$event]
      or return;

   List::Util::max map &$_, values %$cb
}

sub inject_command {
   my ($name, $obj, $params) = @_;

   for my $cmd (@{ $command{$name} }) {
      $cmd->[1]->($obj, $params);
   }

   -1
}

sub register_command {
   my ($name, $time, $cb) = @_;

   my $caller = caller;
   #warn "registering command '$name/$time' to '$caller'";

   push @{ $command{$name} }, [$time, $cb, $caller];
   $COMMAND{"$name\000"} = List::Util::max map $_->[0], @{ $command{$name} };
}

sub register_extcmd {
   my ($name, $cb) = @_;

   my $caller = caller;
   #warn "registering extcmd '$name' to '$caller'";

   $extcmd{$name} = [$cb, $caller];
}

sub register {
   my ($base, $pkg) = @_;

   #TODO
}

sub load_extension {
   my ($path) = @_;

   $path =~ /([^\/\\]+)\.ext$/ or die "$path";
   my $base = $1;
   my $pkg = $1;
   $pkg =~ s/[^[:word:]]/_/g;
   $pkg = "ext::$pkg";

   warn "loading '$path' into '$pkg'\n";

   open my $fh, "<:utf8", $path
      or die "$path: $!";

   my $source =
      "package $pkg; use strict; use utf8;\n"
      . "#line 1 \"$path\"\n{\n"
      . (do { local $/; <$fh> })
      . "\n};\n1";

   eval $source
      or die "$path: $@";

   push @exts, $pkg;
   $ext_pkg{$base} = $pkg;

#   no strict 'refs';
#   @{"$pkg\::ISA"} = ext::;

   register $base, $pkg;
}

sub unload_extension {
   my ($pkg) = @_;

   warn "removing extension $pkg\n";

   # remove hooks
   #TODO
#   for my $idx (0 .. $#PLUGIN_EVENT) {
#      delete $hook[$idx]{$pkg};
#   }

   # remove commands
   for my $name (keys %command) {
      my @cb = grep $_->[2] ne $pkg, @{ $command{$name} };

      if (@cb) {
         $command{$name} = \@cb;
         $COMMAND{"$name\000"} = List::Util::max map $_->[0], @cb;
      } else {
         delete $command{$name};
         delete $COMMAND{"$name\000"};
      }
   }

   # remove extcmds
   for my $name (grep $extcmd{$_}[1] eq $pkg, keys %extcmd) {
      delete $extcmd{$name};
   }

   if (my $cb = $pkg->can ("unload")) {
      eval {
         $cb->($pkg);
         1
      } or warn "$pkg unloaded, but with errors: $@";
   }

   Symbol::delete_package $pkg;
}

sub load_extensions {
   my $LIBDIR = maps_directory "perl";

   for my $ext (<$LIBDIR/*.ext>) {
      next unless -r $ext;
      eval {
         load_extension $ext;
         1
      } or warn "$ext not loaded: $@";
   }
}

sub _perl_reload(&) {
   my ($msg) = @_;

   $msg->("reloading...");

   eval {
      # 1. cancel all watchers
      $_->cancel for Event::all_watchers;

      # 2. unload all extensions
      for (@exts) {
         $msg->("unloading <$_>");
         unload_extension $_;
      }

      # 3. unload all modules loaded from $LIBDIR
      while (my ($k, $v) = each %INC) {
         next unless $v =~ /^\Q$LIBDIR\E\/.*\.pm$/;

         $msg->("removing <$k>");
         delete $INC{$k};

         $k =~ s/\.pm$//;
         $k =~ s/\//::/g;

         if (my $cb = $k->can ("unload_module")) {
            $cb->();
         }

         Symbol::delete_package $k;
      }

      # 4. get rid of safe::, as good as possible
      Symbol::delete_package "safe::$_"
         for qw(cf::object cf::object::player cf::player cf::map cf::party cf::region);

      # 5. remove register_script_function callbacks
      # TODO
      
      # 6. unload cf.pm "a bit"
      delete $INC{"cf.pm"};

      # don't, removes xs symbols, too,
      # and global variables created in xs
      #Symbol::delete_package __PACKAGE__;

      # 7. reload cf.pm
      $msg->("reloading cf.pm");
      require cf;
   };
   $msg->($@) if $@;

   $msg->("reloaded");
};

sub perl_reload() {
   _perl_reload {
      warn $_[0];
      print "$_[0]\n";
   };
}

register_command "perl-reload", 0, sub {
   my ($who, $arg) = @_;

   if ($who->flag (FLAG_WIZ)) {
      _perl_reload {
         warn $_[0];
         $who->message ($_[0]);
      };
   }
};

#############################################################################
# extcmd framework, basically convert ext <msg>
# into pkg::->on_extcmd_arg1 (...) while shortcutting a few

attach_to_players
   on_extcmd => sub {
      my ($pl, $buf) = @_;

      my $msg = eval { from_json $buf };

      if (ref $msg) {
         if (my $cb = $extcmd{$msg->{msgtype}}) {
            if (my %reply = $cb->[0]->($pl, $msg)) {
               $pl->ext_reply ($msg->{msgid}, %reply);
            }
         }
      } else {
         warn "player " . ($pl->ob->name) . " sent unparseable ext message: <$buf>\n";
      }

      cf::override;
   },
;

#############################################################################
# load/save/clean perl data associated with a map

*cf::mapsupport::on_clean = sub {
   my ($map) = @_;

   my $path = $map->tmpname;
   defined $path or return;

   unlink "$path.pst";
};

# old style persistent data, TODO: remove #d#
*cf::mapsupport::on_swapin = sub {
   my ($map) = @_;

   my $path = $map->tmpname;
   $path = $map->path unless defined $path;

   warn "$path.cfperl\n";#d#

   open my $fh, "<:raw", "$path.cfperl"
      or return; # no perl data

   my $data = Storable::thaw do { local $/; <$fh> };

   $data->{version} <= 1
      or return; # too new

   $map->_set_obs ($data->{obs});
   $map->invoke (EVENT_MAP_UPGRADE);
};

attach_to_maps prio => -10000, package => cf::mapsupport::;

#############################################################################
# load/save perl data associated with player->ob objects

sub all_objects(@) {
   @_, map all_objects ($_->inv), @_
}

attach_to_players
   on_load => sub {
      my ($pl, $path) = @_;

      for my $o (all_objects $pl->ob) {
         if (my $value = $o->get_ob_key_value ("_perl_data")) {
            $o->set_ob_key_value ("_perl_data");

            %$o = %{ Storable::thaw pack "H*", $value };
         }
      }
   },
;

#############################################################################
# core extensions - in perl

=item cf::player::exists $login

Returns true when the given account exists.

=cut

sub cf::player::exists($) {
   cf::player::find $_[0]
      or -f sprintf "%s/%s/%s/%s.pl", cf::localdir, cf::playerdir, ($_[0]) x 2;
}

=item $player->reply ($npc, $msg[, $flags])

Sends a message to the player, as if the npc C<$npc> replied. C<$npc>
can be C<undef>. Does the right thing when the player is currently in a
dialogue with the given NPC character.

=cut

# rough implementation of a future "reply" method that works
# with dialog boxes.
sub cf::object::player::reply($$$;$) {
   my ($self, $npc, $msg, $flags) = @_;

   $flags = cf::NDI_BROWN | cf::NDI_UNIQUE unless @_ >= 4;

   if ($self->{record_replies}) {
      push @{ $self->{record_replies} }, [$npc, $msg, $flags];
   } else {
      $msg = $npc->name . " says: $msg" if $npc;
      $self->message ($msg, $flags);
   }
}

=item $player->ext_reply ($msgid, $msgtype, %msg)

Sends an ext reply to the player.

=cut

sub cf::player::ext_reply($$$%) {
   my ($self, $id, %msg) = @_;

   $msg{msgid} = $id;

   $self->send ("ext " . to_json \%msg);
}

#############################################################################
# map scripting support

our $safe = new Safe "safe";
our $safe_hole = new Safe::Hole;

$SIG{FPE} = 'IGNORE';

$safe->permit_only (Opcode::opset qw(:base_core :base_mem :base_orig :base_math sort time));

# here we export the classes and methods available to script code

for (
   ["cf::object"         => qw(contr pay_amount pay_player)],
   ["cf::object::player" => qw(player)],
   ["cf::player"         => qw(peaceful)],
) {
   no strict 'refs';
   my ($pkg, @funs) = @$_;
   *{"safe::$pkg\::$_"} = $safe_hole->wrap (\&{"$pkg\::$_"})
      for @funs;
}

sub safe_eval($;@) {
   my ($code, %vars) = @_;

   my $qcode = $code;
   $qcode =~ s/"/‟/g; # not allowed in #line filenames
   $qcode =~ s/\n/\\n/g;

   local $_;
   local @safe::cf::_safe_eval_args = values %vars;

   my $eval =
      "do {\n"
      . "my (" . (join ",", map "\$$_", keys %vars) . ") = \@cf::_safe_eval_args;\n"
      . "#line 0 \"{$qcode}\"\n"
      . $code
      . "\n}"
   ;

   sub_generation_inc;
   my @res = wantarray ? $safe->reval ($eval) : scalar $safe->reval ($eval);
   sub_generation_inc;

   if ($@) {
      warn "$@";
      warn "while executing safe code '$code'\n";
      warn "with arguments " . (join " ", %vars) . "\n";
   }

   wantarray ? @res : $res[0]
}

sub register_script_function {
   my ($fun, $cb) = @_;

   no strict 'refs';
   *{"safe::$fun"} = $safe_hole->wrap ($cb);
}

#############################################################################
# the server's main()

sub main {
   Event::loop;
}

#############################################################################
# initialisation

register "<global>", __PACKAGE__;

unshift @INC, $LIBDIR;

load_extensions;

$TICK_WATCHER = Event->timer (
   prio => 1,
   at   => $NEXT_TICK || 1,
   cb   => sub {
      cf::server_tick; # one server iteration

      my $NOW = Event::time;
      $NEXT_TICK += $TICK;

      # if we are delayed by four ticks, skip them all
      $NEXT_TICK = $NOW if $NOW >= $NEXT_TICK + $TICK * 4;

      $TICK_WATCHER->at ($NEXT_TICK);
      $TICK_WATCHER->start;
   },
);

_reload_2;

1