package AnyEvent::Fork::RPC::Sync;

use common::sense; # actually required to avoid spurious warnings...

# declare only
sub AnyEvent::Fork::RPC::event;

sub main::test {#d#
#   AnyEvent::Fork::RPC::event($_[0],$_) for 1..$_[0];
   "3"
}

our $master;

sub xwrite($) {
   my $got = syswrite $master, $_[0];

   while ($got < length $_[0]) {
      my $len = syswrite $master, $_[0], 1<<30, $got;

      defined $len
         or die "AnyEvent::Fork::RPC::Sync: write error ($!), parent gone?";

      $got += $len;
   }
}

sub rlen($) { ($_[0] < 384 ? 512 + 16 : 2 << int +(log $_[0] + 512) / log 2) - $_[0] - 16 }

# the goal here is to keep this simple, small and efficient
sub run {
   my ($function, $init, $serialiser) = splice @_, -3, 3,;

   $master = shift;

   {
      package main;
      &$init if length $init;
      $function = \&$function; # resolve function early for extra speed
   }

   my ($f, $t) = eval $serialiser; die $@ if $@;

   *AnyEvent::Fork::RPC::event = sub {
      xwrite pack "L/a*", $f->(@_, 1);
   };

   my ($rlen, $rbuf) = 512 - 16;

   # the read length here is not optimal, but since we re-use $rbuf,
   # its allocated size should eventually auto-adjust.
   while (sysread $master, $rbuf, $rlen - length $rbuf, length $rbuf) {
      $rlen = $rlen * 2 + 16 if $rlen - 128 < length $rbuf;

      while () {
         last if 5 > length $rbuf;
         my $len = unpack "L", $rbuf;
         last if 4 + $len > length $rbuf;
         my @r = $t->(substr $rbuf, 4, $len);
         substr $rbuf, 0, 4 + $len, "";

         xwrite pack "L/a*", $f->($function->(@r), "");
      }
   }

   shutdown $master, 1;
}

1