1 |
#! perl |
2 |
|
3 |
sub on_user_command { |
4 |
my ($self, $cmd) = @_; |
5 |
|
6 |
$cmd eq "selection:rot13" |
7 |
and $self->selection (map { y/A-Za-z/N-ZA-Mn-za-m/; $_ } $self->selection); |
8 |
|
9 |
() |
10 |
} |
11 |
|
12 |
sub on_init { |
13 |
my ($self) = @_; |
14 |
|
15 |
if (defined (my $res = $self->resource ("cutchars"))) { |
16 |
$res = $self->locale_decode ($res); |
17 |
push @{ $self->{patterns} }, qr{\G [\Q$res\E[:space:]]* ([^\Q$res\E[:space:]]+) }x; |
18 |
} |
19 |
|
20 |
for (my $idx = 0; defined (my $res = $self->x_resource ("selection.pattern-$idx")); $idx++) { |
21 |
$res = $self->locale_decode ($res); |
22 |
utf8::encode $res; |
23 |
push @{ $self->{patterns} }, qr/$res/; |
24 |
} |
25 |
|
26 |
() |
27 |
} |
28 |
|
29 |
# "find interesting things"-patterns |
30 |
my @mark_patterns = ( |
31 |
# common types of "parentheses" |
32 |
qr{ (?<![^[:space:]]) ‘ ([^‘’]+) ’ (?![^[:space]]) }x, |
33 |
qr{ (?<![^[:space:]]) ` ([^`']+) ' (?![^[:space]]) }x, |
34 |
qr{ (?<![^[:space:]]) (" [^[:space:]] [^"]* ") }x, |
35 |
qr{ (" [^"]* [^[:space:]] ") (?![^[:space]]) }x, |
36 |
qr{ \< ([^<>[:space:]]+) \> }x, |
37 |
qr{ \{ ([^{}[:space:]]+) \} }x, |
38 |
qr{ \[ ([^{}[:space:]]+) \] }x, |
39 |
qr{ \( ([^()[:space:]]+) \) }x, |
40 |
|
41 |
# urls, just a heuristic |
42 |
qr{( |
43 |
(?:https?|ftp|news|mailto|file)://[ab-zA-Z0-9\-\@;\/?:&=%\$_.+!*\x27(),~]+ |
44 |
[ab-zA-Z0-9\-\@;\/?:&=%\$_+!*\x27()~] # exclude some trailing characters (heuristic) |
45 |
)}x, |
46 |
|
47 |
# shell-like argument quoting, basically always matches |
48 |
qr{\G [\ \t|&;<>()]* ( |
49 |
(?: |
50 |
[^\\"'\ \t|&;<>()]+ |
51 |
| \\. |
52 |
| " (?: [^\\"]+ | \\. )* " |
53 |
| ' [^']* ' |
54 |
)+ |
55 |
)}x, |
56 |
); |
57 |
|
58 |
# "correct obvious? crap"-patterns |
59 |
my @simplify_patterns = ( |
60 |
qr{^"([^\\"'\ \t|&;<>()*?]+)"$}, # "simple" => simple |
61 |
qr{^(.*)[,\-]$}, # strip off trailing , and - |
62 |
); |
63 |
|
64 |
sub on_sel_extend { |
65 |
my ($self, $time) = @_; |
66 |
|
67 |
my ($row, $col) = $self->selection_mark; |
68 |
my $line = $self->line ($row); |
69 |
my $text = $line->t; |
70 |
my $markofs = $line->offset_of ($row, $col); |
71 |
my $curlen = $line->offset_of ($self->selection_end) |
72 |
- $line->offset_of ($self->selection_beg); |
73 |
|
74 |
my @matches; |
75 |
|
76 |
if ($markofs < $line->l) { |
77 |
# convert markofs form character to UTF-8 offset space |
78 |
{ |
79 |
my $prefix = substr $text, 0, $markofs; |
80 |
utf8::encode $prefix; |
81 |
$markofs = length $prefix; |
82 |
} |
83 |
|
84 |
# not doing matches in unicode mode helps speed |
85 |
# enourmously here. working in utf-8 should be |
86 |
# equivalent due to the magic of utf-8 encoding. |
87 |
utf8::encode $text; |
88 |
study $text; # _really_ helps, too :) |
89 |
|
90 |
for my $regex (@mark_patterns, @{ $self->{patterns} }) { |
91 |
while ($text =~ /$regex/g) { |
92 |
if ($-[1] <= $markofs and $markofs <= $+[1]) { |
93 |
my $ofs = $-[1]; |
94 |
my $match = $1; |
95 |
|
96 |
for my $regex (@simplify_patterns) { |
97 |
if ($match =~ $regex) { |
98 |
$match = $1; |
99 |
$ofs += $-[1]; |
100 |
} |
101 |
} |
102 |
|
103 |
push @matches, [$ofs, length $match]; |
104 |
} |
105 |
} |
106 |
} |
107 |
} |
108 |
|
109 |
# whole line |
110 |
push @matches, [0, ($line->end - $line->beg + 1) * $self->ncol]; |
111 |
|
112 |
for (sort { $a->[1] <=> $b->[1] or $b->[0] <=> $a->[0] } @matches) { |
113 |
my ($ofs, $len) = @$_; |
114 |
|
115 |
next if $len <= $curlen; |
116 |
|
117 |
# convert back from UTF-8 offset space to character space |
118 |
{ |
119 |
my $length = substr "$text ", $ofs, $len; |
120 |
utf8::decode $length; |
121 |
$len = length $length; |
122 |
} |
123 |
{ |
124 |
my $prefix = substr $text, 0, $ofs; |
125 |
utf8::decode $prefix; |
126 |
$ofs = length $prefix; |
127 |
} |
128 |
|
129 |
$self->selection_beg ($line->coord_of ($ofs)); |
130 |
$self->selection_end ($line->coord_of ($ofs + $len)); |
131 |
return 1; |
132 |
} |
133 |
|
134 |
() |
135 |
} |