| 1 |
#! perl |
| 2 |
|
| 3 |
sub on_user_command { |
| 4 |
my ($self, $cmd) = @_; |
| 5 |
|
| 6 |
$cmd eq "selection:rot13" |
| 7 |
and $self->selection (map { y/A-Za-z/N-ZA-Mn-za-m/; $_ } $self->selection); |
| 8 |
|
| 9 |
() |
| 10 |
} |
| 11 |
|
| 12 |
sub on_init { |
| 13 |
my ($self) = @_; |
| 14 |
|
| 15 |
if (defined (my $res = $self->resource ("cutchars"))) { |
| 16 |
$res = $self->locale_decode ($res); |
| 17 |
push @{ $self->{patterns} }, qr{\G [\Q$res\E[:space:]]* ([^\Q$res\E[:space:]]+) }x; |
| 18 |
} |
| 19 |
|
| 20 |
for (my $idx = 0; defined (my $res = $self->x_resource ("selection.pattern-$idx")); $idx++) { |
| 21 |
$res = $self->locale_decode ($res); |
| 22 |
utf8::encode $res; |
| 23 |
push @{ $self->{patterns} }, qr/$res/; |
| 24 |
} |
| 25 |
|
| 26 |
$self->{enabled} = 1; |
| 27 |
|
| 28 |
push @{ $self->{term}{option_popup_hook} }, sub { |
| 29 |
("new selection" => $self->{enabled}, sub { $self->{enabled} = shift }) |
| 30 |
}; |
| 31 |
|
| 32 |
() |
| 33 |
} |
| 34 |
|
| 35 |
# "find interesting things"-patterns |
| 36 |
my @mark_patterns = ( |
| 37 |
# qr{ ([[:word:]]+) }x, |
| 38 |
qr{ ([^[:space:]]+) }x, |
| 39 |
|
| 40 |
# common types of "parentheses" |
| 41 |
qr{ (?<![^[:space:]]) ` ([^‘’]+) ` (?![^[:space:]]) }x, |
| 42 |
qr{ (?<![^[:space:]]) ‘ ([^‘’]+) ’ (?![^[:space:]]) }x, |
| 43 |
qr{ (?<![^[:space:]]) ` ([^`']+) ' (?![^[:space:]]) }x, |
| 44 |
|
| 45 |
qr{ (?<![^[:space:]]) ‘ ([^‘’]+) ’ (?![^[:space:]]) }x, |
| 46 |
qr{ (?<![^[:space:]]) “ ([^“”]+) ” (?![^[:space:]]) }x, |
| 47 |
|
| 48 |
qr{ (?<![^[:space:]]) (' [^[:space:]] [^']* ') }x, |
| 49 |
qr{ (' [^']* [^[:space:]] ') (?![^[:space:]]) }x, |
| 50 |
qr{ (?<![^[:space:]]) (" [^[:space:]] [^"]* ") }x, |
| 51 |
qr{ (" [^"]* [^[:space:]] ") (?![^[:space:]]) }x, |
| 52 |
|
| 53 |
qr{ \{ ([^\{\}]+) \} }x, |
| 54 |
qr{ \( ([^\(\)]+) \) }x, |
| 55 |
qr{ \[ ([^\[\]]+) \] }x, |
| 56 |
qr{ \< ([^\<\>]+) \> }x, |
| 57 |
|
| 58 |
# urls, just a heuristic |
| 59 |
qr{( |
| 60 |
(?:https?://|ftp://|news://|mailto:|file://|\bwww\.)[ab-zA-Z0-9\-\@;\/?:&=%\$_.+!*\x27(),~#]+ |
| 61 |
[ab-zA-Z0-9\-\@;\/?:&=%\$_+*()~] # exclude some trailing characters (heuristic) |
| 62 |
)}x, |
| 63 |
|
| 64 |
# shell-like argument quoting, basically always matches |
| 65 |
qr{\G [\ \t|&;<>()]* ( |
| 66 |
(?: |
| 67 |
[^\\"'\ \t|&;<>()]+ |
| 68 |
| \\. |
| 69 |
| " (?: [^\\"]+ | \\. )* " |
| 70 |
| ' [^']* ' |
| 71 |
)+ |
| 72 |
)}x, |
| 73 |
); |
| 74 |
|
| 75 |
# "correct obvious? crap"-patterns |
| 76 |
my @simplify_patterns = ( |
| 77 |
qr{^"([^\\"'\ \t|&;<>()*?]+)"$}, # "simple" => simple |
| 78 |
qr{^(.*)[,\-]$}, # strip off trailing , and - |
| 79 |
); |
| 80 |
|
| 81 |
sub on_sel_extend { |
| 82 |
my ($self, $time) = @_; |
| 83 |
|
| 84 |
$self->{enabled} |
| 85 |
or return; |
| 86 |
|
| 87 |
my ($row, $col) = $self->selection_mark; |
| 88 |
my $line = $self->line ($row); |
| 89 |
my $text = $line->t; |
| 90 |
my $markofs = $line->offset_of ($row, $col); |
| 91 |
my $curlen = $line->offset_of ($self->selection_end) |
| 92 |
- $line->offset_of ($self->selection_beg); |
| 93 |
|
| 94 |
my @matches; |
| 95 |
|
| 96 |
if ($markofs < $line->l) { |
| 97 |
# convert markofs from character to UTF-8 offset space |
| 98 |
{ |
| 99 |
my $prefix = substr $text, 0, $markofs; |
| 100 |
utf8::encode $prefix; |
| 101 |
$markofs = length $prefix; |
| 102 |
} |
| 103 |
|
| 104 |
# not doing matches in unicode mode helps speed |
| 105 |
# enourmously here. working in utf-8 should be |
| 106 |
# equivalent due to the magic of utf-8 encoding. |
| 107 |
utf8::encode $text; |
| 108 |
study $text; # _really_ helps, too :) |
| 109 |
|
| 110 |
for my $regex (@mark_patterns, @{ $self->{patterns} }) { |
| 111 |
while ($text =~ /$regex/g) { |
| 112 |
if ($-[1] <= $markofs and $markofs <= $+[1]) { |
| 113 |
my $ofs = $-[1]; |
| 114 |
my $match = $1; |
| 115 |
|
| 116 |
for my $regex (@simplify_patterns) { |
| 117 |
if ($match =~ $regex) { |
| 118 |
$match = $1; |
| 119 |
$ofs += $-[1]; |
| 120 |
} |
| 121 |
} |
| 122 |
|
| 123 |
push @matches, [$ofs, length $match]; |
| 124 |
} |
| 125 |
} |
| 126 |
} |
| 127 |
} |
| 128 |
|
| 129 |
# whole line |
| 130 |
push @matches, [0, ($line->end - $line->beg + 1) * $self->ncol]; |
| 131 |
|
| 132 |
for (sort { $a->[1] <=> $b->[1] or $b->[0] <=> $a->[0] } @matches) { |
| 133 |
my ($ofs, $len) = @$_; |
| 134 |
|
| 135 |
next if $len <= $curlen; |
| 136 |
|
| 137 |
# convert back from UTF-8 offset space to character space |
| 138 |
{ |
| 139 |
my $length = substr "$text ", $ofs, $len; |
| 140 |
utf8::decode $length; |
| 141 |
$len = length $length; |
| 142 |
} |
| 143 |
{ |
| 144 |
my $prefix = substr $text, 0, $ofs; |
| 145 |
utf8::decode $prefix; |
| 146 |
$ofs = length $prefix; |
| 147 |
} |
| 148 |
|
| 149 |
$self->selection_beg ($line->coord_of ($ofs)); |
| 150 |
$self->selection_end ($line->coord_of ($ofs + $len)); |
| 151 |
return 1; |
| 152 |
} |
| 153 |
|
| 154 |
() |
| 155 |
} |
