1 |
#! perl |
2 |
|
3 |
#:META:X_RESOURCE:%.expr:string:background expression |
4 |
#:META:X_RESOURCE:%.border:boolean:respect the terminal border |
5 |
#:META:X_RESOURCE:%.interval:seconds:minimum time between updates |
6 |
|
7 |
=head1 NAME |
8 |
|
9 |
background - manage terminal background |
10 |
|
11 |
=head1 SYNOPSIS |
12 |
|
13 |
urxvt --background-expr 'background expression' |
14 |
--background-border |
15 |
--background-interval seconds |
16 |
|
17 |
=head1 DESCRIPTION |
18 |
|
19 |
This extension manages the terminal background by creating a picture that |
20 |
is behind the text, replacing the normal background colour. |
21 |
|
22 |
It does so by evaluating a Perl expression that I<calculates> the image on |
23 |
the fly, for example, by grabbing the root background or loading a file. |
24 |
|
25 |
While the full power of Perl is available, the operators have been design |
26 |
to be as simple as possible. |
27 |
|
28 |
For example, to load an image and scale it to the window size, you would |
29 |
use: |
30 |
|
31 |
urxvt --background-expr 'scale load "/path/to/mybg.png"' |
32 |
|
33 |
Or specified as a X resource: |
34 |
|
35 |
URxvt.background-expr: scale load "/path/to/mybg.png" |
36 |
|
37 |
=head1 THEORY OF OPERATION |
38 |
|
39 |
At startup, just before the window is mapped for the first time, the |
40 |
expression is evaluated and must yield an image. The image is then |
41 |
extended as necessary to cover the whole terminal window, and is set as a |
42 |
background pixmap. |
43 |
|
44 |
If the image contains an alpha channel, then it will be used as-is in |
45 |
visuals that support alpha channels (for example, for a compositing |
46 |
manager). In other visuals, the terminal background colour will be used to |
47 |
replace any transparency. |
48 |
|
49 |
When the expression relies, directly or indirectly, on the window size, |
50 |
position, the root pixmap, or a timer, then it will be remembered. If not, |
51 |
then it will be removed. |
52 |
|
53 |
If any of the parameters that the expression relies on changes (when the |
54 |
window is moved or resized, its position or size changes; when the root |
55 |
pixmap is replaced by another one the root background changes; or when the |
56 |
timer elapses), then the expression will be evaluated again. |
57 |
|
58 |
For example, an expression such as C<scale load "$HOME/mybg.png"> scales the |
59 |
image to the window size, so it relies on the window size and will |
60 |
be reevaluated each time it is changed, but not when it moves for |
61 |
example. That ensures that the picture always fills the terminal, even |
62 |
after its size changes. |
63 |
|
64 |
=head2 EXPRESSIONS |
65 |
|
66 |
Expressions are normal Perl expressions, in fact, they are Perl blocks - |
67 |
which means you could use multiple lines and statements: |
68 |
|
69 |
again 3600; |
70 |
if (localtime now)[6]) { |
71 |
return scale load "$HOME/weekday.png"; |
72 |
} else { |
73 |
return scale load "$HOME/sunday.png"; |
74 |
} |
75 |
|
76 |
This expression gets evaluated once per hour. It will set F<sunday.png> as |
77 |
background on Sundays, and F<weekday.png> on all other days. |
78 |
|
79 |
Fortunately, we expect that most expressions will be much simpler, with |
80 |
little Perl knowledge needed. |
81 |
|
82 |
Basically, you always start with a function that "generates" an image |
83 |
object, such as C<load>, which loads an image from disk, or C<root>, which |
84 |
returns the root window background image: |
85 |
|
86 |
load "$HOME/mypic.png" |
87 |
|
88 |
The path is usually specified as a quoted string (the exact rules can be |
89 |
found in the L<perlop> manpage). The F<$HOME> at the beginning of the |
90 |
string is expanded to the home directory. |
91 |
|
92 |
Then you prepend one or more modifiers or filtering expressions, such as |
93 |
C<scale>: |
94 |
|
95 |
scale load "$HOME/mypic.png" |
96 |
|
97 |
Just like a mathematical expression with functions, you should read these |
98 |
expressions from right to left, as the C<load> is evaluated first, and |
99 |
its result becomes the argument to the C<scale> function. |
100 |
|
101 |
Many operators also allow some parameters preceding the input image |
102 |
that modify its behaviour. For example, C<scale> without any additional |
103 |
arguments scales the image to size of the terminal window. If you specify |
104 |
an additional argument, it uses it as a scale factor (multiply by 100 to |
105 |
get a percentage): |
106 |
|
107 |
scale 2, load "$HOME/mypic.png" |
108 |
|
109 |
This enlarges the image by a factor of 2 (200%). As you can see, C<scale> |
110 |
has now two arguments, the C<200> and the C<load> expression, while |
111 |
C<load> only has one argument. Arguments are separated from each other by |
112 |
commas. |
113 |
|
114 |
Scale also accepts two arguments, which are then separate factors for both |
115 |
horizontal and vertical dimensions. For example, this halves the image |
116 |
width and doubles the image height: |
117 |
|
118 |
scale 0.5, 2, load "$HOME/mypic.png" |
119 |
|
120 |
Other effects than scaling are also readily available, for example, you can |
121 |
tile the image to fill the whole window, instead of resizing it: |
122 |
|
123 |
tile load "$HOME/mypic.png" |
124 |
|
125 |
In fact, images returned by C<load> are in C<tile> mode by default, so the C<tile> operator |
126 |
is kind of superfluous. |
127 |
|
128 |
Another common effect is to mirror the image, so that the same edges touch: |
129 |
|
130 |
mirror load "$HOME/mypic.png" |
131 |
|
132 |
This is also a typical background expression: |
133 |
|
134 |
rootalign root |
135 |
|
136 |
It first takes a snapshot of the screen background image, and then |
137 |
moves it to the upper left corner of the screen - the result is |
138 |
pseudo-transparency, as the image seems to be static while the window is |
139 |
moved around. |
140 |
|
141 |
=head2 CYCLES AND CACHING |
142 |
|
143 |
As has been mentioned before, the expression might be evaluated multiple |
144 |
times. Each time the expression is reevaluated, a new cycle is said to |
145 |
have begun. Many operators cache their results till the next cycle. |
146 |
|
147 |
For example, the C<load> operator keeps a copy of the image. If it is |
148 |
asked to load the same image on the next cycle it will not load it again, |
149 |
but return the cached copy. |
150 |
|
151 |
This only works for one cycle though, so as long as you load the same |
152 |
image every time, it will always be cached, but when you load a different |
153 |
image, it will forget about the first one. |
154 |
|
155 |
This allows you to either speed things up by keeping multiple images in |
156 |
memory, or conserve memory by loading images more often. |
157 |
|
158 |
For example, you can keep two images in memory and use a random one like |
159 |
this: |
160 |
|
161 |
my $img1 = load "img1.png"; |
162 |
my $img2 = load "img2.png"; |
163 |
(0.5 > rand) ? $img1 : $img2 |
164 |
|
165 |
Since both images are "loaded" every time the expression is evaluated, |
166 |
they are always kept in memory. Contrast this version: |
167 |
|
168 |
my $path1 = "img1.png"; |
169 |
my $path2 = "img2.png"; |
170 |
load ((0.5 > rand) ? $path1 : $path2) |
171 |
|
172 |
Here, a path is selected randomly, and load is only called for one image, |
173 |
so keeps only one image in memory. If, on the next evaluation, luck |
174 |
decides to use the other path, then it will have to load that image again. |
175 |
|
176 |
=head1 REFERENCE |
177 |
|
178 |
=head2 COMMAND LINE SWITCHES |
179 |
|
180 |
=over 4 |
181 |
|
182 |
=item --background-expr perl-expression |
183 |
|
184 |
Specifies the Perl expression to evaluate. |
185 |
|
186 |
=item --background-border |
187 |
|
188 |
By default, the expression creates an image that fills the full window, |
189 |
overwriting borders and any other areas, such as the scrollbar. |
190 |
|
191 |
Specifying this flag changes the behaviour, so that the image only |
192 |
replaces the background of the character area. |
193 |
|
194 |
=item --background-interval seconds |
195 |
|
196 |
Since some operations in the underlying XRender extension can effectively |
197 |
freeze your X-server for prolonged time, this extension enforces a minimum |
198 |
time between updates, which is normally about 0.1 seconds. |
199 |
|
200 |
If you want to do updates more often, you can decrease this safety |
201 |
interval with this switch. |
202 |
|
203 |
=back |
204 |
|
205 |
=cut |
206 |
|
207 |
our %_IMG_CACHE; |
208 |
our %_ONCE_CACHE; |
209 |
our $HOME; |
210 |
our ($self, $old, $new); |
211 |
our ($x, $y, $w, $h); |
212 |
|
213 |
# enforce at least this interval between updates |
214 |
our $MIN_INTERVAL = 6/59.951; |
215 |
|
216 |
{ |
217 |
package urxvt::bgdsl; # background language |
218 |
|
219 |
use List::Util qw(min max sum shuffle); |
220 |
|
221 |
=head2 PROVIDERS/GENERATORS |
222 |
|
223 |
These functions provide an image, by loading it from disk, grabbing it |
224 |
from the root screen or by simply generating it. They are used as starting |
225 |
points to get an image you can play with. |
226 |
|
227 |
=over 4 |
228 |
|
229 |
=item load $path |
230 |
|
231 |
Loads the image at the given C<$path>. The image is set to plane tiling |
232 |
mode. |
233 |
|
234 |
Loaded images will be cached for one cycle. |
235 |
|
236 |
=cut |
237 |
|
238 |
sub load($) { |
239 |
my ($path) = @_; |
240 |
|
241 |
$new->{load}{$path} = $old->{load}{$path} || $self->new_img_from_file ($path); |
242 |
} |
243 |
|
244 |
=item root |
245 |
|
246 |
Returns the root window pixmap, that is, hopefully, the background image |
247 |
of your screen. The image is set to extend mode. |
248 |
|
249 |
This function makes your expression root sensitive, that means it will be |
250 |
reevaluated when the bg image changes. |
251 |
|
252 |
=cut |
253 |
|
254 |
sub root() { |
255 |
$new->{rootpmap_sensitive} = 1; |
256 |
$self->new_img_from_root |
257 |
} |
258 |
|
259 |
=item solid $colour |
260 |
|
261 |
=item solid $width, $height, $colour |
262 |
|
263 |
Creates a new image and completely fills it with the given colour. The |
264 |
image is set to tiling mode. |
265 |
|
266 |
If C<$width> and C<$height> are omitted, it creates a 1x1 image, which is |
267 |
useful for solid backgrounds or for use in filtering effects. |
268 |
|
269 |
=cut |
270 |
|
271 |
sub solid($;$$) { |
272 |
my $colour = pop; |
273 |
|
274 |
my $img = $self->new_img (urxvt::PictStandardARGB32, $_[0] || 1, $_[1] || 1); |
275 |
$img->fill ($colour); |
276 |
$img |
277 |
} |
278 |
|
279 |
=item clone $img |
280 |
|
281 |
Returns an exact copy of the image. This is useful if you want to have |
282 |
multiple copies of the same image to apply different effects to. |
283 |
|
284 |
=cut |
285 |
|
286 |
sub clone($) { |
287 |
$_[0]->clone |
288 |
} |
289 |
|
290 |
=head2 TILING MODES |
291 |
|
292 |
The following operators modify the tiling mode of an image, that is, the |
293 |
way that pixels outside the image area are painted when the image is used. |
294 |
|
295 |
=over 4 |
296 |
|
297 |
=item tile $img |
298 |
|
299 |
Tiles the whole plane with the image and returns this new image - or in |
300 |
other words, it returns a copy of the image in plane tiling mode. |
301 |
|
302 |
Example: load an image and tile it over the background, without |
303 |
resizing. The C<tile> call is superfluous because C<load> already defaults |
304 |
to tiling mode. |
305 |
|
306 |
tile load "mybg.png" |
307 |
|
308 |
=item mirror $img |
309 |
|
310 |
Similar to tile, but reflects the image each time it uses a new copy, so |
311 |
that top edges always touch top edges, right edges always touch right |
312 |
edges and so on (with normal tiling, left edges always touch right edges |
313 |
and top always touch bottom edges). |
314 |
|
315 |
Example: load an image and mirror it over the background, avoiding sharp |
316 |
edges at the image borders at the expense of mirroring the image itself |
317 |
|
318 |
mirror load "mybg.png" |
319 |
|
320 |
=item pad $img |
321 |
|
322 |
Takes an image and modifies it so that all pixels outside the image area |
323 |
become transparent. This mode is most useful when you want to place an |
324 |
image over another image or the background colour while leaving all |
325 |
background pixels outside the image unchanged. |
326 |
|
327 |
Example: load an image and display it in the upper left corner. The rest |
328 |
of the space is left "empty" (transparent or whatever your compositor does |
329 |
in alpha mode, else background colour). |
330 |
|
331 |
pad load "mybg.png" |
332 |
|
333 |
=item extend $img |
334 |
|
335 |
Extends the image over the whole plane, using the closest pixel in the |
336 |
area outside the image. This mode is mostly useful when you use more complex |
337 |
filtering operations and want the pixels outside the image to have the |
338 |
same values as the pixels near the edge. |
339 |
|
340 |
Example: just for curiosity, how does this pixel extension stuff work? |
341 |
|
342 |
extend move 50, 50, load "mybg.png" |
343 |
|
344 |
=cut |
345 |
|
346 |
sub pad($) { |
347 |
my $img = $_[0]->clone; |
348 |
$img->repeat_mode (urxvt::RepeatNone); |
349 |
$img |
350 |
} |
351 |
|
352 |
sub tile($) { |
353 |
my $img = $_[0]->clone; |
354 |
$img->repeat_mode (urxvt::RepeatNormal); |
355 |
$img |
356 |
} |
357 |
|
358 |
sub mirror($) { |
359 |
my $img = $_[0]->clone; |
360 |
$img->repeat_mode (urxvt::RepeatReflect); |
361 |
$img |
362 |
} |
363 |
|
364 |
sub extend($) { |
365 |
my $img = $_[0]->clone; |
366 |
$img->repeat_mode (urxvt::RepeatPad); |
367 |
$img |
368 |
} |
369 |
|
370 |
=back |
371 |
|
372 |
=head2 VARIABLE VALUES |
373 |
|
374 |
The following functions provide variable data such as the terminal window |
375 |
dimensions. They are not (Perl-) variables, they just return stuff that |
376 |
varies. Most of them make your expression sensitive to some events, for |
377 |
example using C<TW> (terminal width) means your expression is evaluated |
378 |
again when the terminal is resized. |
379 |
|
380 |
=over 4 |
381 |
|
382 |
=item TX |
383 |
|
384 |
=item TY |
385 |
|
386 |
Return the X and Y coordinates of the terminal window (the terminal |
387 |
window is the full window by default, and the character area only when in |
388 |
border-respect mode). |
389 |
|
390 |
Using these functions make your expression sensitive to window moves. |
391 |
|
392 |
These functions are mainly useful to align images to the root window. |
393 |
|
394 |
Example: load an image and align it so it looks as if anchored to the |
395 |
background. |
396 |
|
397 |
move -TX, -TY, load "mybg.png" |
398 |
|
399 |
=item TW |
400 |
|
401 |
Return the width (C<TW>) and height (C<TH>) of the terminal window (the |
402 |
terminal window is the full window by default, and the character area only |
403 |
when in border-respect mode). |
404 |
|
405 |
Using these functions make your expression sensitive to window resizes. |
406 |
|
407 |
These functions are mainly useful to scale images, or to clip images to |
408 |
the window size to conserve memory. |
409 |
|
410 |
Example: take the screen background, clip it to the window size, blur it a |
411 |
bit, align it to the window position and use it as background. |
412 |
|
413 |
clip move -TX, -TY, blur 5, root |
414 |
|
415 |
=cut |
416 |
|
417 |
sub TX() { $new->{position_sensitive} = 1; $x } |
418 |
sub TY() { $new->{position_sensitive} = 1; $y } |
419 |
sub TW() { $new->{size_sensitive} = 1; $w } |
420 |
sub TH() { $new->{size_sensitive} = 1; $h } |
421 |
|
422 |
=item now |
423 |
|
424 |
Returns the current time as (fractional) seconds since the epoch. |
425 |
|
426 |
Using this expression does I<not> make your expression sensitive to time, |
427 |
but the next two functions do. |
428 |
|
429 |
=item again $seconds |
430 |
|
431 |
When this function is used the expression will be reevaluated again in |
432 |
C<$seconds> seconds. |
433 |
|
434 |
Example: load some image and rotate it according to the time of day (as if it were |
435 |
the hour pointer of a clock). Update this image every minute. |
436 |
|
437 |
again 60; rotate TW, TH, 50, 50, (now % 86400) * -720 / 86400, scale load "myclock.png" |
438 |
|
439 |
=item counter $seconds |
440 |
|
441 |
Like C<again>, but also returns an increasing counter value, starting at |
442 |
0, which might be useful for some simple animation effects. |
443 |
|
444 |
=cut |
445 |
|
446 |
sub now() { urxvt::NOW } |
447 |
|
448 |
sub again($) { |
449 |
$new->{again} = $_[0]; |
450 |
} |
451 |
|
452 |
sub counter($) { |
453 |
$new->{again} = $_[0]; |
454 |
$self->{counter} + 0 |
455 |
} |
456 |
|
457 |
=back |
458 |
|
459 |
=head2 SHAPE CHANGING OPERATORS |
460 |
|
461 |
The following operators modify the shape, size or position of the image. |
462 |
|
463 |
=over 4 |
464 |
|
465 |
=item clip $img |
466 |
|
467 |
=item clip $width, $height, $img |
468 |
|
469 |
=item clip $x, $y, $width, $height, $img |
470 |
|
471 |
Clips an image to the given rectangle. If the rectangle is outside the |
472 |
image area (e.g. when C<$x> or C<$y> are negative) or the rectangle is |
473 |
larger than the image, then the tiling mode defines how the extra pixels |
474 |
will be filled. |
475 |
|
476 |
If C<$x> an C<$y> are missing, then C<0> is assumed for both. |
477 |
|
478 |
If C<$width> and C<$height> are missing, then the window size will be |
479 |
assumed. |
480 |
|
481 |
Example: load an image, blur it, and clip it to the window size to save |
482 |
memory. |
483 |
|
484 |
clip blur 10, load "mybg.png" |
485 |
|
486 |
=cut |
487 |
|
488 |
sub clip($;$$;$$) { |
489 |
my $img = pop; |
490 |
my $h = pop || TH; |
491 |
my $w = pop || TW; |
492 |
$img->sub_rect ($_[0], $_[1], $w, $h) |
493 |
} |
494 |
|
495 |
=item scale $img |
496 |
|
497 |
=item scale $size_factor, $img |
498 |
|
499 |
=item scale $width_factor, $height_factor, $img |
500 |
|
501 |
Scales the image by the given factors in horizontal |
502 |
(C<$width>) and vertical (C<$height>) direction. |
503 |
|
504 |
If only one factor is give, it is used for both directions. |
505 |
|
506 |
If no factors are given, scales the image to the window size without |
507 |
keeping aspect. |
508 |
|
509 |
=item resize $width, $height, $img |
510 |
|
511 |
Resizes the image to exactly C<$width> times C<$height> pixels. |
512 |
|
513 |
=item fit $img |
514 |
|
515 |
=item fit $width, $height, $img |
516 |
|
517 |
Fits the image into the given C<$width> and C<$height> without changing |
518 |
aspect, or the terminal size. That means it will be shrunk or grown until |
519 |
the whole image fits into the given area, possibly leaving borders. |
520 |
|
521 |
=item cover $img |
522 |
|
523 |
=item cover $width, $height, $img |
524 |
|
525 |
Similar to C<fit>, but shrinks or grows until all of the area is covered |
526 |
by the image, so instead of potentially leaving borders, it will cut off |
527 |
image data that doesn't fit. |
528 |
|
529 |
=cut |
530 |
|
531 |
sub scale($;$;$) { |
532 |
my $img = pop; |
533 |
|
534 |
@_ == 2 ? $img->scale ($_[0] * $img->w, $_[1] * $img->h) |
535 |
: @_ ? $img->scale ($_[0] * $img->w, $_[0] * $img->h) |
536 |
: $img->scale (TW, TH) |
537 |
} |
538 |
|
539 |
sub resize($$$) { |
540 |
my $img = pop; |
541 |
$img->scale ($_[0], $_[1]) |
542 |
} |
543 |
|
544 |
sub fit($;$$) { |
545 |
my $img = pop; |
546 |
my $w = ($_[0] || TW) / $img->w; |
547 |
my $h = ($_[1] || TH) / $img->h; |
548 |
scale +(min $w, $h), $img |
549 |
} |
550 |
|
551 |
sub cover($;$$) { |
552 |
my $img = pop; |
553 |
my $w = ($_[0] || TW) / $img->w; |
554 |
my $h = ($_[1] || TH) / $img->h; |
555 |
scale +(max $w, $h), $img |
556 |
} |
557 |
|
558 |
=item move $dx, $dy, $img |
559 |
|
560 |
Moves the image by C<$dx> pixels in the horizontal, and C<$dy> pixels in |
561 |
the vertical. |
562 |
|
563 |
Example: move the image right by 20 pixels and down by 30. |
564 |
|
565 |
move 20, 30, ... |
566 |
|
567 |
=item align $xalign, $yalign, $img |
568 |
|
569 |
Aligns the image according to a factor - C<0> means the image is moved to |
570 |
the left or top edge (for C<$xalign> or C<$yalign>), C<0.5> means it is |
571 |
exactly centered and C<1> means it touches the right or bottom edge. |
572 |
|
573 |
Example: remove any visible border around an image, center it vertically but move |
574 |
it to the right hand side. |
575 |
|
576 |
align 1, 0.5, pad $img |
577 |
|
578 |
=item center $img |
579 |
|
580 |
=item center $width, $height, $img |
581 |
|
582 |
Centers the image, i.e. the center of the image is moved to the center of |
583 |
the terminal window (or the box specified by C<$width> and C<$height> if |
584 |
given). |
585 |
|
586 |
Example: load an image and center it. |
587 |
|
588 |
center pad load "mybg.png" |
589 |
|
590 |
=item rootalign $img |
591 |
|
592 |
Moves the image so that it appears glued to the screen as opposed to the |
593 |
window. This gives the illusion of a larger area behind the window. It is |
594 |
exactly equivalent to C<move -TX, -TY>, that is, it moves the image to the |
595 |
top left of the screen. |
596 |
|
597 |
Example: load a background image, put it in mirror mode and root align it. |
598 |
|
599 |
rootalign mirror load "mybg.png" |
600 |
|
601 |
Example: take the screen background and align it, giving the illusion of |
602 |
transparency as long as the window isn't in front of other windows. |
603 |
|
604 |
rootalign root |
605 |
|
606 |
=cut |
607 |
|
608 |
sub move($$;$) { |
609 |
my $img = pop->clone; |
610 |
$img->move ($_[0], $_[1]); |
611 |
$img |
612 |
} |
613 |
|
614 |
sub align($;$$) { |
615 |
my $img = pop; |
616 |
|
617 |
move $_[0] * (TW - $img->w), |
618 |
$_[1] * (TH - $img->h), |
619 |
$img |
620 |
} |
621 |
|
622 |
sub center($;$$) { |
623 |
my $img = pop; |
624 |
my $w = $_[0] || TW; |
625 |
my $h = $_[1] || TH; |
626 |
|
627 |
move 0.5 * ($w - $img->w), 0.5 * ($h - $img->h), $img |
628 |
} |
629 |
|
630 |
sub rootalign($) { |
631 |
move -TX, -TY, $_[0] |
632 |
} |
633 |
|
634 |
=item rotate $center_x, $center_y, $degrees, $new_width, $new_height |
635 |
|
636 |
Rotates the image by C<$degrees> degrees, counter-clockwise, around the |
637 |
pointer at C<$center_x> and C<$center_y> (specified as factor of image |
638 |
width/height), generating a new image with width C<$new_width> and height |
639 |
C<$new_height>. |
640 |
|
641 |
#TODO# new width, height, maybe more operators? |
642 |
|
643 |
Example: rotate the image by 90 degrees |
644 |
|
645 |
=cut |
646 |
|
647 |
sub rotate($$$$$$) { |
648 |
my $img = pop; |
649 |
$img->rotate ( |
650 |
$_[0] * $img->w, |
651 |
$_[1] * $img->h, |
652 |
$_[2] * (3.14159265 / 180), |
653 |
$_[3], |
654 |
$_[4], |
655 |
) |
656 |
} |
657 |
|
658 |
=back |
659 |
|
660 |
=head2 COLOUR MODIFICATIONS |
661 |
|
662 |
The following operators change the pixels of the image. |
663 |
|
664 |
=over 4 |
665 |
|
666 |
=item contrast $factor, $img |
667 |
|
668 |
=item contrast $r, $g, $b, $img |
669 |
|
670 |
=item contrast $r, $g, $b, $a, $img |
671 |
|
672 |
Adjusts the I<contrast> of an image. |
673 |
|
674 |
The first form applies a single C<$factor> to red, green and blue, the |
675 |
second form applies separate factors to each colour channel, and the last |
676 |
form includes the alpha channel. |
677 |
|
678 |
Values from 0 to 1 lower the contrast, values higher than 1 increase the |
679 |
contrast. |
680 |
|
681 |
Due to limitations in the underlying XRender extension, lowering contrast |
682 |
also reduces brightness, while increasing contrast currently also |
683 |
increases brightness. |
684 |
|
685 |
=item brightness $bias, $img |
686 |
|
687 |
=item brightness $r, $g, $b, $img |
688 |
|
689 |
=item brightness $r, $g, $b, $a, $img |
690 |
|
691 |
Adjusts the brightness of an image. |
692 |
|
693 |
The first form applies a single C<$bias> to red, green and blue, the |
694 |
second form applies separate biases to each colour channel, and the last |
695 |
form includes the alpha channel. |
696 |
|
697 |
Values less than 0 reduce brightness, while values larger than 0 increase |
698 |
it. Useful range is from -1 to 1 - the former results in a black, the |
699 |
latter in a white picture. |
700 |
|
701 |
Due to idiosyncrasies in the underlying XRender extension, biases less |
702 |
than zero can be I<very> slow. |
703 |
|
704 |
=cut |
705 |
|
706 |
sub contrast($$;$$;$) { |
707 |
my $img = pop; |
708 |
my ($r, $g, $b, $a) = @_; |
709 |
|
710 |
($g, $b) = ($r, $r) if @_ < 3; |
711 |
$a = 1 if @_ < 4; |
712 |
|
713 |
$img = $img->clone; |
714 |
$img->contrast ($r, $g, $b, $a); |
715 |
$img |
716 |
} |
717 |
|
718 |
sub brightness($$;$$;$) { |
719 |
my $img = pop; |
720 |
my ($r, $g, $b, $a) = @_; |
721 |
|
722 |
($g, $b) = ($r, $r) if @_ < 3; |
723 |
$a = 1 if @_ < 4; |
724 |
|
725 |
$img = $img->clone; |
726 |
$img->brightness ($r, $g, $b, $a); |
727 |
$img |
728 |
} |
729 |
|
730 |
=item blur $radius, $img |
731 |
|
732 |
=item blur $radius_horz, $radius_vert, $img |
733 |
|
734 |
Gaussian-blurs the image with (roughly) C<$radius> pixel radius. The radii |
735 |
can also be specified separately. |
736 |
|
737 |
Blurring is often I<very> slow, at least compared or other |
738 |
operators. Larger blur radii are slower than smaller ones, too, so if you |
739 |
don't want to freeze your screen for long times, start experimenting with |
740 |
low values for radius (<5). |
741 |
|
742 |
=cut |
743 |
|
744 |
sub blur($$;$) { |
745 |
my $img = pop; |
746 |
$img->blur ($_[0], @_ >= 2 ? $_[1] : $_[0]) |
747 |
} |
748 |
|
749 |
=back |
750 |
|
751 |
=head2 OTHER STUFF |
752 |
|
753 |
Anything that didn't fit any of the other categories, even after appliyng |
754 |
force and closing our eyes. |
755 |
|
756 |
=over 4 |
757 |
|
758 |
=item once { ... } |
759 |
|
760 |
This function takes a code block as argument, that is, one or more |
761 |
statements enclosed by braces. |
762 |
|
763 |
The trick is that this code block is only evaluated once - future calls |
764 |
will simply return the original image (yes, it should only be used with |
765 |
images). |
766 |
|
767 |
This can be extremely useful to avoid redoign the same slow operations |
768 |
again and again- for example, if your background expression takes the root |
769 |
background, blurs it and then root-aligns it it would have to blur the |
770 |
root background on every window move or resize. |
771 |
|
772 |
Putting the blur into a C<once> block will make sure the blur is only done |
773 |
once: |
774 |
|
775 |
rootlign once { blur 10, root } |
776 |
|
777 |
This leaves the question of how to force reevaluation of the block, in |
778 |
case the root background changes: Right now, all once blocks forget that |
779 |
they ahve been executed before each time the root background changes (if |
780 |
the expression is sensitive to that) or when C<once_again> is called. |
781 |
|
782 |
=item once_again |
783 |
|
784 |
Resets all C<once> block as if they had never been called, i.e. on the |
785 |
next call they will be reevaluated again. |
786 |
|
787 |
=cut |
788 |
|
789 |
sub once(&) { |
790 |
$_ONCE_CACHE{$_[0]+0} ||= $_[0]() |
791 |
} |
792 |
|
793 |
sub once_again() { |
794 |
%_ONCE_CACHE = (); |
795 |
} |
796 |
|
797 |
=back |
798 |
|
799 |
=cut |
800 |
|
801 |
} |
802 |
|
803 |
sub parse_expr { |
804 |
my $expr = eval "sub {\npackage urxvt::bgdsl;\n#line 0 'background expression'\n$_[0]\n}"; |
805 |
die if $@; |
806 |
$expr |
807 |
} |
808 |
|
809 |
# compiles a parsed expression |
810 |
sub set_expr { |
811 |
my ($self, $expr) = @_; |
812 |
|
813 |
$self->{expr} = $expr; |
814 |
$self->recalculate; |
815 |
} |
816 |
|
817 |
# evaluate the current bg expression |
818 |
sub recalculate { |
819 |
my ($arg_self) = @_; |
820 |
|
821 |
# rate limit evaluation |
822 |
|
823 |
if ($arg_self->{next_refresh} > urxvt::NOW) { |
824 |
$arg_self->{next_refresh_timer} = urxvt::timer->new->after ($arg_self->{next_refresh} - urxvt::NOW)->cb (sub { |
825 |
$arg_self->recalculate; |
826 |
}); |
827 |
return; |
828 |
} |
829 |
|
830 |
$arg_self->{next_refresh} = urxvt::NOW + $MIN_INTERVAL; |
831 |
|
832 |
# set environment to evaluate user expression |
833 |
|
834 |
local $self = $arg_self; |
835 |
|
836 |
local $HOME = $ENV{HOME}; |
837 |
local $old = $self->{state}; |
838 |
local $new = my $state = $self->{state} = {}; |
839 |
|
840 |
($x, $y, $w, $h) = |
841 |
$self->background_geometry ($self->{border}); |
842 |
|
843 |
# evaluate user expression |
844 |
|
845 |
my $img = eval { $self->{expr}->() }; |
846 |
warn $@ if $@;#d# |
847 |
die "background-expr did not return an image.\n" if !UNIVERSAL::isa $img, "urxvt::img"; |
848 |
|
849 |
$state->{size_sensitive} = 1 |
850 |
if $img->repeat_mode != urxvt::RepeatNormal; |
851 |
|
852 |
# if the expression is sensitive to external events, prepare reevaluation then |
853 |
|
854 |
my $repeat; |
855 |
|
856 |
if (my $again = $state->{again}) { |
857 |
$repeat = 1; |
858 |
my $self = $self; |
859 |
$state->{timer} = $again == $old->{again} |
860 |
? $old->{timer} |
861 |
: urxvt::timer->new->after ($again)->interval ($again)->cb (sub { |
862 |
++$self->{counter}; |
863 |
$self->recalculate |
864 |
}); |
865 |
} |
866 |
|
867 |
if (delete $state->{position_sensitive}) { |
868 |
$repeat = 1; |
869 |
$self->enable (position_change => sub { $_[0]->recalculate }); |
870 |
} else { |
871 |
$self->disable ("position_change"); |
872 |
} |
873 |
|
874 |
if (delete $state->{size_sensitive}) { |
875 |
$repeat = 1; |
876 |
$self->enable (size_change => sub { $_[0]->recalculate }); |
877 |
} else { |
878 |
$self->disable ("size_change"); |
879 |
} |
880 |
|
881 |
if (delete $state->{rootpmap_sensitive}) { |
882 |
$repeat = 1; |
883 |
$self->enable (rootpmap_change => sub { $_[0]->recalculate }); |
884 |
} else { |
885 |
$self->disable ("rootpmap_change"); |
886 |
} |
887 |
|
888 |
# clear stuff we no longer need |
889 |
|
890 |
%$old = (); |
891 |
|
892 |
unless ($repeat) { |
893 |
delete $self->{state}; |
894 |
delete $self->{expr}; |
895 |
} |
896 |
|
897 |
# set background pixmap |
898 |
|
899 |
$self->set_background ($img, $self->{border}); |
900 |
$self->scr_recolour (0); |
901 |
$self->want_refresh; |
902 |
} |
903 |
|
904 |
sub on_start { |
905 |
my ($self) = @_; |
906 |
|
907 |
my $expr = $self->x_resource ("%.expr") |
908 |
or return; |
909 |
|
910 |
$self->has_render |
911 |
or die "background extension needs RENDER extension 0.10 or higher, ignoring background-expr.\n"; |
912 |
|
913 |
$self->set_expr (parse_expr $expr); |
914 |
$self->{border} = $self->x_resource_boolean ("%.border"); |
915 |
|
916 |
$MIN_INTERVAL = $self->x_resource ("%.interval"); |
917 |
|
918 |
() |
919 |
} |
920 |
|