1 |
#! perl |
2 |
|
3 |
# Author: Tim Pope <rxvt-unicodeNOSPAM@tpope.org> |
4 |
# Bob Farrell <robertanthonyfarrell@gmail.com> |
5 |
|
6 |
#:META:RESOURCE:%.launcher:string:default launcher command |
7 |
#:META:RESOURCE:%.button:string:the button, yeah |
8 |
#:META:RESOURCE:%.pattern.:string:extra pattern to match |
9 |
#:META:RESOURCE:%.launcher.:string:custom launcher for pattern |
10 |
#:META:RESOURCE:%.rend.:string:custom rednition for pattern |
11 |
|
12 |
=head1 NAME |
13 |
|
14 |
matcher - match strings in terminal output and change their rendition |
15 |
|
16 |
=head1 DESCRIPTION |
17 |
|
18 |
Uses per-line display filtering (C<on_line_update>) to underline text |
19 |
matching a certain pattern and make it clickable. When clicked with the |
20 |
mouse button specified in the C<matcher.button> resource (default 2, or |
21 |
middle), the program specified in the C<matcher.launcher> resource |
22 |
(default, the C<url-launcher> resource, C<sensible-browser>) will be started |
23 |
with the matched text as first argument. The default configuration is |
24 |
suitable for matching URLs and launching a web browser, like the |
25 |
former "mark-urls" extension. |
26 |
|
27 |
The default pattern to match URLs can be overridden with the |
28 |
C<matcher.pattern.0> resource, and additional patterns can be specified |
29 |
with numbered patterns, in a manner similar to the "selection" extension. |
30 |
The launcher can also be overridden on a per-pattern basis. |
31 |
|
32 |
It is possible to activate the most recently seen match or a list of matches |
33 |
from the keyboard. Simply bind a keysym to "matcher:last" or |
34 |
"matcher:list" as seen in the example below. |
35 |
|
36 |
Example: load and use the matcher extension with defaults. |
37 |
|
38 |
URxvt.perl-ext: default,matcher |
39 |
|
40 |
Example: use a custom configuration. |
41 |
|
42 |
URxvt.url-launcher: sensible-browser |
43 |
URxvt.keysym.C-Delete: matcher:last |
44 |
URxvt.keysym.M-Delete: matcher:list |
45 |
URxvt.matcher.button: 1 |
46 |
URxvt.matcher.pattern.1: \\bwww\\.[\\w-]+\\.[\\w./?&@#-]*[\\w/-] |
47 |
URxvt.matcher.pattern.2: \\B(/\\S+?):(\\d+)(?=:|$) |
48 |
URxvt.matcher.launcher.2: gvim +$2 $1 |
49 |
|
50 |
=cut |
51 |
|
52 |
my $url = |
53 |
qr{ |
54 |
(?:https?://|ftp://|news://|mailto:|file://|\bwww\.) |
55 |
[\w\-\@;\/?:&=%\$.+!*\x27,~#]* |
56 |
( |
57 |
\([\w\-\@;\/?:&=%\$.+!*\x27,~#]*\)| # Allow a pair of matched parentheses |
58 |
[\w\-\@;\/?:&=%\$+*~] # exclude some trailing characters (heuristic) |
59 |
)+ |
60 |
}x; |
61 |
|
62 |
sub on_key_press { |
63 |
my ($self, $event, $keysym, $octets) = @_; |
64 |
|
65 |
return unless $self->{overlay}; |
66 |
|
67 |
delete $self->{overlay}; |
68 |
|
69 |
my $i = ($keysym == 96 ? 0 : $keysym - 48); |
70 |
if ($i >= 0 && $i < @{ $self->{matches} }) { |
71 |
my @exec = @{ $self->{matches}[$i] }; |
72 |
shift @exec; |
73 |
$self->exec_async (@exec); |
74 |
} |
75 |
|
76 |
1 |
77 |
} |
78 |
|
79 |
# backwards compat |
80 |
sub on_user_command { |
81 |
my ($self, $cmd) = @_; |
82 |
|
83 |
if ($cmd =~ s/^matcher:list\b//) { |
84 |
$self->matchlist; |
85 |
} else { |
86 |
if ($cmd =~ s/^matcher:last\b//) { |
87 |
$self->most_recent; |
88 |
} elsif ($cmd =~ s/^matcher\b//) { |
89 |
# for backward compatibility |
90 |
$self->most_recent; |
91 |
} |
92 |
} |
93 |
|
94 |
() |
95 |
} |
96 |
|
97 |
sub on_action { |
98 |
my ($self, $action) = @_; |
99 |
|
100 |
if ($action eq "list") { |
101 |
$self->matchlist; |
102 |
} elsif ($action eq "last") { |
103 |
$self->most_recent; |
104 |
} |
105 |
|
106 |
() |
107 |
} |
108 |
|
109 |
sub matchlist { |
110 |
my ($self) = @_; |
111 |
|
112 |
@{ $self->{matches} } = (); |
113 |
my $row = $self->nrow - 1; |
114 |
while ($row >= 0 && @{ $self->{matches} } < 10) { |
115 |
my $line = $self->line ($row); |
116 |
my @matches = $self->find_matches ($row, 0); |
117 |
|
118 |
for (sort { $b->[0] <=> $a->[0] } @matches) { |
119 |
shift @$_; |
120 |
push @{ $self->{matches} }, $_; |
121 |
last if @{ $self->{matches} } == 10; |
122 |
} |
123 |
|
124 |
$row = $line->beg - 1; |
125 |
} |
126 |
|
127 |
return unless @{ $self->{matches} }; |
128 |
|
129 |
my $width = 0; |
130 |
|
131 |
my $i = 0; |
132 |
for my $match (@{ $self->{matches} }) { |
133 |
my $text = $match->[0]; |
134 |
my $w = $self->strwidth ("$i-$text"); |
135 |
|
136 |
$width = $w if $w > $width; |
137 |
$i++; |
138 |
} |
139 |
|
140 |
$width = $self->ncol - 2 if $width > $self->ncol - 2; |
141 |
|
142 |
$self->{overlay} = $self->overlay (0, 0, $width, scalar (@{ $self->{matches} }), urxvt::OVERLAY_RSTYLE, 2); |
143 |
my $i = 0; |
144 |
for my $match (@{ $self->{matches} }) { |
145 |
my $text = $match->[0]; |
146 |
|
147 |
$self->{overlay}->set (0, $i, "$i-$text"); |
148 |
$i++; |
149 |
} |
150 |
|
151 |
} |
152 |
|
153 |
sub most_recent { |
154 |
my ($self) = shift; |
155 |
my $row = $self->nrow; |
156 |
my @exec; |
157 |
while($row-- > $self->top_row) { |
158 |
@exec = $self->command_for($row); |
159 |
last if(@exec); |
160 |
} |
161 |
if(@exec) { |
162 |
return $self->exec_async (@exec); |
163 |
} |
164 |
() |
165 |
} |
166 |
|
167 |
sub my_resource { |
168 |
$_[0]->x_resource ("%.$_[1]") |
169 |
} |
170 |
|
171 |
# turn a rendition spec in the resource into a sub that implements it on $_ |
172 |
sub parse_rend { |
173 |
my ($self, $str) = @_; |
174 |
my ($mask, $fg, $bg, $failed) = $str ? urxvt::rend2mask($str) |
175 |
: (urxvt::RS_Uline, undef, undef, []); |
176 |
warn "Failed to parse rendition string: " . join(',', @$failed) if @$failed; |
177 |
my @rend; |
178 |
push @rend, sub { $_ |= $mask } if $mask; |
179 |
push @rend, sub { $_ = urxvt::SET_FGCOLOR($_, $fg) } if defined $fg; |
180 |
push @rend, sub { $_ = urxvt::SET_BGCOLOR($_, $bg) } if defined $bg; |
181 |
sub { |
182 |
for my $s ( @rend ) { &$s }; |
183 |
} |
184 |
} |
185 |
|
186 |
sub on_start { |
187 |
my ($self) = @_; |
188 |
|
189 |
$self->{launcher} = $self->my_resource ("launcher") || $self->x_resource("url-launcher") || "sensible-browser"; |
190 |
|
191 |
$self->{matches} = []; |
192 |
$self->{button} = 2; |
193 |
$self->{state} = 0; |
194 |
if($self->{argv}[0] || $self->my_resource ("button")) { |
195 |
my @mods = split '', $self->{argv}[0] || $self->my_resource ("button"); |
196 |
for my $mod (@mods) { |
197 |
if($mod =~ /^\d+$/) { |
198 |
$self->{button} = $mod; |
199 |
} elsif($mod eq "C") { |
200 |
$self->{state} |= urxvt::ControlMask; |
201 |
} elsif($mod eq "S") { |
202 |
$self->{state} |= urxvt::ShiftMask; |
203 |
} elsif($mod eq "M") { |
204 |
$self->{state} |= $self->ModMetaMask; |
205 |
} elsif($mod ne "-" && $mod ne " ") { |
206 |
warn("$mod is invalid in $self->{_name}<$self->{argv}[0]>\n"); |
207 |
} |
208 |
} |
209 |
} |
210 |
|
211 |
my @defaults = ($url); |
212 |
my @matchers; |
213 |
for (my $idx = 0; defined (my $res = $self->my_resource ("pattern.$idx") || $defaults[$idx]); $idx++) { |
214 |
$res = $self->locale_decode ($res); |
215 |
utf8::encode $res; |
216 |
my $launcher = $self->my_resource ("launcher.$idx"); |
217 |
$launcher =~ s/\$&|\$\{&\}/\${0}/g if $launcher; |
218 |
my $rend = $self->parse_rend($self->my_resource ("rend.$idx")); |
219 |
unshift @matchers, [qr($res)x,$launcher,$rend]; |
220 |
} |
221 |
$self->{matchers} = \@matchers; |
222 |
|
223 |
() |
224 |
} |
225 |
|
226 |
sub on_line_update { |
227 |
my ($self, $row) = @_; |
228 |
|
229 |
# fetch the line that has changed |
230 |
my $line = $self->line ($row); |
231 |
my $text = $line->t; |
232 |
my $i = 0; |
233 |
|
234 |
# find all urls (if any) |
235 |
for my $matcher (@{$self->{matchers}}) { |
236 |
while ($text =~ /$matcher->[0]/g) { |
237 |
#print "$&\n"; |
238 |
my $rend = $line->r; |
239 |
|
240 |
# mark all characters as underlined. we _must_ not toggle underline, |
241 |
# as we might get called on an already-marked url. |
242 |
&{$matcher->[2]} |
243 |
for @{$rend}[ $-[0] .. $+[0] - 1]; |
244 |
|
245 |
$line->r ($rend); |
246 |
} |
247 |
} |
248 |
|
249 |
() |
250 |
} |
251 |
|
252 |
sub valid_button { |
253 |
my ($self, $event) = @_; |
254 |
my $mask = $self->ModLevel3Mask | $self->ModMetaMask |
255 |
| urxvt::ShiftMask | urxvt::ControlMask; |
256 |
return ($event->{button} == $self->{button} && |
257 |
($event->{state} & $mask) == $self->{state}); |
258 |
} |
259 |
|
260 |
sub find_matches { |
261 |
my ($self, $row, $col) = @_; |
262 |
my $line = $self->line ($row); |
263 |
my $text = $line->t; |
264 |
|
265 |
my @matches; |
266 |
for my $matcher (@{$self->{matchers}}) { |
267 |
my $launcher = $matcher->[1] || $self->{launcher}; |
268 |
while ($text =~ /$matcher->[0]/g) { |
269 |
my $match = substr $text, $-[0], $+[0] - $-[0]; |
270 |
my @begin = @-; |
271 |
my @end = @+; |
272 |
my @exec; |
273 |
|
274 |
if (!defined($col) || ($-[0] <= $col && $+[0] >= $col)) { |
275 |
if ($launcher !~ /\$/) { |
276 |
@exec = ($launcher, $match); |
277 |
} else { |
278 |
# It'd be nice to just access a list like ($&,$1,$2...), |
279 |
# but alas, m//g behaves differently in list context. |
280 |
@exec = map { s/\$(\d+)|\$\{(\d+)\}/ |
281 |
substr $text, $begin[$1 || $2], $end[$1 || $2] - $begin[$1 || $2] |
282 |
/egx; $_ } split /\s+/, $launcher; |
283 |
} |
284 |
|
285 |
push @matches, [ $begin[0], $match, @exec ]; |
286 |
} |
287 |
} |
288 |
} |
289 |
|
290 |
@matches; |
291 |
} |
292 |
|
293 |
sub command_for { |
294 |
my ($self, $row, $col) = @_; |
295 |
|
296 |
my @matches = $self->find_matches ($row, $col); |
297 |
if (@matches) { |
298 |
my @match = @{ $matches[0] }; |
299 |
return @match[2 .. $#match]; |
300 |
} |
301 |
|
302 |
() |
303 |
} |
304 |
|
305 |
sub on_button_press { |
306 |
my ($self, $event) = @_; |
307 |
if($self->valid_button($event) |
308 |
&& (my @exec = $self->command_for($event->{row},$event->{col}))) { |
309 |
$self->{row} = $event->{row}; |
310 |
$self->{col} = $event->{col}; |
311 |
$self->{cmd} = \@exec; |
312 |
return 1; |
313 |
} else { |
314 |
delete $self->{row}; |
315 |
delete $self->{col}; |
316 |
delete $self->{cmd}; |
317 |
} |
318 |
|
319 |
() |
320 |
} |
321 |
|
322 |
sub on_button_release { |
323 |
my ($self, $event) = @_; |
324 |
|
325 |
my $row = delete $self->{row}; |
326 |
my $col = delete $self->{col}; |
327 |
my $cmd = delete $self->{cmd}; |
328 |
|
329 |
return if !defined $row; |
330 |
|
331 |
if($row == $event->{row} && abs($col-$event->{col}) < 2 |
332 |
&& join("\x00", @$cmd) eq join("\x00", $self->command_for($row,$col))) { |
333 |
if($self->valid_button($event)) { |
334 |
|
335 |
$self->exec_async (@$cmd); |
336 |
|
337 |
} |
338 |
} |
339 |
|
340 |
1; |
341 |
} |
342 |
|
343 |
# vim:set sw=3 sts=3 et: |