[ViewVC] Annotation of: cvs/rxvt-unicode/src/perl/searchable-scrollback

#! perl

# this extension implements scrollback buffer search

#:META:RESOURCE:%:string:activation hotkey keysym

=head1 NAME

searchable-scrollback - incremental scrollback search (enabled by default)

=head1 DESCRIPTION

Adds regex search functionality to the scrollback buffer, triggered by
the C<searchable-scrollback:start> action (bound to C<M-s> by
default). While in search mode, normal terminal input/output is
suspended and a regex is displayed at the bottom of the screen.

Inputting characters appends them to the regex and continues incremental
search. C<BackSpace> removes a character from the regex, C<Up> and C<Down>
search upwards/downwards in the scrollback buffer, C<End> jumps to the
bottom. C<Escape> leaves search mode and returns to the point where search
was started, while C<Enter> or C<Return> stay at the current position and
additionally stores the first match in the current line into the primary
selection if the C<Shift> modifier is active.

The regex defaults to "(?i)", resulting in a case-insensitive search. To
get a case-sensitive search you can delete this prefix using C<BackSpace>
or simply use an uppercase character which removes the "(?i)" prefix.

See L<perlre> for more info about perl regular expression syntax.

=cut

sub on_init {
   my ($self) = @_;

   # only for backwards compatibility
   my $hotkey = $self->{argv}[0]
                || $self->x_resource ("%")
                || "M-s";

   $self->bind_action ($hotkey, "searchable-scrollback:start")
      or warn "unable to register '$hotkey' as scrollback search start hotkey\n";

   ()
}

sub on_user_command {
   my ($self, $cmd) = @_;

   $cmd eq "searchable-scrollback:start"
      and $self->enter;

   ()
}

sub on_action {
   my ($self, $action) = @_;

   $action eq "start"
      and $self->enter;

   ()
}

sub msg {
   my ($self, $msg) = @_;

   $self->{overlay} = $self->overlay (0, -1, $self->ncol, 1, urxvt::OVERLAY_RSTYLE, 0);
   $self->{overlay}->set (0, 0, $self->special_encode ($msg));
}

sub enter {
   my ($self) = @_;

   return if $self->{overlay};

   $self->{view_start} = $self->view_start;
   $self->{pty_ev_events} = $self->pty_ev_events (urxvt::EV_NONE);
   $self->{row} = $self->nrow - 1;
   $self->{search} = "(?i)";

   $self->enable (
      key_press     => \&key_press,
      tt_write      => \&tt_write,
      refresh_begin => \&refresh,
      refresh_end   => \&refresh,
   );

   $self->{manpage_overlay} = $self->overlay (0, -2, $self->ncol, 1, urxvt::OVERLAY_RSTYLE, 0);
   $self->{manpage_overlay}->set (0, 0, "scrollback search, see the ${urxvt::RXVTNAME}perl manpage for details");

   $self->idle;
}

sub leave {
   my ($self) = @_;

   $self->disable ("key_press", "tt_write", "refresh_begin", "refresh_end");
   $self->pty_ev_events ($self->{pty_ev_events});

   delete $self->{manpage_overlay};
   delete $self->{overlay};
   delete $self->{search};
   delete $self->{found};
}

sub idle {
   my ($self) = @_;

   $self->msg ("(escape cancels) /$self->{search}█");
}

sub search {
   my ($self, $dir, $row) = @_;

   my $search = $self->special_encode ($self->{search});

   no re 'eval'; # just to be sure
   if (my $re = eval { qr/$search/ }) {
      while ($self->nrow > $row && $row >= $self->top_row) {
         my $line = $self->line ($row)
            or last;

         my $text = $line->t;
         if ($text =~ /$re/g) {
            delete $self->{found};

            do {
               push @{ $self->{found} }, [$line->coord_of ($-[0]), $line->coord_of ($+[0])];
            } while $text =~ /$re/g;

            $self->{row} = $row;
            $self->view_start (List::Util::min 0, $row - ($self->nrow >> 1));
            $self->want_refresh;
            return;
         }

         $row = $dir < 0 ? $line->beg - 1 : $line->end + 1;
      }
   }

   $self->scr_bell;
}

sub refresh {
   my ($self) = @_;

   return unless $self->{found};

   my $xor = urxvt::RS_RVid | urxvt::RS_Blink;
   for (@{ $self->{found} }) {
      $self->scr_xor_span (@$_, $xor);
      $xor = urxvt::RS_RVid;
   }

   ()
}

sub key_press {
   my ($self, $event, $keysym, $string) =  @_;

   delete $self->{manpage_overlay};

   if ($keysym == 0xff0d || $keysym == 0xff8d) { # enter
      if ($self->{found} && $event->{state} & urxvt::ShiftMask) {
         my ($br, $bc, $er, $ec) = @{ $self->{found}[0] };
         $self->selection_beg ($br, $bc);
         $self->selection_end ($er, $ec);
         $self->selection_make ($event->{time});
      }
      $self->leave;
   } elsif ($keysym == 0xff1b) { # escape
      $self->view_start ($self->{view_start});
      $self->leave;
   } elsif ($keysym == 0xff57) { # end
      $self->{row} = $self->nrow - 1;
      $self->view_start (0);
   } elsif ($keysym == 0xff52) { # up
      my $line = $self->line ($self->{row});
      $self->search (-1, $line->beg - 1)
         if $line->beg > $self->top_row;
   } elsif ($keysym == 0xff54) { # down
      my $line = $self->line ($self->{row});
      $self->search (+1, $line->end + 1)
         if $line->end < $self->nrow;
   } elsif ($keysym == 0xff08) { # backspace
      substr $self->{search}, -1, 1, "";
      $self->search (+1, $self->{row});
      $self->idle;
   } elsif ($string !~ /[\x00-\x1f\x80-\xaf]/) {
      return; # pass to tt_write
   }

   1
}

sub tt_write {
   my ($self, $data) = @_;

   $self->{search} .= $self->locale_decode ($data);

   $self->{search} =~ s/^\(\?i\)//
      if $self->{search} =~ /^\(.*[[:upper:]]/;

   delete $self->{found};
   $self->search (-1, $self->{row});
   $self->idle;

   1
}


Revision:	1.42
Committed:	Fri Dec 26 18:58:19 2014 UTC (9 years, 5 months ago) by root
Branch:	MAIN
Changes since 1.41:	+2 -3 lines
Log Message:	nuked as added
#	User	Rev	Content
1	root	1.1	#! perl
2
3			# this extension implements scrollback buffer search
4
5	root	1.32	#:META:RESOURCE:%:string:activation hotkey keysym
6	root	1.27
7	root	1.29	=head1 NAME
8
9	sf-exg	1.36	searchable-scrollback - incremental scrollback search (enabled by default)
10	root	1.29
11			=head1 DESCRIPTION
12
13	sf-exg	1.36	Adds regex search functionality to the scrollback buffer, triggered by
14			the C<searchable-scrollback:start> action (bound to C<M-s> by
15			default). While in search mode, normal terminal input/output is
16			suspended and a regex is displayed at the bottom of the screen.
17	root	1.29
18			Inputting characters appends them to the regex and continues incremental
19			search. C<BackSpace> removes a character from the regex, C<Up> and C<Down>
20			search upwards/downwards in the scrollback buffer, C<End> jumps to the
21			bottom. C<Escape> leaves search mode and returns to the point where search
22			was started, while C<Enter> or C<Return> stay at the current position and
23			additionally stores the first match in the current line into the primary
24			selection if the C<Shift> modifier is active.
25
26			The regex defaults to "(?i)", resulting in a case-insensitive search. To
27			get a case-sensitive search you can delete this prefix using C<BackSpace>
28			or simply use an uppercase character which removes the "(?i)" prefix.
29
30			See L<perlre> for more info about perl regular expression syntax.
31
32			=cut
33
34	root	1.1	sub on_init {
35			my ($self) = @_;
36
37	root	1.33	# only for backwards compatibility
38	root	1.12	my $hotkey = $self->{argv}[0]
39	root	1.28	\|\| $self->x_resource ("%")
40	root	1.42	\|\| "M-s";
41	root	1.1
42	root	1.42	$self->bind_action ($hotkey, "searchable-scrollback:start")
43	root	1.4	or warn "unable to register '$hotkey' as scrollback search start hotkey\n";
44	root	1.1
45			()
46			}
47
48	sf-exg	1.40	sub on_user_command {
49			my ($self, $cmd) = @_;
50
51			$cmd eq "searchable-scrollback:start"
52			and $self->enter;
53
54			()
55			}
56
57	root	1.33	sub on_action {
58			my ($self, $action) = @_;
59	root	1.1
60	root	1.33	$action eq "start"
61	root	1.8	and $self->enter;
62	root	1.1
63			()
64			}
65
66			sub msg {
67			my ($self, $msg) = @_;
68
69			$self->{overlay} = $self->overlay (0, -1, $self->ncol, 1, urxvt::OVERLAY_RSTYLE, 0);
70			$self->{overlay}->set (0, 0, $self->special_encode ($msg));
71			}
72
73			sub enter {
74			my ($self) = @_;
75
76			return if $self->{overlay};
77
78	root	1.8	$self->{view_start} = $self->view_start;
79	root	1.24	$self->{pty_ev_events} = $self->pty_ev_events (urxvt::EV_NONE);
80	root	1.13	$self->{row} = $self->nrow - 1;
81	root	1.22	$self->{search} = "(?i)";
82	root	1.1
83			$self->enable (
84	root	1.2	key_press => \&key_press,
85	root	1.7	tt_write => \&tt_write,
86	root	1.2	refresh_begin => \&refresh,
87			refresh_end => \&refresh,
88	root	1.1	);
89
90	root	1.8	$self->{manpage_overlay} = $self->overlay (0, -2, $self->ncol, 1, urxvt::OVERLAY_RSTYLE, 0);
91	root	1.11	$self->{manpage_overlay}->set (0, 0, "scrollback search, see the ${urxvt::RXVTNAME}perl manpage for details");
92	root	1.8
93	root	1.1	$self->idle;
94			}
95
96			sub leave {
97			my ($self) = @_;
98
99	root	1.7	$self->disable ("key_press", "tt_write", "refresh_begin", "refresh_end");
100	root	1.8	$self->pty_ev_events ($self->{pty_ev_events});
101	root	1.1
102	root	1.8	delete $self->{manpage_overlay};
103			delete $self->{overlay};
104	root	1.13	delete $self->{search};
105	sf-exg	1.41	delete $self->{found};
106	root	1.1	}
107
108			sub idle {
109			my ($self) = @_;
110
111	root	1.13	$self->msg ("(escape cancels) /$self->{search}█");
112	root	1.1	}
113
114			sub search {
115	sf-exg	1.37	my ($self, $dir, $row) = @_;
116	root	1.1
117	root	1.7	my $search = $self->special_encode ($self->{search});
118
119	root	1.1	no re 'eval'; # just to be sure
120	root	1.16	if (my $re = eval { qr/$search/ }) {
121	sf-exg	1.25	while ($self->nrow > $row && $row >= $self->top_row) {
122	root	1.16	my $line = $self->line ($row)
123			or last;
124
125			my $text = $line->t;
126			if ($text =~ /$re/g) {
127	sf-exg	1.38	delete $self->{found};
128
129	root	1.16	do {
130			push @{ $self->{found} }, [$line->coord_of ($-[0]), $line->coord_of ($+[0])];
131			} while $text =~ /$re/g;
132
133			$self->{row} = $row;
134	root	1.20	$self->view_start (List::Util::min 0, $row - ($self->nrow >> 1));
135	root	1.16	$self->want_refresh;
136	sf-exg	1.39	return;
137	root	1.16	}
138	root	1.1
139	root	1.16	$row = $dir < 0 ? $line->beg - 1 : $line->end + 1;
140	root	1.1	}
141			}
142
143	sf-exg	1.39	$self->scr_bell;
144	root	1.1	}
145
146	root	1.2	sub refresh {
147			my ($self) = @_;
148
149	root	1.18	return unless $self->{found};
150
151	root	1.15	my $xor = urxvt::RS_RVid \| urxvt::RS_Blink;
152	root	1.13	for (@{ $self->{found} }) {
153			$self->scr_xor_span (@$_, $xor);
154			$xor = urxvt::RS_RVid;
155			}
156	root	1.2
157			()
158			}
159
160			sub key_press {
161	root	1.1	my ($self, $event, $keysym, $string) = @_;
162
163	root	1.13	delete $self->{manpage_overlay};
164
165	root	1.14	if ($keysym == 0xff0d \|\| $keysym == 0xff8d) { # enter
166	ayin	1.23	if ($self->{found} && $event->{state} & urxvt::ShiftMask) {
167	root	1.13	my ($br, $bc, $er, $ec) = @{ $self->{found}[0] };
168			$self->selection_beg ($br, $bc);
169			$self->selection_end ($er, $ec);
170			$self->selection_make ($event->{time});
171			}
172			$self->leave;
173	root	1.14	} elsif ($keysym == 0xff1b) { # escape
174	root	1.13	$self->view_start ($self->{view_start});
175			$self->leave;
176	root	1.14	} elsif ($keysym == 0xff57) { # end
177	root	1.13	$self->{row} = $self->nrow - 1;
178			$self->view_start (0);
179	root	1.14	} elsif ($keysym == 0xff52) { # up
180	sf-exg	1.37	my $line = $self->line ($self->{row});
181			$self->search (-1, $line->beg - 1)
182			if $line->beg > $self->top_row;
183	root	1.14	} elsif ($keysym == 0xff54) { # down
184	sf-exg	1.37	my $line = $self->line ($self->{row});
185			$self->search (+1, $line->end + 1)
186			if $line->end < $self->nrow;
187	root	1.14	} elsif ($keysym == 0xff08) { # backspace
188	root	1.13	substr $self->{search}, -1, 1, "";
189	sf-exg	1.37	$self->search (+1, $self->{row});
190	root	1.13	$self->idle;
191	root	1.19	} elsif ($string !~ /[\x00-\x1f\x80-\xaf]/) {
192	root	1.13	return; # pass to tt_write
193	root	1.1	}
194
195			1
196			}
197
198	root	1.7	sub tt_write {
199			my ($self, $data) = @_;
200
201			$self->{search} .= $self->locale_decode ($data);
202	root	1.22
203			$self->{search} =~ s/^\(\?i\)//
204			if $self->{search} =~ /^\(.*[[:upper:]]/;
205	sf-exg	1.26
206	sf-exg	1.38	delete $self->{found};
207	sf-exg	1.37	$self->search (-1, $self->{row});
208	root	1.13	$self->idle;
209	root	1.7
210			1
211			}
212
213	root	1.1