cvsroot/Linux-Inotify2/Inotify2.pm

=head1 NAME

Linux::Inotify2 - scalable directory/file change notification

=head1 SYNOPSIS

=head2 Callback Interface

 use Linux::Inotify2;

 # create a new object
 my $inotify = new Linux::Inotify2
    or die "unable to create new inotify object: $!";
 
 # add watchers
 $inotify->watch ("/etc/passwd", IN_ACCESS, sub {
    my $e = shift;
    my $name = $e->fullname;
    print "$name was accessed\n" if $e->IN_ACCESS;
    print "$name is no longer mounted\n" if $e->IN_UNMOUNT;
    print "$name is gone\n" if $e->IN_IGNORED;
    print "events for $name have been lost\n" if $e->IN_Q_OVERFLOW;
 
    # cancel this watcher: remove no further events
    $e->w->cancel;
 });

 # integration into AnyEvent (works with EV, Glib, Tk, POE...)
 my $inotify_w = AE::io $inotify->fileno, 0, sub { $inotify->poll };

 # manual event loop
 1 while $inotify->poll;

=head2 Streaming Interface

 use Linux::Inotify2;

 # create a new object
 my $inotify = new Linux::Inotify2
    or die "Unable to create new inotify object: $!";

 # create watch
 $inotify->watch ("/etc/passwd", IN_ACCESS)
    or die "watch creation failed";

 while () {
   my @events = $inotify->read;
   unless (@events > 0) {
     print "read error: $!";
     last;
   }
   printf "mask\t%d\n", $_->mask foreach @events;
 }

=head1 DESCRIPTION

This module implements an interface to the Linux 2.6.13 and later Inotify
file/directory change notification system.

It has a number of advantages over the Linux::Inotify module:

   - it is portable (Linux::Inotify only works on x86)
   - the equivalent of fullname works correctly
   - it is better documented
   - it has callback-style interface, which is better suited for
     integration.

=head2 The Linux::Inotify2 Class

=over 4

=cut

package Linux::Inotify2;

use Scalar::Util ();

use common::sense;

use Exporter qw(import);

BEGIN {
   our $VERSION = '1.23';
   our @EXPORT = qw(
      IN_ACCESS IN_MODIFY IN_ATTRIB IN_CLOSE_WRITE
      IN_CLOSE_NOWRITE IN_OPEN IN_MOVED_FROM IN_MOVED_TO
      IN_CREATE IN_DELETE IN_DELETE_SELF IN_MOVE_SELF
      IN_ALL_EVENTS
      IN_UNMOUNT IN_Q_OVERFLOW IN_IGNORED
      IN_CLOSE IN_MOVE
      IN_ISDIR IN_ONESHOT IN_MASK_ADD
      IN_DONT_FOLLOW IN_EXCL_UNLINK IN_ONLYDIR
   );

   require XSLoader;
   XSLoader::load Linux::Inotify2, $VERSION;
}

=item my $inotify = new Linux::Inotify2

Create a new notify object and return it. A notify object is kind of a
container that stores watches on file system names and is responsible for
handling event data.

On error, C<undef> is returned and C<$!> will be set accordingly. The
following errors are documented:

 ENFILE   The system limit on the total number of file descriptors has been reached.
 EMFILE   The user limit on the total number of inotify instances has been reached.
 ENOMEM   Insufficient kernel memory is available.

Example:

   my $inotify = new Linux::Inotify2
      or die "Unable to create new inotify object: $!";

=cut

sub new {
   my ($class) = @_;

   my $fd = inotify_init;

   return unless $fd >= 0;

   bless { fd => $fd }, $class
}

=item $watch = $inotify->watch ($name, $mask[, $cb])

Add a new watcher to the given notifier. The watcher will create events
on the pathname C<$name> as given in C<$mask>, which can be any of the
following constants (all exported by default) ORed together.

"file" refers to any file system object in the watched object (always a
directory), that is files, directories, symlinks, device nodes etc., while
"object" refers to the object the watcher has been set on itself:

 IN_ACCESS            object was accessed
 IN_MODIFY            object was modified
 IN_ATTRIB            object metadata changed
 IN_CLOSE_WRITE       writable fd to file / to object was closed
 IN_CLOSE_NOWRITE     readonly fd to file / to object closed
 IN_OPEN              object was opened
 IN_MOVED_FROM        file was moved from this object (directory)
 IN_MOVED_TO          file was moved to this object (directory)
 IN_CREATE            file was created in this object (directory)
 IN_DELETE            file was deleted from this object (directory)
 IN_DELETE_SELF       object itself was deleted
 IN_MOVE_SELF         object itself was moved
 IN_ALL_EVENTS        all of the above events

 IN_ONESHOT           only send event once
 IN_ONLYDIR           only watch the path if it is a directory
 IN_DONT_FOLLOW       don't follow a sym link (Linux 2.6.15+)
 IN_EXCL_UNLINK       don't create events for unlinked objects (Linux 2.6.36+)
 IN_MASK_ADD          not supported with the current version of this module

 IN_CLOSE             same as IN_CLOSE_WRITE | IN_CLOSE_NOWRITE
 IN_MOVE              same as IN_MOVED_FROM | IN_MOVED_TO

C<$cb> is a perl code reference that, if given, is called for each
event. It receives a C<Linux::Inotify2::Event> object.

The returned C<$watch> object is of class C<Linux::Inotify2::Watch>.

On error, C<undef> is returned and C<$!> will be set accordingly. The
following errors are documented:

 EBADF    The given file descriptor is not valid.
 EINVAL   The given event mask contains no legal events.
 ENOMEM   Insufficient kernel memory was available.
 ENOSPC   The user limit on the total number of inotify watches was reached or the kernel failed to allocate a needed resource.
 EACCESS  Read access to the given file is not permitted.

Example, show when C</etc/passwd> gets accessed and/or modified once:

   $inotify->watch ("/etc/passwd", IN_ACCESS | IN_MODIFY, sub {
      my $e = shift;
      print "$e->{w}{name} was accessed\n" if $e->IN_ACCESS;
      print "$e->{w}{name} was modified\n" if $e->IN_MODIFY;
      print "$e->{w}{name} is no longer mounted\n" if $e->IN_UNMOUNT;
      print "events for $e->{w}{name} have been lost\n" if $e->IN_Q_OVERFLOW;

      $e->w->cancel;
   });

=cut

sub watch {
   my ($self, $name, $mask, $cb) = @_;

   my $wd = inotify_add_watch $self->{fd}, $name, $mask;

   return unless $wd >= 0;
   
   my $w = $self->{w}{$wd} = bless {
      inotify => $self,
      wd      => $wd,
      name    => $name,
      mask    => $mask,
      cb      => $cb,
   }, "Linux::Inotify2::Watch";

   Scalar::Util::weaken $w->{inotify};

   $w
}

=item $inotify->fileno

Returns the file descriptor for this notify object. When in non-blocking
mode, you are responsible for calling the C<poll> method when this file
descriptor becomes ready for reading.

=cut

sub fileno {
   $_[0]{fd}
}

=item $inotify->blocking ($blocking)

Clears ($blocking true) or sets ($blocking false) the C<O_NONBLOCK> flag on the file descriptor.

=cut

sub blocking {
   my ($self, $blocking) = @_;

   inotify_blocking $self->{fd}, $blocking;
}

=item $count = $inotify->poll

Reads events from the kernel and handles them. If the notify file
descriptor is blocking (the default), then this method waits for at least
one event (and thus returns true unless an error occurs). Otherwise it
returns immediately when no pending events could be read.

Returns the count of events that have been handled.

=cut

sub poll {
   scalar &read
}

=item @events = $inotify->read

Reads events from the kernel. Blocks when the file descriptor is in
blocking mode (default) until any event arrives. Returns list of
C<Linux::Inotify2::Event> objects or empty list if none (non-blocking
mode) or error occurred ($! should be checked).

Normally you shouldn't use this function, but instead use watcher
callbacks and call C<< ->poll >>.

=cut

sub read {
   my ($self) = @_;

   my @ev = inotify_read $self->{fd};
   my @res;

   for (@ev) {
      $_->{wd}=-1; $_->{mask} = IN_Q_OVERFLOW;#d#

      exists $self->{ignore}{$_->{wd}}
         and next; # watcher has been canceled

      push @res, bless $_, "Linux::Inotify2::Event";

      my $w = $_->{w} = $self->{w}{$_->{wd}}
         or do {
            # no such watcher, but maybe we can do overflow handling
            if ($_->{mask} & IN_Q_OVERFLOW) {
               if ($self->{on_overflow}) {
                  $self->{on_overflow}($_);
               } else {
                  $self->broadcast ($_);
               }
            }
            next;
         };

      $w->{cb}($_) if $w->{cb};
      $w->cancel if $_->{mask} & (IN_IGNORED | IN_UNMOUNT | IN_ONESHOT | IN_DELETE_SELF);
   }

   delete $self->{ignore};

   wantarray ? @res : scalar @res
}

=item $inotify->on_overflow ($cb->($ev))

Sets the callback to be used for overflow handling
(default: C<undef>): When C<read> receives an event with C<IN_Q_OVERFLOW>
set, it will invoke this callback with the event.

When the callback is C<undef>, then it broadcasts the event to all
registered watchers, i.e., C<undef> is equivalent to:

   sub { $inotify->broadcast ($_[0]) }

=cut

sub on_overflow {
   my $prev = $_[0]{on_overflow};

   $_[0]{on_overflow} = $_[1]
      if @_ >= 2;

   $prev
}

=item $inotify->broadcast ($ev)

Invokes all registered watcher callbacks and passes the given event to
them. Most useful in overflow handlers.

=cut

sub broadcast {
   my ($self, $ev) = @_;

   for my $w (values %{ $self->{w} }) {
      local $ev->{w} = $w;
      $w->{cb}($ev) if $w->{cb};
   }
}

sub DESTROY {
   inotify_close $_[0]{fd}
}

=back

=head2 The Linux::Inotify2::Event Class

Objects of this class are handed as first argument to the watcher
callback. It has the following members and methods:

=over 4

=item $event->w

=item $event->{w}

The watcher object for this event, if one is available. Generally, you cna
only rely on the value of this member inside watcher callbacks.

=item $event->name

=item $event->{name}

The path of the file system object, relative to the watched name.

=item $event->fullname

Returns the "full" name of the relevant object, i.e. including the C<name>
member of the watcher (if the watch object is on a directory and a
directory entry is affected), or simply the C<name> member itself when the
object is the watch object itself.

This call requires C<< $event->{w} >> to be valid, which is generally only
the case within watcher callbacks.

=item $event->mask

=item $event->{mask}

The received event mask. In addition to the events described for C<<
$inotify->watch >>, the following flags (exported by default) can be set:

 IN_ISDIR             event object is a directory
 IN_Q_OVERFLOW        event queue overflowed

 # when any of the following flags are set,
 # then watchers for this event are automatically canceled
 IN_UNMOUNT           filesystem for watched object was unmounted
 IN_IGNORED           file was ignored/is gone (no more events are delivered)
 IN_ONESHOT           only one event was generated
 IN_Q_OVERFLOW        queue overflow - event might not be specific to a watcher

=item $event->IN_xxx

Returns a boolean that returns true if the event mask contains any events
specified by the mask. All of the C<IN_xxx> constants can be used as
methods.

=item $event->cookie

=item $event->{cookie}

The event cookie to "synchronize two events". Normally zero, this value is
set when two events relating to the same file are generated. As far as I
know, this only happens for C<IN_MOVED_FROM> and C<IN_MOVED_TO> events, to
identify the old and new name of a file.

Note that the inotify API makes it impossible to know whether there will
be a C<IN_MOVED_TO> event - you might receive only one of the events,
and even if you receive both, there might be any number of events in
between. The best approach seems to be to implement a small timeout
after C<IN_MOVED_FROM> to see if a matching C<IN_MOVED_TO> event will be
received - 2ms seem to work relatively well.

=back

=cut

package Linux::Inotify2::Event;

sub w       { $_[0]{w}      }
sub name    { $_[0]{name}   }
sub mask    { $_[0]{mask}   }
sub cookie  { $_[0]{cookie} }

sub fullname {
   length $_[0]{name}
      ? "$_[0]{w}{name}/$_[0]{name}"
      : $_[0]{w}{name};
}

for my $name (@Linux::Inotify2::EXPORT) {
   my $mask = &{"Linux::Inotify2::$name"};

   *$name = sub { $_[0]{mask} & $mask };
}

=head2 The Linux::Inotify2::Watch Class

Watcher objects are created by calling the C<watch> method of a notifier.

It has the following members and methods:

=over 4

=item $watch->name

=item $watch->{name}

The name as specified in the C<watch> call. For the object itself, this is
the empty string.  For directory watches, this is the name of the entry
without leading path elements.

=item $watch->mask

=item $watch->{mask}

The mask as specified in the C<watch> call.

=item $watch->cb ([new callback])

=item $watch->{cb}

The callback as specified in the C<watch> call. Can optionally be changed.

=item $watch->cancel

Cancels/removes this watcher. Future events, even if already queued queued,
will not be handled and resources will be freed.

=back

=cut

package Linux::Inotify2::Watch;

sub name    { $_[0]{name} }
sub mask    { $_[0]{mask} }

sub cb {
   $_[0]{cb} = $_[1] if @_ > 1;
   $_[0]{cb}
}

sub cancel {
   my ($self) = @_;

   my $inotify = delete $self->{inotify}
      or return 1; # already canceled

   delete $inotify->{w}{$self->{wd}}; # we are no longer there
   $inotify->{ignore}{$self->{wd}} = 1; # ignore further events for one poll

   (Linux::Inotify2::inotify_rm_watch $inotify->{fd}, $self->{wd})
      ? 1 : undef
}

=head1 SEE ALSO

L<AnyEvent>, L<Linux::Inotify>.

=head1 AUTHOR

 Marc Lehmann <schmorp@schmorp.de>
 http://home.schmorp.de/

=cut

1
Revision:	1.29
Committed:	Thu Oct 25 01:10:44 2018 UTC (7 years, 11 months ago) by root
Branch:	MAIN
Changes since 1.28:	+67 -7 lines
Log Message:	* empty log message *
#	User	Rev	Content
1	root	1.1	=head1 NAME
2
3			Linux::Inotify2 - scalable directory/file change notification
4
5			=head1 SYNOPSIS
6
7	root	1.19	=head2 Callback Interface
8	root	1.11
9	root	1.1	use Linux::Inotify2;
10
11	root	1.4	# create a new object
12			my $inotify = new Linux::Inotify2
13	root	1.19	or die "unable to create new inotify object: $!";
14	root	1.4
15			# add watchers
16			$inotify->watch ("/etc/passwd", IN_ACCESS, sub {
17			my $e = shift;
18			my $name = $e->fullname;
19			print "$name was accessed\n" if $e->IN_ACCESS;
20			print "$name is no longer mounted\n" if $e->IN_UNMOUNT;
21			print "$name is gone\n" if $e->IN_IGNORED;
22			print "events for $name have been lost\n" if $e->IN_Q_OVERFLOW;
23
24	root	1.11	# cancel this watcher: remove no further events
25	root	1.4	$e->w->cancel;
26			});
27
28	root	1.20	# integration into AnyEvent (works with EV, Glib, Tk, POE...)
29	root	1.25	my $inotify_w = AE::io $inotify->fileno, 0, sub { $inotify->poll };
30	root	1.17
31			# manual event loop
32			1 while $inotify->poll;
33
34	root	1.11	=head2 Streaming Interface
35
36	root	1.27	use Linux::Inotify2;
37	root	1.11
38			# create a new object
39			my $inotify = new Linux::Inotify2
40	root	1.27	or die "Unable to create new inotify object: $!";
41	root	1.11
42			# create watch
43			$inotify->watch ("/etc/passwd", IN_ACCESS)
44	root	1.27	or die "watch creation failed";
45	root	1.11
46			while () {
47			my @events = $inotify->read;
48			unless (@events > 0) {
49			print "read error: $!";
50	root	1.27	last;
51	root	1.11	}
52	root	1.27	printf "mask\t%d\n", $_->mask foreach @events;
53	root	1.11	}
54
55	root	1.1	=head1 DESCRIPTION
56
57	root	1.3	This module implements an interface to the Linux 2.6.13 and later Inotify
58	root	1.24	file/directory change notification system.
59	root	1.2
60	root	1.3	It has a number of advantages over the Linux::Inotify module:
61	root	1.2
62			- it is portable (Linux::Inotify only works on x86)
63			- the equivalent of fullname works correctly
64			- it is better documented
65			- it has callback-style interface, which is better suited for
66			integration.
67
68	root	1.6	=head2 The Linux::Inotify2 Class
69
70	root	1.1	=over 4
71
72			=cut
73
74			package Linux::Inotify2;
75
76			use Scalar::Util ();
77
78	root	1.20	use common::sense;
79
80	root	1.26	use Exporter qw(import);
81	root	1.1
82			BEGIN {
83	root	1.28	our $VERSION = '1.23';
84	root	1.20	our @EXPORT = qw(
85	root	1.1	IN_ACCESS IN_MODIFY IN_ATTRIB IN_CLOSE_WRITE
86			IN_CLOSE_NOWRITE IN_OPEN IN_MOVED_FROM IN_MOVED_TO
87	root	1.9	IN_CREATE IN_DELETE IN_DELETE_SELF IN_MOVE_SELF
88	root	1.1	IN_ALL_EVENTS
89			IN_UNMOUNT IN_Q_OVERFLOW IN_IGNORED
90			IN_CLOSE IN_MOVE
91	root	1.28	IN_ISDIR IN_ONESHOT IN_MASK_ADD
92			IN_DONT_FOLLOW IN_EXCL_UNLINK IN_ONLYDIR
93	root	1.1	);
94
95			require XSLoader;
96			XSLoader::load Linux::Inotify2, $VERSION;
97			}
98
99			=item my $inotify = new Linux::Inotify2
100
101			Create a new notify object and return it. A notify object is kind of a
102	root	1.24	container that stores watches on file system names and is responsible for
103	root	1.1	handling event data.
104
105	root	1.22	On error, C<undef> is returned and C<$!> will be set accordingly. The
106			following errors are documented:
107	root	1.1
108			ENFILE The system limit on the total number of file descriptors has been reached.
109			EMFILE The user limit on the total number of inotify instances has been reached.
110			ENOMEM Insufficient kernel memory is available.
111
112	root	1.4	Example:
113
114			my $inotify = new Linux::Inotify2
115			or die "Unable to create new inotify object: $!";
116
117	root	1.1	=cut
118
119			sub new {
120			my ($class) = @_;
121
122			my $fd = inotify_init;
123
124			return unless $fd >= 0;
125
126			bless { fd => $fd }, $class
127			}
128
129	root	1.11	=item $watch = $inotify->watch ($name, $mask[, $cb])
130	root	1.1
131			Add a new watcher to the given notifier. The watcher will create events
132			on the pathname C<$name> as given in C<$mask>, which can be any of the
133	root	1.4	following constants (all exported by default) ORed together.
134
135	root	1.24	"file" refers to any file system object in the watched object (always a
136	root	1.4	directory), that is files, directories, symlinks, device nodes etc., while
137	root	1.24	"object" refers to the object the watcher has been set on itself:
138	root	1.4
139			IN_ACCESS object was accessed
140			IN_MODIFY object was modified
141			IN_ATTRIB object metadata changed
142			IN_CLOSE_WRITE writable fd to file / to object was closed
143			IN_CLOSE_NOWRITE readonly fd to file / to object closed
144			IN_OPEN object was opened
145			IN_MOVED_FROM file was moved from this object (directory)
146			IN_MOVED_TO file was moved to this object (directory)
147			IN_CREATE file was created in this object (directory)
148			IN_DELETE file was deleted from this object (directory)
149			IN_DELETE_SELF object itself was deleted
150	root	1.9	IN_MOVE_SELF object itself was moved
151	root	1.4	IN_ALL_EVENTS all of the above events
152	root	1.1
153			IN_ONESHOT only send event once
154	root	1.15	IN_ONLYDIR only watch the path if it is a directory
155	root	1.28	IN_DONT_FOLLOW don't follow a sym link (Linux 2.6.15+)
156			IN_EXCL_UNLINK don't create events for unlinked objects (Linux 2.6.36+)
157	root	1.15	IN_MASK_ADD not supported with the current version of this module
158	root	1.1
159	root	1.4	IN_CLOSE same as IN_CLOSE_WRITE \| IN_CLOSE_NOWRITE
160			IN_MOVE same as IN_MOVED_FROM \| IN_MOVED_TO
161	root	1.1
162	root	1.11	C<$cb> is a perl code reference that, if given, is called for each
163			event. It receives a C<Linux::Inotify2::Event> object.
164	root	1.1
165			The returned C<$watch> object is of class C<Linux::Inotify2::Watch>.
166
167			On error, C<undef> is returned and C<$!> will be set accordingly. The
168			following errors are documented:
169
170			EBADF The given file descriptor is not valid.
171			EINVAL The given event mask contains no legal events.
172			ENOMEM Insufficient kernel memory was available.
173			ENOSPC The user limit on the total number of inotify watches was reached or the kernel failed to allocate a needed resource.
174			EACCESS Read access to the given file is not permitted.
175
176			Example, show when C</etc/passwd> gets accessed and/or modified once:
177
178			$inotify->watch ("/etc/passwd", IN_ACCESS \| IN_MODIFY, sub {
179			my $e = shift;
180			print "$e->{w}{name} was accessed\n" if $e->IN_ACCESS;
181			print "$e->{w}{name} was modified\n" if $e->IN_MODIFY;
182			print "$e->{w}{name} is no longer mounted\n" if $e->IN_UNMOUNT;
183			print "events for $e->{w}{name} have been lost\n" if $e->IN_Q_OVERFLOW;
184
185			$e->w->cancel;
186			});
187
188			=cut
189
190			sub watch {
191			my ($self, $name, $mask, $cb) = @_;
192
193			my $wd = inotify_add_watch $self->{fd}, $name, $mask;
194
195			return unless $wd >= 0;
196
197			my $w = $self->{w}{$wd} = bless {
198			inotify => $self,
199			wd => $wd,
200			name => $name,
201			mask => $mask,
202			cb => $cb,
203	root	1.13	}, "Linux::Inotify2::Watch";
204	root	1.1
205			Scalar::Util::weaken $w->{inotify};
206
207			$w
208			}
209
210	root	1.4	=item $inotify->fileno
211	root	1.1
212	root	1.24	Returns the file descriptor for this notify object. When in non-blocking
213			mode, you are responsible for calling the C<poll> method when this file
214			descriptor becomes ready for reading.
215	root	1.1
216			=cut
217
218			sub fileno {
219			$_[0]{fd}
220			}
221
222	root	1.11	=item $inotify->blocking ($blocking)
223
224			Clears ($blocking true) or sets ($blocking false) the C<O_NONBLOCK> flag on the file descriptor.
225
226			=cut
227
228			sub blocking {
229			my ($self, $blocking) = @_;
230
231			inotify_blocking $self->{fd}, $blocking;
232			}
233
234	root	1.4	=item $count = $inotify->poll
235	root	1.1
236	root	1.24	Reads events from the kernel and handles them. If the notify file
237			descriptor is blocking (the default), then this method waits for at least
238			one event (and thus returns true unless an error occurs). Otherwise it
239			returns immediately when no pending events could be read.
240	root	1.1
241			Returns the count of events that have been handled.
242
243			=cut
244
245			sub poll {
246	root	1.11	scalar &read
247			}
248
249	root	1.24	=item @events = $inotify->read
250	root	1.11
251	root	1.24	Reads events from the kernel. Blocks when the file descriptor is in
252			blocking mode (default) until any event arrives. Returns list of
253			C<Linux::Inotify2::Event> objects or empty list if none (non-blocking
254			mode) or error occurred ($! should be checked).
255
256			Normally you shouldn't use this function, but instead use watcher
257			callbacks and call C<< ->poll >>.
258	root	1.11
259			=cut
260
261			sub read {
262	root	1.1	my ($self) = @_;
263
264	root	1.4	my @ev = inotify_read $self->{fd};
265	root	1.11	my @res;
266	root	1.4
267			for (@ev) {
268	root	1.29	$_->{wd}=-1; $_->{mask} = IN_Q_OVERFLOW;#d#
269	root	1.4
270			exists $self->{ignore}{$_->{wd}}
271			and next; # watcher has been canceled
272
273	root	1.29	push @res, bless $_, "Linux::Inotify2::Event";
274	root	1.12
275	root	1.29	my $w = $_->{w} = $self->{w}{$_->{wd}}
276			or do {
277			# no such watcher, but maybe we can do overflow handling
278			if ($_->{mask} & IN_Q_OVERFLOW) {
279			if ($self->{on_overflow}) {
280			$self->{on_overflow}($_);
281			} else {
282			$self->broadcast ($_);
283			}
284			}
285			next;
286			};
287	root	1.11
288	root	1.29	$w->{cb}($_) if $w->{cb};
289	root	1.16	$w->cancel if $_->{mask} & (IN_IGNORED \| IN_UNMOUNT \| IN_ONESHOT \| IN_DELETE_SELF);
290	root	1.1	}
291	root	1.4
292			delete $self->{ignore};
293
294	root	1.29	wantarray ? @res : scalar @res
295			}
296
297			=item $inotify->on_overflow ($cb->($ev))
298
299			Sets the callback to be used for overflow handling
300			(default: C<undef>): When C<read> receives an event with C<IN_Q_OVERFLOW>
301			set, it will invoke this callback with the event.
302
303			When the callback is C<undef>, then it broadcasts the event to all
304			registered watchers, i.e., C<undef> is equivalent to:
305
306			sub { $inotify->broadcast ($_[0]) }
307
308			=cut
309
310			sub on_overflow {
311			my $prev = $_[0]{on_overflow};
312
313			$_[0]{on_overflow} = $_[1]
314			if @_ >= 2;
315
316			$prev
317			}
318
319			=item $inotify->broadcast ($ev)
320
321			Invokes all registered watcher callbacks and passes the given event to
322			them. Most useful in overflow handlers.
323
324			=cut
325
326			sub broadcast {
327			my ($self, $ev) = @_;
328
329			for my $w (values %{ $self->{w} }) {
330			local $ev->{w} = $w;
331			$w->{cb}($ev) if $w->{cb};
332			}
333	root	1.1	}
334
335			sub DESTROY {
336			inotify_close $_[0]{fd}
337			}
338
339			=back
340
341			=head2 The Linux::Inotify2::Event Class
342
343	root	1.24	Objects of this class are handed as first argument to the watcher
344	root	1.1	callback. It has the following members and methods:
345
346			=over 4
347
348			=item $event->w
349
350			=item $event->{w}
351
352	root	1.29	The watcher object for this event, if one is available. Generally, you cna
353			only rely on the value of this member inside watcher callbacks.
354	root	1.1
355			=item $event->name
356
357			=item $event->{name}
358
359	root	1.24	The path of the file system object, relative to the watched name.
360	root	1.1
361	root	1.23	=item $event->fullname
362	root	1.1
363			Returns the "full" name of the relevant object, i.e. including the C<name>
364	root	1.24	member of the watcher (if the watch object is on a directory and a
365			directory entry is affected), or simply the C<name> member itself when the
366			object is the watch object itself.
367	root	1.1
368	root	1.29	This call requires C<< $event->{w} >> to be valid, which is generally only
369			the case within watcher callbacks.
370
371	root	1.1	=item $event->mask
372
373			=item $event->{mask}
374
375	root	1.24	The received event mask. In addition to the events described for C<<
376			$inotify->watch >>, the following flags (exported by default) can be set:
377	root	1.1
378	root	1.4	IN_ISDIR event object is a directory
379			IN_Q_OVERFLOW event queue overflowed
380
381	root	1.10	# when any of the following flags are set,
382			# then watchers for this event are automatically canceled
383	root	1.24	IN_UNMOUNT filesystem for watched object was unmounted
384	root	1.4	IN_IGNORED file was ignored/is gone (no more events are delivered)
385	root	1.10	IN_ONESHOT only one event was generated
386	root	1.29	IN_Q_OVERFLOW queue overflow - event might not be specific to a watcher
387	root	1.1
388			=item $event->IN_xxx
389
390	root	1.24	Returns a boolean that returns true if the event mask contains any events
391			specified by the mask. All of the C<IN_xxx> constants can be used as
392			methods.
393	root	1.1
394			=item $event->cookie
395
396			=item $event->{cookie}
397
398	root	1.10	The event cookie to "synchronize two events". Normally zero, this value is
399			set when two events relating to the same file are generated. As far as I
400			know, this only happens for C<IN_MOVED_FROM> and C<IN_MOVED_TO> events, to
401			identify the old and new name of a file.
402	root	1.1
403	root	1.29	Note that the inotify API makes it impossible to know whether there will
404			be a C<IN_MOVED_TO> event - you might receive only one of the events,
405			and even if you receive both, there might be any number of events in
406			between. The best approach seems to be to implement a small timeout
407			after C<IN_MOVED_FROM> to see if a matching C<IN_MOVED_TO> event will be
408			received - 2ms seem to work relatively well.
409
410	root	1.1	=back
411
412			=cut
413
414			package Linux::Inotify2::Event;
415
416			sub w { $_[0]{w} }
417			sub name { $_[0]{name} }
418			sub mask { $_[0]{mask} }
419			sub cookie { $_[0]{cookie} }
420
421			sub fullname {
422			length $_[0]{name}
423			? "$_[0]{w}{name}/$_[0]{name}"
424			: $_[0]{w}{name};
425			}
426
427	root	1.20	for my $name (@Linux::Inotify2::EXPORT) {
428	root	1.1	my $mask = &{"Linux::Inotify2::$name"};
429
430	root	1.24	*$name = sub { $_[0]{mask} & $mask };
431	root	1.1	}
432
433			=head2 The Linux::Inotify2::Watch Class
434
435	root	1.24	Watcher objects are created by calling the C<watch> method of a notifier.
436	root	1.1
437			It has the following members and methods:
438
439	root	1.14	=over 4
440
441	root	1.1	=item $watch->name
442
443			=item $watch->{name}
444
445			The name as specified in the C<watch> call. For the object itself, this is
446			the empty string. For directory watches, this is the name of the entry
447			without leading path elements.
448
449			=item $watch->mask
450
451			=item $watch->{mask}
452
453			The mask as specified in the C<watch> call.
454
455			=item $watch->cb ([new callback])
456
457			=item $watch->{cb}
458
459			The callback as specified in the C<watch> call. Can optionally be changed.
460
461			=item $watch->cancel
462
463	root	1.24	Cancels/removes this watcher. Future events, even if already queued queued,
464	root	1.1	will not be handled and resources will be freed.
465
466	root	1.14	=back
467
468	root	1.1	=cut
469
470			package Linux::Inotify2::Watch;
471
472			sub name { $_[0]{name} }
473			sub mask { $_[0]{mask} }
474
475			sub cb {
476			$_[0]{cb} = $_[1] if @_ > 1;
477			$_[0]{cb}
478			}
479
480			sub cancel {
481			my ($self) = @_;
482
483	root	1.4	my $inotify = delete $self->{inotify}
484			or return 1; # already canceled
485
486			delete $inotify->{w}{$self->{wd}}; # we are no longer there
487			$inotify->{ignore}{$self->{wd}} = 1; # ignore further events for one poll
488
489			(Linux::Inotify2::inotify_rm_watch $inotify->{fd}, $self->{wd})
490	root	1.1	? 1 : undef
491			}
492
493			=head1 SEE ALSO
494
495	root	1.19	L<AnyEvent>, L<Linux::Inotify>.
496	root	1.1
497			=head1 AUTHOR
498
499			Marc Lehmann <schmorp@schmorp.de>
500			http://home.schmorp.de/
501
502			=cut
503
504			1