#!/usr/bin/perl

use strict;

use Socket;
use IO::Socket::INET;

use YAML;
use Encode;
use Event;
use Net::Knuddels;
use Algorithm::MarkovChain;

my @CHANNELS = (
  'Flirt', 
  'Flirt 2', 
  'Flirt 23+', 
  'Flirt 30+', 
);

my $logdir = "logs/";

my $Knick = "ich bin suess";
my $Kpass = "qwerty";

my $client;

my $seed = Load do { open my $fh, "<", "markovd.dat"; binmode $fh, ":utf8"; local $/; <$fh> };
$seed ||= [];

$SIG{INT} = sub { Event::unloop(-1) };

Event->timer (interval => 60, cb => sub {
   open my $fh, ">", "markovd.dat~"
      or return;
   print $fh Encode::encode_utf8 Dump $seed;
   close $fh;
   rename "markovd.dat~", "markovd.dat";
});

sub connect_knuddels {
  $client->login;
  Event->io (
    fd => $client->fh, 
    poll => 'r', 
    cb => sub { 
      my $e = shift;
      if (not $client->ready) {
        $e->w->cancel;
      }
    });
}

sub logit {
  my ($msg, $file, $src, $dst, $room) = @_;

  unless (-e $logdir) {
    mkdir $logdir;
  }

  unless (open T, ">>$logdir/$file") {
    warn "Couldn't open for appending $logdir/$src: $!\n";
    return;
  }

  print T "$room\t$src\t$dst\t$msg\n";
  close T;
}

####################################################################################
########################## MAIN START ##############################################
####################################################################################

$client = new Net::Knuddels::Client PeerAddr => "213.61.5.150:2710";

#$client->register (UNHANDLED => sub {
#   use Dumpvalue;
#   print "---\n";
#   Dumpvalue->new (compactDump => 1, veryCompact => 1, quoteHighBit => 1, tick => '"')->dumpValue ([@_]);
#});

$client->register (login => sub {
   $client->enter_room ($_, $Knick, $Kpass)
     for (@CHANNELS);
});

$client->register (msg_room => sub {
   my ($room, $user, $msg) = @_;
});

my @queue;

Event->timer (interval => 1, cb => sub {
   my $msg = shift @queue
      or return;

   logit ($msg->[2], $msg->[0], $Knick, $msg->[0], $msg->[1]);
   $client->send_priv_msg (@$msg);
});

$client->register (msg_priv => sub {
   my ($room, $src, $dst, $msg) = @_;

   return if $src eq "James";
   return if $src eq $Knick;

   $msg =~ s/\260[^\260]*\260//g;

   print "($room) $src >> $msg\n";
   logit ($msg, $src, $src, $dst, $room);

   my @msg = $msg =~ /(\S+)/g;

   for (@msg) {
      $_ .= "\n" if /[?!.]$/;
   }

   $msg[-1] .= "\n\n" if @msg;

   push @$seed, @msg;

   my $markov = new Algorithm::MarkovChain;
   $markov->seed (symbols => $seed, longest => 7);

   my $reply = join " ", $markov->spew (length => 3, stop_at_terminal => 1);
   $reply =~ s/(?<=.....)\n.*//;
   $reply =~ s/\n//g;

   my $delay = 30 * (rand) ** 5 + 0.3 * length $reply;

   print "($room) $src << $reply ($delay)\n";

   Event->timer (after => $delay, cb => sub {
      push @queue, [$src, $room, $reply];
   });
});

connect_knuddels;
Event::loop;