#!/usr/bin/perl -I../lib/

#use PApp::Util qw(dumpval); # debug only

use Gtk;
use Gtk::Gdk;
#use Gtk::Gdk::Pixbuf;
use Gtk::Gdk::ImlibImage;

use Gnome;

use KGS::Protocol;
use KGS::Listener::Debug;

use IO::Socket::INET;

use Errno;

init Gnome "kgsueme";

$HACK = 1; # do NEVER enable. ;)

our $config;
our $IMGDIR = "images";

sub load_img {
#   new_from_file Gtk::Gdk::Pixbuf "$IMGDIR/$_[0]"
   load_image Gtk::Gdk::ImlibImage "$IMGDIR/$_[0]"
      or die "$IMGDIR/$_[0]: $!";
}

our @black_img =       load_img "b-01.png";
our @white_img = map +(load_img "w-0$_.png"), 1,2,3,4,5;
our $board_img =       load_img "woodgrain-01.jpg";

{
   use Storable ();
   use Scalar::Util ();

   my $staterc = "$ENV{HOME}/.kgsueme";

   my $state = -r $staterc ? Storable::retrieve($staterc) : {};
   my @widgets;

   $config = $state->{config} ||= {};

   # grr... more gtk+ brokenness
   my %get = (
      hpane_position  => sub { ($_[0]->children)[0]->allocation->[2] },
      vpane_position  => sub { ($_[0]->children)[0]->allocation->[3] },
      window_size     => sub { [ @{$_[0]->allocation}[2,3] ] },
      #window_pos     => sub { die PApp::Util::dumpval [ $_[0]->get_root_origin ] },
      clist_column_widths => sub {
         $_[0]{column_widths};
      },
   );

   my %set = (
      hpane_position => sub { $_[0]->set_position($_[1]) },
      vpane_position => sub { $_[0]->set_position($_[1]) },
      window_size    => sub { $_[0]->set_default_size(@{$_[1]}) },
      #window_pos     => sub { $_[0]->set_uposition(@{$_[1]}) if @{$_[1]} },
      clist_column_widths => sub {
         my ($w, $v) = @_;
         $v->[$_] && $w->set_column_width($_, $v->[$_]) for 0..$#$v;
         $w->{column_widths} = $v;
         $w->signal_connect(resize_column => sub { $v->[$_[1]] = $_[2]; });
      },
   );

   sub state {
      my ($widget, $class, $instance, %attr) = @_;

      while (my ($k, $v) = each %attr) {
         my ($set, $get) = $k =~ /=/ ? split /=/, $k : ($k, $k);
         $v = $state->{$class}{"*"}{$get}       if exists $state->{$class}{"*"}{$get};
         $v = $state->{$class}{$instance}{$get} if exists $state->{$class}{$instance}{$get};
         $set{$get} ? $set{$get}->($widget, $v) : $widget->set($set => $v);
      }

      $widget = [$widget, $class, $instance, \%attr];
      Scalar::Util::weaken $widget->[0];

      @widgets = (grep $_->[0], @widgets, $widget);
   }

   sub save_state {
      for (@widgets) {
         if ($_->[0]) {
            my ($widget, $class, $instance, $attr) = @$_;

            $widget->realize;

            while (my ($k, $v) = each %$attr) {
               my ($set, $get) = $k =~ /=/ ? split /=/, $k : ($k, $k);
               $v = $get{$get} ? $get{$get}->($widget) : $widget->get($get);

               $state->{$class}{"*"}{$get}       = $v;
               $state->{$class}{$instance}{$get} = $v;
            }
         }
         ::status("save_state", "layout saved");
      }

      Storable::nstore($state, $staterc);
   }
}

# make a clist unselectable
sub clist_autosort {
   my $w = shift;
   my ($c, $o) = (-1);
   for (0..$w->columns-1) {
      $w->signal_connect(click_column => sub {
         if ($_[1] != $c) {
            $c = $_[1];
            $o = 0;
         } else {
            $o = !$o;
         }
         $w->set_sort_column($c);
         $w->set_sort_type($o ? "descending" : "ascending");
         $w->sort;
      });
   }
   
}

{
   my $main = new kgsueme;

   my %context_id;

   sub status {
      my ($type, $text) = @_;

      $main->{status}->pop($context_id{$type}) if $context_id{$type};
      $main->{status}->push($context_id{$type} ||= $main->{status}->get_context_id($type), $text) if $text;
   }
}

main Gtk;

#############################################################################

package kgsueme;

use base KGS::Listener;

sub new {
   my $self = shift;
   $self = $self->SUPER::new(@_);

   $self->{conn} = new KGS::Protocol;

   KGS::Listener::Debug->new->listen($self->{conn}); #d# debug only :)

   $self->listen($self->{conn});

   $self->{roomlist} = new roomlist conn => $self->{conn};

   $self->{window} = new Gtk::Window 'toplevel';
   $self->{window}->set_title('kgsueme');
   ::state $self->{window}, "main::window", undef, window_size => [400, 100];
   $self->{window}->signal_connect(delete_event => sub { main_quit Gtk; 1 });

   $self->{window}->add(my $vbox = new Gtk::VBox);

   $vbox->pack_start(($buttonbox = new Gtk::HButtonBox), 0, 1, 0);
   $buttonbox->set_spacing(0);

   my $button = sub {
      $buttonbox->add(my $button = new Gtk::Button $_[0]);
      signal_connect $button clicked => $_[1];
   };

   $button->("Login", sub { $self->login; });
   $button->("Roomlist", sub { $self->{roomlist}->show; });
   $button->("Save Config & Layout", sub { ::save_state });
   $button->("Quit", sub { main_quit Gtk });

   $vbox->pack_start((my $hbox = new Gtk::HBox), 0, 1, 0);

   $hbox->add(new Gtk::Label "Login");

   $hbox->add($self->{login} = new_with_max_length Gtk::Entry 12);
   $self->{login}->set_text($::config->{login});

   if ($::HACK) {
      $self->{login}->signal_connect(activate => sub {
         $self->{conn}{name} = $self->{login}->get_text;
      });
   }

   $hbox->add(new Gtk::Label "Password");
   $hbox->add($self->{password} = new Gtk::Entry);
   $self->{password}->set_visibility(0);

   $vbox->pack_start(($self->{status} = new Gtk::Statusbar), 0, 1, 0);

   $self->{window}->show_all;

   $self;
}

sub login {
   my ($self) = @_;

   $self->{conn}->disconnect;

   # initialize new socket and connection
   my $sock = new IO::Socket::INET PeerHost => "kgs.kiseido.com", PeerPort => "2379"
      or die;

   $sock->blocking(1);
   $self->{conn}->handshake($sock);
   $sock->blocking(0);

   my $input; $input = input_add Gtk::Gdk fileno $sock, "read", sub {
      # this is dorked
      my $buf;
      if (0 >= sysread $sock, $buf, 16384
          and !$!{EINTR} and !$!{EAGAIN}) {
         input_remove Gtk::Gdk $input;
         $self->event_disconnect;
      }
      $self->{conn}->feed_data($buf);
   };

   # now login
   $self->{conn}->login($self->{login}->get_text, $self->{password}->get_text);
}

sub inject_login {
   my ($self, $msg) = @_;

   ::status("login", "logged in as '$self->{conn}{name}' with status '$msg->{result}'");
   $::config->{login} = $self->{conn}{name};

   if ($msg->{success}) {
      for (keys %{$::config->{rooms}}) {
         $self->{roomlist}->join_room($_);
      }
   }

   warn PApp::Util::dumpval($::config);
}

sub event_disconnect { }

#############################################################################

package roomlist;

use base KGS::Listener::Roomlist;

sub new {
   my $self = shift;
   $self = $self->SUPER::new(@_);

   $self->listen($self->{conn});

   $self->{window} = new Gtk::Window 'toplevel';
   $self->{window}->set_title('KGS Rooms');
   ::state $self->{window}, "roomlist::window", undef, window_size => [400, 200];

   $self->{window}->signal_connect(delete_event => sub { $self->{window}->hide; 1 });

   $self->{window}->add(my $vbox = new Gtk::VBox);

   $vbox->pack_start((my $sw = new Gtk::ScrolledWindow), 1, 1, 0);
   $sw->set_policy("automatic", "always");

   $sw->add($self->{roomlist} = new_with_titles Gtk::CList "Group", "Room Name", "Users", "Games", "Flags", "Channel");
   $self->{roomlist}->set_selection_mode('multiple');
   ::clist_autosort $self->{roomlist};
   ::state $self->{roomlist}, "roomlist::roomlist", undef, clist_column_widths => [20, 200];

   $self->{roomlist}->signal_connect(select_row => sub {
      my $room = $self->{roomlist}->get_row_data($_[1])
         or return;
      $self->{roomlist}->unselect_all;
      $self->join_room($room->{channel});
   });

   $self;
}

sub join_room {
   my ($self, $channel) = @_;

   $self->{room}{$channel} ||= room->new(channel => $channel, conn => $self->{conn}, users => {});
   $self->{room}{$channel}->join;
}

sub show {
   my ($self, $msg) = @_;

   $self->msg(list_rooms => group => $_) for 0..5; # fetch all room names (should not!)
   $self->{window}->show_all;
}

sub event_update {
   my ($self) = @_;

   $self->{event_update} ||= Gtk->timeout_add(200, sub {
      my $l = $self->{roomlist};

      $l->freeze;
      my $pos = $l->get_vadjustment->get_value;
      $l->clear;

      my $row = 0;
      for (values %{$self->{rooms}}) {
         $l->append($_->{group}, $_->{name}, $_->{users}, $_->{games}, $_->{flags}, $_->{channel});
         $l->set_row_data($row++, $_);
      }
      $l->sort;
      $l->get_vadjustment->set_value($pos);
      $l->thaw;

      delete $self->{event_update};
      0;
   });
}

#############################################################################

package room;

use base KGS::Listener::Room;

sub new {
   my $self = shift;
   $self = $self->SUPER::new(@_);

   $self->listen($self->{conn});

   $self->{window} = new Gtk::Window 'toplevel';
   $self->{window}->set_title("KGS Room $self->{name}");
   ::state $self->{window}, "room::window", $self->{name}, window_size => [600, 400];

   $self->{window}->signal_connect(delete_event => sub { $self->part; 1 });

   $self->{window}->add(my $hpane = new Gtk::HPaned);
   ::state $hpane, "room::hpane", $self->{name}, hpane_position => 200;

   $hpane->add(my $vpane = new Gtk::VPaned);
   ::state $vpane, "room::vpane", $self->{name}, vpane_position => 200;

   $vpane->add(my $sw = new Gtk::ScrolledWindow);
   $sw->set_policy("automatic", "always");

   $sw->add($self->{gamelist} = new_with_titles Gtk::CList "T", "Black", "White", "Rules", "Notes");
   ::clist_autosort $self->{gamelist};
   ::state $self->{gamelist}, "room::gamelist", $self->{name}, clist_column_widths => [20, 120, 120, 120];

   $self->{gamelist}->signal_connect(select_row => sub {
      my $game = $self->{gamelist}->get_row_data($_[1])
         or return;
      $self->{game}{$game->{channel}} ||= new game %$game, conn => $self->{conn};
      $self->{game}{$game->{channel}}->join;
      $self->{gamelist}->unselect_all;
   });

   $vpane->add(my $vbox = new Gtk::VBox);
   
   $vbox->pack_start((my $sw = new Gtk::ScrolledWindow), 1, 1, 0);
   $sw->set_policy("automatic", "always");

   $sw->add($self->{text} = new Gtk::Text);

   $vbox->pack_start(($self->{entry} = new Gtk::Entry), 0, 1, 0);
   $self->{entry}->signal_connect(activate => sub {
      my $text = $self->{entry}->get_text;
      $self->say($text) if $text =~ /\S/;
      $self->{entry}->set_text("");
   });

   $hpane->add(my $sw = new Gtk::ScrolledWindow);
   $sw->set_policy("automatic", "always");

   $sw->add($self->{userlist} = new_with_titles Gtk::CList "User", "Rank", "Flags");
   ::clist_autosort $self->{userlist};
   ::state $self->{userlist}, "room::userlist", $self->{name}, clist_column_widths => [120, 30];

   $self;
}

sub event_update {
   my ($self) = @_;

   $self->{event_update} ||= Gtk->timeout_add(200, sub {
      my $l = $self->{userlist};

      $l->freeze;
      my $pos = $l->get_vadjustment->get_value;
      $l->clear;

      my $row = 0;
      for (values %{$self->{users}}) {
         $l->append($_->{name});
         $l->set_row_data($row++, $_);
      }
      $l->sort;
      $l->get_vadjustment->set_value($pos);
      $l->thaw;

      delete $self->{event_update};
      0;
   });
}

sub event_update_games {
   my ($self) = @_;

   $self->{event_update_games} ||= Gtk->timeout_add(200, sub {
      my $l = $self->{gamelist};

      $l->freeze;
      my $pos = $l->get_vadjustment->get_value;
      $l->clear;

      my $row = 0;
      for (values %{$self->{games}}) {
         $l->append($_->type, $_->user0, $_->user1, $_->rules, $_->notes);
         $l->set_row_data($row++, $_);
      }
      $l->sort;
      $l->get_vadjustment->set_value($pos);
      $l->thaw;

      delete $self->{event_update_games};
      0;
   });
}

sub join {
   my ($self) = @_;
   $self->SUPER::join;

   $self->{window}->show_all;
}

sub part {
   my ($self) = @_;
   $self->SUPER::part;

   delete $::config->{rooms}{$self->{channel}};
   $self->{window}->hide_all;
   $self->event_update;
   $self->event_update_games;
}

sub event_join {
   my ($self) = @_;
   $self->SUPER::event_join;

   $::config->{rooms}{$self->{channel}} = 1;
}

sub event_update_roominfo {
   my ($self) = @_;

   $self->{text}->insert(undef, undef, undef, "\n$self->{owner}: $self->{description}\n");
}

sub inject_msg_room {
   my ($self, $msg) = @_;
   return unless $self->{channel} == $msg->{channel};

   $self->{text}->insert(undef, undef, undef, "\n$msg->{name}: $msg->{message}");
}

#############################################################################

package game;

use KGS::Constants;

use base KGS::Listener::Game;
use base KGS::Game;

sub new {
   my $self = shift;
   $self = $self->SUPER::new(@_);

   $self->listen($self->{conn});

   $self->{window} = new Gtk::Window 'toplevel';
   $self->{window}->set_title("KGS Game ".$self->user0." ".$self->user1);
   ::state $self->{window}, "game::window", undef, window_size => [600, 500];

   $self->{window}->signal_connect(delete_event => sub { $self->part; 1 });

   $self->{window}->add(my $hpane = new Gtk::HPaned);
   ::state $hpane, "game::hpane", undef, hpane_position => 500;

   $::config{aa} = 1;
   $self->{canvas} = $::config{aa} ? new_aa Gnome::Canvas : new Gnome::Canvas;
   $hpane->add($self->{canvas});

   {
      my $line_colour = $::config{line_colour} || "darkbrown";
      my $border      = 0.1;
      my $ofs         = 0.5 / $self->{size};
   
      $self->{canvas}->set_pixels_per_unit(1000);
      $self->{canvas}->set_scroll_region(-$border,-$border,1+$border,1+$border);

      $self->{canvas}->signal_connect(size_allocate => sub {
         my ($w, $h) = @{$_[1]}[2,3];

         $self->{canvas}->set_pixels_per_unit(($w > $h ? $h : $w)/(1+$border*2));

         1;
      });

      my $croot  = $self->{canvas}->root;
      my $cgroup = $croot; #->new($croot, "Gnome::CanvasGroup");

      if ($::board_img) {
         $cgroup->new($cgroup, "Gnome::CanvasImage",
            x      => -$border,    y      => -$border,
            width  => 1+$border*2, height => 1+$border*2,
            image  => $::board_img,
            anchor => "nw"
         );
      } else {
         $cgroup->new($cgroup, "Gnome::CanvasRect",
            x1 => -$border, x2 => 1+$border,
            y1 => -$border, y2 => 1+$border,
            outline_color => "black",
            fill_color => "brown",
            width_pixels => 2,
         );
      }

      my $a = "A";
      for my $i (1 .. $self->{size}) { # one more iteration for the last lines
        my $k = $i / $self->{size} - $ofs;

        $cgroup->new($cgroup, "Gnome::CanvasLine",
           points       => [ $k,$ofs, $k,1-$ofs ],
           fill_color   => $line_colour,
           width_pixels => 1);

        $cgroup->new($cgroup, "Gnome::CanvasLine",
           points       => [ $ofs,$k, 1-$ofs,$k ],
           fill_color   => $line_colour,
           width_pixels => 1);

        for ( [$k,-$border*0.5,$a], [$k,1+$border*0.5,$a], [-$border*0.5,$k,$i], [1+$border*0.5,$k,$i] ) {
           my ($x, $y, $text) = @$_;

           my $text = $cgroup->new($cgroup, "Gnome::CanvasText",
              x => 0, y => 0, text => $text,
              justification => "center",
              anchor        => "center",
              font          => $::config{aa} ? "-*-helvetica-medium-r-*--34-*" : "-*-helvetica-bold-r-*--17-*",
              fill_color    => $line_colour);

           $text->affine_relative($border*0.015,0, 0,$border*0.015, $x,$y);
        }

        $a++;
      }

      my $stones = [[]];

      for my $x (1 .. $self->{size}) {
         my $xk = $x / $self->{size} - $ofs;
         for my $y (1 .. $self->{size}) {
            my $yk = $y / $self->{size} - $ofs;

            my $col = $stones->[$x-1][$y-1] = [];

            if (1) {
               $col->[0] =
                  $cgroup->new($cgroup, "Gnome::CanvasImage",
                     x      => $xk,    y      => $yk,
                     width  => $ofs*2, height => $ofs*2,
                     image  => $::black_img[int rand @::black_img],
                     anchor => "center");
               $col->[1] =
                  $cgroup->new($cgroup, "Gnome::CanvasImage",
                     x      => $xk,    y      => $yk,
                     width  => $ofs*2, height => $ofs*2,
                     image  => $::white_img[int rand @::white_img],
                     anchor => "center");
            } else {
               die "need pixmaps\n";
               # too large, scale has NO effect
               $col->[0] =
                  $cgroup->new($cgroup, "Gnome::CanvasEllipse",
                     x1 => $xk, x2 => $xk + 0.001,
                     y1 => $yk, y2 => $yk + 0.001,
                     outline_color => "black", width_pixels => 2,
                     fill_color => "black");
               $col->[1] =
                  $cgroup->new($cgroup, "Gnome::CanvasEllipse",
                     x1 => $xk, x2 => $xk + 0.001,
                     y1 => $yk, y2 => $yk + 0.001,
                     outline_color => "black", width_pixels => 2,
                     fill_color => "white");
            }
         }
      }

      $self->{board_gfx}{stones} = $stones;
   }

   $hpane->add(my $vpane = new Gtk::VPaned);
   ::state $vpane, "game", $self->{name}, vpane_position => 80;

   $vpane->add(my $sw = new Gtk::ScrolledWindow);
   $sw->set_policy("automatic", "always");

   $sw->add($self->{userlist} = new_with_titles Gtk::CList "User", "Rank", "Flags");
   ::clist_autosort $self->{userlist};
   ::state $self->{userlist}, "room::userlist", $self->{name}, clist_column_widths => [120, 30];

   $vpane->add(my $vbox = new Gtk::VBox);
   
   $vbox->pack_start((my $sw = new Gtk::ScrolledWindow), 1, 1, 0);
   $sw->set_policy("automatic", "always");

   $sw->add($self->{text} = new Gtk::Text);

   $vbox->pack_start(($self->{entry} = new Gtk::Entry), 0, 1, 0);
   $self->{entry}->signal_connect(activate => sub {
      my $text = $self->{entry}->get_text;
      # add message
      $self->{entry}->set_text("");
   });

   $self;
}

sub event_update {
   my ($self) = @_;

   $self->{event_update} ||= Gtk->timeout_add(200, sub {
      my $l = $self->{userlist};

      $l->freeze;
      my $pos = $l->get_vadjustment->get_value;
      $l->clear;

      my $row = 0;
      for (values %{$self->{users}}) {
         $l->append($_->{name});
         $l->set_row_data($row++, $_);
      }
      $l->sort;
      $l->get_vadjustment->set_value($pos);
      $l->thaw;

      delete $self->{event_update};
      0;
   });
}

sub join {
   my ($self) = @_;
   $self->SUPER::join;

   $self->{window}->show_all;
}

sub part {
   my ($self) = @_;
   $self->SUPER::part;

   $self->{window}->hide_all;
   $self->event_update;
}

sub event_update_tree {
   my ($self) = @_;

   my $board = new KGS::Game::Board $self->{size};
   $board->interpret_path ($self->get_path);

#   if (not defined $self->{board_pm}) {
#     $self->{board_pm} = new Gtk::Gdk::Pixmap ($self->{board}->window, 100, 100, -1);
#     $self->{board_pm}->draw_rectangle($self->{board}->style->white_gc, 1, 0, 0, 100, 100);
#   }
#   my $red = $self->{board}->window->get_colormap->color_alloc( { red => 65000, green => 0, blue => 0 } );
#   my $red_gc = new Gtk::Gdk::GC ( $self->{board}->window );
#   $red_gc->set_foreground( $red );
#
#   my $px = $self->{board_pm};

   for my $x (0 .. $self->{size} - 1) {
      for my $y (0 .. $self->{size} - 1) {
         my $v = $board->{board}[$x][$y];

         $v & MARK_B
            ? $self->{board_gfx}->{stones}->[$x][$y][0]->show
            : $self->{board_gfx}->{stones}->[$x][$y][0]->hide;
         $v & MARK_W
            ? $self->{board_gfx}->{stones}->[$x][$y][1]->show
            : $self->{board_gfx}->{stones}->[$x][$y][1]->hide;
      }
   }
}

1;