| 1 |
#! perl |
| 2 |
|
| 3 |
sub on_keyboard_command { |
| 4 |
my ($self, $cmd) = @_; |
| 5 |
|
| 6 |
$cmd eq "selection:rot13" |
| 7 |
and $self->selection (map { y/A-Za-z/N-ZA-Mn-za-m/; $_ } $self->selection); |
| 8 |
|
| 9 |
() |
| 10 |
} |
| 11 |
|
| 12 |
sub on_init { |
| 13 |
my ($self) = @_; |
| 14 |
|
| 15 |
for (my $idx = 0; defined (my $res = $self->x_resource ("selection.pattern-$idx")); $idx++) { |
| 16 |
no re 'eval'; # just to be sure |
| 17 |
$res = $self->locale_decode ($res); |
| 18 |
utf8::encode $res; |
| 19 |
push @{ $self->{patterns} }, qr/$res/; |
| 20 |
} |
| 21 |
|
| 22 |
() |
| 23 |
} |
| 24 |
|
| 25 |
# "find interetsing things"-patterns |
| 26 |
my @mark_patterns = ( |
| 27 |
# common types of "parentheses" |
| 28 |
qr{ (?<![^[:space:]]) ‘ ([^‘’]+) ’ (?![^[:space]]) }x, |
| 29 |
qr{ (?<![^[:space:]]) ` ([^`']+) ' (?![^[:space]]) }x, |
| 30 |
qr{ (?<![^[:space:]]) (" [^[:space:]] [^"]* ") }x, |
| 31 |
qr{ (" [^"]* [^[:space:]] ") (?![^[:space]]) }x, |
| 32 |
qr{ \< ([^<>[:space:]]+) \> }x, |
| 33 |
qr{ \{ ([^{}[:space:]]+) \} }x, |
| 34 |
qr{ \[ ([^{}[:space:]]+) \] }x, |
| 35 |
qr{ \( ([^()[:space:]]+) \) }x, |
| 36 |
|
| 37 |
# urls, just a heuristic |
| 38 |
qr{( |
| 39 |
(?:https?|ftp|news|mailto|file)://[ab-zA-Z0-9\-\@;\/?:&=%\$_.+!*\x27(),~]+ |
| 40 |
[ab-zA-Z0-9\-\@;\/?:&=%\$_+!*\x27()~] # exclude some trailing characters (heuristic) |
| 41 |
)}x, |
| 42 |
|
| 43 |
# shell-like argument quoting, basically always matches |
| 44 |
qr{\G [\ \t|&;<>()] *( |
| 45 |
(?: |
| 46 |
[^\\"'\ \t|&;<>()]+ |
| 47 |
| \\. |
| 48 |
| " (?: [^\\"]+ | \\. )* " |
| 49 |
| ' [^']* ' |
| 50 |
)+ |
| 51 |
)}x, |
| 52 |
); |
| 53 |
|
| 54 |
# "correct obvious? crap"-patterns |
| 55 |
my @simplify_patterns = ( |
| 56 |
qr{^"([^\\"'\ \t|&;<>()*?]+)"$}, # "simple" => simple |
| 57 |
qr{^(.*)[,\-]$}, # strip off trailing , and - |
| 58 |
); |
| 59 |
|
| 60 |
sub on_sel_extend { |
| 61 |
my ($self, $time) = @_; |
| 62 |
|
| 63 |
my ($row, $col) = $self->selection_mark; |
| 64 |
my $line = $self->line ($row); |
| 65 |
my $text = $line->t; |
| 66 |
my $markofs = $line->offset_of ($row, $col); |
| 67 |
my $curlen = $line->offset_of ($self->selection_end) |
| 68 |
- $line->offset_of ($self->selection_beg); |
| 69 |
|
| 70 |
my @matches; |
| 71 |
|
| 72 |
if ($markofs < $line->l) { |
| 73 |
# convert markofs form character to UTF-8 offset space |
| 74 |
{ |
| 75 |
my $prefix = substr $text, 0, $markofs; |
| 76 |
utf8::encode $prefix; |
| 77 |
$markofs = length $prefix; |
| 78 |
} |
| 79 |
|
| 80 |
# not doing matches in unicode mode helps speed |
| 81 |
# enourmously here. working in utf-8 should be |
| 82 |
# equivalent due to the magic of utf-8 encoding. |
| 83 |
utf8::encode $text; |
| 84 |
study $text; # _really_ helps, too :) |
| 85 |
|
| 86 |
for my $regex (@mark_patterns, @{ $self->{patterns} }) { |
| 87 |
while ($text =~ /$regex/g) { |
| 88 |
if ($-[1] <= $markofs and $markofs <= $+[1]) { |
| 89 |
my $ofs = $-[1]; |
| 90 |
my $match = $1; |
| 91 |
|
| 92 |
for my $regex (@simplify_patterns) { |
| 93 |
if ($match =~ $regex) { |
| 94 |
$match = $1; |
| 95 |
$ofs += $-[1]; |
| 96 |
} |
| 97 |
} |
| 98 |
|
| 99 |
push @matches, [$ofs, length $match]; |
| 100 |
} |
| 101 |
} |
| 102 |
} |
| 103 |
} |
| 104 |
|
| 105 |
# whole line |
| 106 |
push @matches, [0, ($line->end - $line->beg + 1) * $self->ncol]; |
| 107 |
|
| 108 |
for (sort { $a->[1] <=> $b->[1] or $b->[0] <=> $a->[0] } @matches) { |
| 109 |
my ($ofs, $len) = @$_; |
| 110 |
|
| 111 |
next if $len <= $curlen; |
| 112 |
|
| 113 |
# convert back from UTF-8 offset space to character space |
| 114 |
{ |
| 115 |
my $length = substr "$text ", $ofs, $len; |
| 116 |
utf8::decode $length; |
| 117 |
$len = length $length; |
| 118 |
} |
| 119 |
{ |
| 120 |
my $prefix = substr $text, 0, $ofs; |
| 121 |
utf8::decode $prefix; |
| 122 |
$ofs = length $prefix; |
| 123 |
} |
| 124 |
|
| 125 |
$self->selection_beg ($line->coord_of ($ofs)); |
| 126 |
$self->selection_end ($line->coord_of ($ofs + $len)); |
| 127 |
return 1; |
| 128 |
} |
| 129 |
|
| 130 |
() |
| 131 |
} |
