1 |
#!@PERL@ |
2 |
|
3 |
use strict; |
4 |
|
5 |
my $prefix = "@prefix@"; |
6 |
my $exec_prefix = "@exec_prefix@"; |
7 |
my $datarootdir = "@datarootdir@"; |
8 |
my $DATADIR = "@datadir@/@PACKAGE@"; |
9 |
|
10 |
my $CONVERT = "@CONVERT@"; |
11 |
#my $IDENTIFY = "@IDENTIFY@"; |
12 |
my $OPTIPNG = "@OPTIPNG@"; |
13 |
my $RSYNC = "@RSYNC@"; |
14 |
my $PNGNQ = "@PNGNQ@"; |
15 |
|
16 |
use Getopt::Long; |
17 |
use Coro::Event; |
18 |
use AnyEvent; |
19 |
use YAML::Syck (); |
20 |
use JSON::XS (); |
21 |
use IO::AIO (); |
22 |
use File::Temp; |
23 |
use Crossfire; |
24 |
use Coro; |
25 |
use Coro::AIO; |
26 |
use Coro::Util; |
27 |
use POSIX (); |
28 |
use Carp; |
29 |
use Coro::Channel; |
30 |
use Coro::Storable; $Storable::canonical = 1; |
31 |
|
32 |
$SIG{QUIT} = sub { Carp::cluck "QUIT" }; |
33 |
|
34 |
sub usage { |
35 |
warn <<EOF; |
36 |
Usage: cfutil [-v] [-q] [--force] [--cache] |
37 |
[--install-arch path] |
38 |
[--install-maps maps] |
39 |
[--print-statedir] |
40 |
[--print-confdir] |
41 |
[--print-datadir] |
42 |
[--print-libdir] |
43 |
[--print-bindir] |
44 |
EOF |
45 |
exit 1; |
46 |
} |
47 |
|
48 |
my $VERBOSE = 1; |
49 |
my $CACHE = 0; |
50 |
my $FORCE; |
51 |
my $TMPDIR = "/tmp/cfutil$$~"; |
52 |
my $TMPFILE = "aaaa0"; |
53 |
|
54 |
our %COLOR = ( |
55 |
black => 0, |
56 |
white => 1, |
57 |
navy => 2, |
58 |
red => 3, |
59 |
orange => 4, |
60 |
blue => 5, |
61 |
darkorange => 6, |
62 |
green => 7, |
63 |
lightgreen => 8, |
64 |
grey => 9, |
65 |
brown => 10, |
66 |
gold => 11, |
67 |
tan => 12, |
68 |
); |
69 |
|
70 |
END { system "rm", "-rf", $TMPDIR } |
71 |
|
72 |
Event->signal (signal => "INT", cb => sub { exit 1 }); |
73 |
Event->signal (signal => "TERM", cb => sub { exit 1 }); |
74 |
|
75 |
mkdir $TMPDIR, 0700 |
76 |
or die "$TMPDIR: $!"; |
77 |
|
78 |
sub fork_sub(&) { |
79 |
my ($cb) = @_; |
80 |
|
81 |
if (my $pid = fork) { |
82 |
my $current = $Coro::current; |
83 |
my $w = AnyEvent->child (pid => $pid, cb => sub { $current->ready }); |
84 |
Coro::schedule; |
85 |
} else { |
86 |
eval { $cb->() }; |
87 |
POSIX::_exit 0 unless $@; |
88 |
warn $@; |
89 |
POSIX::_exit 1; |
90 |
} |
91 |
} |
92 |
|
93 |
sub inst_maps($) { |
94 |
my (undef, $path) = @_; |
95 |
|
96 |
print "\nInstalling '$path' to '$DATADIR/maps'\n\n"; |
97 |
|
98 |
if (!-f "$path/regions") { |
99 |
warn "'$path' does not look like a maps directory ('regions' file is missing).\n"; |
100 |
exit 1 unless $FORCE; |
101 |
} |
102 |
|
103 |
system $RSYNC, "-av", "--chmod=u=rwX,go=rX", |
104 |
"$path/.", "$DATADIR/maps/.", |
105 |
"--exclude", "CVS", "--exclude", "/world-precomposed", |
106 |
"--delete", "--delete-excluded" |
107 |
and die "map installation failed.\n"; |
108 |
|
109 |
print "maps installed successfully.\n"; |
110 |
} |
111 |
|
112 |
{ |
113 |
our %ANIMINFO; |
114 |
our %FACEINFO; |
115 |
our %RESOURCE; |
116 |
our @ARC; |
117 |
our %ARC; |
118 |
our $TRS; |
119 |
our $NFILE; |
120 |
our $PATH; |
121 |
|
122 |
our $QUANTIZE = "+dither -colorspace RGB -colors 256"; |
123 |
|
124 |
our $c_arc = new Coro::Channel; |
125 |
our $c_trs = new Coro::Channel; |
126 |
our $c_res = new Coro::Channel; |
127 |
|
128 |
our @c_png; |
129 |
|
130 |
sub commit_png($$$) { |
131 |
my ($name, $data, $T) = @_; |
132 |
|
133 |
$FACEINFO{$name}{"data$T"} = $data; |
134 |
} |
135 |
|
136 |
sub process_png { |
137 |
while (@c_png) { |
138 |
my ($path, $delete) = @{pop @c_png}; |
139 |
|
140 |
my $png; |
141 |
aio_lstat $path; |
142 |
my ($size, $mtime) = (stat _)[7,9]; |
143 |
|
144 |
if (0 > aio_load $path, $png) { |
145 |
warn "$path: $!, skipping.\n"; |
146 |
next; |
147 |
} |
148 |
|
149 |
my $stem = $path; |
150 |
my $T; |
151 |
|
152 |
if ($stem =~ s/\.32x32\.png~?$//) { |
153 |
$T = 32; |
154 |
} elsif ($stem =~ s/\.64x64\.png~?$//) { |
155 |
$T = 64; |
156 |
} else { |
157 |
warn "$path: weird filename, skipping.\n"; |
158 |
next; |
159 |
} |
160 |
|
161 |
# quickly extract width and height of the (necessarily PNG) image |
162 |
unless ($png =~ /^\x89PNG\x0d\x0a\x1a\x0a....IHDR(........)/s) { |
163 |
warn "$path: not a recognized png file, skipping.\n"; |
164 |
next; |
165 |
} |
166 |
|
167 |
my ($w, $h) = unpack "NN", $1; |
168 |
|
169 |
if ($w < $T || $h < $T) { |
170 |
warn "$path: too small ($w $h), skipping.\n"; |
171 |
next; |
172 |
} |
173 |
|
174 |
if ($w % $T || $h % $T) { |
175 |
warn "$path: weird png size ($w $h), skipping.\n"; |
176 |
next; |
177 |
} |
178 |
|
179 |
(my $base = $stem) =~ s/^.*\///; |
180 |
|
181 |
my $fi = $FACEINFO{$base}; |
182 |
unless ($fi) { |
183 |
#warn "$path: <$base> not referenced by any archetype, skipping.\n"; |
184 |
#next; |
185 |
} |
186 |
|
187 |
my $arc = $fi->{arc} || { }; |
188 |
|
189 |
unless ($path =~ /~$/) { |
190 |
# possibly enlarge |
191 |
if (0 > aio_stat "$stem.64x64.png") { |
192 |
my $other = "$stem.64x64.png~"; |
193 |
|
194 |
if (0 > aio_lstat $other or (-M _) > (-M $path)) { |
195 |
fork_sub { |
196 |
my $CROP; |
197 |
my $SRC = "png:\Q$path\E"; |
198 |
|
199 |
my $is_floor = $arc->{is_floor}; |
200 |
my $is_wall = 0; |
201 |
|
202 |
my ($wall_pfx, $wall_dir, $wall_sfx); |
203 |
|
204 |
if ( |
205 |
!$is_floor |
206 |
&& !$arc->{alive} |
207 |
&& $arc->{move_block} eq "all" |
208 |
&& $path =~ /^(.*_)([0-9A-F])(\.x11.*\.png)$/ |
209 |
) { |
210 |
($wall_pfx, $wall_dir, $wall_sfx) = ($1, hex $2, $3); |
211 |
|
212 |
unless (grep { !-e sprintf "%s%X%s", $wall_pfx, $_, $wall_sfx } 0..15) { |
213 |
$is_wall = 1; |
214 |
} |
215 |
} |
216 |
|
217 |
if ($is_wall || $is_floor) { |
218 |
# add a 4px border and add other images around it |
219 |
$CROP = "-shave 8x8 +repage"; |
220 |
|
221 |
$w += 8; |
222 |
$h += 8; |
223 |
|
224 |
$SRC = "-size ${w}x${h} xc:transparent"; |
225 |
$SRC .= " png:\Q$path\E -geometry +4+4 -composite"; |
226 |
|
227 |
# 8 surrounding images |
228 |
for ( |
229 |
# x y b r0 r1 |
230 |
[-1, -1, 0, 6], |
231 |
[ 0, -1, 1, 10, 14], |
232 |
[+1, -1, 0, 12], |
233 |
|
234 |
[-1, 0, 8, 5, 7], |
235 |
# |
236 |
[+1, 0, 2, 5, 13], |
237 |
|
238 |
[-1, +1, 0, 3], |
239 |
[ 0, +1, 4, 10, 11], |
240 |
[+1, +1, 0, 9], |
241 |
) { |
242 |
my ($x, $y, $d, $r0, $r1) = @$_; |
243 |
|
244 |
my $tile = $is_floor ? $path |
245 |
: $is_wall ? sprintf "%s%X%s", $wall_pfx, ($wall_dir & $d) ? $r1 : $r0, $wall_sfx |
246 |
: die; |
247 |
|
248 |
$SRC .= sprintf " png:%s -geometry %+d%+d -composite", |
249 |
"\Q$tile", |
250 |
$x * ($w - 8) + 4, |
251 |
$y * ($h - 8) + 4; |
252 |
} |
253 |
} |
254 |
|
255 |
system "convert -depth 8 $SRC rgba:-" |
256 |
. "| $exec_prefix/bin/cfhq2xa $w $h 0" |
257 |
. "| convert -depth 8 -size ".($w * 2)."x".($h * 2)." rgba:- $CROP $QUANTIZE -quality 00 png32:\Q$other\E~" |
258 |
and die "convert/cfhq2xa pipeline error: status $? ($!)"; |
259 |
system $OPTIPNG, "-i0", "-q", "$other~"; |
260 |
die "$other~ has zero size, aborting." unless -s "$other~"; |
261 |
rename "$other~", $other; |
262 |
}; |
263 |
} |
264 |
|
265 |
push @c_png, [$other, !$CACHE]; |
266 |
} |
267 |
|
268 |
# possibly scale down |
269 |
if (0 > aio_stat "$stem.32x32.png") { |
270 |
my $other = "$stem.32x32.png~"; |
271 |
|
272 |
if (0 > aio_lstat $other or (-M _) > (-M $path)) { |
273 |
fork_sub { |
274 |
system "convert png:\Q$path\E -geometry 50% -filter lanczos $QUANTIZE -quality 00 png32:\Q$other\E~"; |
275 |
system $OPTIPNG, "-i0", "-q", "$other~"; |
276 |
|
277 |
# reduce smoothfaces >10000 bytes |
278 |
if ($stem =~ /_S\./ && (-s "$other~") > 10000) { |
279 |
my $ncolor = 256; |
280 |
while () { |
281 |
system "<\Q$other~\E $PNGNQ -s1 -n$ncolor >\Q$other~~\E"; |
282 |
system $OPTIPNG, "-i0", "-q", "$other~~"; |
283 |
last if 10000 > -s "$other~~"; |
284 |
$ncolor = int $ncolor * 0.9; |
285 |
$ncolor > 8 or die "cannot reduce filesize to < 10000 bytes"; |
286 |
} |
287 |
|
288 |
printf "reduced %s from %d to %d bytes using %d colours.\n", |
289 |
$other, -s "$other~", -s "$other~~", $ncolor |
290 |
if $VERBOSE >= 2; |
291 |
rename "$other~~", "$other~"; |
292 |
} |
293 |
|
294 |
die "$other~ has zero size, aborting." unless -s "$other~"; |
295 |
rename "$other~", $other; |
296 |
}; |
297 |
} |
298 |
|
299 |
#warn "scaled down $path to $other\n";#d# |
300 |
push @c_png, [$other, !$CACHE]; |
301 |
} |
302 |
} |
303 |
|
304 |
(my $face = $stem) =~ s/^.*\///; |
305 |
|
306 |
# split all bigfaces, but avoid smoothfaces (*_S) |
307 |
if (($w > $T || $h > $T) && $face !~ /_S\./) { |
308 |
# split |
309 |
my @tile; |
310 |
for my $x (0 .. (int $w / $T) - 1) { |
311 |
for my $y (0 .. (int $h / $T) - 1) { |
312 |
my $file = "$path+$x+$y~"; |
313 |
aio_lstat $file; |
314 |
push @tile, [$x, $y, $file, (stat _)[9]]; |
315 |
} |
316 |
} |
317 |
|
318 |
my $mtime = (lstat $path)[9]; |
319 |
my @todo = grep { $_->[3] <= $mtime } @tile; |
320 |
if (@todo) { |
321 |
fork_sub { |
322 |
open my $convert, "|-", $CONVERT, |
323 |
"png:-", |
324 |
(map { |
325 |
( |
326 |
"(", |
327 |
"+clone", |
328 |
-crop => (sprintf "%dx%d+%d+%d", $T, $T, $_->[0] * $T, $_->[1] * $T), |
329 |
"+repage", |
330 |
-quality => "00", |
331 |
-write => "png32:$_->[2]~", |
332 |
"+delete", |
333 |
")", |
334 |
) |
335 |
} @todo), |
336 |
"null:"; |
337 |
|
338 |
binmode $convert; |
339 |
print $convert $png; |
340 |
close $convert; |
341 |
|
342 |
# pass 2, optimise, and rename |
343 |
for (@todo) { |
344 |
system $OPTIPNG, "-o5", "-i0", "-q", "$_->[2]~"; |
345 |
die "$_->[2]~ has zero size, aborting." unless -s "$_->[2]~"; |
346 |
rename "$_->[2]~", $_->[2]; |
347 |
} |
348 |
}; |
349 |
} |
350 |
|
351 |
for (@tile) { |
352 |
my ($x, $y, $file) = @$_; |
353 |
my $tile; |
354 |
|
355 |
if (0 > aio_load $file, $tile) { |
356 |
die "$path: unable to read tile +$x+$y, aborting.\n"; |
357 |
} |
358 |
IO::AIO::aio_unlink $file unless $CACHE; |
359 |
commit_png $x|$y ? "$face+$x+$y" : $face, $tile, $T; |
360 |
} |
361 |
} else { |
362 |
# use as-is (either small, use smooth) |
363 |
commit_png $face, $png, $T; |
364 |
} |
365 |
|
366 |
aio_unlink $path if $delete; |
367 |
} |
368 |
} |
369 |
|
370 |
sub process_arc { |
371 |
while (my $job = $c_arc->get) { |
372 |
my ($dir, $file) = @$job; |
373 |
|
374 |
my $arc; |
375 |
aio_load "$dir/$file", $arc; # simply pre-cache, as read_arch wants a file :/ |
376 |
|
377 |
my $arc = read_arch "$dir/$file"; |
378 |
for my $o (values %$arc) { |
379 |
push @ARC, $o; |
380 |
for (my $m = $o; $m; $m = $m->{more}) { |
381 |
$ARC{$m->{_name}} = $m; |
382 |
} |
383 |
|
384 |
$o->{editor_folder} = $dir; |
385 |
|
386 |
my $visibility = delete $o->{visibility}; |
387 |
my $magicmap = delete $o->{magicmap}; |
388 |
|
389 |
# find upper left corner :/ |
390 |
# omg, this is sooo broken |
391 |
my ($dx, $dy); |
392 |
for (my $o = $o; $o; $o = $o->{more}) { |
393 |
$dx = $o->{x} if $o->{x} < $dx; |
394 |
$dy = $o->{y} if $o->{y} < $dy; |
395 |
} |
396 |
|
397 |
for (my $o = $o; $o; $o = $o->{more}) { |
398 |
my $x = $o->{x} - $dx; |
399 |
my $y = $o->{y} - $dy; |
400 |
|
401 |
my $ext = $x|$y ? "+$x+$y" : ""; |
402 |
|
403 |
$o->{face} .= $ext unless /^blank.x11$|^empty.x11$/ || !$o->{face}; |
404 |
|
405 |
$visibility = delete $o->{visibility} if exists $o->{visibility}; |
406 |
$magicmap = delete $o->{magicmap} if exists $o->{magicmap}; |
407 |
|
408 |
my $anim = delete $o->{anim}; |
409 |
|
410 |
if ($anim) { |
411 |
# possibly add $ext to the animation name to avoid |
412 |
# the need to specify archnames for all parts |
413 |
# of a multipart archetype. |
414 |
$o->{animation} = "$o->{_name}"; |
415 |
my $facings = 1; |
416 |
my @frames; |
417 |
|
418 |
for (@$anim) { |
419 |
if (/^facings\s+(\d+)/) { |
420 |
$facings = $1*1; |
421 |
} elsif (/^blank.x11$|^empty.x11$/) { |
422 |
push @frames, $_; |
423 |
} else { |
424 |
push @frames, "$_$ext"; |
425 |
} |
426 |
} |
427 |
|
428 |
$ANIMINFO{$o->{animation}} = { |
429 |
facings => $facings, |
430 |
frames => \@frames, |
431 |
}; |
432 |
} |
433 |
|
434 |
for ($o->{face} || (), @{$anim || []}) { |
435 |
next if /^facings\s/; |
436 |
|
437 |
my $face = $_; |
438 |
$face =~ s/\+\d+\+\d+$//; # remove tile offset coordinates |
439 |
|
440 |
my $info = $FACEINFO{$face} ||= { }; |
441 |
$info->{arc} = $o; |
442 |
|
443 |
next if $face =~ /^blank.x11$|^empty.x11$/; |
444 |
|
445 |
$info->{visibility} = $visibility if defined $visibility; |
446 |
$info->{magicmap} = $magicmap if defined $magicmap; |
447 |
} |
448 |
|
449 |
if (my $smooth = delete $o->{smoothface}) { |
450 |
my %kv = split /\s+/, $smooth; |
451 |
my $level = $o->{smoothlevel}; #TODO: delete from $o if !gcfclient-support |
452 |
while (my ($face, $smooth) = each %kv) { |
453 |
$FACEINFO{$smooth}{arc} = $o; |
454 |
|
455 |
$FACEINFO{$face}{smooth} = $smooth; |
456 |
$FACEINFO{$face}{smoothlevel} = $level; |
457 |
} |
458 |
} |
459 |
} |
460 |
} |
461 |
} |
462 |
} |
463 |
|
464 |
sub process_trs { |
465 |
while (my $job = $c_trs->get) { |
466 |
my ($dir, $file) = @$job; |
467 |
my $path = "$dir/$file"; |
468 |
|
469 |
my $trs; |
470 |
if (0 > aio_load $path, $trs) { |
471 |
warn "$path: $!, skipping.\n"; |
472 |
next; |
473 |
} |
474 |
|
475 |
$TRS .= $trs; |
476 |
} |
477 |
} |
478 |
|
479 |
my %FILECACHE; |
480 |
|
481 |
sub load_cached($;$) { |
482 |
unless (exists $FILECACHE{$_[0]}) { |
483 |
my $data; |
484 |
if (0 < aio_load $_[0], $data) { |
485 |
if ($_[1]) { |
486 |
$data = eval { $_[1]->($data) }; |
487 |
warn "$_[0]: $@" if $@; |
488 |
} |
489 |
} |
490 |
|
491 |
$FILECACHE{$_[0]} = $data; |
492 |
} |
493 |
|
494 |
$FILECACHE{$_[0]} |
495 |
} |
496 |
|
497 |
sub process_res { |
498 |
while (my $job = $c_res->get) { |
499 |
my ($dir, $file, $type) = @$job; |
500 |
|
501 |
my $data; |
502 |
aio_load "$dir/$file", $data; |
503 |
|
504 |
my $meta = load_cached "$dir/meta", sub { JSON::XS->new->utf8->relaxed->decode (shift) }; |
505 |
|
506 |
utf8::decode $dir; |
507 |
utf8::decode $file; |
508 |
|
509 |
# a meta file for resources is now mandatory |
510 |
unless (exists $meta->{$file}) { |
511 |
warn "skipping $dir/$file\n" if $VERBOSE >= 3; |
512 |
} |
513 |
|
514 |
$meta = { |
515 |
%{ $meta->{"" } || {} }, |
516 |
%{ $meta->{$file} || {} }, |
517 |
}; |
518 |
|
519 |
if ($meta->{license} =~ s/^#//) { |
520 |
$meta->{license} = ({ |
521 |
"pd" => "Public Domain", |
522 |
"gpl" => "GNU General Public License, version 3.0 or any later", |
523 |
"cc/by/2.0" => "Licensed under Creative Commons Attribution 2.0 http://creativecommons.org/licenses/by/2.0/", |
524 |
"cc/by/2.5" => "Licensed under Creative Commons Attribution 2.5 http://creativecommons.org/licenses/by/2.5/", |
525 |
"cc/by/3.0" => "Licensed under Creative Commons Attribution 3.0 http://creativecommons.org/licenses/by/3.0/", |
526 |
})->{$meta->{license}} |
527 |
|| warn "$dir/$file: license tag '$meta->{license}' not found."; |
528 |
} |
529 |
|
530 |
$file =~ s/\.res$//; |
531 |
$file =~ s/\.(ogg|wav|jpg|png)$//; |
532 |
|
533 |
substr $dir, 0, 1 + length $PATH, ""; |
534 |
|
535 |
if (my $filter = $meta->{cfutil_filter}) { |
536 |
if ($filter eq "yaml2json") { |
537 |
$data = JSON::XS::encode_json YAML::Syck::Load $data; |
538 |
} else { |
539 |
warn "$dir/$file: unknown filter $filter, skipping\n"; |
540 |
} |
541 |
} |
542 |
|
543 |
$RESOURCE{"$dir/$file"} = { |
544 |
type => (exists $meta->{type} ? delete $meta->{type} : $type), |
545 |
data => $data, |
546 |
%$meta ? (meta => $meta) : (), |
547 |
}; |
548 |
} |
549 |
} |
550 |
|
551 |
sub find_files; |
552 |
sub find_files { |
553 |
my ($path) = @_; |
554 |
|
555 |
IO::AIO::aioreq_pri 4; |
556 |
IO::AIO::aio_scandir $path, 4, sub { |
557 |
my ($dirs, $nondirs) = @_; |
558 |
|
559 |
find_files "$path/$_" |
560 |
for grep $_ !~ /^(?:CVS|dev)$/, @$dirs; |
561 |
|
562 |
my $dir = $path; |
563 |
substr $dir, 0, 1 + length $PATH, ""; |
564 |
|
565 |
for my $file (@$nondirs) { |
566 |
if ($dir =~ /^music(?:\/|$)/) { |
567 |
$c_res->put ([$path, $file, 3]) # FT_MUSIC |
568 |
if $file =~ /\.(ogg)$/; |
569 |
|
570 |
} elsif ($dir =~ /^sound(?:\/|$)/) { |
571 |
$c_res->put ([$path, $file, 5]) # FT_SOUND |
572 |
if $file =~ /\.(wav|ogg)$/; |
573 |
|
574 |
} elsif ($dir =~ /^res(?:\/|$)/) { |
575 |
if ($file =~ /\.(jpg|png)$/) { |
576 |
$c_res->put ([$path, $file, 0]) # FT_FACE |
577 |
} elsif ($file =~ /\.(res)$/) { |
578 |
$c_res->put ([$path, $file, 7]) # FT_RSRC |
579 |
} else { |
580 |
$c_res->put ([$path, $file, undef]); |
581 |
} |
582 |
|
583 |
} elsif ($file =~ /\.png$/) { |
584 |
push @c_png, ["$path/$file", 0]; |
585 |
|
586 |
} elsif ($file =~ /\.trs$/) { |
587 |
$c_trs->put ([$path, $file]); |
588 |
|
589 |
} elsif ($file =~ /\.arc$/) { |
590 |
$c_arc->put ([$path, $file]); |
591 |
|
592 |
} else { |
593 |
warn "ignoring $path/$file\n" if $VERBOSE >= 3; |
594 |
} |
595 |
} |
596 |
}; |
597 |
} |
598 |
|
599 |
sub inst_arch($) { |
600 |
my (undef, $path) = @_; |
601 |
|
602 |
$PATH = $path; |
603 |
|
604 |
print "\n", |
605 |
"Installing '$path' to '$DATADIR'\n", |
606 |
"\n", |
607 |
"This can take a long time if you run this\n", |
608 |
"for the first time or do not use --cache.\n", |
609 |
"\n", |
610 |
"Unless you run verbosely, all following warning\n", |
611 |
"or error messages indicate serious problems.\n", |
612 |
"\n"; |
613 |
|
614 |
if (!-d "$path/treasures") { |
615 |
warn "'$path' does not look like an arch directory ('treasures' directory is missing).\n"; |
616 |
exit 1 unless $FORCE; |
617 |
} |
618 |
|
619 |
print "scanning files...\n" if $VERBOSE; |
620 |
|
621 |
find_files $path; |
622 |
|
623 |
my @a_arc = map +(async \&process_arc), 1..2; |
624 |
my @a_res = map +(async \&process_res), 1..2; |
625 |
my @a_trs = map +(async \&process_trs), 1..2; |
626 |
|
627 |
IO::AIO::flush; |
628 |
|
629 |
$c_res->put (undef) for @a_res; |
630 |
$c_arc->put (undef) for @a_arc; |
631 |
$c_trs->put (undef) for @a_trs; |
632 |
|
633 |
print "start file scan, arc, res processing...\n" if $VERBOSE; |
634 |
|
635 |
$_->join for @a_arc; # need to parse all archetypes before png processing |
636 |
|
637 |
print "end arc, start png processing...\n" if $VERBOSE; |
638 |
|
639 |
# four png crunchers work fine for my 2x smp machine |
640 |
my @a_png = map +(async \&process_png), 1..4; |
641 |
|
642 |
$_->join for (@a_trs, @a_res, @a_png); |
643 |
|
644 |
print "scanning done, processing results...\n" if $VERBOSE; |
645 |
{ |
646 |
# remove path prefix from editor_folder |
647 |
substr $_->{editor_folder}, 0, 1 + length $path, "" |
648 |
for values %ARC; |
649 |
|
650 |
print "resolving inheritance tree...\n" if $VERBOSE; |
651 |
# resolve inherit |
652 |
while () { |
653 |
my $progress; |
654 |
my $loop; |
655 |
|
656 |
for my $o (values %ARC) { |
657 |
if (my $other = $o->{inherit}) { |
658 |
if (my $s = $ARC{$other}) { |
659 |
if ($s->{inherit}) { |
660 |
$loop = $s; |
661 |
} else { |
662 |
delete $o->{inherit}; |
663 |
my %s = %$s; |
664 |
delete @s{qw(_name more name name_pl)}; |
665 |
%$o = ( %s, %$o ); |
666 |
++$progress; |
667 |
} |
668 |
} else { |
669 |
warn "'$o->{_name}' tries to inherit from undefined archetype '$other', skipping.\n"; |
670 |
delete $ARC{$o->{_name}}; |
671 |
} |
672 |
} |
673 |
} |
674 |
|
675 |
unless ($progress) { |
676 |
die "inheritance loop detected starting at archetype '$loop->{_name}', aborting.\n" |
677 |
if $loop; |
678 |
|
679 |
last; |
680 |
} |
681 |
} |
682 |
|
683 |
# remove base classes (by naming scheme, should use something like "baseclass xxx" to inherit |
684 |
@ARC = grep $_->{_name} !~ /^(?:type|class)_/, @ARC; |
685 |
|
686 |
print "writing archetypes...\n" if $VERBOSE; |
687 |
open my $fh, ">:utf8", "$DATADIR/archetypes~" |
688 |
or die "$DATADIR/archetypes~: $!"; |
689 |
print $fh Crossfire::archlist_to_string [sort { $a->{_name} cmp $b->{_name} } @ARC]; |
690 |
} |
691 |
|
692 |
{ |
693 |
print "writing treasures...\n" if $VERBOSE; |
694 |
open my $fh, ">:utf8", "$DATADIR/treasures~" |
695 |
or die "$DATADIR/treasures~: $!"; |
696 |
print $fh $TRS; |
697 |
} |
698 |
|
699 |
{ |
700 |
print "processing facedata...\n" if $VERBOSE; |
701 |
while (my ($k, $v) = each %FACEINFO) { |
702 |
length $v->{data32} or warn "$k: face has no png32. this will not work (shoddy gcfclient will crash of course).\n"; |
703 |
length $v->{data64} or warn "$k: face has no png64. this will not work very well.\n"; |
704 |
|
705 |
length $v->{data32} <= 10000 or warn "$k: face32 larger than 10000 bytes, will not work with crossfire client.\n"; |
706 |
#length $v->{data64} <= 10000 or warn "$k: face64 larger than 10000 bytes.\n"; |
707 |
|
708 |
if (my $magicmap = $v->{magicmap}) { |
709 |
$magicmap =~ y/A-Z_\-/a-z/d; |
710 |
$v->{magicmap} = $COLOR{$magicmap}; |
711 |
} |
712 |
|
713 |
delete $v->{arc}; |
714 |
} |
715 |
|
716 |
print "writing facedata...\n" if $VERBOSE; |
717 |
open my $fh, ">:perlio", "$DATADIR/facedata~" |
718 |
or die "$DATADIR/facedata~: $!"; |
719 |
|
720 |
print $fh freeze { |
721 |
version => 2, |
722 |
faceinfo => \%FACEINFO, |
723 |
animinfo => \%ANIMINFO, |
724 |
resource => \%RESOURCE, |
725 |
}; |
726 |
} |
727 |
|
728 |
print "committing files...\n" if $VERBOSE; |
729 |
|
730 |
for (qw(archetypes facedata treasures)) { |
731 |
chmod 0644, "$DATADIR/$_~"; |
732 |
rename "$DATADIR/$_~", "$DATADIR/$_" |
733 |
or die "$DATADIR/$_: $!"; |
734 |
} |
735 |
|
736 |
print "archetype data installed successfully.\n"; |
737 |
} |
738 |
} |
739 |
|
740 |
Getopt::Long::Configure ("bundling", "no_ignore_case"); |
741 |
GetOptions ( |
742 |
"verbose|v:+" => \$VERBOSE, |
743 |
"cache" => \$CACHE, |
744 |
"quiet|q" => sub { $VERBOSE = 0 }, |
745 |
"force" => sub { $FORCE = 1 }, |
746 |
"install-arch=s" => \&inst_arch, |
747 |
"install-maps=s" => \&inst_maps, |
748 |
"print-statedir" => sub { print "@pkgstatedir@\n" }, |
749 |
"print-datadir" => sub { print "$DATADIR\n" }, |
750 |
"print-confdir" => sub { print "@pkgconfdir@\n" }, |
751 |
"print-libdir" => sub { print "@libdir@/@PACKAGE@\n" }, |
752 |
"print-bindir" => sub { print "@bindir@/@PACKAGE@\n" }, |
753 |
) or usage; |
754 |
|