[ViewVC] Contents of: cvs/rxvt-unicode/src/perl/tabbed

#! perl

#:META:RESOURCE:tabbar-fg:colour:tab bar foreground colour
#:META:RESOURCE:tabbar-bg:colour:tab bar background colour
#:META:RESOURCE:tab-fg:colour:tab foreground colour
#:META:RESOURCE:tab-bg:colour:tab background colour

=head1 NAME

tabbed - tabbed interface to urxvt

=head1 DESCRIPTION

This transforms the terminal into a tabbar with additional terminals, that
is, it implements what is commonly referred to as "tabbed terminal". The topmost line
displays a "[NEW]" button, which, when clicked, will add a new tab, followed by one
button per tab.

Clicking a button will activate that tab. Pressing B<Shift-Left> and
B<Shift-Right> will switch to the tab left or right of the current one,
while B<Shift-Down> creates a new tab. Pressing B<Ctrl-Left> and
B<Ctrl-Right> will renumber the current tab by moving it to the left or
to the right.

The tabbar itself can be configured similarly to a normal terminal, but
with a resource class of C<URxvt.tabbed>. In addition, it supports the
following four resources (shown with defaults):

   URxvt.tabbed.tabbar-fg: <colour-index, default 3>
   URxvt.tabbed.tabbar-bg: <colour-index, default 0>
   URxvt.tabbed.tab-fg:    <colour-index, default 0>
   URxvt.tabbed.tab-bg:    <colour-index, default 1>

See I<COLOR AND GRAPHICS> in the urxvt(1) manpage for valid
indices.

=cut

sub refresh {
   my ($self) = @_;

   my $ncol = $self->ncol;

   my $text = " " x $ncol;
   my $rend = [($self->{rs_tabbar}) x $ncol];

   my @ofs;

   substr $text, 0, 7, "[NEW] |";
   @$rend[0 .. 5] = ($self->{rs_tab}) x 6;
   push @ofs, [0, 6, sub { $_[0]->new_tab }];

   my $ofs = 7;
   my $idx = 0;

   for my $tab (@{ $self->{tabs} }) {
      $idx++;

      my $act = $tab->{activity} && $tab != $self->{cur}
                ? "*" : " ";

      my $txt = "$act$idx$act";
      my $len = length $txt;

      substr $text, $ofs, $len + 1, "$txt|";
      @$rend[$ofs .. $ofs + $len - 1] = ($self->{rs_tab}) x $len
         if $tab == $self->{cur};

      push @ofs, [ $ofs, $ofs + $len, sub { $_[0]->make_current ($tab) } ];

      $ofs += $len + 1;
   }

   $self->{tabofs} = \@ofs;

   $self->ROW_t (0, $text, 0, 0, $ncol);
   $self->ROW_r (0, $rend, 0, 0, $ncol);

   $self->want_refresh;
}

sub new_tab {
   my ($self, @argv) = @_;

   # save a backlink to us, make sure tabbed is inactive
   push @urxvt::TERM_INIT, sub {
      my ($term) = @_;
      $term->{parent} = $self;

      for (0 .. urxvt::NUM_RESOURCES - 1) {
         my $value = $self->{resource}[$_];

         $term->resource ("+$_" => $value)
            if defined $value;
      }

      $term->resource (perl_ext_2 => $term->resource ("perl_ext_2") . ",-tabbed");
   };

   push @urxvt::TERM_EXT, urxvt::ext::tabbed::tab::;

   my $term = new urxvt::term
      $self->env, $urxvt::RXVTNAME,
      -embed => $self->parent,
      @argv,
   ;
}

sub configure {
   my ($self) = @_;

   my $tab = $self->{cur};

   # this is an extremely dirty way to force a configurenotify, but who cares
   $tab->XMoveResizeWindow (
      $tab->parent,
      0, $self->{tabheight} + 1,
      $self->width, $self->height - $self->{tabheight}
   );
   $tab->XMoveResizeWindow (
      $tab->parent,
      0, $self->{tabheight},
      $self->width, $self->height - $self->{tabheight}
   );
}

sub on_resize_all_windows {
   my ($self, $width, $height) = @_;

   1
}

sub copy_properties {
   my ($self) = @_;
   my $tab = $self->{cur};

   my $wm_normal_hints = $self->XInternAtom ("WM_NORMAL_HINTS");

   my $current = delete $self->{current_properties};

   # pass 1: copy over properties different or nonexisting
   for my $atom ($tab->XListProperties ($tab->parent)) {
      my ($type, $format, $items) = $self->XGetWindowProperty ($tab->parent, $atom);

      # fix up size hints
      if ($atom == $wm_normal_hints) {
         my (@hints) = unpack "l!*", $items;

         $hints[$_] += $self->{tabheight} for (4, 6, 16);

         $items = pack "l!*", @hints;
      }

      my $cur = delete $current->{$atom};

      # update if changed, we assume empty items and zero type and format will not happen
      $self->XChangeProperty ($self->parent, $atom, $type, $format, $items)
         if $cur->[0] != $type or $cur->[1] != $format or $cur->[2] ne $items;

      $self->{current_properties}{$atom} = [$type, $format, $items];
   }

   # pass 2, delete all extraneous properties
   $self->XDeleteProperty ($self->parent, $_) for keys %$current;
}

sub make_current {
   my ($self, $tab) = @_;

   if (my $cur = $self->{cur}) {
      delete $cur->{activity};
      $cur->XUnmapWindow ($cur->parent) if $cur->mapped;
      $cur->focus_out;
   }

   $self->{cur} = $tab;

   $self->configure;
   $self->copy_properties;

   $tab->focus_out; # just in case, should be a nop
   $tab->focus_in if $self->focus;

   $tab->XMapWindow ($tab->parent);
   delete $tab->{activity};
   $self->refresh;

   ()
}

sub on_focus_in {
   my ($self, $event) = @_;

   $self->{cur}->focus_in;

   ()
}

sub on_focus_out {
   my ($self, $event) = @_;

   $self->{cur}->focus_out;

   ()
}

sub on_tt_write {
    my ($self, $octets) = @_;

    $self->{cur}->tt_write ($octets);

    1
}

sub on_key_press {
   my ($self, $event) = @_;

   $self->{cur}->key_press ($event->{state}, $event->{keycode}, $event->{time});
   $self->{cur}->refresh_check;

   1
}

sub on_key_release {
   my ($self, $event) = @_;

   $self->{cur}->key_release ($event->{state}, $event->{keycode}, $event->{time});
   $self->{cur}->refresh_check;

   1
}

sub on_button_press {
   1
}

sub on_button_release {
   my ($self, $event) = @_;

   if ($event->{row} == 0) {
      for my $button (@{ $self->{tabofs} }) {
         $button->[2]->($self, $event)
            if $event->{col} >= $button->[0]
               && $event->{col} < $button->[1];
      }
   }

   1
}

sub on_motion_notify {
   1
}

sub on_init {
   my ($self) = @_;

   $self->{resource} = [map $self->resource ("+$_"), 0 .. urxvt::NUM_RESOURCES - 1];

   $self->resource (int_bwidth => 0);
   $self->resource (name => "URxvt.tabbed");
   $self->resource (pty_fd => -1);

   $self->option ($urxvt::OPTION{scrollBar}, 0);

   my $fg    = $self->x_resource ("tabbar-fg");
   my $bg    = $self->x_resource ("tabbar-bg");
   my $tabfg = $self->x_resource ("tab-fg");
   my $tabbg = $self->x_resource ("tab-bg");

   defined $fg    or $fg    = 3;
   defined $bg    or $bg    = 0;
   defined $tabfg or $tabfg = 0;
   defined $tabbg or $tabbg = 1;

   $self->{rs_tabbar} = urxvt::SET_COLOR (urxvt::DEFAULT_RSTYLE, $fg    + 2, $bg    + 2);
   $self->{rs_tab}    = urxvt::SET_COLOR (urxvt::DEFAULT_RSTYLE, $tabfg + 2, $tabbg + 2);

   ()
}

sub on_start {
   my ($self) = @_;

   $self->{tabheight} = $self->int_bwidth + $self->fheight + $self->lineSpace;

   $self->cmd_parse ("\033[?25l");

   my @argv = $self->argv;

   do {
      shift @argv;
   } while @argv && $argv[0] ne "-e";

   $self->new_tab (@argv);

   ()
}

sub on_configure_notify {
   my ($self, $event) = @_;

   $self->configure;
   $self->refresh;

   ()
}

sub on_wm_delete_window {
   my ($self) = @_;

   $_->destroy for @{ $self->{tabs} };

   1
}

sub tab_start {
   my ($self, $tab) = @_;

   $tab->XChangeInput ($tab->parent, urxvt::PropertyChangeMask);

   push @{ $self->{tabs} }, $tab;

#   $tab->{name} ||= scalar @{ $self->{tabs} };
   $self->make_current ($tab);

   ()
}

sub tab_destroy {
   my ($self, $tab) = @_;

   $self->{tabs} = [ grep $_ != $tab, @{ $self->{tabs} } ];

   if (@{ $self->{tabs} }) {
      if ($self->{cur} == $tab) {
         delete $self->{cur};
         $self->make_current ($self->{tabs}[-1]);
      } else {
         $self->refresh;
      }
   } else {
      # delay destruction a tiny bit
      $self->{destroy} = urxvt::iw->new->start->cb (sub { $self->destroy });
   }

   ()
}

sub tab_key_press {
   my ($self, $tab, $event, $keysym, $str) = @_;

   if ($event->{state} & urxvt::ShiftMask) {
      if ($keysym == 0xff51 || $keysym == 0xff53) {
         my ($idx) = grep $self->{tabs}[$_] == $tab, 0 .. $#{ $self->{tabs} };

         --$idx if $keysym == 0xff51;
         ++$idx if $keysym == 0xff53;

         $self->make_current ($self->{tabs}[$idx % @{ $self->{tabs}}]);

         return 1;
      } elsif ($keysym == 0xff54) {
         $self->new_tab;

         return 1;
      }
   }
   elsif ($event->{state} & urxvt::ControlMask) {
      if ($keysym == 0xff51 || $keysym == 0xff53) {
         my ($idx1) = grep $self->{tabs}[$_] == $tab, 0 .. $#{ $self->{tabs} };
         my  $idx2  = ($idx1 + ($keysym == 0xff51 ? -1 : +1)) % @{ $self->{tabs} };

         ($self->{tabs}[$idx1], $self->{tabs}[$idx2]) =
            ($self->{tabs}[$idx2], $self->{tabs}[$idx1]);

         $self->make_current ($self->{tabs}[$idx2]);

         return 1;
      }
   }

   ()
}

sub tab_property_notify {
   my ($self, $tab, $event) = @_;

   $self->copy_properties
      if $event->{window} == $tab->parent;

   ()
}

sub tab_activity {
   my ($self, $tab) = @_;

   $self->refresh;
}

package urxvt::ext::tabbed::tab;

# helper extension implementing the subwindows of a tabbed terminal.
# simply proxies all interesting calls back to the tabbed class.

{
   for my $hook (qw(start destroy key_press property_notify)) {
      eval qq{
         sub on_$hook {
            my \$parent = \$_[0]{term}{parent}
               or return;
            \$parent->tab_$hook (\@_)
         }
      };
      die if $@;
   }
}

sub on_add_lines {
  $_[0]->{activity}++
     or $_[0]{term}{parent}->tab_activity ($_[0]);
  ()
}


Revision:	1.39
Committed:	Sun Feb 26 06:36:46 2017 UTC (7 years, 2 months ago) by sf-exg
Branch:	MAIN
CVS Tags:	rxvt-unicode-rel-9_29, rxvt-unicode-rel-9_26, rxvt-unicode-rel-9_25, rxvt-unicode-rel-9_30, HEAD
Changes since 1.38:	+1 -1 lines
Log Message:	Doc fix.
#	Content
1	#! perl
2
3	#:META:RESOURCE:tabbar-fg:colour:tab bar foreground colour
4	#:META:RESOURCE:tabbar-bg:colour:tab bar background colour
5	#:META:RESOURCE:tab-fg:colour:tab foreground colour
6	#:META:RESOURCE:tab-bg:colour:tab background colour
7
8	=head1 NAME
9
10	tabbed - tabbed interface to urxvt
11
12	=head1 DESCRIPTION
13
14	This transforms the terminal into a tabbar with additional terminals, that
15	is, it implements what is commonly referred to as "tabbed terminal". The topmost line
16	displays a "[NEW]" button, which, when clicked, will add a new tab, followed by one
17	button per tab.
18
19	Clicking a button will activate that tab. Pressing B<Shift-Left> and
20	B<Shift-Right> will switch to the tab left or right of the current one,
21	while B<Shift-Down> creates a new tab. Pressing B<Ctrl-Left> and
22	B<Ctrl-Right> will renumber the current tab by moving it to the left or
23	to the right.
24
25	The tabbar itself can be configured similarly to a normal terminal, but
26	with a resource class of C<URxvt.tabbed>. In addition, it supports the
27	following four resources (shown with defaults):
28
29	URxvt.tabbed.tabbar-fg: <colour-index, default 3>
30	URxvt.tabbed.tabbar-bg: <colour-index, default 0>
31	URxvt.tabbed.tab-fg: <colour-index, default 0>
32	URxvt.tabbed.tab-bg: <colour-index, default 1>
33
34	See I<COLOR AND GRAPHICS> in the urxvt(1) manpage for valid
35	indices.
36
37	=cut
38
39	sub refresh {
40	my ($self) = @_;
41
42	my $ncol = $self->ncol;
43
44	my $text = " " x $ncol;
45	my $rend = [($self->{rs_tabbar}) x $ncol];
46
47	my @ofs;
48
49	substr $text, 0, 7, "[NEW] \|";
50	@$rend[0 .. 5] = ($self->{rs_tab}) x 6;
51	push @ofs, [0, 6, sub { $_[0]->new_tab }];
52
53	my $ofs = 7;
54	my $idx = 0;
55
56	for my $tab (@{ $self->{tabs} }) {
57	$idx++;
58
59	my $act = $tab->{activity} && $tab != $self->{cur}
60	? "*" : " ";
61
62	my $txt = "$act$idx$act";
63	my $len = length $txt;
64
65	substr $text, $ofs, $len + 1, "$txt\|";
66	@$rend[$ofs .. $ofs + $len - 1] = ($self->{rs_tab}) x $len
67	if $tab == $self->{cur};
68
69	push @ofs, [ $ofs, $ofs + $len, sub { $_[0]->make_current ($tab) } ];
70
71	$ofs += $len + 1;
72	}
73
74	$self->{tabofs} = \@ofs;
75
76	$self->ROW_t (0, $text, 0, 0, $ncol);
77	$self->ROW_r (0, $rend, 0, 0, $ncol);
78
79	$self->want_refresh;
80	}
81
82	sub new_tab {
83	my ($self, @argv) = @_;
84
85	# save a backlink to us, make sure tabbed is inactive
86	push @urxvt::TERM_INIT, sub {
87	my ($term) = @_;
88	$term->{parent} = $self;
89
90	for (0 .. urxvt::NUM_RESOURCES - 1) {
91	my $value = $self->{resource}[$_];
92
93	$term->resource ("+$_" => $value)
94	if defined $value;
95	}
96
97	$term->resource (perl_ext_2 => $term->resource ("perl_ext_2") . ",-tabbed");
98	};
99
100	push @urxvt::TERM_EXT, urxvt::ext::tabbed::tab::;
101
102	my $term = new urxvt::term
103	$self->env, $urxvt::RXVTNAME,
104	-embed => $self->parent,
105	@argv,
106	;
107	}
108
109	sub configure {
110	my ($self) = @_;
111
112	my $tab = $self->{cur};
113
114	# this is an extremely dirty way to force a configurenotify, but who cares
115	$tab->XMoveResizeWindow (
116	$tab->parent,
117	0, $self->{tabheight} + 1,
118	$self->width, $self->height - $self->{tabheight}
119	);
120	$tab->XMoveResizeWindow (
121	$tab->parent,
122	0, $self->{tabheight},
123	$self->width, $self->height - $self->{tabheight}
124	);
125	}
126
127	sub on_resize_all_windows {
128	my ($self, $width, $height) = @_;
129
130	1
131	}
132
133	sub copy_properties {
134	my ($self) = @_;
135	my $tab = $self->{cur};
136
137	my $wm_normal_hints = $self->XInternAtom ("WM_NORMAL_HINTS");
138
139	my $current = delete $self->{current_properties};
140
141	# pass 1: copy over properties different or nonexisting
142	for my $atom ($tab->XListProperties ($tab->parent)) {
143	my ($type, $format, $items) = $self->XGetWindowProperty ($tab->parent, $atom);
144
145	# fix up size hints
146	if ($atom == $wm_normal_hints) {
147	my (@hints) = unpack "l!*", $items;
148
149	$hints[$_] += $self->{tabheight} for (4, 6, 16);
150
151	$items = pack "l!*", @hints;
152	}
153
154	my $cur = delete $current->{$atom};
155
156	# update if changed, we assume empty items and zero type and format will not happen
157	$self->XChangeProperty ($self->parent, $atom, $type, $format, $items)
158	if $cur->[0] != $type or $cur->[1] != $format or $cur->[2] ne $items;
159
160	$self->{current_properties}{$atom} = [$type, $format, $items];
161	}
162
163	# pass 2, delete all extraneous properties
164	$self->XDeleteProperty ($self->parent, $_) for keys %$current;
165	}
166
167	sub make_current {
168	my ($self, $tab) = @_;
169
170	if (my $cur = $self->{cur}) {
171	delete $cur->{activity};
172	$cur->XUnmapWindow ($cur->parent) if $cur->mapped;
173	$cur->focus_out;
174	}
175
176	$self->{cur} = $tab;
177
178	$self->configure;
179	$self->copy_properties;
180
181	$tab->focus_out; # just in case, should be a nop
182	$tab->focus_in if $self->focus;
183
184	$tab->XMapWindow ($tab->parent);
185	delete $tab->{activity};
186	$self->refresh;
187
188	()
189	}
190
191	sub on_focus_in {
192	my ($self, $event) = @_;
193
194	$self->{cur}->focus_in;
195
196	()
197	}
198
199	sub on_focus_out {
200	my ($self, $event) = @_;
201
202	$self->{cur}->focus_out;
203
204	()
205	}
206
207	sub on_tt_write {
208	my ($self, $octets) = @_;
209
210	$self->{cur}->tt_write ($octets);
211
212	1
213	}
214
215	sub on_key_press {
216	my ($self, $event) = @_;
217
218	$self->{cur}->key_press ($event->{state}, $event->{keycode}, $event->{time});
219	$self->{cur}->refresh_check;
220
221	1
222	}
223
224	sub on_key_release {
225	my ($self, $event) = @_;
226
227	$self->{cur}->key_release ($event->{state}, $event->{keycode}, $event->{time});
228	$self->{cur}->refresh_check;
229
230	1
231	}
232
233	sub on_button_press {
234	1
235	}
236
237	sub on_button_release {
238	my ($self, $event) = @_;
239
240	if ($event->{row} == 0) {
241	for my $button (@{ $self->{tabofs} }) {
242	$button->[2]->($self, $event)
243	if $event->{col} >= $button->[0]
244	&& $event->{col} < $button->[1];
245	}
246	}
247
248	1
249	}
250
251	sub on_motion_notify {
252	1
253	}
254
255	sub on_init {
256	my ($self) = @_;
257
258	$self->{resource} = [map $self->resource ("+$_"), 0 .. urxvt::NUM_RESOURCES - 1];
259
260	$self->resource (int_bwidth => 0);
261	$self->resource (name => "URxvt.tabbed");
262	$self->resource (pty_fd => -1);
263
264	$self->option ($urxvt::OPTION{scrollBar}, 0);
265
266	my $fg = $self->x_resource ("tabbar-fg");
267	my $bg = $self->x_resource ("tabbar-bg");
268	my $tabfg = $self->x_resource ("tab-fg");
269	my $tabbg = $self->x_resource ("tab-bg");
270
271	defined $fg or $fg = 3;
272	defined $bg or $bg = 0;
273	defined $tabfg or $tabfg = 0;
274	defined $tabbg or $tabbg = 1;
275
276	$self->{rs_tabbar} = urxvt::SET_COLOR (urxvt::DEFAULT_RSTYLE, $fg + 2, $bg + 2);
277	$self->{rs_tab} = urxvt::SET_COLOR (urxvt::DEFAULT_RSTYLE, $tabfg + 2, $tabbg + 2);
278
279	()
280	}
281
282	sub on_start {
283	my ($self) = @_;
284
285	$self->{tabheight} = $self->int_bwidth + $self->fheight + $self->lineSpace;
286
287	$self->cmd_parse ("\033[?25l");
288
289	my @argv = $self->argv;
290
291	do {
292	shift @argv;
293	} while @argv && $argv[0] ne "-e";
294
295	$self->new_tab (@argv);
296
297	()
298	}
299
300	sub on_configure_notify {
301	my ($self, $event) = @_;
302
303	$self->configure;
304	$self->refresh;
305
306	()
307	}
308
309	sub on_wm_delete_window {
310	my ($self) = @_;
311
312	$_->destroy for @{ $self->{tabs} };
313
314	1
315	}
316
317	sub tab_start {
318	my ($self, $tab) = @_;
319
320	$tab->XChangeInput ($tab->parent, urxvt::PropertyChangeMask);
321
322	push @{ $self->{tabs} }, $tab;
323
324	# $tab->{name} \|\|= scalar @{ $self->{tabs} };
325	$self->make_current ($tab);
326
327	()
328	}
329
330	sub tab_destroy {
331	my ($self, $tab) = @_;
332
333	$self->{tabs} = [ grep $_ != $tab, @{ $self->{tabs} } ];
334
335	if (@{ $self->{tabs} }) {
336	if ($self->{cur} == $tab) {
337	delete $self->{cur};
338	$self->make_current ($self->{tabs}[-1]);
339	} else {
340	$self->refresh;
341	}
342	} else {
343	# delay destruction a tiny bit
344	$self->{destroy} = urxvt::iw->new->start->cb (sub { $self->destroy });
345	}
346
347	()
348	}
349
350	sub tab_key_press {
351	my ($self, $tab, $event, $keysym, $str) = @_;
352
353	if ($event->{state} & urxvt::ShiftMask) {
354	if ($keysym == 0xff51 \|\| $keysym == 0xff53) {
355	my ($idx) = grep $self->{tabs}[$_] == $tab, 0 .. $#{ $self->{tabs} };
356
357	--$idx if $keysym == 0xff51;
358	++$idx if $keysym == 0xff53;
359
360	$self->make_current ($self->{tabs}[$idx % @{ $self->{tabs}}]);
361
362	return 1;
363	} elsif ($keysym == 0xff54) {
364	$self->new_tab;
365
366	return 1;
367	}
368	}
369	elsif ($event->{state} & urxvt::ControlMask) {
370	if ($keysym == 0xff51 \|\| $keysym == 0xff53) {
371	my ($idx1) = grep $self->{tabs}[$_] == $tab, 0 .. $#{ $self->{tabs} };
372	my $idx2 = ($idx1 + ($keysym == 0xff51 ? -1 : +1)) % @{ $self->{tabs} };
373
374	($self->{tabs}[$idx1], $self->{tabs}[$idx2]) =
375	($self->{tabs}[$idx2], $self->{tabs}[$idx1]);
376
377	$self->make_current ($self->{tabs}[$idx2]);
378
379	return 1;
380	}
381	}
382
383	()
384	}
385
386	sub tab_property_notify {
387	my ($self, $tab, $event) = @_;
388
389	$self->copy_properties
390	if $event->{window} == $tab->parent;
391
392	()
393	}
394
395	sub tab_activity {
396	my ($self, $tab) = @_;
397
398	$self->refresh;
399	}
400
401	package urxvt::ext::tabbed::tab;
402
403	# helper extension implementing the subwindows of a tabbed terminal.
404	# simply proxies all interesting calls back to the tabbed class.
405
406	{
407	for my $hook (qw(start destroy key_press property_notify)) {
408	eval qq{
409	sub on_$hook {
410	my \$parent = \$_[0]{term}{parent}
411	or return;
412	\$parent->tab_$hook (\@_)
413	}
414	};
415	die if $@;
416	}
417	}
418
419	sub on_add_lines {
420	$_[0]->{activity}++
421	or $_[0]{term}{parent}->tab_activity ($_[0]);
422	()
423	}
424
425