#!/usr/bin/env perl

use strict;
use warnings;
use utf8;

use Template;
use YAML;
use Pod::POM;

# Static variables
my $static = YAML::LoadFile("variables.yml");
my $parser = new Pod::POM;

my @podfiles = <pod/*.pod>;

for my $file (@podfiles) {
   my $pom = $parser->parse ($file)
      or die $parser->error();
   $file =~ s/pod\/(.+)\.pod$/template\/$1.tt/;
   open FH, ">", $file;
   print FH $pom->present ("Ermyth::Pod");
   close FH;
}

my @files = <template/*.tt>;

for my $file (@files) {
   my @contents = do { open my $fh, "<$file" or die "$file: $!\n"; <$fh> };
   my $subtitle = shift @contents;
   chomp $subtitle;
   
   my $tt = Template->new({
         INCLUDE_PATH => 'lib:template',
         INTERPOLATE  => 1,
         POST_CHOMP   => 1,
         EVAL_PERL    => 1,
      }) or die "$Template::ERROR\n";

   my $vars = { file => sub { return do { local $/; open my $fh, "<$_[0]" or die "$_[0]: $!\n"; <$fh> } if $_[0]; } };

   my $contents = "@contents";
   my $data = ''; # Variable to store processed templates
   $tt->process(\$contents, $vars, \$data)
      or die $tt->error();

   # Re-initialised with static variables from YAML
   $vars = $static;
   $vars->{subtitle} = $subtitle;
   $vars->{contents} = $data;

   my $output = ''; # Variable to store the complete page
   $tt->process('html.tt', $vars, \$output)
      or die $tt->error(), "\n";

   # Save the page to a html file
   $file =~ s/template\/(.+)\.tt$/html\/$1.html/;
   open HTML, ">$file";
   print HTML $output;
   close HTML;
}


package Ermyth::Pod;

use strict;
use warnings;
use utf8;

use base "Pod::POM::View";

sub view_pod {
   my ($self, $item) = @_;
   $item->content->present ($self)
}

sub view_head1 {
   my ($self, $item) = @_;
   $item->title->present($self), "\n\n",
   $item->content->present($self);
}

sub view_head2 {
   my ($self, $item) = @_;
   '<h3>',
   $item->title->present($self),
   "</h3>",
   $item->content->present($self);
}

sub view_head3 {
   my ($self, $item) = @_;
   '<h4>',
   $item->title->present($self),
   "</h4>",
   $item->content->present($self);
}

sub view_seq_entity {
   my ($self, $item) = @_;
   $item =~ /^x/
      ? ('&#', $item, ';')
      : ('&', $item, ';')
}

sub view_seq_code {
   my ($self, $item) = @_;
   '<i>', $item, '</i>'
}

sub view_seq_bold {
   my ($self, $item) = @_;
   '<b>', $item, '</b>'
}

sub view_seq_link {
   my ($self, $item) = @_;
   my ($title, $link) = split '\|', $item, 2;
   "<a href='$link'>$title</a>"
}

sub view_verbatim {
   my ($self, $item) = @_;
   "<pre>\n", $item, '</pre>'
}

sub view_over {
   my ($self, $item) = @_;
   '<ul>',
   $item->content->present ($self),
   '</ul>'
}

sub view_item {
   my ($self, $item) = @_;
   my $title;
   if ($item->title =~ /^L</) {
      $title = $item->title;
      $title =~ s/L<(.+)>/- $1/;
      $title = $self->xmlise ($title);
      $title = $self->view_seq_link ($title);
   } else {
      $title = $item->title;
      $title = $self->xmlise ($title);
   }

   '<li>', ($item->title eq '*' ? '<b>---</b> ' : '<b>' . $title . '</b> '), $item->content->present ($self), '</li>'
}

sub view_textblock {
   my ($self, $item) = @_;
   '<p>', $item, '</p>'
}

sub xmlise {
   my ($self, $text) = @_;
   $text =~ s/>/&gt;/;
   $text =~ s/</&lt;/;

   $text
}


1