[ViewVC] Contents of: cvs/rxvt-unicode/src/perl/tabbed

#! perl

sub refresh {
   my ($self) = @_;

   my $ncol = $self->ncol;

   my $text = " " x $ncol;
   my $rend = [($self->{rs_tabbar}) x $ncol];

   my @ofs;

   substr $text, 0, 7, "[NEW] |";
   @$rend[0 .. 5] = ($self->{rs_tab}) x 6;
   push @ofs, [0, 6, sub { $_[0]->new_tab }];

   my $ofs = 7;
   my $idx = 0;

   for my $tab (@{ $self->{tabs} }) {
      $idx++;

      my $act = $tab->{activity} && $tab != $self->{cur}
                ? "*" : " ";

      my $txt = "$act$idx$act";
      my $len = length $txt;

      substr $text, $ofs, $len + 1, "$txt|";
      @$rend[$ofs .. $ofs + $len - 1] = ($self->{rs_tab}) x $len
         if $tab == $self->{cur};

      push @ofs, [ $ofs, $ofs + $len, sub { $_[0]->make_current ($tab) } ];

      $ofs += $len + 1;
   }

   $self->{tabofs} = \@ofs;

   $self->ROW_t (0, $text, 0, 0, $ncol);
   $self->ROW_r (0, $rend, 0, 0, $ncol);

   $self->want_refresh;
}

sub new_tab {
   my ($self) = @_;

   my $offset = $self->fheight;

   # save a backlink to us, make sure tabbed is inactive
   push @urxvt::TERM_INIT, sub {
      my ($term) = @_;
      $term->{parent} = $self;

      $term->resource ($_->[0] => $_->[1])
         for @{ $self->{resource} || [] };

      $term->resource (perl_ext_2 => $term->resource ("perl_ext_2") . ",-tabbed");
      
   };

   push @urxvt::TERM_EXT, urxvt::ext::tabbed::tab::;

   my $term = new urxvt::term
      $self->env, $urxvt::RXVTNAME,
      -embed => $self->parent,
   ;
}

sub configure {
   my ($self) = @_;

   my $tab = $self->{cur};

   # this is an extremely dirty way to force a configurenotify, but who cares
   $tab->XMoveResizeWindow (
      $tab->parent,
      0, $self->{tabheight} + 1,
      $self->width, $self->height - $self->{tabheight}
   );
   $tab->XMoveResizeWindow (
      $tab->parent,
      0, $self->{tabheight},
      $self->width, $self->height - $self->{tabheight}
   );
}

sub copy_properties {
   my ($self) = @_;
   my $tab = $self->{cur};

   my $wm_normal_hints = $self->XInternAtom ("WM_NORMAL_HINTS");
   my $wm_state        = $self->XInternAtom ("WM_STATE");

   my %our_props = map +($_ => undef), $self->XListProperties ($self->parent);

   delete $our_props{$wm_state};

   for my $atom ($tab->XListProperties ($tab->parent)) {
      my ($type, $format, $items) = $self->XGetWindowProperty ($tab->parent, $atom);
      
      delete $our_props{$atom};

      if ($atom == $wm_normal_hints) {
         my (@hints) = unpack "l!*", $items;

         $hints[$_] += $self->{tabheight} for (4, 6, 16);

         $items = pack "l!*", @hints;
      }
      $self->XChangeWindowProperty ($self->parent, $atom, $type, $format, $items);
   }

   $self->XDeleteProperty ($self->parent, $_) for keys %our_props;
}

sub make_current {
   my ($self, $tab) = @_;

   if (my $cur = $self->{cur}) {
      delete $cur->{activity};
      $cur->XUnmapWindow ($cur->parent) if $cur->mapped;
      $cur->focus_out;
   }
   
   $self->{cur} = $tab;

   $self->configure;
   $self->copy_properties;
   $tab->focus_in;
   $tab->XMapWindow ($tab->parent);
   delete $tab->{activity};
   $self->refresh;

   ()
}

sub on_focus_in {
   my ($self, $event) = @_;

   $self->{cur}->focus_in;

   ()
}

sub on_focus_out {
   my ($self, $event) = @_;

   $self->{cur}->focus_out;

   ()
}

sub on_key_press {
   my ($self, $event) = @_;

   $self->{cur}->key_press ($event->{state}, $event->{keycode}, $event->{time});

   1
}

sub on_key_release {
   my ($self, $event) = @_;

   $self->{cur}->key_release ($event->{state}, $event->{keycode}, $event->{time});

   1
}

sub on_button_press {
   1
}

sub on_button_release {
   my ($self, $event) = @_;

   if ($event->{row} == 0) {
      for my $button (@{ $self->{tabofs} }) {
         $button->[2]->($self, $event)
            if $event->{col} >= $button->[0]
               && $event->{col} < $button->[1];
      }
   }

   1
}

sub on_motion_notify {
   1
}

sub on_init {
   my ($self) = @_;

   for (qw(name perl_ext_1 perl_ext_2)) {
      my $val = $self->resource ($_);

      push @{ $self->{resource} }, [$_ => $val]
        if defined $val;
   }

   $self->resource (int_bwidth => 0);
   $self->resource (name => "URxvt.tabbed");
   $self->resource (pty_fd => -1);

   $self->option ($urxvt::OPTION{scrollBar}, 0);

   my $fg    = $self->x_resource ("tabbar-fg");
   my $bg    = $self->x_resource ("tabbar-bg");
   my $tabfg = $self->x_resource ("tab-fg");
   my $tabbg = $self->x_resource ("tab-bg");

   defined $fg    or $fg    = 3;
   defined $bg    or $bg    = 0;
   defined $tabfg or $tabfg = 0;
   defined $tabbg or $tabbg = 1;

   $self->{rs_tabbar} = urxvt::SET_COLOR (urxvt::DEFAULT_RSTYLE, $fg    + 2, $bg    + 2);
   $self->{rs_tab}    = urxvt::SET_COLOR (urxvt::DEFAULT_RSTYLE, $tabfg + 2, $tabbg + 2);

   ()
}

sub on_start {
   my ($self) = @_;

   $self->{tabheight} = $self->int_bwidth + $self->fheight + $self->lineSpace;

   $self->cmd_parse ("\033[?25l");

   $self->new_tab;

   ()
}

sub on_configure_notify {
   my ($self, $event) = @_;

   $self->configure;
   $self->refresh;

   ()
}

sub on_wm_delete_window {
   my ($self) = @_;

   $_->destroy for @{ $self->{tabs} };

   1
}

sub tab_start {
   my ($self, $tab) = @_;

   $tab->XChangeInput ($tab->parent, urxvt::PropertyChangeMask);

   push @{ $self->{tabs} }, $tab;

#   $tab->{name} ||= scalar @{ $self->{tabs} };
   $self->make_current ($tab);

   ()
}

sub tab_destroy {
   my ($self, $tab) = @_;

   $self->{tabs} = [ grep $_ != $tab, @{ $self->{tabs} } ];

   if (@{ $self->{tabs} }) {
      if ($self->{cur} == $tab) {
         delete $self->{cur};
         $self->make_current ($self->{tabs}[-1]);
      } else {
         $self->refresh;
      }
   } else {
      # delay destruction a tiny bit
      $self->{destroy} = urxvt::iw->new->start->cb (sub { $self->destroy });
   }

   ()
}

sub tab_key_press {
   my ($self, $tab, $event, $keysym, $str) = @_;

   if ($event->{state} & urxvt::ShiftMask) {
      if ($keysym == 0xff51 || $keysym == 0xff53) {
         my ($idx) = grep $self->{tabs}[$_] == $tab, 0 .. $#{ $self->{tabs} };

         --$idx if $keysym == 0xff51;
         ++$idx if $keysym == 0xff53;

         $self->make_current ($self->{tabs}[$idx % @{ $self->{tabs}}]);
         
         return 1;
      } elsif ($keysym == 0xff54) {
         $self->new_tab;

         return 1;
      }
   }

   ()
}

sub tab_property_notify {
   my ($self, $tab, $event) = @_;

   $self->copy_properties
      if $event->{window} == $tab->parent;

   ()
}

sub tab_activity {
   my ($self, $tab) = @_;

   $self->refresh;
}

package urxvt::ext::tabbed::tab;

# helper extension implementing the subwindows of a tabbed terminal.
# simply proxies all interesting calls back to the tabbed class.

{
   for my $hook qw(start destroy key_press property_notify) {
      eval qq{
         sub on_$hook {
            my \$parent = \$_[0]{term}{parent}
               or return;
            \$parent->tab_$hook (\@_)
         }
      };
      die if $@;
   }
}

sub on_add_lines {
  $_[0]->{activity}++
     or $_[0]{term}{parent}->tab_activity ($_[0]);
  ()
}


Revision:	1.16
Committed:	Sat Feb 11 01:58:28 2006 UTC (18 years, 3 months ago) by root
Branch:	MAIN
Changes since 1.15:	+3 -0 lines
Log Message:	* empty log message *
#	Content
1	#! perl
2
3	sub refresh {
4	my ($self) = @_;
5
6	my $ncol = $self->ncol;
7
8	my $text = " " x $ncol;
9	my $rend = [($self->{rs_tabbar}) x $ncol];
10
11	my @ofs;
12
13	substr $text, 0, 7, "[NEW] \|";
14	@$rend[0 .. 5] = ($self->{rs_tab}) x 6;
15	push @ofs, [0, 6, sub { $_[0]->new_tab }];
16
17	my $ofs = 7;
18	my $idx = 0;
19
20	for my $tab (@{ $self->{tabs} }) {
21	$idx++;
22
23	my $act = $tab->{activity} && $tab != $self->{cur}
24	? "*" : " ";
25
26	my $txt = "$act$idx$act";
27	my $len = length $txt;
28
29	substr $text, $ofs, $len + 1, "$txt\|";
30	@$rend[$ofs .. $ofs + $len - 1] = ($self->{rs_tab}) x $len
31	if $tab == $self->{cur};
32
33	push @ofs, [ $ofs, $ofs + $len, sub { $_[0]->make_current ($tab) } ];
34
35	$ofs += $len + 1;
36	}
37
38	$self->{tabofs} = \@ofs;
39
40	$self->ROW_t (0, $text, 0, 0, $ncol);
41	$self->ROW_r (0, $rend, 0, 0, $ncol);
42
43	$self->want_refresh;
44	}
45
46	sub new_tab {
47	my ($self) = @_;
48
49	my $offset = $self->fheight;
50
51	# save a backlink to us, make sure tabbed is inactive
52	push @urxvt::TERM_INIT, sub {
53	my ($term) = @_;
54	$term->{parent} = $self;
55
56	$term->resource ($_->[0] => $_->[1])
57	for @{ $self->{resource} \|\| [] };
58
59	$term->resource (perl_ext_2 => $term->resource ("perl_ext_2") . ",-tabbed");
60
61	};
62
63	push @urxvt::TERM_EXT, urxvt::ext::tabbed::tab::;
64
65	my $term = new urxvt::term
66	$self->env, $urxvt::RXVTNAME,
67	-embed => $self->parent,
68	;
69	}
70
71	sub configure {
72	my ($self) = @_;
73
74	my $tab = $self->{cur};
75
76	# this is an extremely dirty way to force a configurenotify, but who cares
77	$tab->XMoveResizeWindow (
78	$tab->parent,
79	0, $self->{tabheight} + 1,
80	$self->width, $self->height - $self->{tabheight}
81	);
82	$tab->XMoveResizeWindow (
83	$tab->parent,
84	0, $self->{tabheight},
85	$self->width, $self->height - $self->{tabheight}
86	);
87	}
88
89	sub copy_properties {
90	my ($self) = @_;
91	my $tab = $self->{cur};
92
93	my $wm_normal_hints = $self->XInternAtom ("WM_NORMAL_HINTS");
94	my $wm_state = $self->XInternAtom ("WM_STATE");
95
96	my %our_props = map +($_ => undef), $self->XListProperties ($self->parent);
97
98	delete $our_props{$wm_state};
99
100	for my $atom ($tab->XListProperties ($tab->parent)) {
101	my ($type, $format, $items) = $self->XGetWindowProperty ($tab->parent, $atom);
102
103	delete $our_props{$atom};
104
105	if ($atom == $wm_normal_hints) {
106	my (@hints) = unpack "l!*", $items;
107
108	$hints[$_] += $self->{tabheight} for (4, 6, 16);
109
110	$items = pack "l!*", @hints;
111	}
112	$self->XChangeWindowProperty ($self->parent, $atom, $type, $format, $items);
113	}
114
115	$self->XDeleteProperty ($self->parent, $_) for keys %our_props;
116	}
117
118	sub make_current {
119	my ($self, $tab) = @_;
120
121	if (my $cur = $self->{cur}) {
122	delete $cur->{activity};
123	$cur->XUnmapWindow ($cur->parent) if $cur->mapped;
124	$cur->focus_out;
125	}
126
127	$self->{cur} = $tab;
128
129	$self->configure;
130	$self->copy_properties;
131	$tab->focus_in;
132	$tab->XMapWindow ($tab->parent);
133	delete $tab->{activity};
134	$self->refresh;
135
136	()
137	}
138
139	sub on_focus_in {
140	my ($self, $event) = @_;
141
142	$self->{cur}->focus_in;
143
144	()
145	}
146
147	sub on_focus_out {
148	my ($self, $event) = @_;
149
150	$self->{cur}->focus_out;
151
152	()
153	}
154
155	sub on_key_press {
156	my ($self, $event) = @_;
157
158	$self->{cur}->key_press ($event->{state}, $event->{keycode}, $event->{time});
159
160	1
161	}
162
163	sub on_key_release {
164	my ($self, $event) = @_;
165
166	$self->{cur}->key_release ($event->{state}, $event->{keycode}, $event->{time});
167
168	1
169	}
170
171	sub on_button_press {
172	1
173	}
174
175	sub on_button_release {
176	my ($self, $event) = @_;
177
178	if ($event->{row} == 0) {
179	for my $button (@{ $self->{tabofs} }) {
180	$button->[2]->($self, $event)
181	if $event->{col} >= $button->[0]
182	&& $event->{col} < $button->[1];
183	}
184	}
185
186	1
187	}
188
189	sub on_motion_notify {
190	1
191	}
192
193	sub on_init {
194	my ($self) = @_;
195
196	for (qw(name perl_ext_1 perl_ext_2)) {
197	my $val = $self->resource ($_);
198
199	push @{ $self->{resource} }, [$_ => $val]
200	if defined $val;
201	}
202
203	$self->resource (int_bwidth => 0);
204	$self->resource (name => "URxvt.tabbed");
205	$self->resource (pty_fd => -1);
206
207	$self->option ($urxvt::OPTION{scrollBar}, 0);
208
209	my $fg = $self->x_resource ("tabbar-fg");
210	my $bg = $self->x_resource ("tabbar-bg");
211	my $tabfg = $self->x_resource ("tab-fg");
212	my $tabbg = $self->x_resource ("tab-bg");
213
214	defined $fg or $fg = 3;
215	defined $bg or $bg = 0;
216	defined $tabfg or $tabfg = 0;
217	defined $tabbg or $tabbg = 1;
218
219	$self->{rs_tabbar} = urxvt::SET_COLOR (urxvt::DEFAULT_RSTYLE, $fg + 2, $bg + 2);
220	$self->{rs_tab} = urxvt::SET_COLOR (urxvt::DEFAULT_RSTYLE, $tabfg + 2, $tabbg + 2);
221
222	()
223	}
224
225	sub on_start {
226	my ($self) = @_;
227
228	$self->{tabheight} = $self->int_bwidth + $self->fheight + $self->lineSpace;
229
230	$self->cmd_parse ("\033[?25l");
231
232	$self->new_tab;
233
234	()
235	}
236
237	sub on_configure_notify {
238	my ($self, $event) = @_;
239
240	$self->configure;
241	$self->refresh;
242
243	()
244	}
245
246	sub on_wm_delete_window {
247	my ($self) = @_;
248
249	$_->destroy for @{ $self->{tabs} };
250
251	1
252	}
253
254	sub tab_start {
255	my ($self, $tab) = @_;
256
257	$tab->XChangeInput ($tab->parent, urxvt::PropertyChangeMask);
258
259	push @{ $self->{tabs} }, $tab;
260
261	# $tab->{name} \|\|= scalar @{ $self->{tabs} };
262	$self->make_current ($tab);
263
264	()
265	}
266
267	sub tab_destroy {
268	my ($self, $tab) = @_;
269
270	$self->{tabs} = [ grep $_ != $tab, @{ $self->{tabs} } ];
271
272	if (@{ $self->{tabs} }) {
273	if ($self->{cur} == $tab) {
274	delete $self->{cur};
275	$self->make_current ($self->{tabs}[-1]);
276	} else {
277	$self->refresh;
278	}
279	} else {
280	# delay destruction a tiny bit
281	$self->{destroy} = urxvt::iw->new->start->cb (sub { $self->destroy });
282	}
283
284	()
285	}
286
287	sub tab_key_press {
288	my ($self, $tab, $event, $keysym, $str) = @_;
289
290	if ($event->{state} & urxvt::ShiftMask) {
291	if ($keysym == 0xff51 \|\| $keysym == 0xff53) {
292	my ($idx) = grep $self->{tabs}[$_] == $tab, 0 .. $#{ $self->{tabs} };
293
294	--$idx if $keysym == 0xff51;
295	++$idx if $keysym == 0xff53;
296
297	$self->make_current ($self->{tabs}[$idx % @{ $self->{tabs}}]);
298
299	return 1;
300	} elsif ($keysym == 0xff54) {
301	$self->new_tab;
302
303	return 1;
304	}
305	}
306
307	()
308	}
309
310	sub tab_property_notify {
311	my ($self, $tab, $event) = @_;
312
313	$self->copy_properties
314	if $event->{window} == $tab->parent;
315
316	()
317	}
318
319	sub tab_activity {
320	my ($self, $tab) = @_;
321
322	$self->refresh;
323	}
324
325	package urxvt::ext::tabbed::tab;
326
327	# helper extension implementing the subwindows of a tabbed terminal.
328	# simply proxies all interesting calls back to the tabbed class.
329
330	{
331	for my $hook qw(start destroy key_press property_notify) {
332	eval qq{
333	sub on_$hook {
334	my \$parent = \$_[0]{term}{parent}
335	or return;
336	\$parent->tab_$hook (\@_)
337	}
338	};
339	die if $@;
340	}
341	}
342
343	sub on_add_lines {
344	$_[0]->{activity}++
345	or $_[0]{term}{parent}->tab_activity ($_[0]);
346	()
347	}
348
349