package game;

use KGS::Constants;
use KGS::Game::Board;

use base KGS::Listener::Game;
use base KGS::Game;

use base gtk::widget;

use POSIX qw(ceil);

sub new {
   my $self = shift;
   $self = $self->SUPER::new(@_);

   $self->listen($self->{conn});

   $self->{window} = new Gtk2::Window 'toplevel';
   my $title = $self->{channel} ? $self->owner->as_string." ".$self->opponent_string : "Game Window";
   $self->{window}->set_title("KGS Game $title");
   gtk::state $self->{window}, "game::window", undef, window_size => [600, 500];

   $self->{window}->signal_connect(delete_event => sub {
      if ($self->{joined}) {
         $self->part;
      } else {
         $self->event_part;
      }
      1;
   });

   $self->{window}->add($self->{hpane} = new Gtk2::HPaned);
   gtk::state $self->{hpane}, "game::hpane", undef, position => 500;

   $self->{hpane}->pack1((my $vbox = new Gtk2::VBox), 1, 1);

   $vbox->pack_start((my $frame = new Gtk2::Frame), 0, 1, 0);

   {
      # grrr...
      $frame->add(my $vbox = new Gtk2::VBox);
      $vbox->add($self->{title} = new Gtk2::Label $title);

      $self->{moveadj} = new Gtk2::Adjustment 1, 0, 1, 0.001, 0.05, 0;

      $vbox->add(my $scale = new Gtk2::HScale $self->{moveadj});
      $scale->set_draw_value (0);

      $self->{moveadj}->signal_connect (value_changed => sub {
         return unless $self->{path};

         my $move = int (@{$self->{path}} * $_[0]->get_value);

         $self->{board} = new KGS::Game::Board $self->{size};
         $self->{board}->interpret_path ([@{$self->{path}}[0 .. $move - 1]]);

         $self->redraw ($self->repaint_board);

         $self->{text}->set_text(KGS::Listener::Debug::dumpval([$self->{board}{time},$self->{board}{captures}]). $self->{board}{comment});
      });
   }
   
   $vbox->pack_start(($self->{canvas} = new Gtk2::DrawingArea), 1, 1, 0);

   $self->{canvas}->signal_connect(configure_event => \&configure_event, $self);
   $self->{canvas}->signal_connect(expose_event    => \&expose_event,    $self);

   $self->{hpane}->pack2(($self->{vpane} = new Gtk2::VPaned), 0, 0);
   $self->{hpane}->set(position_set => 1);
   gtk::state $self->{vpane}, "game::vpane", $self->{name}, position => 80;

   $self->{vpane}->add(my $sw = new Gtk2::ScrolledWindow);
   $sw->set_policy("automatic", "always");

   $sw->add(($self->{userlist} = new gtk::userlist)->widget);

   $self->{vpane}->add(my $vbox = new Gtk2::VBox);
   
   $vbox->pack_start((my $sw = new Gtk2::ScrolledWindow), 1, 1, 0);
   $sw->set_policy("never", "always");

   $sw->add(($self->{text} = new gtk::text)->widget);

   $vbox->pack_start(($self->{entry} = new Gtk2::Entry), 0, 1, 0);
   $self->{entry}->signal_connect(activate => sub {
      my $text = $self->{entry}->get_text;
      $self->say($text) if $text =~ /\S/;
      $self->{entry}->set_text("");
   });

   $self;
}

sub event_update_users {
   my ($self) = @_;

   $self->{userlist}->update($self->{users});
}

sub join {
   my ($self) = @_;
   $self->SUPER::join;

   $self->{window}->show_all;
}

sub part {
   my ($self) = @_;
   $self->SUPER::part;

   $self->{window}->hide;
}

sub configure_event {
   my ($widget, $event, $self) = @_;
   delete $self->{stack};
   delete $self->{pixbuf};
   delete $self->{board_shown};
   delete $self->{background};
   $self->repaint_board;
   0;
}

sub expose_event {
   my ($widget, $event, $self) = @_;

   $self->{pixbuf} or return;

   my $area = $event->area;
   my ($ox, $oy, $s) = @{$self->{offsets}};

   $self->redraw (
             (new Gtk2::Gdk::Rectangle $area->x - $ox, $area->y - $oy, $area->width, $area->height)
                ->intersect(new Gtk2::Gdk::Rectangle 0, 0, $s, $s)
          );

   0;
}

# something Gtk2 fixed
sub INTERP_NEAREST  (){ 'nearest'  }
sub INTERP_TILES    (){ 'tiles'    }
sub INTERP_BILINEAR (){ 'bilinear' }
sub INTERP_HYPER    (){ 'hyper'    }

sub new_pixbuf {
   my ($w, $h, $alpha, $fill) = @_;

   my $pixbuf = new Gtk2::Gdk::Pixbuf 'rgb', $alpha, 8, $w, $h;
   $pixbuf->fill ($fill) if defined $fill;

   $pixbuf;
}

sub scale_pixbuf {
   my ($src, $w, $h, $mode) = @_;

   my $dst = new_pixbuf $w, $h, 1;

   $src->scale(
      $dst, 0, 0, $w, $h, 0, 0,
      $w / $src->get_width, $h / $src->get_height,
      $mode,
   );

   $dst;
}

# create a stack of stones
sub create_stack {
   my ($self, $mark, $size, $rand) = @_;

   my $shadow = $size * 0.05;

   my $c = \$self->{stack}{$mark};
   unless ($$c) {
      for my $stone ($mark & (MARK_W | MARK_GRAY_W) ? @::white_img : @::black_img) {
         my $base = new_pixbuf $size + $shadow, $size + $shadow, 1, 0x00000000;

         # zeroeth the shadow
         if ($mark & (MARK_B | MARK_W)) {
            $::shadow_img->composite (
               $base, $shadow, $shadow, $size, $size, $shadow - 0.5, $shadow - 0.5,
               $size / $stone->get_width, $size / $stone->get_height,
               $::config->{speed} ? INTERP_NEAREST : INTERP_BILINEAR, 192
            );
         }

         # first the big stones (handicap stones different for effect)
         for ([MARK_B,      $mark & MARK_MOVE ? 255 : 192],
              [MARK_W,      $mark & MARK_MOVE ? 255 : 192],
              [MARK_GRAY_B, 128],
              [MARK_GRAY_W, 128]) {
            my ($mask, $alpha) = @$_;
            if ($mark & $mask) {
               $stone->composite (
                  $base, 0, 0, $size, $size, 0, 0,
                  $size / $stone->get_width, $size / $stone->get_height,
                  $::config->{speed} ? INTERP_NEAREST : INTERP_BILINEAR, $alpha
               );
            }
         }

         # then the small stones
         for ([MARK_SMALL_B, $::black_img[$rand % @::black_img]],
              [MARK_SMALL_W, $::white_img[$rand % @::white_img]]) {
            my ($mask, $img) = @$_;
            if ($mark & $mask) {
               $img->composite (
                  $base, (ceil ($size / 4)) x2, (ceil ($size / 2)) x2, (ceil ($size / 4)) x2,
                  $size / $img->get_width / 2, $size / $img->get_height / 2,
                  $::config->{speed} ? INTERP_NEAREST : INTERP_BILINEAR, 224
               );
            }
         }

         # and lastly any markers
         my $dark_bg = ! ! ($mark & (MARK_B | MARK_GRAY_B));

         for ([MARK_CIRCLE,   $::circle_img[$dark_bg]],
              [MARK_TRIANGLE, $::triangle_img[$dark_bg]],
              [MARK_SQUARE,   $::square_img[$dark_bg]]) {
           my ($mask, $img) = @$_;
           if ($mark & $mask) {
              $img->composite (
                 $base, 0, 0, $size, $size, -0.5, -0.5,
                 $size / $img->get_width, $size / $img->get_height,
                 $::config->{speed} ? INTERP_NEAREST : INTERP_BILINEAR, 255
              );
           }
         }

         push @$$c, $base;
      }
   }

   $$c->[$rand % @$$c];
}

sub pixbuf_text {
   my ($pixbuf, $colour, $x, $y, $height, $text) = @_;

   my @c = grep $_,
              map $::font[$colour][$::fontmap{$_}],
                 split //, $text;

   if (@c) {
      my $spacing = $height * 0.1;
      my $s = $height / List::Util::max map $_->get_height, @c;
      my $W = List::Util::sum map $_->get_width, @c;

      $x -= ($W * $s + $spacing * (@c - 1)) * 0.5;
      $y -= $height * 0.5;

      for (@c) {
         my $w = $_->get_width * $s;
         # +2 == don't fight the rounding
         $_->composite ($pixbuf,
               $x, $y, $w+2, $height+2, $x, $y, $s, $s,
               $::config->{speed} ? INTERP_NEAREST : INTERP_BILINEAR, 255);

         $x += $w + $spacing;
      }
   }
}

sub pixbuf_rect {
   my ($pb, $colour, $x1, $y1, $x2, $y2, $alpha) = @_;
   # we fake lines by... a horrible method :/
   my $colour_pb = new_pixbuf 1, 1, 0, $colour;
   $colour_pb->composite ($pb, $x1, $y1, $x2 - $x1 + 1, $y2 - $y1 + 1, $x1, $y1, $x2 + 1, $y2 + 1,
                          INTERP_NEAREST, $alpha);
}

sub repaint_board {
   my ($self) = @_;
   my $canvas = $self->{canvas};
   my $expose_area = undef;

   return $expose_area unless $self->{board};

   my ($w, $h) = ($canvas->allocation->values)[2,3];
   
   my $s = $w > $h ? $h : $w;

   return unless $s > 128;
   
   $self->{offsets} = [int (($w - $s) / 2), int (($h - $s) / 2), $s];

   my $size = $self->{size};

   # we leave enough space for the shadows.. I like smaller stones, and we
   # do no need to do the nifty recursive screen updates that goban2 does
   my $border = int ($s / ($size + 3) * 0.5);
   my $s2     = $s - $border * 2;
   my $edge   = int ($s2 / ($size + 1) * 0.96) - ($::config->{randomize} ? 3 : 0);
   my $ofs    = int ($edge / 2);

   my @k = map int ($s2 * $_ / ($size+1) + $border + 0.5), 0 .. $size;

   my $pixbuf;

   my $oldboard;

   if ($self->{background}) {
      if ($oldboard = $self->{board_shown}) {
         $pixbuf = $self->{pixbuf};
      } else {
         $pixbuf = $self->{background}->copy;
         $expose_area = new Gtk2::Gdk::Rectangle 0, 0, $s, $s;
      }
   } else {
      $expose_area = new Gtk2::Gdk::Rectangle 0, 0, $s, $s;

      my ($bw, $bh) = ($::board_img->get_width, $::board_img->get_height);

      if ($s < $bw && $s < $bh) {
         $pixbuf = new_pixbuf $s, $s, 0;
         $::board_img->copy_area (0, 0, $s, $s, $pixbuf, 0, 0);
      } else {
         $pixbuf = scale_pixbuf $::board_img, $s, $s, $::config->{speed} ? INTERP_NEAREST : INTERP_TILES;
      }

      my $linew = int ($s / 25 / $size);

      # ornamental border... we have time to waste :/
      pixbuf_rect $pixbuf, 0xffcc7700, 0, 0,           $s-1, $linew, 255;
      pixbuf_rect $pixbuf, 0xffcc7700, 0, 0,           $linew, $s-1, 255;
      pixbuf_rect $pixbuf,0xffcc7700, $s-$linew-1, 0, $s-1, $s-1,   255;
      pixbuf_rect $pixbuf,0xffcc7700, 0, $s-$linew-1, $s-1, $s-1,   255;

      for my $i (1 .. $size) {
         pixbuf_rect $pixbuf, 0x44111100, $k[$i] - $linew, $k[1] - $linew, $k[$i] + $linew, $k[$size] + $linew, 192;
         pixbuf_rect $pixbuf, 0x44111100, $k[1] - $linew, $k[$i] - $linew, $k[$size] + $linew, $k[$i] + $linew, 192;

         # 38 max, but we allow a bit more
         my $label = (qw(- A  B  C  D  E  F  G  H  J  K  L  M  N  O  P  Q  R  S  T  U  V  W  X  Y  Z
                           AA BB CC DD EE FF GG HH JJ KK LL MM NN OO PP QQ RR SS TT UU VV WW XX YY ZZ))[$i];

         pixbuf_text $pixbuf, 0, $k[$i], $border,       $ofs, $label;
         pixbuf_text $pixbuf, 0, $k[$i], $s2 + $border, $ofs, $label;
         pixbuf_text $pixbuf, 0, $border, $k[$i],       $ofs, $size - $i + 1;
         pixbuf_text $pixbuf, 0, $s2 + $border, $k[$i], $ofs, $size - $i + 1;

         $a++;
         $a++ if $a eq "I"; # not correct, instead of AA AB, we should get HH JJ KK...
      }

      unless ($::config->{conserve_memory}) {
         $self->{background} = $pixbuf;
         $pixbuf = $pixbuf->copy;
      }
   }

   $self->{pixbuf} = $pixbuf;

   # hoshi-points(!)#d#
   # caching of empty board gfx(!)#d#

   for my $x (1 .. $size) {
      for my $y (1 .. $size) {
         my $rand = ($x ^ $y ^ 0x5555);

         my ($dx, $dy) = ($k[$x] - $ofs, $k[$y] - $ofs);

         if ($::config->{randomize}) {
            $dx += ($rand     % 7) - 3;
            $dy += ($rand / 3 % 7) - 3;
         }

         my $shadow = $edge * 0.05;
         my $area = [$dx, $dy, $edge + $shadow, $edge + $shadow];
         
         my $mark = $self->{board}{board}[$x-1][$y-1];
         my $old = $oldboard ? $oldboard->{board}[$x-1][$y-1] : 0;

         if ($oldboard) {
            next if $old == $mark; # no change

            $self->{background}->copy_area (@$area, $pixbuf, $dx, $dy);
            $expose_area = $expose_area
                              ? $expose_area->union (new Gtk2::Gdk::Rectangle @$area)
                              : new Gtk2::Gdk::Rectangle @$area;
         }

         if ($mark) {
            my $pb = $self->create_stack($mark, $edge, $rand);

            $pb->composite ($pixbuf, @$area,
                            $dx, $dy, 1, 1, $::config->{speed} ? INTERP_NEAREST : INTERP_NEAREST, 255);

            # labels are handled here because they are quite rare
            if ($mark & MARK_LABEL) {
               my $white = $mark & (MARK_W | MARK_GRAY_W) ? 0 : 1;

               if ($white) {
                  pixbuf_text $pixbuf, 0,
                              $k[$x] + $ofs * 0.1, $k[$y] + $ofs * 0.1, $ofs * 0.7,
                              $self->{board}{label}[$x-1][$y-1];
               }
               pixbuf_text $pixbuf, $white,
                           $k[$x], $k[$y], $ofs * 0.7,
                           $self->{board}{label}[$x-1][$y-1];
            }
            
            # old pixmap&mask-way. that was fast ;(
            #my ($pm, $bm) = $self->create_stack($gc, $mark, $edge, $x * 17 + $y * 11 );

            #$gc->set_clip_mask ($bm);
            #$gc->set_clip_origin ($dx, $dy);
            #$pixmap->draw_pixmap ($gc, $pm, 0, 0, $dx, $dy, $edge, $edge);
         }
      }
   }

   $self->{board_shown} = Storable::dclone $self->{board};
   #d# save
   #Storable::nstore { board => $self->{board}, size => $self->{size}, path => $self->{path}}, "testboard.storable";

   $expose_area;
}

sub redraw {
   my ($self, $area) = @_;

   if ($area && $self->{pixbuf}) {
      my ($x, $y, $w, $h) = $area->values;
      my ($ox, $oy, $s) = @{$self->{offsets}};

      $self->{canvas}->window->draw_pixbuf ($self->{canvas}->style->white_gc, $self->{pixbuf},
            $x, $y, $x + $ox, $y + $oy, $w, $h,
            "normal", 0, 0);
      $self->{canvas}->window->draw_rectangle ($self->{canvas}->style->black_gc, 0,
                         $x + $ox - 1, $y + $oy - 1, $w + 2, $h + 2) if $::DEBUG_EXPOSE;
   }
}

sub event_update_tree {
   my ($self) = @_;

   $self->{path} = $self->get_path;
   $self->{moveadj}->value_changed if $self->{moveadj};
}

sub event_part {
   my ($self) = @_;
   $self->SUPER::event_part;
   delete $appwin::gamelist->{game}{$self->{channel}};
   $self->destroy;
}

sub event_move {
   my ($self, $pass) = @_;
   sound::play 1, $pass ? "pass" : "move";
}

1;