1 |
#! perl |
2 |
|
3 |
our $EXPR = 'move load "/root/pix/das_fette_schwein.jpg", repeat_wrap, X, Y'; |
4 |
$EXPR = 'rotate load "/root/pix/das_fette_schwein.jpg", W, H, 50, 50, counter 1/60, repeat_mirror'; |
5 |
#$EXPR = 'blur root, 10, 10' |
6 |
#$EXPR = 'blur move (root, -x, -y), 5, 5' |
7 |
#resize load "/root/pix/das_fette_schwein.jpg", w, h |
8 |
|
9 |
use Safe; |
10 |
|
11 |
our ($bgdsl_self, $old, $new); |
12 |
our ($l, $t, $w, $h); |
13 |
|
14 |
{ |
15 |
package urxvt::bgdsl; # background language |
16 |
|
17 |
*repeat_black = \&urxvt::RepeatNone; #TODO wtf |
18 |
*repeat_wrap = \&urxvt::RepeatNormal; |
19 |
*repeat_pad = \&urxvt::RepeatPad; |
20 |
*repeat_mirror = \&urxvt::RepeatReflect; |
21 |
|
22 |
sub load($) { |
23 |
my ($path) = @_; |
24 |
|
25 |
$new->{load}{$path} = $old->{load}{$path} || $bgdsl_self->new_img_from_file ($path); |
26 |
} |
27 |
|
28 |
sub root() { |
29 |
die "root op not supported, exg, we need you"; |
30 |
} |
31 |
|
32 |
# sub clone($) { |
33 |
# $_[0]->clone |
34 |
# } |
35 |
|
36 |
sub subrect($$$$$;$) { |
37 |
$_[0]->sub_rect ($_[1], $_[2], $_[3], $_[4], $_[5]) |
38 |
} |
39 |
|
40 |
sub resize($$$) { |
41 |
$_[0]->scale ($_[1], $_[2]) |
42 |
} |
43 |
|
44 |
sub move($$$;$) { |
45 |
# TODO: must be simpler |
46 |
$_[0]->transform ($_[0]->w, $_[0]->h, |
47 |
1, 0, $_[1], |
48 |
0, 1, $_[2], |
49 |
0, 0, 1, |
50 |
$_[3], |
51 |
) |
52 |
} |
53 |
|
54 |
sub rotate($$$$$$;$) { |
55 |
$_[0]->rotate ( |
56 |
$_[1], |
57 |
$_[2], |
58 |
$_[3] * $_[0]->w * .01, |
59 |
$_[4] * $_[0]->h * .01, |
60 |
$_[5] * (3.14159265 / 180), |
61 |
$_[6], |
62 |
) |
63 |
} |
64 |
|
65 |
sub blur($$$) { |
66 |
my ($img, $rh, $rv) = @_; |
67 |
|
68 |
$img = $img->clone; |
69 |
$img->blur ($rh, $rv); |
70 |
$img |
71 |
} |
72 |
|
73 |
sub contrast($$;$$;$) { |
74 |
my ($img, $r, $g, $b, $a) = @_; |
75 |
|
76 |
($g, $b) = ($r, $r) if @_ < 4; |
77 |
$a = 1 if @_ < 5; |
78 |
|
79 |
$img = $img->clone; |
80 |
$img->contrast ($r, $g, $b, $a); |
81 |
$img |
82 |
} |
83 |
|
84 |
sub brightness($$;$$;$) { |
85 |
my ($img, $r, $g, $b, $a) = @_; |
86 |
|
87 |
($g, $b) = ($r, $r) if @_ < 4; |
88 |
$a = 1 if @_ < 5; |
89 |
|
90 |
$img = $img->clone; |
91 |
$img->brightness ($r, $g, $b, $a); |
92 |
$img |
93 |
} |
94 |
|
95 |
sub X() { $new->{position_sensitive} = 1; $l } |
96 |
sub Y() { $new->{position_sensitive} = 1; $t } |
97 |
sub W() { $new->{size_sensitive} = 1; $w } |
98 |
sub H() { $new->{size_sensitive} = 1; $h } |
99 |
|
100 |
sub now() { urxvt::NOW } |
101 |
|
102 |
sub again($) { |
103 |
$new->{again} = $_[0]; |
104 |
} |
105 |
|
106 |
sub counter($) { |
107 |
$new->{again} = $_[0]; |
108 |
$bgdsl_self->{counter}++ + 0 |
109 |
} |
110 |
} |
111 |
|
112 |
sub parse_expr { |
113 |
my $expr = eval "sub {\npackage urxvt::bgdsl;\n#line 0 'background expression'\n$_[0]\n}"; |
114 |
die if $@; |
115 |
$expr |
116 |
} |
117 |
|
118 |
# compiles a parsed expression |
119 |
sub set_expr { |
120 |
my ($self, $expr) = @_; |
121 |
|
122 |
$self->{expr} = $expr; |
123 |
$self->recalculate; |
124 |
} |
125 |
|
126 |
# evaluate the current bg expression |
127 |
sub recalculate { |
128 |
my ($self) = @_; |
129 |
|
130 |
local $bgdsl_self = $self; |
131 |
|
132 |
local $old = $self->{state}; |
133 |
local $new = my $state = $self->{state} = {}; |
134 |
|
135 |
($l, $t, $w, $h) = |
136 |
$self->get_geometry; |
137 |
|
138 |
my $img = eval { $self->{expr}->() }; |
139 |
warn $@ if $@;#d# |
140 |
|
141 |
%$old = (); |
142 |
|
143 |
my $repeat; |
144 |
|
145 |
if (my $again = $state->{again}) { |
146 |
$repeat = 1; |
147 |
$state->{again} = urxvt::timer->new->after ($again)->cb (sub { $self->recalculate }); |
148 |
} |
149 |
|
150 |
if (delete $state->{position_sensitive}) { |
151 |
$repeat = 1; |
152 |
$self->enable (position_change => sub { $_[0]->recalculate }); |
153 |
} else { |
154 |
$self->disable ("position_change"); |
155 |
} |
156 |
|
157 |
if (delete $state->{size_sensitive}) { |
158 |
$repeat = 1; |
159 |
$self->enable (size_change => sub { $_[0]->recalculate }); |
160 |
} else { |
161 |
$self->disable ("size_change"); |
162 |
} |
163 |
|
164 |
unless ($repeat) { |
165 |
delete $self->{state}; |
166 |
delete $self->{expr}; |
167 |
} |
168 |
|
169 |
$img = $img->sub_rect (0, 0, $w, $h) |
170 |
if $img->w != $w || $img->h != $h; |
171 |
|
172 |
$self->set_background ($img); |
173 |
$self->scr_recolour (0); |
174 |
$self->want_refresh; |
175 |
} |
176 |
|
177 |
sub on_start { |
178 |
my ($self) = @_; |
179 |
|
180 |
$self->set_expr (parse_expr $EXPR); |
181 |
|
182 |
() |
183 |
} |
184 |
|