1 |
dnl Process this file with autoconf to produce a configure script. |
2 |
|
3 |
AC_PREREQ(2.59) |
4 |
AC_INIT |
5 |
AC_CONFIG_SRCDIR([src/gvpe.C]) |
6 |
AC_CANONICAL_TARGET |
7 |
AM_INIT_AUTOMAKE(gvpe, 2.21) |
8 |
AC_CONFIG_HEADERS([config.h]) |
9 |
AM_MAINTAINER_MODE |
10 |
|
11 |
AH_TOP([ |
12 |
#ifndef CONFIG_H__ |
13 |
#define CONFIG_H__ |
14 |
|
15 |
#ifdef __cplusplus |
16 |
using namespace std; |
17 |
#endif |
18 |
|
19 |
]) |
20 |
|
21 |
AH_BOTTOM([ |
22 |
typedef unsigned char u8; |
23 |
typedef signed char s8; |
24 |
|
25 |
#if __CYGWIN__ |
26 |
|
27 |
typedef unsigned short u16; |
28 |
typedef unsigned int u32; |
29 |
typedef signed short s16; |
30 |
typedef signed int s32; |
31 |
|
32 |
#else |
33 |
#include <inttypes.h> |
34 |
|
35 |
/* old modula-2 habits */ |
36 |
typedef uint16_t u16; |
37 |
typedef uint32_t u32; |
38 |
typedef int16_t s16; |
39 |
typedef int32_t s32; |
40 |
#endif |
41 |
|
42 |
#endif |
43 |
|
44 |
#if HAVE_CLOCALE |
45 |
# define CLOCALE <clocale> |
46 |
#else |
47 |
# define CLOCALE <locale.h> |
48 |
#endif |
49 |
]) |
50 |
|
51 |
dnl Include the macros from the m4/ directory |
52 |
AM_ACLOCAL_INCLUDE(m4) |
53 |
|
54 |
AM_GNU_GETTEXT([external]) |
55 |
AM_GNU_GETTEXT_VERSION(0.11.5) |
56 |
|
57 |
# Enable GNU extensions. |
58 |
# Define this here, not in acconfig's @TOP@ section, since definitions |
59 |
# in the latter don't make it into the configure-time tests. |
60 |
AC_DEFINE([_GNU_SOURCE], 1, [Enable GNU extensions]) |
61 |
|
62 |
# do NOT define POSIX_SOURCE, sicne this clashes with many BSDs |
63 |
dnl AC_DEFINE([_POSIX_SOURCE], 1, [Enable POSIX 1003.1 extensions]) |
64 |
dnl AC_DEFINE([_XOPEN_SOURCE], 500, [Enable XOPEN extensions]) |
65 |
|
66 |
ALL_LINGUAS="" |
67 |
|
68 |
dnl Checks for programs. |
69 |
AC_PROG_CPP |
70 |
AC_PROG_CXX |
71 |
AC_PROG_GCC_TRADITIONAL |
72 |
AC_PROG_AWK |
73 |
AC_PROG_INSTALL |
74 |
AC_PROG_LN_S |
75 |
AC_PROG_MAKE_SET |
76 |
AC_PROG_RANLIB |
77 |
|
78 |
AC_ARG_ENABLE(iftype, |
79 |
[AS_HELP_STRING(--enable-iftype=TYPE/SUBTYPE, |
80 |
Use kernel/net device interface TYPE/SUBTYPE. |
81 |
Working combinations are (see doc/gvpe.osdep.5.pod): |
82 |
"native/linux" |
83 |
"tincd/linux" |
84 |
"tincd/netbsd" |
85 |
"tincd/freebsd" |
86 |
"tincd/openbsd" |
87 |
"native/darwin" |
88 |
"tincd/darwin" |
89 |
"native/cygwin"; |
90 |
Untested combinations are: |
91 |
"tincd/bsd" |
92 |
"tincd/solaris" |
93 |
"tincd/mingw" |
94 |
"tincd/raw_socket" |
95 |
"tincd/uml_socket"; |
96 |
Broken combinations are: |
97 |
"tincd/cygwin"; |
98 |
The default is to autodetect. |
99 |
)], |
100 |
[ |
101 |
IFTYPE=`echo $enableval | sed s%/.*%%` |
102 |
IFSUBTYPE=`echo $enableval | sed s%.*/%%` |
103 |
] |
104 |
) |
105 |
|
106 |
dnl Check and set OS |
107 |
AC_MSG_CHECKING(for kernel networking interface type) |
108 |
|
109 |
if test "x$IFTYPE" = "x"; then |
110 |
case $target_os in |
111 |
*linux*) |
112 |
IFTYPE=native |
113 |
IFSUBTYPE=linux |
114 |
AC_DEFINE(HAVE_LINUX, 1, [Linux]) |
115 |
;; |
116 |
*freebsd*) |
117 |
IFTYPE=tincd |
118 |
IFSUBTYPE=freebsd |
119 |
AC_DEFINE(HAVE_FREEBSD, 1, [FreeBSD]) |
120 |
;; |
121 |
*darwin*) |
122 |
IFTYPE=native |
123 |
IFSUBTYPE=darwin |
124 |
AC_DEFINE(HAVE_DARWIN, 1, [Darwin (MacOS/X)]) |
125 |
;; |
126 |
*solaris*) |
127 |
IFTYPE=tincd |
128 |
IFSUBTYPE=solaris |
129 |
AC_DEFINE(HAVE_SOLARIS, 1, [Solaris/SunOS]) |
130 |
;; |
131 |
*openbsd*) |
132 |
IFTYPE=tincd |
133 |
IFSUBTYPE=openbsd |
134 |
AC_DEFINE(HAVE_OPENBSD, 1, [OpenBSD]) |
135 |
;; |
136 |
*netbsd*) |
137 |
IFTYPE=tincd |
138 |
IFSUBTYPE=netbsd |
139 |
AC_DEFINE(HAVE_NETBSD, 1, [NetBSD]) |
140 |
;; |
141 |
*cygwin*) |
142 |
IFTYPE=native |
143 |
IFSUBTYPE=cygwin |
144 |
AC_DEFINE(HAVE_CYGWIN, 1, [Cygwin]) |
145 |
;; |
146 |
*) |
147 |
AC_MSG_ERROR("Unknown operating system.") |
148 |
;; |
149 |
esac |
150 |
fi |
151 |
AC_MSG_RESULT($IFTYPE/$IFSUBTYPE) |
152 |
AC_SUBST(IFTYPE,$IFTYPE) |
153 |
AC_SUBST(IFSUBTYPE,$IFSUBTYPE) |
154 |
AC_DEFINE_UNQUOTED(IFTYPE,"$IFTYPE",[kernel interface type]) |
155 |
AC_DEFINE_UNQUOTED(IFSUBTYPE,"$IFSUBTYPE",[kernel interface subtype]) |
156 |
|
157 |
AC_CACHE_SAVE |
158 |
|
159 |
dnl Checks for libraries. |
160 |
|
161 |
AC_LANG(C++) |
162 |
AC_CHECK_HEADERS(tr1/unordered_map ext/hash_map clocale) |
163 |
|
164 |
dnl Checks for header files. |
165 |
AC_CHECK_HEADERS([fcntl.h inttypes.h limits.h malloc.h stdint.h strings.h syslog.h unistd.h \ |
166 |
sys/file.h sys/ioctl.h sys/param.h sys/time.h netinet/in_systm.h sys/cygwin.h \ |
167 |
sys/mman.h netinet/in.h]) |
168 |
AC_CHECK_HEADERS([arpa/inet.h net/ethernet.h net/if.h netinet/ip.h netinet/tcp.h netinet/in_systm.h], [], [], |
169 |
[ |
170 |
#include <sys/types.h> |
171 |
#include <sys/socket.h> |
172 |
#ifdef HAVE_NETINET_IN_H |
173 |
# include <netinet/in.h> |
174 |
#endif |
175 |
#ifdef HAVE_ARPA_INET_H |
176 |
# include <arpa/inet.h> |
177 |
#endif |
178 |
#ifdef HAVE_NETINET_IN_SYSTM_H |
179 |
# include <netinet/in_systm.h> |
180 |
#endif |
181 |
]) |
182 |
|
183 |
dnl Checks for typedefs, structures, and compiler characteristics. |
184 |
AC_C_CONST |
185 |
AC_TYPE_PID_T |
186 |
AC_TYPE_SIZE_T |
187 |
AC_HEADER_TIME |
188 |
AC_STRUCT_TM |
189 |
|
190 |
AC_CACHE_CHECK([for socklen_t], ac_cv_type_socklen_t, |
191 |
[ |
192 |
AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h> |
193 |
#include <sys/socket.h>]], [[socklen_t len = 42; return len;]])],[ac_cv_type_socklen_t=yes],[ac_cv_type_socklen_t=no]) |
194 |
]) |
195 |
if test $ac_cv_type_socklen_t = yes; then |
196 |
AC_DEFINE(HAVE_SOCKLEN_T, 1, [socklen_t available]) |
197 |
fi |
198 |
|
199 |
AC_CACHE_CHECK([for struct addrinfo], ac_cv_struct_addrinfo, |
200 |
[ |
201 |
AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h> |
202 |
#include <sys/socket.h> |
203 |
#include <netdb.h>]], [[struct addrinfo ai; ai.ai_family = AF_INET; return ai.ai_family;]])],[ac_cv_struct_addrinfo=yes],[ac_cv_struct_addrinfo=no]) |
204 |
]) |
205 |
if test $ac_cv_struct_addrinfo = yes; then |
206 |
AC_DEFINE(HAVE_STRUCT_ADDRINFO, 1, [struct addrinfo available]) |
207 |
fi |
208 |
|
209 |
dnl Checks for library functions. |
210 |
AC_TYPE_SIGNAL |
211 |
|
212 |
AC_LANG_PUSH(C) |
213 |
|
214 |
AC_HEADER_STDC |
215 |
|
216 |
dnl argl, could somebody catapult darwin into the 21st century??? |
217 |
AC_CHECK_FUNCS(asprintf daemon get_current_dir_name putenv select strerror strsignal strtol unsetenv mlockall) |
218 |
|
219 |
AC_FUNC_ALLOCA |
220 |
|
221 |
dnl Support for SunOS |
222 |
|
223 |
AC_CHECK_FUNC(socket, [], [ |
224 |
AC_CHECK_LIB(socket, connect) |
225 |
]) |
226 |
AC_CHECK_FUNC(gethostbyname, [], [ |
227 |
AC_CHECK_LIB(nsl, gethostbyname) |
228 |
]) |
229 |
|
230 |
dnl libev support |
231 |
m4_include([libev/libev.m4]) |
232 |
|
233 |
AC_LANG_POP |
234 |
|
235 |
dnl AC_CHECK_FUNCS([freeaddrinfo gai_strerror getaddrinfo getnameinfo]) |
236 |
|
237 |
AC_CACHE_SAVE |
238 |
|
239 |
dnl These are defined in files in m4/ |
240 |
tinc_TUNTAP |
241 |
|
242 |
tinc_OPENSSL |
243 |
if test "x$openssl_include" != x; then |
244 |
CXXFLAGS="$CXXFLAGS -I$openssl_include" |
245 |
fi |
246 |
dnl tinc_ZLIB |
247 |
|
248 |
AC_ARG_ENABLE(static-daemon, |
249 |
[AS_HELP_STRING(--enable-static-daemon,enable statically linked daemon.)], |
250 |
[LDFLAGS_DAEMON=-static] |
251 |
) |
252 |
AC_SUBST(LDFLAGS_DAEMON) |
253 |
|
254 |
dnl AC_ARG_ENABLE(rohc, |
255 |
dnl [AS_HELP_STRING(--enable-rohc,enable robust header compression (rfc3095).)], |
256 |
dnl [ |
257 |
dnl echo |
258 |
dnl echo "**********************************************************************" |
259 |
dnl echo "**********************************************************************" |
260 |
dnl echo "**** --enable-rohc is highly experimental, do not use ****************" |
261 |
dnl echo "**********************************************************************" |
262 |
dnl echo "**********************************************************************" |
263 |
dnl echo |
264 |
dnl rohc=true |
265 |
dnl AC_DEFINE_UNQUOTED(ENABLE_ROHC, 1, [ROHC support]) |
266 |
dnl ] |
267 |
dnl ) |
268 |
|
269 |
AM_CONDITIONAL(ROHC, test x$rohc = xtrue) |
270 |
|
271 |
dnl AC_ARG_ENABLE(bridging, |
272 |
dnl [AS_HELP_STRING(--enable-bridging,enable bridging support (default disabled).)], |
273 |
dnl AC_DEFINE_UNQUOTED(ENABLE_BRIDGING, 1, [bridging support.]) |
274 |
dnl ) |
275 |
|
276 |
ICMP=1 |
277 |
AC_ARG_ENABLE(icmp, |
278 |
[AS_HELP_STRING(--disable-icmp,enable icmp protocol support (default enabled).)], |
279 |
if test "x$enableval" = xno; then |
280 |
ICMP=0 |
281 |
fi |
282 |
) |
283 |
if test "x$ICMP" = x1; then |
284 |
AC_DEFINE_UNQUOTED(ENABLE_ICMP, 1, [ICMP protocol support.]) |
285 |
fi |
286 |
|
287 |
TCP=1 |
288 |
AC_ARG_ENABLE(tcp, |
289 |
[AS_HELP_STRING(--disable-tcp,enable tcp protocol support (default enabled).)], |
290 |
if test "x$enableval" = xno; then |
291 |
TCP=0 |
292 |
fi |
293 |
) |
294 |
if test "x$TCP" = x1; then |
295 |
AC_DEFINE_UNQUOTED(ENABLE_TCP, 1, [TCP protocol support.]) |
296 |
fi |
297 |
|
298 |
HTTP=1 |
299 |
AC_ARG_ENABLE(http-proxy, |
300 |
[AS_HELP_STRING(--disable-http-proxy,enable http proxy connect support (default enabled).)], |
301 |
if test "x$enableval" = xno; then |
302 |
HTTP=0 |
303 |
fi |
304 |
) |
305 |
if test "x$HTTP" = x1; then |
306 |
AC_DEFINE_UNQUOTED(ENABLE_HTTP_PROXY, 1, [http proxy connect support.]) |
307 |
fi |
308 |
|
309 |
AC_ARG_ENABLE(dns, |
310 |
[AS_HELP_STRING(--enable-dns,enable dns tunnel protocol support (default disabled).)], |
311 |
[ |
312 |
AC_CHECK_HEADER(gmp.h,,[AC_MSG_ERROR([gmp.h not found, required for --enable-dns])]) |
313 |
AC_CHECK_LIB(gmp,main,,[AC_MSG_ERROR([libgmp not found, required for --enable-dns])]) |
314 |
|
315 |
AC_DEFINE_UNQUOTED(ENABLE_DNS, 1, [DNS tunnel protocol support.]) |
316 |
] |
317 |
) |
318 |
|
319 |
HMAC=12 |
320 |
AC_ARG_ENABLE(hmac-length, |
321 |
[AS_HELP_STRING(--enable-hmac-length=BYTES,[ |
322 |
use a hmac of length BYTES bytes (default 12). Allowed values are 4, 8, 12, 16.])], |
323 |
HMAC=$enableval |
324 |
) |
325 |
AC_DEFINE_UNQUOTED(HMACLENGTH, $HMAC, [Size of HMAC in each packet in bytes.]) |
326 |
|
327 |
RAND=8 |
328 |
AC_ARG_ENABLE(rand-length, |
329 |
[AS_HELP_STRING(--enable-rand-length=BYTES, |
330 |
[use BYTES bytes of extra randomness (default 8). Allowed values are 0, 4, 8.])], |
331 |
RAND=$enableval |
332 |
) |
333 |
AC_DEFINE_UNQUOTED(RAND_SIZE, $RAND, [Add this many bytes of randomness to each packet.]) |
334 |
|
335 |
MTU=1500 |
336 |
AC_ARG_ENABLE(mtu, |
337 |
[AS_HELP_STRING(--enable-max-mtu=BYTES,enable mtu sizes upto BYTES bytes (default 1500). Use 9100 for jumbogram support.)], |
338 |
MTU=$enableval |
339 |
) |
340 |
AC_DEFINE_UNQUOTED(MAX_MTU, $MTU + 14, [Maximum MTU supported.]) |
341 |
|
342 |
COMPRESS=1 |
343 |
AC_ARG_ENABLE(compression, |
344 |
[AS_HELP_STRING(--disable-compression,Disable compression support.)], |
345 |
if test "x$enableval" = xno; then |
346 |
COMPRESS=0 |
347 |
fi |
348 |
) |
349 |
AC_DEFINE_UNQUOTED(ENABLE_COMPRESSION, $COMPRESS, [Enable compression support.]) |
350 |
|
351 |
CIPHER=aes_128_cbc |
352 |
AC_ARG_ENABLE(cipher, |
353 |
[AS_HELP_STRING(--enable-cipher=CIPHER,[ |
354 |
Select the symmetric cipher (default "aes-128"). |
355 |
Must be one of "bf" (blowfish), "aes-128" (rijndael), "aes-192" or "aes-256".])], |
356 |
if test "x$enableval" = xbf ; then CIPHER=bf_cbc ; fi |
357 |
if test "x$enableval" = xaes-128; then CIPHER=aes_128_cbc; fi |
358 |
if test "x$enableval" = xaes-192; then CIPHER=aes_192_cbc; fi |
359 |
if test "x$enableval" = xaes-256; then CIPHER=aes_256_cbc; fi |
360 |
) |
361 |
AC_DEFINE_UNQUOTED(ENABLE_CIPHER, EVP_${CIPHER}, [Select the symmetric cipher to use.]) |
362 |
|
363 |
DIGEST=ripemd160 |
364 |
AC_ARG_ENABLE(digest, |
365 |
[AS_HELP_STRING(--enable-digest=CIPHER,[ |
366 |
Select the digest algorithm to use (default "ripemd160"). Must be one of |
367 |
"sha512", "sha256", "sha1", "ripemd160", "md5" or "md4" (insecure).])], |
368 |
if test "x$enableval" = xsha512 ; then DIGEST=sha512 ; fi |
369 |
if test "x$enableval" = xsha256 ; then DIGEST=sha256 ; fi |
370 |
if test "x$enableval" = xsha1 ; then DIGEST=sha1 ; fi |
371 |
if test "x$enableval" = xripemd160; then DIGEST=ripemd160; fi |
372 |
if test "x$enableval" = xmd5 ; then DIGEST=md5 ; fi |
373 |
if test "x$enableval" = xmd4 ; then DIGEST=md4 ; fi |
374 |
) |
375 |
AC_DEFINE_UNQUOTED(ENABLE_DIGEST, EVP_${DIGEST}, [Select the digest algorithm to use.]) |
376 |
|
377 |
if $CXX -v --help 2>&1 | grep -q fno-rtti; then |
378 |
CXXFLAGS="$CXXFLAGS -fno-rtti" |
379 |
fi |
380 |
|
381 |
#if $CXX -v --help 2>&1 | grep -q fexceptions; then |
382 |
# CXXFLAGS="$CXXFLAGS -fno-exceptions" |
383 |
#fi |
384 |
|
385 |
LIBS="$EXTRA_LIBS $LIBS" |
386 |
|
387 |
dnl if $CXX -v --help 2>&1 | grep -q ffunction-sections; then |
388 |
dnl CXXFLAGS="$CXXFLAGS -ffunction-sections" |
389 |
dnl fi |
390 |
dnl |
391 |
dnl if $LD -v --help 2>&1 | grep -q gc-sections; then |
392 |
dnl LDFLAGS="$LDFLAGS -Wl,--gc-sections" |
393 |
dnl fi |
394 |
|
395 |
AC_SUBST(INCLUDES) |
396 |
|
397 |
AC_CONFIG_FILES([Makefile po/Makefile.in |
398 |
src/Makefile |
399 |
doc/Makefile |
400 |
lib/Makefile |
401 |
m4/Makefile |
402 |
]) |
403 |
AC_OUTPUT |
404 |
|
405 |
echo |
406 |
echo "***" |
407 |
echo "*** Configuration Summary" |
408 |
echo "***" |
409 |
echo "*** Kernel Iface: $IFTYPE/$IFSUBTYPE" |
410 |
echo "*** Cipher used: $CIPHER" |
411 |
echo "*** Digest used: $DIGEST" |
412 |
echo "*** HMAC length: $HMAC" |
413 |
echo "*** RAND used: $RAND" |
414 |
echo "*** Max. MTU: $MTU" |
415 |
|
416 |
echo "***" |
417 |
echo "*** Enable options:" |
418 |
grep ENABLE_ config.h | sed -e 's/^/*** /' |
419 |
|
420 |
if test "x$DIGEST" = xmd4; then |
421 |
echo "***" |
422 |
echo "*** WARNING: The digest you have chosen ($DIGEST) is known to be insecure" |
423 |
fi |
424 |
|
425 |
if test "$HMAC" -lt 12; then |
426 |
echo "***" |
427 |
echo "*** WARNING: The hmac length you have chosen ($HMAC) is probably insecure" |
428 |
fi |
429 |
|
430 |
if test "$RAND" -lt 8; then |
431 |
echo "***" |
432 |
echo "*** WARNING: The random prefix you have chosen ($RAND) is probably insecure" |
433 |
fi |
434 |
|
435 |
echo "***" |
436 |
echo |
437 |
|
438 |
|