1 |
#! perl |
2 |
|
3 |
#:META:X_RESOURCE:%.expr:string:background expression |
4 |
#:META:X_RESOURCE:%.border:boolean:respect the terminal border |
5 |
#:META:X_RESOURCE:%.interval:seconds:minimum time between updates |
6 |
|
7 |
=head1 NAME |
8 |
|
9 |
background - manage terminal background |
10 |
|
11 |
=head1 SYNOPSIS |
12 |
|
13 |
urxvt --background-expr 'background expression' |
14 |
--background-border |
15 |
--background-interval seconds |
16 |
|
17 |
=head1 QUICK AND DIRTY CHEAT SHEET |
18 |
|
19 |
Just load a random jpeg image and tile the background with it without |
20 |
scaling or anything else: |
21 |
|
22 |
load "/path/to/img.jpg" |
23 |
|
24 |
The same, but use mirroring/reflection instead of tiling: |
25 |
|
26 |
mirror load "/path/to/img.jpg" |
27 |
|
28 |
Load an image and scale it to exactly fill the terminal window: |
29 |
|
30 |
scale keep { load "/path/to/img.jpg" } |
31 |
|
32 |
Implement pseudo-transparency by using a suitably-aligned root pixmap |
33 |
as window background: |
34 |
|
35 |
rootalign root |
36 |
|
37 |
Likewise, but keep a blurred copy: |
38 |
|
39 |
rootalign keep { blur 10, root } |
40 |
|
41 |
=head1 DESCRIPTION |
42 |
|
43 |
This extension manages the terminal background by creating a picture that |
44 |
is behind the text, replacing the normal background colour. |
45 |
|
46 |
It does so by evaluating a Perl expression that I<calculates> the image on |
47 |
the fly, for example, by grabbing the root background or loading a file. |
48 |
|
49 |
While the full power of Perl is available, the operators have been design |
50 |
to be as simple as possible. |
51 |
|
52 |
For example, to load an image and scale it to the window size, you would |
53 |
use: |
54 |
|
55 |
urxvt --background-expr 'scale keep { load "/path/to/mybg.png" }' |
56 |
|
57 |
Or specified as a X resource: |
58 |
|
59 |
URxvt.background-expr: scale keep { load "/path/to/mybg.png" } |
60 |
|
61 |
=head1 THEORY OF OPERATION |
62 |
|
63 |
At startup, just before the window is mapped for the first time, the |
64 |
expression is evaluated and must yield an image. The image is then |
65 |
extended as necessary to cover the whole terminal window, and is set as a |
66 |
background pixmap. |
67 |
|
68 |
If the image contains an alpha channel, then it will be used as-is in |
69 |
visuals that support alpha channels (for example, for a compositing |
70 |
manager). In other visuals, the terminal background colour will be used to |
71 |
replace any transparency. |
72 |
|
73 |
When the expression relies, directly or indirectly, on the window size, |
74 |
position, the root pixmap, or a timer, then it will be remembered. If not, |
75 |
then it will be removed. |
76 |
|
77 |
If any of the parameters that the expression relies on changes (when the |
78 |
window is moved or resized, its position or size changes; when the root |
79 |
pixmap is replaced by another one the root background changes; or when the |
80 |
timer elapses), then the expression will be evaluated again. |
81 |
|
82 |
For example, an expression such as C<scale keep { load "$HOME/mybg.png" |
83 |
}> scales the image to the window size, so it relies on the window size |
84 |
and will be reevaluated each time it is changed, but not when it moves for |
85 |
example. That ensures that the picture always fills the terminal, even |
86 |
after its size changes. |
87 |
|
88 |
=head2 EXPRESSIONS |
89 |
|
90 |
Expressions are normal Perl expressions, in fact, they are Perl blocks - |
91 |
which means you could use multiple lines and statements: |
92 |
|
93 |
scale keep { |
94 |
again 3600; |
95 |
if (localtime now)[6]) { |
96 |
return load "$HOME/weekday.png"; |
97 |
} else { |
98 |
return load "$HOME/sunday.png"; |
99 |
} |
100 |
} |
101 |
|
102 |
This inner expression is evaluated once per hour (and whenever the |
103 |
terminal window is resized). It sets F<sunday.png> as background on |
104 |
Sundays, and F<weekday.png> on all other days. |
105 |
|
106 |
Fortunately, we expect that most expressions will be much simpler, with |
107 |
little Perl knowledge needed. |
108 |
|
109 |
Basically, you always start with a function that "generates" an image |
110 |
object, such as C<load>, which loads an image from disk, or C<root>, which |
111 |
returns the root window background image: |
112 |
|
113 |
load "$HOME/mypic.png" |
114 |
|
115 |
The path is usually specified as a quoted string (the exact rules can be |
116 |
found in the L<perlop> manpage). The F<$HOME> at the beginning of the |
117 |
string is expanded to the home directory. |
118 |
|
119 |
Then you prepend one or more modifiers or filtering expressions, such as |
120 |
C<scale>: |
121 |
|
122 |
scale load "$HOME/mypic.png" |
123 |
|
124 |
Just like a mathematical expression with functions, you should read these |
125 |
expressions from right to left, as the C<load> is evaluated first, and |
126 |
its result becomes the argument to the C<scale> function. |
127 |
|
128 |
Many operators also allow some parameters preceding the input image |
129 |
that modify its behaviour. For example, C<scale> without any additional |
130 |
arguments scales the image to size of the terminal window. If you specify |
131 |
an additional argument, it uses it as a scale factor (multiply by 100 to |
132 |
get a percentage): |
133 |
|
134 |
scale 2, load "$HOME/mypic.png" |
135 |
|
136 |
This enlarges the image by a factor of 2 (200%). As you can see, C<scale> |
137 |
has now two arguments, the C<200> and the C<load> expression, while |
138 |
C<load> only has one argument. Arguments are separated from each other by |
139 |
commas. |
140 |
|
141 |
Scale also accepts two arguments, which are then separate factors for both |
142 |
horizontal and vertical dimensions. For example, this halves the image |
143 |
width and doubles the image height: |
144 |
|
145 |
scale 0.5, 2, load "$HOME/mypic.png" |
146 |
|
147 |
IF you try out these expressions, you might suffer from some sluggishness, |
148 |
because each time the terminal is resized, it loads the PNG image again |
149 |
and scales it. Scaling is usually fast (and unavoidable), but loading the |
150 |
image can be quite time consuming. This is where C<keep> comes in handy: |
151 |
|
152 |
scale 0.5, 2, keep { load "$HOME/mypic.png" } |
153 |
|
154 |
The C<keep> operator executes all the statements inside the braces only |
155 |
once, or when it thinks the outcome might change. In other cases it |
156 |
returns the last value computed by the brace block. |
157 |
|
158 |
This means that the C<load> is only executed once, which makes it much |
159 |
faster, but also means that more memory is being used, because the loaded |
160 |
image must be kept in memory at all times. In this expression, the |
161 |
trade-off is likely worth it. |
162 |
|
163 |
But back to effects: Other effects than scaling are also readily |
164 |
available, for example, you can tile the image to fill the whole window, |
165 |
instead of resizing it: |
166 |
|
167 |
tile keep { load "$HOME/mypic.png" } |
168 |
|
169 |
In fact, images returned by C<load> are in C<tile> mode by default, so the |
170 |
C<tile> operator is kind of superfluous. |
171 |
|
172 |
Another common effect is to mirror the image, so that the same edges |
173 |
touch: |
174 |
|
175 |
mirror keep { load "$HOME/mypic.png" } |
176 |
|
177 |
Another common background expression is: |
178 |
|
179 |
rootalign root |
180 |
|
181 |
This one first takes a snapshot of the screen background image, and then |
182 |
moves it to the upper left corner of the screen (as opposed to the upper |
183 |
left corner of the terminal window)- the result is pseudo-transparency: |
184 |
the image seems to be static while the window is moved around. |
185 |
|
186 |
=head2 COLOUR SPECIFICATIONS |
187 |
|
188 |
Whenever an operator expects a "colour", then this can be specified in one |
189 |
of two ways: Either as string with an X11 colour specification, such as: |
190 |
|
191 |
"red" # named colour |
192 |
"#f00" # simple rgb |
193 |
"[50]red" # red with 50% alpha |
194 |
"TekHVC:300/50/50" # anything goes |
195 |
|
196 |
OR as an array reference with one, three or four components: |
197 |
|
198 |
[0.5] # 50% gray, 100% alpha |
199 |
[0.5, 0, 0] # dark red, no green or blur, 100% alpha |
200 |
[0.5, 0, 0, 0.7] # same with explicit 70% alpha |
201 |
|
202 |
=head2 CACHING AND SENSITIVITY |
203 |
|
204 |
Since some operations (such as C<load> and C<blur>) can take a long time, |
205 |
caching results can be very important for a smooth operation. Caching can |
206 |
also be useful to reduce memory usage, though, for example, when an image |
207 |
is cached by C<load>, it could be shared by multiple terminal windows |
208 |
running inside urxvtd. |
209 |
|
210 |
=head3 C<keep { ... }> caching |
211 |
|
212 |
The most important way to cache expensive operations is to use C<keep { |
213 |
... }>. The C<keep> operator takes a block of multiple statements enclosed |
214 |
by C<{}> and keeps the return value in memory. |
215 |
|
216 |
An expression can be "sensitive" to various external events, such as |
217 |
scaling or moving the window, root background changes and timers. Simply |
218 |
using an expression (such as C<scale> without parameters) that depends on |
219 |
certain changing values (called "variables"), or using those variables |
220 |
directly, will make an expression sensitive to these events - for example, |
221 |
using C<scale> or C<TW> will make the expression sensitive to the terminal |
222 |
size, and thus to resizing events. |
223 |
|
224 |
When such an event happens, C<keep> will automatically trigger a |
225 |
reevaluation of the whole expression with the new value of the expression. |
226 |
|
227 |
C<keep> is most useful for expensive operations, such as C<blur>: |
228 |
|
229 |
rootalign keep { blur 20, root } |
230 |
|
231 |
This makes a blurred copy of the root background once, and on subsequent |
232 |
calls, just root-aligns it. Since C<blur> is usually quite slow and |
233 |
C<rootalign> is quite fast, this trades extra memory (for the cached |
234 |
blurred pixmap) with speed (blur only needs to be redone when root |
235 |
changes). |
236 |
|
237 |
=head3 C<load> caching |
238 |
|
239 |
The C<load> operator itself does not keep images in memory, but as long as |
240 |
the image is still in memory, C<load> will use the in-memory image instead |
241 |
of loading it freshly from disk. |
242 |
|
243 |
That means that this expression: |
244 |
|
245 |
keep { load "$HOME/path..." } |
246 |
|
247 |
Not only caches the image in memory, other terminal instances that try to |
248 |
C<load> it can reuse that in-memory copy. |
249 |
|
250 |
=head1 REFERENCE |
251 |
|
252 |
=head2 COMMAND LINE SWITCHES |
253 |
|
254 |
=over 4 |
255 |
|
256 |
=item --background-expr perl-expression |
257 |
|
258 |
Specifies the Perl expression to evaluate. |
259 |
|
260 |
=item --background-border |
261 |
|
262 |
By default, the expression creates an image that fills the full window, |
263 |
overwriting borders and any other areas, such as the scrollbar. |
264 |
|
265 |
Specifying this flag changes the behaviour, so that the image only |
266 |
replaces the background of the character area. |
267 |
|
268 |
=item --background-interval seconds |
269 |
|
270 |
Since some operations in the underlying XRender extension can effectively |
271 |
freeze your X-server for prolonged time, this extension enforces a minimum |
272 |
time between updates, which is normally about 0.1 seconds. |
273 |
|
274 |
If you want to do updates more often, you can decrease this safety |
275 |
interval with this switch. |
276 |
|
277 |
=back |
278 |
|
279 |
=cut |
280 |
|
281 |
our %_IMG_CACHE; |
282 |
our $HOME; |
283 |
our ($self, $frame); |
284 |
our ($x, $y, $w, $h); |
285 |
|
286 |
# enforce at least this interval between updates |
287 |
our $MIN_INTERVAL = 6/59.951; |
288 |
|
289 |
{ |
290 |
package urxvt::bgdsl; # background language |
291 |
|
292 |
sub FR_PARENT() { 0 } # parent frame, if any - must be #0 |
293 |
sub FR_CACHE () { 1 } # cached values |
294 |
sub FR_AGAIN () { 2 } # what this expr is sensitive to |
295 |
sub FR_STATE () { 3 } # watchers etc. |
296 |
|
297 |
use List::Util qw(min max sum shuffle); |
298 |
|
299 |
=head2 PROVIDERS/GENERATORS |
300 |
|
301 |
These functions provide an image, by loading it from disk, grabbing it |
302 |
from the root screen or by simply generating it. They are used as starting |
303 |
points to get an image you can play with. |
304 |
|
305 |
=over 4 |
306 |
|
307 |
=item load $path |
308 |
|
309 |
Loads the image at the given C<$path>. The image is set to plane tiling |
310 |
mode. |
311 |
|
312 |
If the image is already in memory (e.g. because another terminal instance |
313 |
uses it), then the in-memory copy us returned instead. |
314 |
|
315 |
=item load_uc $path |
316 |
|
317 |
Load uncached - same as load, but does not cache the image, which means it |
318 |
is I<always> loaded from the filesystem again, even if another copy of it |
319 |
is in memory at the time. |
320 |
|
321 |
=cut |
322 |
|
323 |
sub load_uc($) { |
324 |
$self->new_img_from_file ($_[0]) |
325 |
} |
326 |
|
327 |
sub load($) { |
328 |
my ($path) = @_; |
329 |
|
330 |
$_IMG_CACHE{$path} || do { |
331 |
my $img = load_uc $path; |
332 |
Scalar::Util::weaken ($_IMG_CACHE{$path} = $img); |
333 |
$img |
334 |
} |
335 |
} |
336 |
|
337 |
=item root |
338 |
|
339 |
Returns the root window pixmap, that is, hopefully, the background image |
340 |
of your screen. |
341 |
|
342 |
This function makes your expression root sensitive, that means it will be |
343 |
reevaluated when the bg image changes. |
344 |
|
345 |
=cut |
346 |
|
347 |
sub root() { |
348 |
$frame->[FR_AGAIN]{rootpmap} = 1; |
349 |
$self->new_img_from_root |
350 |
} |
351 |
|
352 |
=item solid $colour |
353 |
|
354 |
=item solid $width, $height, $colour |
355 |
|
356 |
Creates a new image and completely fills it with the given colour. The |
357 |
image is set to tiling mode. |
358 |
|
359 |
If C<$width> and C<$height> are omitted, it creates a 1x1 image, which is |
360 |
useful for solid backgrounds or for use in filtering effects. |
361 |
|
362 |
=cut |
363 |
|
364 |
sub solid($;$$) { |
365 |
my $colour = pop; |
366 |
|
367 |
my $img = $self->new_img (urxvt::PictStandardARGB32, 0, 0, $_[0] || 1, $_[1] || 1); |
368 |
$img->fill ($colour); |
369 |
$img |
370 |
} |
371 |
|
372 |
=item clone $img |
373 |
|
374 |
Returns an exact copy of the image. This is useful if you want to have |
375 |
multiple copies of the same image to apply different effects to. |
376 |
|
377 |
=cut |
378 |
|
379 |
sub clone($) { |
380 |
$_[0]->clone |
381 |
} |
382 |
|
383 |
=item merge $img ... |
384 |
|
385 |
Takes any number of images and merges them together, creating a single |
386 |
image containing them all. The tiling mode of the first image is used as |
387 |
the tiling mode of the resulting image. |
388 |
|
389 |
This function is called automatically when an expression returns multiple |
390 |
images. |
391 |
|
392 |
=cut |
393 |
|
394 |
sub merge(@) { |
395 |
return $_[0] unless $#_; |
396 |
|
397 |
# rather annoyingly clumsy, but optimisation is for another time |
398 |
|
399 |
my $x0 = +1e9; |
400 |
my $y0 = +1e9; |
401 |
my $x1 = -1e9; |
402 |
my $y1 = -1e9; |
403 |
|
404 |
for (@_) { |
405 |
my ($x, $y, $w, $h) = $_->geometry; |
406 |
|
407 |
$x0 = $x if $x0 > $x; |
408 |
$y0 = $y if $y0 > $y; |
409 |
|
410 |
$x += $w; |
411 |
$y += $h; |
412 |
|
413 |
$x1 = $x if $x1 < $x; |
414 |
$y1 = $y if $y1 < $y; |
415 |
} |
416 |
|
417 |
my $base = $self->new_img (urxvt::PictStandardARGB32, $x0, $y0, $x1 - $x0, $y1 - $y0); |
418 |
$base->repeat_mode ($_[0]->repeat_mode); |
419 |
$base->fill ([0, 0, 0, 0]); |
420 |
|
421 |
$base->draw ($_) |
422 |
for @_; |
423 |
|
424 |
$base |
425 |
} |
426 |
|
427 |
=head2 TILING MODES |
428 |
|
429 |
The following operators modify the tiling mode of an image, that is, the |
430 |
way that pixels outside the image area are painted when the image is used. |
431 |
|
432 |
=over 4 |
433 |
|
434 |
=item tile $img |
435 |
|
436 |
Tiles the whole plane with the image and returns this new image - or in |
437 |
other words, it returns a copy of the image in plane tiling mode. |
438 |
|
439 |
Example: load an image and tile it over the background, without |
440 |
resizing. The C<tile> call is superfluous because C<load> already defaults |
441 |
to tiling mode. |
442 |
|
443 |
tile load "mybg.png" |
444 |
|
445 |
=item mirror $img |
446 |
|
447 |
Similar to tile, but reflects the image each time it uses a new copy, so |
448 |
that top edges always touch top edges, right edges always touch right |
449 |
edges and so on (with normal tiling, left edges always touch right edges |
450 |
and top always touch bottom edges). |
451 |
|
452 |
Example: load an image and mirror it over the background, avoiding sharp |
453 |
edges at the image borders at the expense of mirroring the image itself |
454 |
|
455 |
mirror load "mybg.png" |
456 |
|
457 |
=item pad $img |
458 |
|
459 |
Takes an image and modifies it so that all pixels outside the image area |
460 |
become transparent. This mode is most useful when you want to place an |
461 |
image over another image or the background colour while leaving all |
462 |
background pixels outside the image unchanged. |
463 |
|
464 |
Example: load an image and display it in the upper left corner. The rest |
465 |
of the space is left "empty" (transparent or whatever your compositor does |
466 |
in alpha mode, else background colour). |
467 |
|
468 |
pad load "mybg.png" |
469 |
|
470 |
=item extend $img |
471 |
|
472 |
Extends the image over the whole plane, using the closest pixel in the |
473 |
area outside the image. This mode is mostly useful when you use more complex |
474 |
filtering operations and want the pixels outside the image to have the |
475 |
same values as the pixels near the edge. |
476 |
|
477 |
Example: just for curiosity, how does this pixel extension stuff work? |
478 |
|
479 |
extend move 50, 50, load "mybg.png" |
480 |
|
481 |
=cut |
482 |
|
483 |
sub pad($) { |
484 |
my $img = $_[0]->clone; |
485 |
$img->repeat_mode (urxvt::RepeatNone); |
486 |
$img |
487 |
} |
488 |
|
489 |
sub tile($) { |
490 |
my $img = $_[0]->clone; |
491 |
$img->repeat_mode (urxvt::RepeatNormal); |
492 |
$img |
493 |
} |
494 |
|
495 |
sub mirror($) { |
496 |
my $img = $_[0]->clone; |
497 |
$img->repeat_mode (urxvt::RepeatReflect); |
498 |
$img |
499 |
} |
500 |
|
501 |
sub extend($) { |
502 |
my $img = $_[0]->clone; |
503 |
$img->repeat_mode (urxvt::RepeatPad); |
504 |
$img |
505 |
} |
506 |
|
507 |
=back |
508 |
|
509 |
=head2 VARIABLE VALUES |
510 |
|
511 |
The following functions provide variable data such as the terminal window |
512 |
dimensions. They are not (Perl-) variables, they just return stuff that |
513 |
varies. Most of them make your expression sensitive to some events, for |
514 |
example using C<TW> (terminal width) means your expression is evaluated |
515 |
again when the terminal is resized. |
516 |
|
517 |
=over 4 |
518 |
|
519 |
=item TX |
520 |
|
521 |
=item TY |
522 |
|
523 |
Return the X and Y coordinates of the terminal window (the terminal |
524 |
window is the full window by default, and the character area only when in |
525 |
border-respect mode). |
526 |
|
527 |
Using these functions make your expression sensitive to window moves. |
528 |
|
529 |
These functions are mainly useful to align images to the root window. |
530 |
|
531 |
Example: load an image and align it so it looks as if anchored to the |
532 |
background (that's exactly what C<rootalign> does btw.): |
533 |
|
534 |
move -TX, -TY, keep { load "mybg.png" } |
535 |
|
536 |
=item TW |
537 |
|
538 |
Return the width (C<TW>) and height (C<TH>) of the terminal window (the |
539 |
terminal window is the full window by default, and the character area only |
540 |
when in border-respect mode). |
541 |
|
542 |
Using these functions make your expression sensitive to window resizes. |
543 |
|
544 |
These functions are mainly useful to scale images, or to clip images to |
545 |
the window size to conserve memory. |
546 |
|
547 |
Example: take the screen background, clip it to the window size, blur it a |
548 |
bit, align it to the window position and use it as background. |
549 |
|
550 |
clip move -TX, -TY, keep { blur 5, root } |
551 |
|
552 |
=cut |
553 |
|
554 |
sub TX() { $frame->[FR_AGAIN]{position} = 1; $x } |
555 |
sub TY() { $frame->[FR_AGAIN]{position} = 1; $y } |
556 |
sub TW() { $frame->[FR_AGAIN]{size} = 1; $w } |
557 |
sub TH() { $frame->[FR_AGAIN]{size} = 1; $h } |
558 |
|
559 |
=item now |
560 |
|
561 |
Returns the current time as (fractional) seconds since the epoch. |
562 |
|
563 |
Using this expression does I<not> make your expression sensitive to time, |
564 |
but the next two functions do. |
565 |
|
566 |
=item again $seconds |
567 |
|
568 |
When this function is used the expression will be reevaluated again in |
569 |
C<$seconds> seconds. |
570 |
|
571 |
Example: load some image and rotate it according to the time of day (as if it were |
572 |
the hour pointer of a clock). Update this image every minute. |
573 |
|
574 |
again 60; |
575 |
rotate 50, 50, (now % 86400) * -72 / 8640, scale keep { load "myclock.png" } |
576 |
|
577 |
=item counter $seconds |
578 |
|
579 |
Like C<again>, but also returns an increasing counter value, starting at |
580 |
0, which might be useful for some simple animation effects. |
581 |
|
582 |
=cut |
583 |
|
584 |
sub now() { urxvt::NOW } |
585 |
|
586 |
sub again($) { |
587 |
$frame->[FR_AGAIN]{time} = $_[0]; |
588 |
} |
589 |
|
590 |
sub counter($) { |
591 |
$frame->[FR_AGAIN]{time} = $_[0]; |
592 |
$frame->[FR_STATE]{counter} + 0 |
593 |
} |
594 |
|
595 |
=back |
596 |
|
597 |
=head2 SHAPE CHANGING OPERATORS |
598 |
|
599 |
The following operators modify the shape, size or position of the image. |
600 |
|
601 |
=over 4 |
602 |
|
603 |
=item clip $img |
604 |
|
605 |
=item clip $width, $height, $img |
606 |
|
607 |
=item clip $x, $y, $width, $height, $img |
608 |
|
609 |
Clips an image to the given rectangle. If the rectangle is outside the |
610 |
image area (e.g. when C<$x> or C<$y> are negative) or the rectangle is |
611 |
larger than the image, then the tiling mode defines how the extra pixels |
612 |
will be filled. |
613 |
|
614 |
If C<$x> an C<$y> are missing, then C<0> is assumed for both. |
615 |
|
616 |
If C<$width> and C<$height> are missing, then the window size will be |
617 |
assumed. |
618 |
|
619 |
Example: load an image, blur it, and clip it to the window size to save |
620 |
memory. |
621 |
|
622 |
clip keep { blur 10, load "mybg.png" } |
623 |
|
624 |
=cut |
625 |
|
626 |
sub clip($;$$;$$) { |
627 |
my $img = pop; |
628 |
my $h = pop || TH; |
629 |
my $w = pop || TW; |
630 |
$img->sub_rect ($_[0], $_[1], $w, $h) |
631 |
} |
632 |
|
633 |
=item scale $img |
634 |
|
635 |
=item scale $size_factor, $img |
636 |
|
637 |
=item scale $width_factor, $height_factor, $img |
638 |
|
639 |
Scales the image by the given factors in horizontal |
640 |
(C<$width>) and vertical (C<$height>) direction. |
641 |
|
642 |
If only one factor is give, it is used for both directions. |
643 |
|
644 |
If no factors are given, scales the image to the window size without |
645 |
keeping aspect. |
646 |
|
647 |
=item resize $width, $height, $img |
648 |
|
649 |
Resizes the image to exactly C<$width> times C<$height> pixels. |
650 |
|
651 |
=item fit $img |
652 |
|
653 |
=item fit $width, $height, $img |
654 |
|
655 |
Fits the image into the given C<$width> and C<$height> without changing |
656 |
aspect, or the terminal size. That means it will be shrunk or grown until |
657 |
the whole image fits into the given area, possibly leaving borders. |
658 |
|
659 |
=item cover $img |
660 |
|
661 |
=item cover $width, $height, $img |
662 |
|
663 |
Similar to C<fit>, but shrinks or grows until all of the area is covered |
664 |
by the image, so instead of potentially leaving borders, it will cut off |
665 |
image data that doesn't fit. |
666 |
|
667 |
=cut |
668 |
|
669 |
sub scale($;$;$) { |
670 |
my $img = pop; |
671 |
|
672 |
@_ == 2 ? $img->scale ($_[0] * $img->w, $_[1] * $img->h) |
673 |
: @_ ? $img->scale ($_[0] * $img->w, $_[0] * $img->h) |
674 |
: $img->scale (TW, TH) |
675 |
} |
676 |
|
677 |
sub resize($$$) { |
678 |
my $img = pop; |
679 |
$img->scale ($_[0], $_[1]) |
680 |
} |
681 |
|
682 |
sub fit($;$$) { |
683 |
my $img = pop; |
684 |
my $w = ($_[0] || TW) / $img->w; |
685 |
my $h = ($_[1] || TH) / $img->h; |
686 |
scale +(min $w, $h), $img |
687 |
} |
688 |
|
689 |
sub cover($;$$) { |
690 |
my $img = pop; |
691 |
my $w = ($_[0] || TW) / $img->w; |
692 |
my $h = ($_[1] || TH) / $img->h; |
693 |
scale +(max $w, $h), $img |
694 |
} |
695 |
|
696 |
=item move $dx, $dy, $img |
697 |
|
698 |
Moves the image by C<$dx> pixels in the horizontal, and C<$dy> pixels in |
699 |
the vertical. |
700 |
|
701 |
Example: move the image right by 20 pixels and down by 30. |
702 |
|
703 |
move 20, 30, ... |
704 |
|
705 |
=item align $xalign, $yalign, $img |
706 |
|
707 |
Aligns the image according to a factor - C<0> means the image is moved to |
708 |
the left or top edge (for C<$xalign> or C<$yalign>), C<0.5> means it is |
709 |
exactly centered and C<1> means it touches the right or bottom edge. |
710 |
|
711 |
Example: remove any visible border around an image, center it vertically but move |
712 |
it to the right hand side. |
713 |
|
714 |
align 1, 0.5, pad $img |
715 |
|
716 |
=item center $img |
717 |
|
718 |
=item center $width, $height, $img |
719 |
|
720 |
Centers the image, i.e. the center of the image is moved to the center of |
721 |
the terminal window (or the box specified by C<$width> and C<$height> if |
722 |
given). |
723 |
|
724 |
Example: load an image and center it. |
725 |
|
726 |
center keep { pad load "mybg.png" } |
727 |
|
728 |
=item rootalign $img |
729 |
|
730 |
Moves the image so that it appears glued to the screen as opposed to the |
731 |
window. This gives the illusion of a larger area behind the window. It is |
732 |
exactly equivalent to C<move -TX, -TY>, that is, it moves the image to the |
733 |
top left of the screen. |
734 |
|
735 |
Example: load a background image, put it in mirror mode and root align it. |
736 |
|
737 |
rootalign keep { mirror load "mybg.png" } |
738 |
|
739 |
Example: take the screen background and align it, giving the illusion of |
740 |
transparency as long as the window isn't in front of other windows. |
741 |
|
742 |
rootalign root |
743 |
|
744 |
=cut |
745 |
|
746 |
sub move($$;$) { |
747 |
my $img = pop->clone; |
748 |
$img->move ($_[0], $_[1]); |
749 |
$img |
750 |
} |
751 |
|
752 |
sub align($;$$) { |
753 |
my $img = pop; |
754 |
|
755 |
move $_[0] * (TW - $img->w), |
756 |
$_[1] * (TH - $img->h), |
757 |
$img |
758 |
} |
759 |
|
760 |
sub center($;$$) { |
761 |
my $img = pop; |
762 |
my $w = $_[0] || TW; |
763 |
my $h = $_[1] || TH; |
764 |
|
765 |
move 0.5 * ($w - $img->w), 0.5 * ($h - $img->h), $img |
766 |
} |
767 |
|
768 |
sub rootalign($) { |
769 |
move -TX, -TY, $_[0] |
770 |
} |
771 |
|
772 |
=item rotate $center_x, $center_y, $degrees, $img |
773 |
|
774 |
Rotates the image clockwise by C<$degrees> degrees, around the point at |
775 |
C<$center_x> and C<$center_y> (specified as factor of image width/height). |
776 |
|
777 |
Example: rotate the image by 90 degrees around it's center. |
778 |
|
779 |
rotate 0.5, 0.5, 90, keep { load "$HOME/mybg.png" } |
780 |
|
781 |
=cut |
782 |
|
783 |
sub rotate($$$$) { |
784 |
my $img = pop; |
785 |
$img->rotate ( |
786 |
$_[0] * ($img->w + $img->x), |
787 |
$_[1] * ($img->h + $img->y), |
788 |
$_[2] * (3.14159265 / 180), |
789 |
) |
790 |
} |
791 |
|
792 |
=back |
793 |
|
794 |
=head2 COLOUR MODIFICATIONS |
795 |
|
796 |
The following operators change the pixels of the image. |
797 |
|
798 |
=over 4 |
799 |
|
800 |
=item tint $color, $img |
801 |
|
802 |
Tints the image in the given colour. |
803 |
|
804 |
Example: tint the image red. |
805 |
|
806 |
tint "red", load "rgb.png" |
807 |
|
808 |
Example: the same, but specify the colour by component. |
809 |
|
810 |
tint [1, 0, 0], load "rgb.png" |
811 |
|
812 |
=cut |
813 |
|
814 |
sub tint($$) { |
815 |
$_[1]->tint ($_[0]) |
816 |
} |
817 |
|
818 |
=item contrast $factor, $img |
819 |
|
820 |
=item contrast $r, $g, $b, $img |
821 |
|
822 |
=item contrast $r, $g, $b, $a, $img |
823 |
|
824 |
Adjusts the I<contrast> of an image. |
825 |
|
826 |
The first form applies a single C<$factor> to red, green and blue, the |
827 |
second form applies separate factors to each colour channel, and the last |
828 |
form includes the alpha channel. |
829 |
|
830 |
Values from 0 to 1 lower the contrast, values higher than 1 increase the |
831 |
contrast. |
832 |
|
833 |
Due to limitations in the underlying XRender extension, lowering contrast |
834 |
also reduces brightness, while increasing contrast currently also |
835 |
increases brightness. |
836 |
|
837 |
=item brightness $bias, $img |
838 |
|
839 |
=item brightness $r, $g, $b, $img |
840 |
|
841 |
=item brightness $r, $g, $b, $a, $img |
842 |
|
843 |
Adjusts the brightness of an image. |
844 |
|
845 |
The first form applies a single C<$bias> to red, green and blue, the |
846 |
second form applies separate biases to each colour channel, and the last |
847 |
form includes the alpha channel. |
848 |
|
849 |
Values less than 0 reduce brightness, while values larger than 0 increase |
850 |
it. Useful range is from -1 to 1 - the former results in a black, the |
851 |
latter in a white picture. |
852 |
|
853 |
Due to idiosyncrasies in the underlying XRender extension, biases less |
854 |
than zero can be I<very> slow. |
855 |
|
856 |
You can also try the experimental(!) C<muladd> operator. |
857 |
|
858 |
=cut |
859 |
|
860 |
sub contrast($$;$$;$) { |
861 |
my $img = pop; |
862 |
my ($r, $g, $b, $a) = @_; |
863 |
|
864 |
($g, $b) = ($r, $r) if @_ < 3; |
865 |
$a = 1 if @_ < 4; |
866 |
|
867 |
$img = $img->clone; |
868 |
$img->contrast ($r, $g, $b, $a); |
869 |
$img |
870 |
} |
871 |
|
872 |
sub brightness($$;$$;$) { |
873 |
my $img = pop; |
874 |
my ($r, $g, $b, $a) = @_; |
875 |
|
876 |
($g, $b) = ($r, $r) if @_ < 3; |
877 |
$a = 1 if @_ < 4; |
878 |
|
879 |
$img = $img->clone; |
880 |
$img->brightness ($r, $g, $b, $a); |
881 |
$img |
882 |
} |
883 |
|
884 |
=item muladd $mul, $add, $img # EXPERIMENTAL |
885 |
|
886 |
First multipliesthe pixels by C<$mul>, then adds C<$add>. This cna be used |
887 |
to implement brightness and contrast at the same time, with a wider value |
888 |
range than contrast and brightness operators. |
889 |
|
890 |
Due to numerous bugs in XRender implementations, it can also introduce a |
891 |
number of visual artifacts. |
892 |
|
893 |
Example: increase contrast by a factor of C<$c> without changing image |
894 |
brightness too much. |
895 |
|
896 |
muladd $c, (1 - $c) * 0.5, $img |
897 |
|
898 |
=cut |
899 |
|
900 |
sub muladd($$$) { |
901 |
$_[2]->muladd ($_[0], $_[1]) |
902 |
} |
903 |
|
904 |
=item blur $radius, $img |
905 |
|
906 |
=item blur $radius_horz, $radius_vert, $img |
907 |
|
908 |
Gaussian-blurs the image with (roughly) C<$radius> pixel radius. The radii |
909 |
can also be specified separately. |
910 |
|
911 |
Blurring is often I<very> slow, at least compared or other |
912 |
operators. Larger blur radii are slower than smaller ones, too, so if you |
913 |
don't want to freeze your screen for long times, start experimenting with |
914 |
low values for radius (<5). |
915 |
|
916 |
=cut |
917 |
|
918 |
sub blur($$;$) { |
919 |
my $img = pop; |
920 |
$img->blur ($_[0], @_ >= 2 ? $_[1] : $_[0]) |
921 |
} |
922 |
|
923 |
=back |
924 |
|
925 |
=head2 OTHER STUFF |
926 |
|
927 |
Anything that didn't fit any of the other categories, even after applying |
928 |
force and closing our eyes. |
929 |
|
930 |
=over 4 |
931 |
|
932 |
=item keep { ... } |
933 |
|
934 |
This operator takes a code block as argument, that is, one or more |
935 |
statements enclosed by braces. |
936 |
|
937 |
The trick is that this code block is only evaluated when the outcome |
938 |
changes - on other calls the C<keep> simply returns the image it computed |
939 |
previously (yes, it should only be used with images). Or in other words, |
940 |
C<keep> I<caches> the result of the code block so it doesn't need to be |
941 |
computed again. |
942 |
|
943 |
This can be extremely useful to avoid redoing slow operations - for |
944 |
example, if your background expression takes the root background, blurs it |
945 |
and then root-aligns it it would have to blur the root background on every |
946 |
window move or resize. |
947 |
|
948 |
Another example is C<load>, which can be quite slow. |
949 |
|
950 |
In fact, urxvt itself encloses the whole expression in some kind of |
951 |
C<keep> block so it only is reevaluated as required. |
952 |
|
953 |
Putting the blur into a C<keep> block will make sure the blur is only done |
954 |
once, while the C<rootalign> is still done each time the window moves. |
955 |
|
956 |
rootalign keep { blur 10, root } |
957 |
|
958 |
This leaves the question of how to force reevaluation of the block, |
959 |
in case the root background changes: If expression inside the block |
960 |
is sensitive to some event (root background changes, window geometry |
961 |
changes), then it will be reevaluated automatically as needed. |
962 |
|
963 |
=cut |
964 |
|
965 |
sub keep(&) { |
966 |
my $id = $_[0]+0; |
967 |
|
968 |
local $frame = $self->{frame_cache}{$id} ||= [$frame]; |
969 |
|
970 |
unless ($frame->[FR_CACHE]) { |
971 |
$frame->[FR_CACHE] = [ $_[0]() ]; |
972 |
|
973 |
my $self = $self; |
974 |
my $frame = $frame; |
975 |
Scalar::Util::weaken $frame; |
976 |
$self->compile_frame ($frame, sub { |
977 |
# clear this frame cache, also for all parents |
978 |
for (my $frame = $frame; $frame; $frame = $frame->[0]) { |
979 |
undef $frame->[FR_CACHE]; |
980 |
} |
981 |
|
982 |
$self->recalculate; |
983 |
}); |
984 |
}; |
985 |
|
986 |
# in scalar context we always return the first original result, which |
987 |
# is not quite how perl works. |
988 |
wantarray |
989 |
? @{ $frame->[FR_CACHE] } |
990 |
: $frame->[FR_CACHE][0] |
991 |
} |
992 |
|
993 |
# sub keep_clear() { |
994 |
# delete $self->{frame_cache}; |
995 |
# } |
996 |
|
997 |
=back |
998 |
|
999 |
=cut |
1000 |
|
1001 |
} |
1002 |
|
1003 |
sub parse_expr { |
1004 |
my $expr = eval |
1005 |
"sub {\n" |
1006 |
. "package urxvt::bgdsl;\n" |
1007 |
. "#line 0 'background expression'\n" |
1008 |
. "$_[0]\n" |
1009 |
. "}"; |
1010 |
die if $@; |
1011 |
$expr |
1012 |
} |
1013 |
|
1014 |
# compiles a parsed expression |
1015 |
sub set_expr { |
1016 |
my ($self, $expr) = @_; |
1017 |
|
1018 |
$self->{root} = []; # the outermost frame |
1019 |
$self->{expr} = $expr; |
1020 |
$self->recalculate; |
1021 |
} |
1022 |
|
1023 |
# takes a hash of sensitivity indicators and installs watchers |
1024 |
sub compile_frame { |
1025 |
my ($self, $frame, $cb) = @_; |
1026 |
|
1027 |
my $state = $frame->[urxvt::bgdsl::FR_STATE] ||= {}; |
1028 |
my $again = $frame->[urxvt::bgdsl::FR_AGAIN]; |
1029 |
|
1030 |
# don't keep stuff alive |
1031 |
Scalar::Util::weaken $state; |
1032 |
|
1033 |
if ($again->{nested}) { |
1034 |
$state->{nested} = 1; |
1035 |
} else { |
1036 |
delete $state->{nested}; |
1037 |
} |
1038 |
|
1039 |
if (my $interval = $again->{time}) { |
1040 |
$state->{time} = [$interval, urxvt::timer->new->after ($interval)->interval ($interval)] |
1041 |
if $state->{time}[0] != $interval; |
1042 |
|
1043 |
# callback *might* have changed, although we could just rule that out |
1044 |
$state->{time}[1]->cb (sub { |
1045 |
++$state->{counter}; |
1046 |
$cb->(); |
1047 |
}); |
1048 |
} else { |
1049 |
delete $state->{time}; |
1050 |
} |
1051 |
|
1052 |
if ($again->{position}) { |
1053 |
$state->{position} = $self->on (position_change => $cb); |
1054 |
} else { |
1055 |
delete $state->{position}; |
1056 |
} |
1057 |
|
1058 |
if ($again->{size}) { |
1059 |
$state->{size} = $self->on (size_change => $cb); |
1060 |
} else { |
1061 |
delete $state->{size}; |
1062 |
} |
1063 |
|
1064 |
if ($again->{rootpmap}) { |
1065 |
$state->{rootpmap} = $self->on (rootpmap_change => $cb); |
1066 |
} else { |
1067 |
delete $state->{rootpmap}; |
1068 |
} |
1069 |
} |
1070 |
|
1071 |
# evaluate the current bg expression |
1072 |
sub recalculate { |
1073 |
my ($arg_self) = @_; |
1074 |
|
1075 |
# rate limit evaluation |
1076 |
|
1077 |
if ($arg_self->{next_refresh} > urxvt::NOW) { |
1078 |
$arg_self->{next_refresh_timer} = urxvt::timer->new->after ($arg_self->{next_refresh} - urxvt::NOW)->cb (sub { |
1079 |
$arg_self->recalculate; |
1080 |
}); |
1081 |
return; |
1082 |
} |
1083 |
|
1084 |
$arg_self->{next_refresh} = urxvt::NOW + $MIN_INTERVAL; |
1085 |
|
1086 |
# set environment to evaluate user expression |
1087 |
|
1088 |
local $self = $arg_self; |
1089 |
local $HOME = $ENV{HOME}; |
1090 |
local $frame = $self->{root}; |
1091 |
|
1092 |
($x, $y, $w, $h) = $self->background_geometry ($self->{border}); |
1093 |
|
1094 |
# evaluate user expression |
1095 |
|
1096 |
my @img = eval { $self->{expr}->() }; |
1097 |
die $@ if $@; |
1098 |
die "background-expr did not return anything.\n" unless @img; |
1099 |
die "background-expr: expected image(s), got something else.\n" |
1100 |
if grep { !UNIVERSAL::isa $_, "urxvt::img" } @img; |
1101 |
|
1102 |
my $img = urxvt::bgdsl::merge @img; |
1103 |
|
1104 |
$frame->[FR_AGAIN]{size} = 1 |
1105 |
if $img->repeat_mode != urxvt::RepeatNormal; |
1106 |
|
1107 |
# if the expression is sensitive to external events, prepare reevaluation then |
1108 |
$self->compile_frame ($frame, sub { $arg_self->recalculate }); |
1109 |
|
1110 |
# clear stuff we no longer need |
1111 |
|
1112 |
# unless (%{ $frame->[FR_STATE] }) { |
1113 |
# delete $self->{state}; |
1114 |
# delete $self->{expr}; |
1115 |
# } |
1116 |
|
1117 |
# set background pixmap |
1118 |
|
1119 |
$self->set_background ($img, $self->{border}); |
1120 |
$self->scr_recolour (0); |
1121 |
$self->want_refresh; |
1122 |
} |
1123 |
|
1124 |
sub on_start { |
1125 |
my ($self) = @_; |
1126 |
|
1127 |
my $expr = $self->x_resource ("%.expr") |
1128 |
or return; |
1129 |
|
1130 |
$self->has_render |
1131 |
or die "background extension needs RENDER extension 0.10 or higher, ignoring background-expr.\n"; |
1132 |
|
1133 |
$self->set_expr (parse_expr $expr); |
1134 |
$self->{border} = $self->x_resource_boolean ("%.border"); |
1135 |
|
1136 |
$MIN_INTERVAL = $self->x_resource ("%.interval"); |
1137 |
|
1138 |
() |
1139 |
} |
1140 |
|