| 1 |
#! perl |
| 2 |
|
| 3 |
# this extension implements scrollback buffer search |
| 4 |
|
| 5 |
#:META:X_RESOURCE:%:string:activation hotkey keysym |
| 6 |
#:META:KEYSYM:M-s:searchable-scrollback:start |
| 7 |
|
| 8 |
=head1 NAME |
| 9 |
|
| 10 |
searchable-scrollback<hotkey> - incremental scrollback search (enabled by default) |
| 11 |
|
| 12 |
=head1 DESCRIPTION |
| 13 |
|
| 14 |
Adds regex search functionality to the scrollback buffer, triggered |
| 15 |
by a hotkey (default: C<M-s>). While in search mode, normal terminal |
| 16 |
input/output is suspended and a regex is displayed at the bottom of the |
| 17 |
screen. |
| 18 |
|
| 19 |
Inputting characters appends them to the regex and continues incremental |
| 20 |
search. C<BackSpace> removes a character from the regex, C<Up> and C<Down> |
| 21 |
search upwards/downwards in the scrollback buffer, C<End> jumps to the |
| 22 |
bottom. C<Escape> leaves search mode and returns to the point where search |
| 23 |
was started, while C<Enter> or C<Return> stay at the current position and |
| 24 |
additionally stores the first match in the current line into the primary |
| 25 |
selection if the C<Shift> modifier is active. |
| 26 |
|
| 27 |
The regex defaults to "(?i)", resulting in a case-insensitive search. To |
| 28 |
get a case-sensitive search you can delete this prefix using C<BackSpace> |
| 29 |
or simply use an uppercase character which removes the "(?i)" prefix. |
| 30 |
|
| 31 |
See L<perlre> for more info about perl regular expression syntax. |
| 32 |
|
| 33 |
=cut |
| 34 |
|
| 35 |
sub on_init { |
| 36 |
my ($self) = @_; |
| 37 |
|
| 38 |
my $hotkey = $self->{argv}[0] |
| 39 |
|| $self->x_resource ("%") |
| 40 |
|| "M-s"; |
| 41 |
|
| 42 |
$self->parse_keysym ($hotkey, "perl:searchable-scrollback:start") |
| 43 |
or warn "unable to register '$hotkey' as scrollback search start hotkey\n"; |
| 44 |
|
| 45 |
() |
| 46 |
} |
| 47 |
|
| 48 |
sub on_user_command { |
| 49 |
my ($self, $cmd) = @_; |
| 50 |
|
| 51 |
$cmd eq "searchable-scrollback:start" |
| 52 |
and $self->enter; |
| 53 |
|
| 54 |
() |
| 55 |
} |
| 56 |
|
| 57 |
sub msg { |
| 58 |
my ($self, $msg) = @_; |
| 59 |
|
| 60 |
$self->{overlay} = $self->overlay (0, -1, $self->ncol, 1, urxvt::OVERLAY_RSTYLE, 0); |
| 61 |
$self->{overlay}->set (0, 0, $self->special_encode ($msg)); |
| 62 |
} |
| 63 |
|
| 64 |
sub enter { |
| 65 |
my ($self) = @_; |
| 66 |
|
| 67 |
return if $self->{overlay}; |
| 68 |
|
| 69 |
$self->{view_start} = $self->view_start; |
| 70 |
$self->{pty_ev_events} = $self->pty_ev_events (urxvt::EV_NONE); |
| 71 |
$self->{row} = $self->nrow - 1; |
| 72 |
$self->{search} = "(?i)"; |
| 73 |
|
| 74 |
$self->enable ( |
| 75 |
key_press => \&key_press, |
| 76 |
tt_write => \&tt_write, |
| 77 |
refresh_begin => \&refresh, |
| 78 |
refresh_end => \&refresh, |
| 79 |
); |
| 80 |
|
| 81 |
$self->{manpage_overlay} = $self->overlay (0, -2, $self->ncol, 1, urxvt::OVERLAY_RSTYLE, 0); |
| 82 |
$self->{manpage_overlay}->set (0, 0, "scrollback search, see the ${urxvt::RXVTNAME}perl manpage for details"); |
| 83 |
|
| 84 |
$self->idle; |
| 85 |
} |
| 86 |
|
| 87 |
sub leave { |
| 88 |
my ($self) = @_; |
| 89 |
|
| 90 |
$self->disable ("key_press", "tt_write", "refresh_begin", "refresh_end"); |
| 91 |
$self->pty_ev_events ($self->{pty_ev_events}); |
| 92 |
|
| 93 |
delete $self->{manpage_overlay}; |
| 94 |
delete $self->{overlay}; |
| 95 |
delete $self->{history}; |
| 96 |
delete $self->{search}; |
| 97 |
} |
| 98 |
|
| 99 |
sub idle { |
| 100 |
my ($self) = @_; |
| 101 |
|
| 102 |
$self->msg ("(escape cancels) /$self->{search}█"); |
| 103 |
} |
| 104 |
|
| 105 |
sub search { |
| 106 |
my ($self, $dir) = @_; |
| 107 |
|
| 108 |
delete $self->{found}; |
| 109 |
my $row = $self->{row}; |
| 110 |
|
| 111 |
my $search = $self->special_encode ($self->{search}); |
| 112 |
|
| 113 |
no re 'eval'; # just to be sure |
| 114 |
if (my $re = eval { qr/$search/ }) { |
| 115 |
while ($self->nrow > $row && $row >= $self->top_row) { |
| 116 |
my $line = $self->line ($row) |
| 117 |
or last; |
| 118 |
|
| 119 |
my $text = $line->t; |
| 120 |
if ($text =~ /$re/g) { |
| 121 |
do { |
| 122 |
push @{ $self->{found} }, [$line->coord_of ($-[0]), $line->coord_of ($+[0])]; |
| 123 |
} while $text =~ /$re/g; |
| 124 |
|
| 125 |
$self->{row} = $row; |
| 126 |
$self->view_start (List::Util::min 0, $row - ($self->nrow >> 1)); |
| 127 |
$self->want_refresh; |
| 128 |
last; |
| 129 |
} |
| 130 |
|
| 131 |
$row = $dir < 0 ? $line->beg - 1 : $line->end + 1; |
| 132 |
} |
| 133 |
} |
| 134 |
|
| 135 |
$self->scr_bell unless $self->{found}; |
| 136 |
} |
| 137 |
|
| 138 |
sub refresh { |
| 139 |
my ($self) = @_; |
| 140 |
|
| 141 |
return unless $self->{found}; |
| 142 |
|
| 143 |
my $xor = urxvt::RS_RVid | urxvt::RS_Blink; |
| 144 |
for (@{ $self->{found} }) { |
| 145 |
$self->scr_xor_span (@$_, $xor); |
| 146 |
$xor = urxvt::RS_RVid; |
| 147 |
} |
| 148 |
|
| 149 |
() |
| 150 |
} |
| 151 |
|
| 152 |
sub key_press { |
| 153 |
my ($self, $event, $keysym, $string) = @_; |
| 154 |
|
| 155 |
delete $self->{manpage_overlay}; |
| 156 |
|
| 157 |
if ($keysym == 0xff0d || $keysym == 0xff8d) { # enter |
| 158 |
if ($self->{found} && $event->{state} & urxvt::ShiftMask) { |
| 159 |
my ($br, $bc, $er, $ec) = @{ $self->{found}[0] }; |
| 160 |
$self->selection_beg ($br, $bc); |
| 161 |
$self->selection_end ($er, $ec); |
| 162 |
$self->selection_make ($event->{time}); |
| 163 |
} |
| 164 |
$self->leave; |
| 165 |
} elsif ($keysym == 0xff1b) { # escape |
| 166 |
$self->view_start ($self->{view_start}); |
| 167 |
$self->leave; |
| 168 |
} elsif ($keysym == 0xff57) { # end |
| 169 |
$self->{row} = $self->nrow - 1; |
| 170 |
$self->view_start (0); |
| 171 |
} elsif ($keysym == 0xff52) { # up |
| 172 |
$self->{row}-- if $self->{row} > $self->top_row; |
| 173 |
$self->search (-1); |
| 174 |
} elsif ($keysym == 0xff54) { # down |
| 175 |
$self->{row}++ if $self->{row} < $self->nrow; |
| 176 |
$self->search (+1); |
| 177 |
} elsif ($keysym == 0xff08) { # backspace |
| 178 |
substr $self->{search}, -1, 1, ""; |
| 179 |
$self->search; |
| 180 |
$self->idle; |
| 181 |
} elsif ($string !~ /[\x00-\x1f\x80-\xaf]/) { |
| 182 |
return; # pass to tt_write |
| 183 |
} |
| 184 |
|
| 185 |
1 |
| 186 |
} |
| 187 |
|
| 188 |
sub tt_write { |
| 189 |
my ($self, $data) = @_; |
| 190 |
|
| 191 |
$self->{search} .= $self->locale_decode ($data); |
| 192 |
|
| 193 |
$self->{search} =~ s/^\(\?i\)// |
| 194 |
if $self->{search} =~ /^\(.*[[:upper:]]/; |
| 195 |
|
| 196 |
$self->search (-1); |
| 197 |
$self->idle; |
| 198 |
|
| 199 |
1 |
| 200 |
} |
| 201 |
|
| 202 |
|
