package room;

use base KGS::Listener::Room;
use base gtk::widget;

sub new {
   my $self = shift;
   $self = $self->SUPER::new(@_);

   $self->listen($self->{conn}, qw(msg_room:));

   $self->{window} = new Gtk2::Window 'toplevel';
   $self->{window}->set_title("KGS Room $self->{name}");
   gtk::state $self->{window}, "room::window", $self->{name}, window_size => [600, 400];

   $self->{window}->signal_connect(delete_event => sub { $self->part; 1 });

   $self->{window}->add($self->{hpane} = new Gtk2::HPaned);
   $self->{hpane}->set(position_set => 1);
   gtk::state $self->{hpane}, "room::hpane", $self->{name}, position => 200;

   $self->{hpane}->pack1((my $vbox = new Gtk2::VBox), 1, 1);
   
   $vbox->add(my $sw = new Gtk2::ScrolledWindow);
   $sw->set_policy("automatic", "always");

   $sw->add(($self->{text} = new gtk::text)->widget);

   $vbox->pack_start(($self->{entry} = new Gtk2::Entry), 0, 1, 0);
   $self->{entry}->signal_connect(activate => sub {
      my $text = $self->{entry}->get_text;
      $self->say($text) if $text =~ /\S/;
      $self->{entry}->set_text("");
   });

   $self->{hpane}->pack2((my $sw = new Gtk2::ScrolledWindow), 0, 1);
   $sw->set_policy("automatic", "always");

   $sw->add(($self->{userlist} = new userlist)->widget);

   $self;
}

sub join {
   my ($self) = @_;
   $self->SUPER::join;

   $self->{window}->show_all;
}

sub part {
   my ($self) = @_;
   $self->SUPER::part;

   delete $::config->{rooms}{$self->{channel}};
   $self->{window}->hide_all;
}

sub inject_msg_room {
   my ($self, $msg) = @_;

   # secret typoe ;-)
   $self->{text}->append_text("\n<user>$self->{name}</user><marker>:</marker> $self->{message}\n");
}

sub event_update_users {
   my ($self, $add, $update, $remove) = @_;

   $self->{userlist}->update ($add, $update, $remove);
}

sub event_update_games {
   my ($self, $add, $update, $remove) = @_;

   $appwin::gamelist->update ($self, $add, $update, $remove);
}

sub event_join {
   my ($self) = @_;
   $self->SUPER::event_join;

   $::config->{rooms}{$self->{channel}} = { channel => $self->{channel}, name => $self->{name} };
}

sub event_update_roominfo {
   my ($self) = @_;

   $self->{text}->append_text("\n<owner>$self->{owner}</owner>\n<description>$self->{description}</description>\n");
}

1;