gvpe/po/insert-header.sin

# Sed script that inserts the file called HEADER before the header entry.
#
# At each occurrence of a line starting with "msgid ", we execute the following
# commands. At the first occurrence, insert the file. At the following
# occurrences, do nothing. The distinction between the first and the following
# occurrences is achieved by looking at the hold space.
/^msgid /{
x
# Test if the hold space is empty.
s/m/m/
ta
# Yes it was empty. First occurrence. Read the file.
r HEADER
# Output the file's contents by reading the next line. But don't lose the
# current line while doing this.
g
N
bb
:a
# The hold space was nonempty. Following occurrences. Do nothing.
x
:b
}
Revision:	1.1
Committed:	Sat Mar 1 15:53:02 2003 UTC (21 years, 7 months ago) by pcg
Branch:	MAIN
CVS Tags:	rel-1_9, rel-1_8, rel-2_01, poll-based-iom, rel-3_0, VPE_0_9, VPE_1_2, rel-2_2, rel-2_0, VPE_1_4, VPE_1_6, rel-1_7, VPE-1_6_1, rel-2_21, rel-2_22, rel-2_25, VPE_1_0, HEAD
Log Message:	* empty log message *
#	Content
1	# Sed script that inserts the file called HEADER before the header entry.
2	#
3	# At each occurrence of a line starting with "msgid ", we execute the following
4	# commands. At the first occurrence, insert the file. At the following
5	# occurrences, do nothing. The distinction between the first and the following
6	# occurrences is achieved by looking at the hold space.
7	/^msgid /{
8	x
9	# Test if the hold space is empty.
10	s/m/m/
11	ta
12	# Yes it was empty. First occurrence. Read the file.
13	r HEADER
14	# Output the file's contents by reading the next line. But don't lose the
15	# current line while doing this.
16	g
17	N
18	bb
19	:a
20	# The hold space was nonempty. Following occurrences. Do nothing.
21	x
22	:b
23	}