[ViewVC] Contents of: cvs/rxvt-unicode/src/perl/tabbed

#! perl

sub refresh {
   my ($self) = @_;

   my $ncol = $self->ncol;

   my $text = " " x $ncol;
   my $rend = [($self->{rs_tabbar}) x $ncol];

   my @ofs;

   substr $text, 0, 7, "[NEW] |";
   @$rend[0 .. 5] = ($self->{rs_tab}) x 6;
   push @ofs, [0, 6, sub { $_[0]->new_tab }];

   my $ofs = 7;
   my $idx = 0;

   for my $tab (@{ $self->{tabs} }) {
      $idx++;

      my $act = $tab->{activity} && $tab != $self->{cur}
                ? "*" : " ";

      my $txt = "$act$idx$act";
      my $len = length $txt;

      substr $text, $ofs, $len + 1, "$txt|";
      @$rend[$ofs .. $ofs + $len - 1] = ($self->{rs_tab}) x $len
         if $tab == $self->{cur};

      push @ofs, [ $ofs, $ofs + $len, sub { $_[0]->make_current ($tab) } ];

      $ofs += $len + 1;
   }

   $self->{tabofs} = \@ofs;

   $self->ROW_t (0, $text, 0, 0, $ncol);
   $self->ROW_r (0, $rend, 0, 0, $ncol);

   $self->want_refresh;
}

sub new_tab {
   my ($self) = @_;

   my $offset = $self->fheight;

   # save a backlink to us, make sure tabbed is inactive
   push @urxvt::TERM_INIT, sub {
      my ($term) = @_;
      $term->{parent} = $self;

      $term->resource ($_->[0] => $_->[1])
         for @{ $self->{resource} || [] };

      $term->resource (perl_ext_2 => $term->resource ("perl_ext_2") . ",-tabbed");
      
   };

   push @urxvt::TERM_EXT, urxvt::ext::tabbed::tab::;

   my $term = new urxvt::term
      $self->env, $urxvt::RXVTNAME,
      -embed => $self->parent,
   ;
}

sub configure {
   my ($self) = @_;

   my $tab = $self->{cur};

   # this is an extremely dirty way to force a configurenotify, but who cares
   $tab->XMoveResizeWindow (
      $tab->parent,
      0, $self->{tabheight} + 1,
      $self->width, $self->height - $self->{tabheight}
   );
   $tab->XMoveResizeWindow (
      $tab->parent,
      0, $self->{tabheight},
      $self->width, $self->height - $self->{tabheight}
   );
}

sub copy_properties {
   my ($self) = @_;
   my $tab = $self->{cur};

   my $wm_normal_hints = $self->XInternAtom ("WM_NORMAL_HINTS");

   my %our_props = map +($_ => undef), $self->XListProperties ($self->parent);

   delete $our_props{$self->XInternAtom ($_)}
      for qw(WM_STATE WM_ICON_SIZE
             _NET_WM_VISIBLE_NAME _NET_WM_VISIBLE_ICON_NAME _NET_WM_ICON_GEOMETRY _NET_FRAME_EXTENTS);

   for my $atom ($tab->XListProperties ($tab->parent)) {
      my ($type, $format, $items) = $self->XGetWindowProperty ($tab->parent, $atom);
      
      delete $our_props{$atom};

      if ($atom == $wm_normal_hints) {
         my (@hints) = unpack "l!*", $items;

         $hints[$_] += $self->{tabheight} for (4, 6, 16);

         $items = pack "l!*", @hints;
      }
      $self->XChangeWindowProperty ($self->parent, $atom, $type, $format, $items);
   }

   $self->XDeleteProperty ($self->parent, $_) for keys %our_props;
}

sub make_current {
   my ($self, $tab) = @_;

   if (my $cur = $self->{cur}) {
      delete $cur->{activity};
      $cur->XUnmapWindow ($cur->parent) if $cur->mapped;
      $cur->focus_out;
   }
   
   $self->{cur} = $tab;

   $self->configure;
   $self->copy_properties;
   $tab->focus_in;
   $tab->XMapWindow ($tab->parent);
   delete $tab->{activity};
   $self->refresh;

   ()
}

sub on_focus_in {
   my ($self, $event) = @_;

   $self->{cur}->focus_in;

   ()
}

sub on_focus_out {
   my ($self, $event) = @_;

   $self->{cur}->focus_out;

   ()
}

sub on_key_press {
   my ($self, $event) = @_;

   $self->{cur}->key_press ($event->{state}, $event->{keycode}, $event->{time});

   1
}

sub on_key_release {
   my ($self, $event) = @_;

   $self->{cur}->key_release ($event->{state}, $event->{keycode}, $event->{time});

   1
}

sub on_button_press {
   1
}

sub on_button_release {
   my ($self, $event) = @_;

   if ($event->{row} == 0) {
      for my $button (@{ $self->{tabofs} }) {
         $button->[2]->($self, $event)
            if $event->{col} >= $button->[0]
               && $event->{col} < $button->[1];
      }
   }

   1
}

sub on_motion_notify {
   1
}

sub on_init {
   my ($self) = @_;

   for (qw(name perl_ext_1 perl_ext_2)) {
      my $val = $self->resource ($_);

      push @{ $self->{resource} }, [$_ => $val]
        if defined $val;
   }

   $self->resource (int_bwidth => 0);
   $self->resource (name => "URxvt.tabbed");
   $self->resource (pty_fd => -1);

   $self->option ($urxvt::OPTION{scrollBar}, 0);

   my $fg    = $self->x_resource ("tabbar-fg");
   my $bg    = $self->x_resource ("tabbar-bg");
   my $tabfg = $self->x_resource ("tab-fg");
   my $tabbg = $self->x_resource ("tab-bg");

   defined $fg    or $fg    = 3;
   defined $bg    or $bg    = 0;
   defined $tabfg or $tabfg = 0;
   defined $tabbg or $tabbg = 1;

   $self->{rs_tabbar} = urxvt::SET_COLOR (urxvt::DEFAULT_RSTYLE, $fg    + 2, $bg    + 2);
   $self->{rs_tab}    = urxvt::SET_COLOR (urxvt::DEFAULT_RSTYLE, $tabfg + 2, $tabbg + 2);

   ()
}

sub on_start {
   my ($self) = @_;

   $self->{tabheight} = $self->int_bwidth + $self->fheight + $self->lineSpace;

   $self->cmd_parse ("\033[?25l");

   $self->new_tab;

   ()
}

sub on_configure_notify {
   my ($self, $event) = @_;

   $self->configure;
   $self->refresh;

   ()
}

sub on_wm_delete_window {
   my ($self) = @_;

   $_->destroy for @{ $self->{tabs} };

   1
}

sub tab_start {
   my ($self, $tab) = @_;

   $tab->XChangeInput ($tab->parent, urxvt::PropertyChangeMask);

   push @{ $self->{tabs} }, $tab;

#   $tab->{name} ||= scalar @{ $self->{tabs} };
   $self->make_current ($tab);

   ()
}

sub tab_destroy {
   my ($self, $tab) = @_;

   $self->{tabs} = [ grep $_ != $tab, @{ $self->{tabs} } ];

   if (@{ $self->{tabs} }) {
      if ($self->{cur} == $tab) {
         delete $self->{cur};
         $self->make_current ($self->{tabs}[-1]);
      } else {
         $self->refresh;
      }
   } else {
      # delay destruction a tiny bit
      $self->{destroy} = urxvt::iw->new->start->cb (sub { $self->destroy });
   }

   ()
}

sub tab_key_press {
   my ($self, $tab, $event, $keysym, $str) = @_;

   if ($event->{state} & urxvt::ShiftMask) {
      if ($keysym == 0xff51 || $keysym == 0xff53) {
         my ($idx) = grep $self->{tabs}[$_] == $tab, 0 .. $#{ $self->{tabs} };

         --$idx if $keysym == 0xff51;
         ++$idx if $keysym == 0xff53;

         $self->make_current ($self->{tabs}[$idx % @{ $self->{tabs}}]);
         
         return 1;
      } elsif ($keysym == 0xff54) {
         $self->new_tab;

         return 1;
      }
   }

   ()
}

sub tab_property_notify {
   my ($self, $tab, $event) = @_;

   $self->copy_properties
      if $event->{window} == $tab->parent;

   ()
}

sub tab_activity {
   my ($self, $tab) = @_;

   $self->refresh;
}

package urxvt::ext::tabbed::tab;

# helper extension implementing the subwindows of a tabbed terminal.
# simply proxies all interesting calls back to the tabbed class.

{
   for my $hook qw(start destroy key_press property_notify) {
      eval qq{
         sub on_$hook {
            my \$parent = \$_[0]{term}{parent}
               or return;
            \$parent->tab_$hook (\@_)
         }
      };
      die if $@;
   }
}

sub on_add_lines {
  $_[0]->{activity}++
     or $_[0]{term}{parent}->tab_activity ($_[0]);
  ()
}


Revision:	1.18
Committed:	Sat Feb 11 02:05:28 2006 UTC (18 years, 4 months ago) by root
Branch:	MAIN
Changes since 1.17:	+3 -1 lines
Log Message:	* empty log message *
#	Content
1	#! perl
2
3	sub refresh {
4	my ($self) = @_;
5
6	my $ncol = $self->ncol;
7
8	my $text = " " x $ncol;
9	my $rend = [($self->{rs_tabbar}) x $ncol];
10
11	my @ofs;
12
13	substr $text, 0, 7, "[NEW] \|";
14	@$rend[0 .. 5] = ($self->{rs_tab}) x 6;
15	push @ofs, [0, 6, sub { $_[0]->new_tab }];
16
17	my $ofs = 7;
18	my $idx = 0;
19
20	for my $tab (@{ $self->{tabs} }) {
21	$idx++;
22
23	my $act = $tab->{activity} && $tab != $self->{cur}
24	? "*" : " ";
25
26	my $txt = "$act$idx$act";
27	my $len = length $txt;
28
29	substr $text, $ofs, $len + 1, "$txt\|";
30	@$rend[$ofs .. $ofs + $len - 1] = ($self->{rs_tab}) x $len
31	if $tab == $self->{cur};
32
33	push @ofs, [ $ofs, $ofs + $len, sub { $_[0]->make_current ($tab) } ];
34
35	$ofs += $len + 1;
36	}
37
38	$self->{tabofs} = \@ofs;
39
40	$self->ROW_t (0, $text, 0, 0, $ncol);
41	$self->ROW_r (0, $rend, 0, 0, $ncol);
42
43	$self->want_refresh;
44	}
45
46	sub new_tab {
47	my ($self) = @_;
48
49	my $offset = $self->fheight;
50
51	# save a backlink to us, make sure tabbed is inactive
52	push @urxvt::TERM_INIT, sub {
53	my ($term) = @_;
54	$term->{parent} = $self;
55
56	$term->resource ($_->[0] => $_->[1])
57	for @{ $self->{resource} \|\| [] };
58
59	$term->resource (perl_ext_2 => $term->resource ("perl_ext_2") . ",-tabbed");
60
61	};
62
63	push @urxvt::TERM_EXT, urxvt::ext::tabbed::tab::;
64
65	my $term = new urxvt::term
66	$self->env, $urxvt::RXVTNAME,
67	-embed => $self->parent,
68	;
69	}
70
71	sub configure {
72	my ($self) = @_;
73
74	my $tab = $self->{cur};
75
76	# this is an extremely dirty way to force a configurenotify, but who cares
77	$tab->XMoveResizeWindow (
78	$tab->parent,
79	0, $self->{tabheight} + 1,
80	$self->width, $self->height - $self->{tabheight}
81	);
82	$tab->XMoveResizeWindow (
83	$tab->parent,
84	0, $self->{tabheight},
85	$self->width, $self->height - $self->{tabheight}
86	);
87	}
88
89	sub copy_properties {
90	my ($self) = @_;
91	my $tab = $self->{cur};
92
93	my $wm_normal_hints = $self->XInternAtom ("WM_NORMAL_HINTS");
94
95	my %our_props = map +($_ => undef), $self->XListProperties ($self->parent);
96
97	delete $our_props{$self->XInternAtom ($_)}
98	for qw(WM_STATE WM_ICON_SIZE
99	_NET_WM_VISIBLE_NAME _NET_WM_VISIBLE_ICON_NAME _NET_WM_ICON_GEOMETRY _NET_FRAME_EXTENTS);
100
101	for my $atom ($tab->XListProperties ($tab->parent)) {
102	my ($type, $format, $items) = $self->XGetWindowProperty ($tab->parent, $atom);
103
104	delete $our_props{$atom};
105
106	if ($atom == $wm_normal_hints) {
107	my (@hints) = unpack "l!*", $items;
108
109	$hints[$_] += $self->{tabheight} for (4, 6, 16);
110
111	$items = pack "l!*", @hints;
112	}
113	$self->XChangeWindowProperty ($self->parent, $atom, $type, $format, $items);
114	}
115
116	$self->XDeleteProperty ($self->parent, $_) for keys %our_props;
117	}
118
119	sub make_current {
120	my ($self, $tab) = @_;
121
122	if (my $cur = $self->{cur}) {
123	delete $cur->{activity};
124	$cur->XUnmapWindow ($cur->parent) if $cur->mapped;
125	$cur->focus_out;
126	}
127
128	$self->{cur} = $tab;
129
130	$self->configure;
131	$self->copy_properties;
132	$tab->focus_in;
133	$tab->XMapWindow ($tab->parent);
134	delete $tab->{activity};
135	$self->refresh;
136
137	()
138	}
139
140	sub on_focus_in {
141	my ($self, $event) = @_;
142
143	$self->{cur}->focus_in;
144
145	()
146	}
147
148	sub on_focus_out {
149	my ($self, $event) = @_;
150
151	$self->{cur}->focus_out;
152
153	()
154	}
155
156	sub on_key_press {
157	my ($self, $event) = @_;
158
159	$self->{cur}->key_press ($event->{state}, $event->{keycode}, $event->{time});
160
161	1
162	}
163
164	sub on_key_release {
165	my ($self, $event) = @_;
166
167	$self->{cur}->key_release ($event->{state}, $event->{keycode}, $event->{time});
168
169	1
170	}
171
172	sub on_button_press {
173	1
174	}
175
176	sub on_button_release {
177	my ($self, $event) = @_;
178
179	if ($event->{row} == 0) {
180	for my $button (@{ $self->{tabofs} }) {
181	$button->[2]->($self, $event)
182	if $event->{col} >= $button->[0]
183	&& $event->{col} < $button->[1];
184	}
185	}
186
187	1
188	}
189
190	sub on_motion_notify {
191	1
192	}
193
194	sub on_init {
195	my ($self) = @_;
196
197	for (qw(name perl_ext_1 perl_ext_2)) {
198	my $val = $self->resource ($_);
199
200	push @{ $self->{resource} }, [$_ => $val]
201	if defined $val;
202	}
203
204	$self->resource (int_bwidth => 0);
205	$self->resource (name => "URxvt.tabbed");
206	$self->resource (pty_fd => -1);
207
208	$self->option ($urxvt::OPTION{scrollBar}, 0);
209
210	my $fg = $self->x_resource ("tabbar-fg");
211	my $bg = $self->x_resource ("tabbar-bg");
212	my $tabfg = $self->x_resource ("tab-fg");
213	my $tabbg = $self->x_resource ("tab-bg");
214
215	defined $fg or $fg = 3;
216	defined $bg or $bg = 0;
217	defined $tabfg or $tabfg = 0;
218	defined $tabbg or $tabbg = 1;
219
220	$self->{rs_tabbar} = urxvt::SET_COLOR (urxvt::DEFAULT_RSTYLE, $fg + 2, $bg + 2);
221	$self->{rs_tab} = urxvt::SET_COLOR (urxvt::DEFAULT_RSTYLE, $tabfg + 2, $tabbg + 2);
222
223	()
224	}
225
226	sub on_start {
227	my ($self) = @_;
228
229	$self->{tabheight} = $self->int_bwidth + $self->fheight + $self->lineSpace;
230
231	$self->cmd_parse ("\033[?25l");
232
233	$self->new_tab;
234
235	()
236	}
237
238	sub on_configure_notify {
239	my ($self, $event) = @_;
240
241	$self->configure;
242	$self->refresh;
243
244	()
245	}
246
247	sub on_wm_delete_window {
248	my ($self) = @_;
249
250	$_->destroy for @{ $self->{tabs} };
251
252	1
253	}
254
255	sub tab_start {
256	my ($self, $tab) = @_;
257
258	$tab->XChangeInput ($tab->parent, urxvt::PropertyChangeMask);
259
260	push @{ $self->{tabs} }, $tab;
261
262	# $tab->{name} \|\|= scalar @{ $self->{tabs} };
263	$self->make_current ($tab);
264
265	()
266	}
267
268	sub tab_destroy {
269	my ($self, $tab) = @_;
270
271	$self->{tabs} = [ grep $_ != $tab, @{ $self->{tabs} } ];
272
273	if (@{ $self->{tabs} }) {
274	if ($self->{cur} == $tab) {
275	delete $self->{cur};
276	$self->make_current ($self->{tabs}[-1]);
277	} else {
278	$self->refresh;
279	}
280	} else {
281	# delay destruction a tiny bit
282	$self->{destroy} = urxvt::iw->new->start->cb (sub { $self->destroy });
283	}
284
285	()
286	}
287
288	sub tab_key_press {
289	my ($self, $tab, $event, $keysym, $str) = @_;
290
291	if ($event->{state} & urxvt::ShiftMask) {
292	if ($keysym == 0xff51 \|\| $keysym == 0xff53) {
293	my ($idx) = grep $self->{tabs}[$_] == $tab, 0 .. $#{ $self->{tabs} };
294
295	--$idx if $keysym == 0xff51;
296	++$idx if $keysym == 0xff53;
297
298	$self->make_current ($self->{tabs}[$idx % @{ $self->{tabs}}]);
299
300	return 1;
301	} elsif ($keysym == 0xff54) {
302	$self->new_tab;
303
304	return 1;
305	}
306	}
307
308	()
309	}
310
311	sub tab_property_notify {
312	my ($self, $tab, $event) = @_;
313
314	$self->copy_properties
315	if $event->{window} == $tab->parent;
316
317	()
318	}
319
320	sub tab_activity {
321	my ($self, $tab) = @_;
322
323	$self->refresh;
324	}
325
326	package urxvt::ext::tabbed::tab;
327
328	# helper extension implementing the subwindows of a tabbed terminal.
329	# simply proxies all interesting calls back to the tabbed class.
330
331	{
332	for my $hook qw(start destroy key_press property_notify) {
333	eval qq{
334	sub on_$hook {
335	my \$parent = \$_[0]{term}{parent}
336	or return;
337	\$parent->tab_$hook (\@_)
338	}
339	};
340	die if $@;
341	}
342	}
343
344	sub on_add_lines {
345	$_[0]->{activity}++
346	or $_[0]{term}{parent}->tab_activity ($_[0]);
347	()
348	}
349
350