1 |
package AnyEvent::Handle; |
2 |
|
3 |
no warnings; |
4 |
use strict qw(subs vars); |
5 |
|
6 |
use AnyEvent (); |
7 |
use AnyEvent::Util qw(WSAEWOULDBLOCK); |
8 |
use Scalar::Util (); |
9 |
use Carp (); |
10 |
use Fcntl (); |
11 |
use Errno qw(EAGAIN EINTR); |
12 |
|
13 |
=head1 NAME |
14 |
|
15 |
AnyEvent::Handle - non-blocking I/O on file handles via AnyEvent |
16 |
|
17 |
=cut |
18 |
|
19 |
our $VERSION = 4.231; |
20 |
|
21 |
=head1 SYNOPSIS |
22 |
|
23 |
use AnyEvent; |
24 |
use AnyEvent::Handle; |
25 |
|
26 |
my $cv = AnyEvent->condvar; |
27 |
|
28 |
my $handle = |
29 |
AnyEvent::Handle->new ( |
30 |
fh => \*STDIN, |
31 |
on_eof => sub { |
32 |
$cv->broadcast; |
33 |
}, |
34 |
); |
35 |
|
36 |
# send some request line |
37 |
$handle->push_write ("getinfo\015\012"); |
38 |
|
39 |
# read the response line |
40 |
$handle->push_read (line => sub { |
41 |
my ($handle, $line) = @_; |
42 |
warn "read line <$line>\n"; |
43 |
$cv->send; |
44 |
}); |
45 |
|
46 |
$cv->recv; |
47 |
|
48 |
=head1 DESCRIPTION |
49 |
|
50 |
This module is a helper module to make it easier to do event-based I/O on |
51 |
filehandles. For utility functions for doing non-blocking connects and accepts |
52 |
on sockets see L<AnyEvent::Util>. |
53 |
|
54 |
In the following, when the documentation refers to of "bytes" then this |
55 |
means characters. As sysread and syswrite are used for all I/O, their |
56 |
treatment of characters applies to this module as well. |
57 |
|
58 |
All callbacks will be invoked with the handle object as their first |
59 |
argument. |
60 |
|
61 |
=head1 METHODS |
62 |
|
63 |
=over 4 |
64 |
|
65 |
=item B<new (%args)> |
66 |
|
67 |
The constructor supports these arguments (all as key => value pairs). |
68 |
|
69 |
=over 4 |
70 |
|
71 |
=item fh => $filehandle [MANDATORY] |
72 |
|
73 |
The filehandle this L<AnyEvent::Handle> object will operate on. |
74 |
|
75 |
NOTE: The filehandle will be set to non-blocking (using |
76 |
AnyEvent::Util::fh_nonblocking). |
77 |
|
78 |
=item on_eof => $cb->($handle) |
79 |
|
80 |
Set the callback to be called when an end-of-file condition is detected, |
81 |
i.e. in the case of a socket, when the other side has closed the |
82 |
connection cleanly. |
83 |
|
84 |
While not mandatory, it is I<highly> recommended to set an eof callback, |
85 |
otherwise you might end up with a closed socket while you are still |
86 |
waiting for data. |
87 |
|
88 |
If an EOF condition has been detected but no C<on_eof> callback has been |
89 |
set, then a fatal error will be raised with C<$!> set to <0>. |
90 |
|
91 |
=item on_error => $cb->($handle, $fatal) |
92 |
|
93 |
This is the error callback, which is called when, well, some error |
94 |
occured, such as not being able to resolve the hostname, failure to |
95 |
connect or a read error. |
96 |
|
97 |
Some errors are fatal (which is indicated by C<$fatal> being true). On |
98 |
fatal errors the handle object will be shut down and will not be |
99 |
usable. Non-fatal errors can be retried by simply returning, but it is |
100 |
recommended to simply ignore this parameter and instead abondon the handle |
101 |
object when this callback is invoked. |
102 |
|
103 |
On callback entrance, the value of C<$!> contains the operating system |
104 |
error (or C<ENOSPC>, C<EPIPE>, C<ETIMEDOUT> or C<EBADMSG>). |
105 |
|
106 |
While not mandatory, it is I<highly> recommended to set this callback, as |
107 |
you will not be notified of errors otherwise. The default simply calls |
108 |
C<croak>. |
109 |
|
110 |
=item on_read => $cb->($handle) |
111 |
|
112 |
This sets the default read callback, which is called when data arrives |
113 |
and no read request is in the queue (unlike read queue callbacks, this |
114 |
callback will only be called when at least one octet of data is in the |
115 |
read buffer). |
116 |
|
117 |
To access (and remove data from) the read buffer, use the C<< ->rbuf >> |
118 |
method or access the C<$handle->{rbuf}> member directly. |
119 |
|
120 |
When an EOF condition is detected then AnyEvent::Handle will first try to |
121 |
feed all the remaining data to the queued callbacks and C<on_read> before |
122 |
calling the C<on_eof> callback. If no progress can be made, then a fatal |
123 |
error will be raised (with C<$!> set to C<EPIPE>). |
124 |
|
125 |
=item on_drain => $cb->($handle) |
126 |
|
127 |
This sets the callback that is called when the write buffer becomes empty |
128 |
(or when the callback is set and the buffer is empty already). |
129 |
|
130 |
To append to the write buffer, use the C<< ->push_write >> method. |
131 |
|
132 |
This callback is useful when you don't want to put all of your write data |
133 |
into the queue at once, for example, when you want to write the contents |
134 |
of some file to the socket you might not want to read the whole file into |
135 |
memory and push it into the queue, but instead only read more data from |
136 |
the file when the write queue becomes empty. |
137 |
|
138 |
=item timeout => $fractional_seconds |
139 |
|
140 |
If non-zero, then this enables an "inactivity" timeout: whenever this many |
141 |
seconds pass without a successful read or write on the underlying file |
142 |
handle, the C<on_timeout> callback will be invoked (and if that one is |
143 |
missing, an C<ETIMEDOUT> error will be raised). |
144 |
|
145 |
Note that timeout processing is also active when you currently do not have |
146 |
any outstanding read or write requests: If you plan to keep the connection |
147 |
idle then you should disable the timout temporarily or ignore the timeout |
148 |
in the C<on_timeout> callback. |
149 |
|
150 |
Zero (the default) disables this timeout. |
151 |
|
152 |
=item on_timeout => $cb->($handle) |
153 |
|
154 |
Called whenever the inactivity timeout passes. If you return from this |
155 |
callback, then the timeout will be reset as if some activity had happened, |
156 |
so this condition is not fatal in any way. |
157 |
|
158 |
=item rbuf_max => <bytes> |
159 |
|
160 |
If defined, then a fatal error will be raised (with C<$!> set to C<ENOSPC>) |
161 |
when the read buffer ever (strictly) exceeds this size. This is useful to |
162 |
avoid denial-of-service attacks. |
163 |
|
164 |
For example, a server accepting connections from untrusted sources should |
165 |
be configured to accept only so-and-so much data that it cannot act on |
166 |
(for example, when expecting a line, an attacker could send an unlimited |
167 |
amount of data without a callback ever being called as long as the line |
168 |
isn't finished). |
169 |
|
170 |
=item autocork => <boolean> |
171 |
|
172 |
When disabled (the default), then C<push_write> will try to immediately |
173 |
write the data to the handle if possible. This avoids having to register |
174 |
a write watcher and wait for the next event loop iteration, but can be |
175 |
inefficient if you write multiple small chunks (this disadvantage is |
176 |
usually avoided by your kernel's nagle algorithm, see C<low_delay>). |
177 |
|
178 |
When enabled, then writes will always be queued till the next event loop |
179 |
iteration. This is efficient when you do many small writes per iteration, |
180 |
but less efficient when you do a single write only. |
181 |
|
182 |
=item no_delay => <boolean> |
183 |
|
184 |
When doing small writes on sockets, your operating system kernel might |
185 |
wait a bit for more data before actually sending it out. This is called |
186 |
the Nagle algorithm, and usually it is beneficial. |
187 |
|
188 |
In some situations you want as low a delay as possible, which cna be |
189 |
accomplishd by setting this option to true. |
190 |
|
191 |
The default is your opertaing system's default behaviour, this option |
192 |
explicitly enables or disables it, if possible. |
193 |
|
194 |
=item read_size => <bytes> |
195 |
|
196 |
The default read block size (the amount of bytes this module will try to read |
197 |
during each (loop iteration). Default: C<8192>. |
198 |
|
199 |
=item low_water_mark => <bytes> |
200 |
|
201 |
Sets the amount of bytes (default: C<0>) that make up an "empty" write |
202 |
buffer: If the write reaches this size or gets even samller it is |
203 |
considered empty. |
204 |
|
205 |
=item linger => <seconds> |
206 |
|
207 |
If non-zero (default: C<3600>), then the destructor of the |
208 |
AnyEvent::Handle object will check wether there is still outstanding write |
209 |
data and will install a watcher that will write out this data. No errors |
210 |
will be reported (this mostly matches how the operating system treats |
211 |
outstanding data at socket close time). |
212 |
|
213 |
This will not work for partial TLS data that could not yet been |
214 |
encoded. This data will be lost. |
215 |
|
216 |
=item tls => "accept" | "connect" | Net::SSLeay::SSL object |
217 |
|
218 |
When this parameter is given, it enables TLS (SSL) mode, that means it |
219 |
will start making tls handshake and will transparently encrypt/decrypt |
220 |
data. |
221 |
|
222 |
TLS mode requires Net::SSLeay to be installed (it will be loaded |
223 |
automatically when you try to create a TLS handle). |
224 |
|
225 |
For the TLS server side, use C<accept>, and for the TLS client side of a |
226 |
connection, use C<connect> mode. |
227 |
|
228 |
You can also provide your own TLS connection object, but you have |
229 |
to make sure that you call either C<Net::SSLeay::set_connect_state> |
230 |
or C<Net::SSLeay::set_accept_state> on it before you pass it to |
231 |
AnyEvent::Handle. |
232 |
|
233 |
See the C<starttls> method if you need to start TLS negotiation later. |
234 |
|
235 |
=item tls_ctx => $ssl_ctx |
236 |
|
237 |
Use the given Net::SSLeay::CTX object to create the new TLS connection |
238 |
(unless a connection object was specified directly). If this parameter is |
239 |
missing, then AnyEvent::Handle will use C<AnyEvent::Handle::TLS_CTX>. |
240 |
|
241 |
=item json => JSON or JSON::XS object |
242 |
|
243 |
This is the json coder object used by the C<json> read and write types. |
244 |
|
245 |
If you don't supply it, then AnyEvent::Handle will create and use a |
246 |
suitable one, which will write and expect UTF-8 encoded JSON texts. |
247 |
|
248 |
Note that you are responsible to depend on the JSON module if you want to |
249 |
use this functionality, as AnyEvent does not have a dependency itself. |
250 |
|
251 |
=item filter_r => $cb |
252 |
|
253 |
=item filter_w => $cb |
254 |
|
255 |
These exist, but are undocumented at this time. |
256 |
|
257 |
=back |
258 |
|
259 |
=cut |
260 |
|
261 |
sub new { |
262 |
my $class = shift; |
263 |
|
264 |
my $self = bless { @_ }, $class; |
265 |
|
266 |
$self->{fh} or Carp::croak "mandatory argument fh is missing"; |
267 |
|
268 |
AnyEvent::Util::fh_nonblocking $self->{fh}, 1; |
269 |
|
270 |
if ($self->{tls}) { |
271 |
require Net::SSLeay; |
272 |
$self->starttls (delete $self->{tls}, delete $self->{tls_ctx}); |
273 |
} |
274 |
|
275 |
$self->{_activity} = AnyEvent->now; |
276 |
$self->_timeout; |
277 |
|
278 |
$self->on_drain (delete $self->{on_drain}) if exists $self->{on_drain}; |
279 |
$self->no_delay (delete $self->{no_delay}) if exists $self->{no_delay}; |
280 |
|
281 |
$self->start_read |
282 |
if $self->{on_read}; |
283 |
|
284 |
$self |
285 |
} |
286 |
|
287 |
sub _shutdown { |
288 |
my ($self) = @_; |
289 |
|
290 |
delete $self->{_tw}; |
291 |
delete $self->{_rw}; |
292 |
delete $self->{_ww}; |
293 |
delete $self->{fh}; |
294 |
|
295 |
$self->stoptls; |
296 |
} |
297 |
|
298 |
sub _error { |
299 |
my ($self, $errno, $fatal) = @_; |
300 |
|
301 |
$self->_shutdown |
302 |
if $fatal; |
303 |
|
304 |
$! = $errno; |
305 |
|
306 |
if ($self->{on_error}) { |
307 |
$self->{on_error}($self, $fatal); |
308 |
} else { |
309 |
Carp::croak "AnyEvent::Handle uncaught error: $!"; |
310 |
} |
311 |
} |
312 |
|
313 |
=item $fh = $handle->fh |
314 |
|
315 |
This method returns the file handle of the L<AnyEvent::Handle> object. |
316 |
|
317 |
=cut |
318 |
|
319 |
sub fh { $_[0]{fh} } |
320 |
|
321 |
=item $handle->on_error ($cb) |
322 |
|
323 |
Replace the current C<on_error> callback (see the C<on_error> constructor argument). |
324 |
|
325 |
=cut |
326 |
|
327 |
sub on_error { |
328 |
$_[0]{on_error} = $_[1]; |
329 |
} |
330 |
|
331 |
=item $handle->on_eof ($cb) |
332 |
|
333 |
Replace the current C<on_eof> callback (see the C<on_eof> constructor argument). |
334 |
|
335 |
=cut |
336 |
|
337 |
sub on_eof { |
338 |
$_[0]{on_eof} = $_[1]; |
339 |
} |
340 |
|
341 |
=item $handle->on_timeout ($cb) |
342 |
|
343 |
Replace the current C<on_timeout> callback, or disables the callback |
344 |
(but not the timeout) if C<$cb> = C<undef>. See C<timeout> constructor |
345 |
argument. |
346 |
|
347 |
=cut |
348 |
|
349 |
sub on_timeout { |
350 |
$_[0]{on_timeout} = $_[1]; |
351 |
} |
352 |
|
353 |
=item $handle->autocork ($boolean) |
354 |
|
355 |
Enables or disables the current autocork behaviour (see C<autocork> |
356 |
constructor argument). |
357 |
|
358 |
=cut |
359 |
|
360 |
=item $handle->no_delay ($boolean) |
361 |
|
362 |
Enables or disables the C<no_delay> setting (see constructor argument of |
363 |
the same name for details). |
364 |
|
365 |
=cut |
366 |
|
367 |
sub no_delay { |
368 |
$_[0]{no_delay} = $_[1]; |
369 |
|
370 |
eval { |
371 |
local $SIG{__DIE__}; |
372 |
setsockopt $_[0]{fh}, &Socket::IPPROTO_TCP, &Socket::TCP_NODELAY, int $_[1]; |
373 |
}; |
374 |
} |
375 |
|
376 |
############################################################################# |
377 |
|
378 |
=item $handle->timeout ($seconds) |
379 |
|
380 |
Configures (or disables) the inactivity timeout. |
381 |
|
382 |
=cut |
383 |
|
384 |
sub timeout { |
385 |
my ($self, $timeout) = @_; |
386 |
|
387 |
$self->{timeout} = $timeout; |
388 |
$self->_timeout; |
389 |
} |
390 |
|
391 |
# reset the timeout watcher, as neccessary |
392 |
# also check for time-outs |
393 |
sub _timeout { |
394 |
my ($self) = @_; |
395 |
|
396 |
if ($self->{timeout}) { |
397 |
my $NOW = AnyEvent->now; |
398 |
|
399 |
# when would the timeout trigger? |
400 |
my $after = $self->{_activity} + $self->{timeout} - $NOW; |
401 |
|
402 |
# now or in the past already? |
403 |
if ($after <= 0) { |
404 |
$self->{_activity} = $NOW; |
405 |
|
406 |
if ($self->{on_timeout}) { |
407 |
$self->{on_timeout}($self); |
408 |
} else { |
409 |
$self->_error (&Errno::ETIMEDOUT); |
410 |
} |
411 |
|
412 |
# callback could have changed timeout value, optimise |
413 |
return unless $self->{timeout}; |
414 |
|
415 |
# calculate new after |
416 |
$after = $self->{timeout}; |
417 |
} |
418 |
|
419 |
Scalar::Util::weaken $self; |
420 |
return unless $self; # ->error could have destroyed $self |
421 |
|
422 |
$self->{_tw} ||= AnyEvent->timer (after => $after, cb => sub { |
423 |
delete $self->{_tw}; |
424 |
$self->_timeout; |
425 |
}); |
426 |
} else { |
427 |
delete $self->{_tw}; |
428 |
} |
429 |
} |
430 |
|
431 |
############################################################################# |
432 |
|
433 |
=back |
434 |
|
435 |
=head2 WRITE QUEUE |
436 |
|
437 |
AnyEvent::Handle manages two queues per handle, one for writing and one |
438 |
for reading. |
439 |
|
440 |
The write queue is very simple: you can add data to its end, and |
441 |
AnyEvent::Handle will automatically try to get rid of it for you. |
442 |
|
443 |
When data could be written and the write buffer is shorter then the low |
444 |
water mark, the C<on_drain> callback will be invoked. |
445 |
|
446 |
=over 4 |
447 |
|
448 |
=item $handle->on_drain ($cb) |
449 |
|
450 |
Sets the C<on_drain> callback or clears it (see the description of |
451 |
C<on_drain> in the constructor). |
452 |
|
453 |
=cut |
454 |
|
455 |
sub on_drain { |
456 |
my ($self, $cb) = @_; |
457 |
|
458 |
$self->{on_drain} = $cb; |
459 |
|
460 |
$cb->($self) |
461 |
if $cb && $self->{low_water_mark} >= length $self->{wbuf}; |
462 |
} |
463 |
|
464 |
=item $handle->push_write ($data) |
465 |
|
466 |
Queues the given scalar to be written. You can push as much data as you |
467 |
want (only limited by the available memory), as C<AnyEvent::Handle> |
468 |
buffers it independently of the kernel. |
469 |
|
470 |
=cut |
471 |
|
472 |
sub _drain_wbuf { |
473 |
my ($self) = @_; |
474 |
|
475 |
if (!$self->{_ww} && length $self->{wbuf}) { |
476 |
|
477 |
Scalar::Util::weaken $self; |
478 |
|
479 |
my $cb = sub { |
480 |
my $len = syswrite $self->{fh}, $self->{wbuf}; |
481 |
|
482 |
if ($len >= 0) { |
483 |
substr $self->{wbuf}, 0, $len, ""; |
484 |
|
485 |
$self->{_activity} = AnyEvent->now; |
486 |
|
487 |
$self->{on_drain}($self) |
488 |
if $self->{low_water_mark} >= length $self->{wbuf} |
489 |
&& $self->{on_drain}; |
490 |
|
491 |
delete $self->{_ww} unless length $self->{wbuf}; |
492 |
} elsif ($! != EAGAIN && $! != EINTR && $! != WSAEWOULDBLOCK) { |
493 |
$self->_error ($!, 1); |
494 |
} |
495 |
}; |
496 |
|
497 |
# try to write data immediately |
498 |
$cb->() unless $self->{autocork}; |
499 |
|
500 |
# if still data left in wbuf, we need to poll |
501 |
$self->{_ww} = AnyEvent->io (fh => $self->{fh}, poll => "w", cb => $cb) |
502 |
if length $self->{wbuf}; |
503 |
}; |
504 |
} |
505 |
|
506 |
our %WH; |
507 |
|
508 |
sub register_write_type($$) { |
509 |
$WH{$_[0]} = $_[1]; |
510 |
} |
511 |
|
512 |
sub push_write { |
513 |
my $self = shift; |
514 |
|
515 |
if (@_ > 1) { |
516 |
my $type = shift; |
517 |
|
518 |
@_ = ($WH{$type} or Carp::croak "unsupported type passed to AnyEvent::Handle::push_write") |
519 |
->($self, @_); |
520 |
} |
521 |
|
522 |
if ($self->{filter_w}) { |
523 |
$self->{filter_w}($self, \$_[0]); |
524 |
} else { |
525 |
$self->{wbuf} .= $_[0]; |
526 |
$self->_drain_wbuf; |
527 |
} |
528 |
} |
529 |
|
530 |
=item $handle->push_write (type => @args) |
531 |
|
532 |
Instead of formatting your data yourself, you can also let this module do |
533 |
the job by specifying a type and type-specific arguments. |
534 |
|
535 |
Predefined types are (if you have ideas for additional types, feel free to |
536 |
drop by and tell us): |
537 |
|
538 |
=over 4 |
539 |
|
540 |
=item netstring => $string |
541 |
|
542 |
Formats the given value as netstring |
543 |
(http://cr.yp.to/proto/netstrings.txt, this is not a recommendation to use them). |
544 |
|
545 |
=cut |
546 |
|
547 |
register_write_type netstring => sub { |
548 |
my ($self, $string) = @_; |
549 |
|
550 |
sprintf "%d:%s,", (length $string), $string |
551 |
}; |
552 |
|
553 |
=item packstring => $format, $data |
554 |
|
555 |
An octet string prefixed with an encoded length. The encoding C<$format> |
556 |
uses the same format as a Perl C<pack> format, but must specify a single |
557 |
integer only (only one of C<cCsSlLqQiInNvVjJw> is allowed, plus an |
558 |
optional C<!>, C<< < >> or C<< > >> modifier). |
559 |
|
560 |
=cut |
561 |
|
562 |
register_write_type packstring => sub { |
563 |
my ($self, $format, $string) = @_; |
564 |
|
565 |
pack "$format/a*", $string |
566 |
}; |
567 |
|
568 |
=item json => $array_or_hashref |
569 |
|
570 |
Encodes the given hash or array reference into a JSON object. Unless you |
571 |
provide your own JSON object, this means it will be encoded to JSON text |
572 |
in UTF-8. |
573 |
|
574 |
JSON objects (and arrays) are self-delimiting, so you can write JSON at |
575 |
one end of a handle and read them at the other end without using any |
576 |
additional framing. |
577 |
|
578 |
The generated JSON text is guaranteed not to contain any newlines: While |
579 |
this module doesn't need delimiters after or between JSON texts to be |
580 |
able to read them, many other languages depend on that. |
581 |
|
582 |
A simple RPC protocol that interoperates easily with others is to send |
583 |
JSON arrays (or objects, although arrays are usually the better choice as |
584 |
they mimic how function argument passing works) and a newline after each |
585 |
JSON text: |
586 |
|
587 |
$handle->push_write (json => ["method", "arg1", "arg2"]); # whatever |
588 |
$handle->push_write ("\012"); |
589 |
|
590 |
An AnyEvent::Handle receiver would simply use the C<json> read type and |
591 |
rely on the fact that the newline will be skipped as leading whitespace: |
592 |
|
593 |
$handle->push_read (json => sub { my $array = $_[1]; ... }); |
594 |
|
595 |
Other languages could read single lines terminated by a newline and pass |
596 |
this line into their JSON decoder of choice. |
597 |
|
598 |
=cut |
599 |
|
600 |
register_write_type json => sub { |
601 |
my ($self, $ref) = @_; |
602 |
|
603 |
require JSON; |
604 |
|
605 |
$self->{json} ? $self->{json}->encode ($ref) |
606 |
: JSON::encode_json ($ref) |
607 |
}; |
608 |
|
609 |
=item storable => $reference |
610 |
|
611 |
Freezes the given reference using L<Storable> and writes it to the |
612 |
handle. Uses the C<nfreeze> format. |
613 |
|
614 |
=cut |
615 |
|
616 |
register_write_type storable => sub { |
617 |
my ($self, $ref) = @_; |
618 |
|
619 |
require Storable; |
620 |
|
621 |
pack "w/a*", Storable::nfreeze ($ref) |
622 |
}; |
623 |
|
624 |
=back |
625 |
|
626 |
=item AnyEvent::Handle::register_write_type type => $coderef->($handle, @args) |
627 |
|
628 |
This function (not method) lets you add your own types to C<push_write>. |
629 |
Whenever the given C<type> is used, C<push_write> will invoke the code |
630 |
reference with the handle object and the remaining arguments. |
631 |
|
632 |
The code reference is supposed to return a single octet string that will |
633 |
be appended to the write buffer. |
634 |
|
635 |
Note that this is a function, and all types registered this way will be |
636 |
global, so try to use unique names. |
637 |
|
638 |
=cut |
639 |
|
640 |
############################################################################# |
641 |
|
642 |
=back |
643 |
|
644 |
=head2 READ QUEUE |
645 |
|
646 |
AnyEvent::Handle manages two queues per handle, one for writing and one |
647 |
for reading. |
648 |
|
649 |
The read queue is more complex than the write queue. It can be used in two |
650 |
ways, the "simple" way, using only C<on_read> and the "complex" way, using |
651 |
a queue. |
652 |
|
653 |
In the simple case, you just install an C<on_read> callback and whenever |
654 |
new data arrives, it will be called. You can then remove some data (if |
655 |
enough is there) from the read buffer (C<< $handle->rbuf >>). Or you cna |
656 |
leave the data there if you want to accumulate more (e.g. when only a |
657 |
partial message has been received so far). |
658 |
|
659 |
In the more complex case, you want to queue multiple callbacks. In this |
660 |
case, AnyEvent::Handle will call the first queued callback each time new |
661 |
data arrives (also the first time it is queued) and removes it when it has |
662 |
done its job (see C<push_read>, below). |
663 |
|
664 |
This way you can, for example, push three line-reads, followed by reading |
665 |
a chunk of data, and AnyEvent::Handle will execute them in order. |
666 |
|
667 |
Example 1: EPP protocol parser. EPP sends 4 byte length info, followed by |
668 |
the specified number of bytes which give an XML datagram. |
669 |
|
670 |
# in the default state, expect some header bytes |
671 |
$handle->on_read (sub { |
672 |
# some data is here, now queue the length-header-read (4 octets) |
673 |
shift->unshift_read (chunk => 4, sub { |
674 |
# header arrived, decode |
675 |
my $len = unpack "N", $_[1]; |
676 |
|
677 |
# now read the payload |
678 |
shift->unshift_read (chunk => $len, sub { |
679 |
my $xml = $_[1]; |
680 |
# handle xml |
681 |
}); |
682 |
}); |
683 |
}); |
684 |
|
685 |
Example 2: Implement a client for a protocol that replies either with "OK" |
686 |
and another line or "ERROR" for the first request that is sent, and 64 |
687 |
bytes for the second request. Due to the availability of a queue, we can |
688 |
just pipeline sending both requests and manipulate the queue as necessary |
689 |
in the callbacks. |
690 |
|
691 |
When the first callback is called and sees an "OK" response, it will |
692 |
C<unshift> another line-read. This line-read will be queued I<before> the |
693 |
64-byte chunk callback. |
694 |
|
695 |
# request one, returns either "OK + extra line" or "ERROR" |
696 |
$handle->push_write ("request 1\015\012"); |
697 |
|
698 |
# we expect "ERROR" or "OK" as response, so push a line read |
699 |
$handle->push_read (line => sub { |
700 |
# if we got an "OK", we have to _prepend_ another line, |
701 |
# so it will be read before the second request reads its 64 bytes |
702 |
# which are already in the queue when this callback is called |
703 |
# we don't do this in case we got an error |
704 |
if ($_[1] eq "OK") { |
705 |
$_[0]->unshift_read (line => sub { |
706 |
my $response = $_[1]; |
707 |
... |
708 |
}); |
709 |
} |
710 |
}); |
711 |
|
712 |
# request two, simply returns 64 octets |
713 |
$handle->push_write ("request 2\015\012"); |
714 |
|
715 |
# simply read 64 bytes, always |
716 |
$handle->push_read (chunk => 64, sub { |
717 |
my $response = $_[1]; |
718 |
... |
719 |
}); |
720 |
|
721 |
=over 4 |
722 |
|
723 |
=cut |
724 |
|
725 |
sub _drain_rbuf { |
726 |
my ($self) = @_; |
727 |
|
728 |
local $self->{_in_drain} = 1; |
729 |
|
730 |
if ( |
731 |
defined $self->{rbuf_max} |
732 |
&& $self->{rbuf_max} < length $self->{rbuf} |
733 |
) { |
734 |
return $self->_error (&Errno::ENOSPC, 1); |
735 |
} |
736 |
|
737 |
while () { |
738 |
my $len = length $self->{rbuf}; |
739 |
|
740 |
if (my $cb = shift @{ $self->{_queue} }) { |
741 |
unless ($cb->($self)) { |
742 |
if ($self->{_eof}) { |
743 |
# no progress can be made (not enough data and no data forthcoming) |
744 |
$self->_error (&Errno::EPIPE, 1), last; |
745 |
} |
746 |
|
747 |
unshift @{ $self->{_queue} }, $cb; |
748 |
last; |
749 |
} |
750 |
} elsif ($self->{on_read}) { |
751 |
last unless $len; |
752 |
|
753 |
$self->{on_read}($self); |
754 |
|
755 |
if ( |
756 |
$len == length $self->{rbuf} # if no data has been consumed |
757 |
&& !@{ $self->{_queue} } # and the queue is still empty |
758 |
&& $self->{on_read} # but we still have on_read |
759 |
) { |
760 |
# no further data will arrive |
761 |
# so no progress can be made |
762 |
$self->_error (&Errno::EPIPE, 1), last |
763 |
if $self->{_eof}; |
764 |
|
765 |
last; # more data might arrive |
766 |
} |
767 |
} else { |
768 |
# read side becomes idle |
769 |
delete $self->{_rw}; |
770 |
last; |
771 |
} |
772 |
} |
773 |
|
774 |
if ($self->{_eof}) { |
775 |
if ($self->{on_eof}) { |
776 |
$self->{on_eof}($self) |
777 |
} else { |
778 |
$self->_error (0, 1); |
779 |
} |
780 |
} |
781 |
|
782 |
# may need to restart read watcher |
783 |
unless ($self->{_rw}) { |
784 |
$self->start_read |
785 |
if $self->{on_read} || @{ $self->{_queue} }; |
786 |
} |
787 |
} |
788 |
|
789 |
=item $handle->on_read ($cb) |
790 |
|
791 |
This replaces the currently set C<on_read> callback, or clears it (when |
792 |
the new callback is C<undef>). See the description of C<on_read> in the |
793 |
constructor. |
794 |
|
795 |
=cut |
796 |
|
797 |
sub on_read { |
798 |
my ($self, $cb) = @_; |
799 |
|
800 |
$self->{on_read} = $cb; |
801 |
$self->_drain_rbuf if $cb && !$self->{_in_drain}; |
802 |
} |
803 |
|
804 |
=item $handle->rbuf |
805 |
|
806 |
Returns the read buffer (as a modifiable lvalue). |
807 |
|
808 |
You can access the read buffer directly as the C<< ->{rbuf} >> member, if |
809 |
you want. |
810 |
|
811 |
NOTE: The read buffer should only be used or modified if the C<on_read>, |
812 |
C<push_read> or C<unshift_read> methods are used. The other read methods |
813 |
automatically manage the read buffer. |
814 |
|
815 |
=cut |
816 |
|
817 |
sub rbuf : lvalue { |
818 |
$_[0]{rbuf} |
819 |
} |
820 |
|
821 |
=item $handle->push_read ($cb) |
822 |
|
823 |
=item $handle->unshift_read ($cb) |
824 |
|
825 |
Append the given callback to the end of the queue (C<push_read>) or |
826 |
prepend it (C<unshift_read>). |
827 |
|
828 |
The callback is called each time some additional read data arrives. |
829 |
|
830 |
It must check whether enough data is in the read buffer already. |
831 |
|
832 |
If not enough data is available, it must return the empty list or a false |
833 |
value, in which case it will be called repeatedly until enough data is |
834 |
available (or an error condition is detected). |
835 |
|
836 |
If enough data was available, then the callback must remove all data it is |
837 |
interested in (which can be none at all) and return a true value. After returning |
838 |
true, it will be removed from the queue. |
839 |
|
840 |
=cut |
841 |
|
842 |
our %RH; |
843 |
|
844 |
sub register_read_type($$) { |
845 |
$RH{$_[0]} = $_[1]; |
846 |
} |
847 |
|
848 |
sub push_read { |
849 |
my $self = shift; |
850 |
my $cb = pop; |
851 |
|
852 |
if (@_) { |
853 |
my $type = shift; |
854 |
|
855 |
$cb = ($RH{$type} or Carp::croak "unsupported type passed to AnyEvent::Handle::push_read") |
856 |
->($self, $cb, @_); |
857 |
} |
858 |
|
859 |
push @{ $self->{_queue} }, $cb; |
860 |
$self->_drain_rbuf unless $self->{_in_drain}; |
861 |
} |
862 |
|
863 |
sub unshift_read { |
864 |
my $self = shift; |
865 |
my $cb = pop; |
866 |
|
867 |
if (@_) { |
868 |
my $type = shift; |
869 |
|
870 |
$cb = ($RH{$type} or Carp::croak "unsupported type passed to AnyEvent::Handle::unshift_read") |
871 |
->($self, $cb, @_); |
872 |
} |
873 |
|
874 |
|
875 |
unshift @{ $self->{_queue} }, $cb; |
876 |
$self->_drain_rbuf unless $self->{_in_drain}; |
877 |
} |
878 |
|
879 |
=item $handle->push_read (type => @args, $cb) |
880 |
|
881 |
=item $handle->unshift_read (type => @args, $cb) |
882 |
|
883 |
Instead of providing a callback that parses the data itself you can chose |
884 |
between a number of predefined parsing formats, for chunks of data, lines |
885 |
etc. |
886 |
|
887 |
Predefined types are (if you have ideas for additional types, feel free to |
888 |
drop by and tell us): |
889 |
|
890 |
=over 4 |
891 |
|
892 |
=item chunk => $octets, $cb->($handle, $data) |
893 |
|
894 |
Invoke the callback only once C<$octets> bytes have been read. Pass the |
895 |
data read to the callback. The callback will never be called with less |
896 |
data. |
897 |
|
898 |
Example: read 2 bytes. |
899 |
|
900 |
$handle->push_read (chunk => 2, sub { |
901 |
warn "yay ", unpack "H*", $_[1]; |
902 |
}); |
903 |
|
904 |
=cut |
905 |
|
906 |
register_read_type chunk => sub { |
907 |
my ($self, $cb, $len) = @_; |
908 |
|
909 |
sub { |
910 |
$len <= length $_[0]{rbuf} or return; |
911 |
$cb->($_[0], substr $_[0]{rbuf}, 0, $len, ""); |
912 |
1 |
913 |
} |
914 |
}; |
915 |
|
916 |
=item line => [$eol, ]$cb->($handle, $line, $eol) |
917 |
|
918 |
The callback will be called only once a full line (including the end of |
919 |
line marker, C<$eol>) has been read. This line (excluding the end of line |
920 |
marker) will be passed to the callback as second argument (C<$line>), and |
921 |
the end of line marker as the third argument (C<$eol>). |
922 |
|
923 |
The end of line marker, C<$eol>, can be either a string, in which case it |
924 |
will be interpreted as a fixed record end marker, or it can be a regex |
925 |
object (e.g. created by C<qr>), in which case it is interpreted as a |
926 |
regular expression. |
927 |
|
928 |
The end of line marker argument C<$eol> is optional, if it is missing (NOT |
929 |
undef), then C<qr|\015?\012|> is used (which is good for most internet |
930 |
protocols). |
931 |
|
932 |
Partial lines at the end of the stream will never be returned, as they are |
933 |
not marked by the end of line marker. |
934 |
|
935 |
=cut |
936 |
|
937 |
register_read_type line => sub { |
938 |
my ($self, $cb, $eol) = @_; |
939 |
|
940 |
if (@_ < 3) { |
941 |
# this is more than twice as fast as the generic code below |
942 |
sub { |
943 |
$_[0]{rbuf} =~ s/^([^\015\012]*)(\015?\012)// or return; |
944 |
|
945 |
$cb->($_[0], $1, $2); |
946 |
1 |
947 |
} |
948 |
} else { |
949 |
$eol = quotemeta $eol unless ref $eol; |
950 |
$eol = qr|^(.*?)($eol)|s; |
951 |
|
952 |
sub { |
953 |
$_[0]{rbuf} =~ s/$eol// or return; |
954 |
|
955 |
$cb->($_[0], $1, $2); |
956 |
1 |
957 |
} |
958 |
} |
959 |
}; |
960 |
|
961 |
=item regex => $accept[, $reject[, $skip], $cb->($handle, $data) |
962 |
|
963 |
Makes a regex match against the regex object C<$accept> and returns |
964 |
everything up to and including the match. |
965 |
|
966 |
Example: read a single line terminated by '\n'. |
967 |
|
968 |
$handle->push_read (regex => qr<\n>, sub { ... }); |
969 |
|
970 |
If C<$reject> is given and not undef, then it determines when the data is |
971 |
to be rejected: it is matched against the data when the C<$accept> regex |
972 |
does not match and generates an C<EBADMSG> error when it matches. This is |
973 |
useful to quickly reject wrong data (to avoid waiting for a timeout or a |
974 |
receive buffer overflow). |
975 |
|
976 |
Example: expect a single decimal number followed by whitespace, reject |
977 |
anything else (not the use of an anchor). |
978 |
|
979 |
$handle->push_read (regex => qr<^[0-9]+\s>, qr<[^0-9]>, sub { ... }); |
980 |
|
981 |
If C<$skip> is given and not C<undef>, then it will be matched against |
982 |
the receive buffer when neither C<$accept> nor C<$reject> match, |
983 |
and everything preceding and including the match will be accepted |
984 |
unconditionally. This is useful to skip large amounts of data that you |
985 |
know cannot be matched, so that the C<$accept> or C<$reject> regex do not |
986 |
have to start matching from the beginning. This is purely an optimisation |
987 |
and is usually worth only when you expect more than a few kilobytes. |
988 |
|
989 |
Example: expect a http header, which ends at C<\015\012\015\012>. Since we |
990 |
expect the header to be very large (it isn't in practise, but...), we use |
991 |
a skip regex to skip initial portions. The skip regex is tricky in that |
992 |
it only accepts something not ending in either \015 or \012, as these are |
993 |
required for the accept regex. |
994 |
|
995 |
$handle->push_read (regex => |
996 |
qr<\015\012\015\012>, |
997 |
undef, # no reject |
998 |
qr<^.*[^\015\012]>, |
999 |
sub { ... }); |
1000 |
|
1001 |
=cut |
1002 |
|
1003 |
register_read_type regex => sub { |
1004 |
my ($self, $cb, $accept, $reject, $skip) = @_; |
1005 |
|
1006 |
my $data; |
1007 |
my $rbuf = \$self->{rbuf}; |
1008 |
|
1009 |
sub { |
1010 |
# accept |
1011 |
if ($$rbuf =~ $accept) { |
1012 |
$data .= substr $$rbuf, 0, $+[0], ""; |
1013 |
$cb->($self, $data); |
1014 |
return 1; |
1015 |
} |
1016 |
|
1017 |
# reject |
1018 |
if ($reject && $$rbuf =~ $reject) { |
1019 |
$self->_error (&Errno::EBADMSG); |
1020 |
} |
1021 |
|
1022 |
# skip |
1023 |
if ($skip && $$rbuf =~ $skip) { |
1024 |
$data .= substr $$rbuf, 0, $+[0], ""; |
1025 |
} |
1026 |
|
1027 |
() |
1028 |
} |
1029 |
}; |
1030 |
|
1031 |
=item netstring => $cb->($handle, $string) |
1032 |
|
1033 |
A netstring (http://cr.yp.to/proto/netstrings.txt, this is not an endorsement). |
1034 |
|
1035 |
Throws an error with C<$!> set to EBADMSG on format violations. |
1036 |
|
1037 |
=cut |
1038 |
|
1039 |
register_read_type netstring => sub { |
1040 |
my ($self, $cb) = @_; |
1041 |
|
1042 |
sub { |
1043 |
unless ($_[0]{rbuf} =~ s/^(0|[1-9][0-9]*)://) { |
1044 |
if ($_[0]{rbuf} =~ /[^0-9]/) { |
1045 |
$self->_error (&Errno::EBADMSG); |
1046 |
} |
1047 |
return; |
1048 |
} |
1049 |
|
1050 |
my $len = $1; |
1051 |
|
1052 |
$self->unshift_read (chunk => $len, sub { |
1053 |
my $string = $_[1]; |
1054 |
$_[0]->unshift_read (chunk => 1, sub { |
1055 |
if ($_[1] eq ",") { |
1056 |
$cb->($_[0], $string); |
1057 |
} else { |
1058 |
$self->_error (&Errno::EBADMSG); |
1059 |
} |
1060 |
}); |
1061 |
}); |
1062 |
|
1063 |
1 |
1064 |
} |
1065 |
}; |
1066 |
|
1067 |
=item packstring => $format, $cb->($handle, $string) |
1068 |
|
1069 |
An octet string prefixed with an encoded length. The encoding C<$format> |
1070 |
uses the same format as a Perl C<pack> format, but must specify a single |
1071 |
integer only (only one of C<cCsSlLqQiInNvVjJw> is allowed, plus an |
1072 |
optional C<!>, C<< < >> or C<< > >> modifier). |
1073 |
|
1074 |
DNS over TCP uses a prefix of C<n>, EPP uses a prefix of C<N>. |
1075 |
|
1076 |
Example: read a block of data prefixed by its length in BER-encoded |
1077 |
format (very efficient). |
1078 |
|
1079 |
$handle->push_read (packstring => "w", sub { |
1080 |
my ($handle, $data) = @_; |
1081 |
}); |
1082 |
|
1083 |
=cut |
1084 |
|
1085 |
register_read_type packstring => sub { |
1086 |
my ($self, $cb, $format) = @_; |
1087 |
|
1088 |
sub { |
1089 |
# when we can use 5.10 we can use ".", but for 5.8 we use the re-pack method |
1090 |
defined (my $len = eval { unpack $format, $_[0]{rbuf} }) |
1091 |
or return; |
1092 |
|
1093 |
$format = length pack $format, $len; |
1094 |
|
1095 |
# bypass unshift if we already have the remaining chunk |
1096 |
if ($format + $len <= length $_[0]{rbuf}) { |
1097 |
my $data = substr $_[0]{rbuf}, $format, $len; |
1098 |
substr $_[0]{rbuf}, 0, $format + $len, ""; |
1099 |
$cb->($_[0], $data); |
1100 |
} else { |
1101 |
# remove prefix |
1102 |
substr $_[0]{rbuf}, 0, $format, ""; |
1103 |
|
1104 |
# read remaining chunk |
1105 |
$_[0]->unshift_read (chunk => $len, $cb); |
1106 |
} |
1107 |
|
1108 |
1 |
1109 |
} |
1110 |
}; |
1111 |
|
1112 |
=item json => $cb->($handle, $hash_or_arrayref) |
1113 |
|
1114 |
Reads a JSON object or array, decodes it and passes it to the callback. |
1115 |
|
1116 |
If a C<json> object was passed to the constructor, then that will be used |
1117 |
for the final decode, otherwise it will create a JSON coder expecting UTF-8. |
1118 |
|
1119 |
This read type uses the incremental parser available with JSON version |
1120 |
2.09 (and JSON::XS version 2.2) and above. You have to provide a |
1121 |
dependency on your own: this module will load the JSON module, but |
1122 |
AnyEvent does not depend on it itself. |
1123 |
|
1124 |
Since JSON texts are fully self-delimiting, the C<json> read and write |
1125 |
types are an ideal simple RPC protocol: just exchange JSON datagrams. See |
1126 |
the C<json> write type description, above, for an actual example. |
1127 |
|
1128 |
=cut |
1129 |
|
1130 |
register_read_type json => sub { |
1131 |
my ($self, $cb) = @_; |
1132 |
|
1133 |
require JSON; |
1134 |
|
1135 |
my $data; |
1136 |
my $rbuf = \$self->{rbuf}; |
1137 |
|
1138 |
my $json = $self->{json} ||= JSON->new->utf8; |
1139 |
|
1140 |
sub { |
1141 |
my $ref = $json->incr_parse ($self->{rbuf}); |
1142 |
|
1143 |
if ($ref) { |
1144 |
$self->{rbuf} = $json->incr_text; |
1145 |
$json->incr_text = ""; |
1146 |
$cb->($self, $ref); |
1147 |
|
1148 |
1 |
1149 |
} else { |
1150 |
$self->{rbuf} = ""; |
1151 |
() |
1152 |
} |
1153 |
} |
1154 |
}; |
1155 |
|
1156 |
=item storable => $cb->($handle, $ref) |
1157 |
|
1158 |
Deserialises a L<Storable> frozen representation as written by the |
1159 |
C<storable> write type (BER-encoded length prefix followed by nfreeze'd |
1160 |
data). |
1161 |
|
1162 |
Raises C<EBADMSG> error if the data could not be decoded. |
1163 |
|
1164 |
=cut |
1165 |
|
1166 |
register_read_type storable => sub { |
1167 |
my ($self, $cb) = @_; |
1168 |
|
1169 |
require Storable; |
1170 |
|
1171 |
sub { |
1172 |
# when we can use 5.10 we can use ".", but for 5.8 we use the re-pack method |
1173 |
defined (my $len = eval { unpack "w", $_[0]{rbuf} }) |
1174 |
or return; |
1175 |
|
1176 |
my $format = length pack "w", $len; |
1177 |
|
1178 |
# bypass unshift if we already have the remaining chunk |
1179 |
if ($format + $len <= length $_[0]{rbuf}) { |
1180 |
my $data = substr $_[0]{rbuf}, $format, $len; |
1181 |
substr $_[0]{rbuf}, 0, $format + $len, ""; |
1182 |
$cb->($_[0], Storable::thaw ($data)); |
1183 |
} else { |
1184 |
# remove prefix |
1185 |
substr $_[0]{rbuf}, 0, $format, ""; |
1186 |
|
1187 |
# read remaining chunk |
1188 |
$_[0]->unshift_read (chunk => $len, sub { |
1189 |
if (my $ref = eval { Storable::thaw ($_[1]) }) { |
1190 |
$cb->($_[0], $ref); |
1191 |
} else { |
1192 |
$self->_error (&Errno::EBADMSG); |
1193 |
} |
1194 |
}); |
1195 |
} |
1196 |
|
1197 |
1 |
1198 |
} |
1199 |
}; |
1200 |
|
1201 |
=back |
1202 |
|
1203 |
=item AnyEvent::Handle::register_read_type type => $coderef->($handle, $cb, @args) |
1204 |
|
1205 |
This function (not method) lets you add your own types to C<push_read>. |
1206 |
|
1207 |
Whenever the given C<type> is used, C<push_read> will invoke the code |
1208 |
reference with the handle object, the callback and the remaining |
1209 |
arguments. |
1210 |
|
1211 |
The code reference is supposed to return a callback (usually a closure) |
1212 |
that works as a plain read callback (see C<< ->push_read ($cb) >>). |
1213 |
|
1214 |
It should invoke the passed callback when it is done reading (remember to |
1215 |
pass C<$handle> as first argument as all other callbacks do that). |
1216 |
|
1217 |
Note that this is a function, and all types registered this way will be |
1218 |
global, so try to use unique names. |
1219 |
|
1220 |
For examples, see the source of this module (F<perldoc -m AnyEvent::Handle>, |
1221 |
search for C<register_read_type>)). |
1222 |
|
1223 |
=item $handle->stop_read |
1224 |
|
1225 |
=item $handle->start_read |
1226 |
|
1227 |
In rare cases you actually do not want to read anything from the |
1228 |
socket. In this case you can call C<stop_read>. Neither C<on_read> nor |
1229 |
any queued callbacks will be executed then. To start reading again, call |
1230 |
C<start_read>. |
1231 |
|
1232 |
Note that AnyEvent::Handle will automatically C<start_read> for you when |
1233 |
you change the C<on_read> callback or push/unshift a read callback, and it |
1234 |
will automatically C<stop_read> for you when neither C<on_read> is set nor |
1235 |
there are any read requests in the queue. |
1236 |
|
1237 |
=cut |
1238 |
|
1239 |
sub stop_read { |
1240 |
my ($self) = @_; |
1241 |
|
1242 |
delete $self->{_rw}; |
1243 |
} |
1244 |
|
1245 |
sub start_read { |
1246 |
my ($self) = @_; |
1247 |
|
1248 |
unless ($self->{_rw} || $self->{_eof}) { |
1249 |
Scalar::Util::weaken $self; |
1250 |
|
1251 |
$self->{_rw} = AnyEvent->io (fh => $self->{fh}, poll => "r", cb => sub { |
1252 |
my $rbuf = $self->{filter_r} ? \my $buf : \$self->{rbuf}; |
1253 |
my $len = sysread $self->{fh}, $$rbuf, $self->{read_size} || 8192, length $$rbuf; |
1254 |
|
1255 |
if ($len > 0) { |
1256 |
$self->{_activity} = AnyEvent->now; |
1257 |
|
1258 |
$self->{filter_r} |
1259 |
? $self->{filter_r}($self, $rbuf) |
1260 |
: $self->{_in_drain} || $self->_drain_rbuf; |
1261 |
|
1262 |
} elsif (defined $len) { |
1263 |
delete $self->{_rw}; |
1264 |
$self->{_eof} = 1; |
1265 |
$self->_drain_rbuf unless $self->{_in_drain}; |
1266 |
|
1267 |
} elsif ($! != EAGAIN && $! != EINTR && $! != WSAEWOULDBLOCK) { |
1268 |
return $self->_error ($!, 1); |
1269 |
} |
1270 |
}); |
1271 |
} |
1272 |
} |
1273 |
|
1274 |
sub _dotls { |
1275 |
my ($self) = @_; |
1276 |
|
1277 |
my $buf; |
1278 |
|
1279 |
if (length $self->{_tls_wbuf}) { |
1280 |
while ((my $len = Net::SSLeay::write ($self->{tls}, $self->{_tls_wbuf})) > 0) { |
1281 |
substr $self->{_tls_wbuf}, 0, $len, ""; |
1282 |
} |
1283 |
} |
1284 |
|
1285 |
if (length ($buf = Net::SSLeay::BIO_read ($self->{_wbio}))) { |
1286 |
$self->{wbuf} .= $buf; |
1287 |
$self->_drain_wbuf; |
1288 |
} |
1289 |
|
1290 |
while (defined ($buf = Net::SSLeay::read ($self->{tls}))) { |
1291 |
if (length $buf) { |
1292 |
$self->{rbuf} .= $buf; |
1293 |
$self->_drain_rbuf unless $self->{_in_drain}; |
1294 |
} else { |
1295 |
# let's treat SSL-eof as we treat normal EOF |
1296 |
$self->{_eof} = 1; |
1297 |
$self->_shutdown; |
1298 |
return; |
1299 |
} |
1300 |
} |
1301 |
|
1302 |
my $err = Net::SSLeay::get_error ($self->{tls}, -1); |
1303 |
|
1304 |
if ($err!= Net::SSLeay::ERROR_WANT_READ ()) { |
1305 |
if ($err == Net::SSLeay::ERROR_SYSCALL ()) { |
1306 |
return $self->_error ($!, 1); |
1307 |
} elsif ($err == Net::SSLeay::ERROR_SSL ()) { |
1308 |
return $self->_error (&Errno::EIO, 1); |
1309 |
} |
1310 |
|
1311 |
# all others are fine for our purposes |
1312 |
} |
1313 |
} |
1314 |
|
1315 |
=item $handle->starttls ($tls[, $tls_ctx]) |
1316 |
|
1317 |
Instead of starting TLS negotiation immediately when the AnyEvent::Handle |
1318 |
object is created, you can also do that at a later time by calling |
1319 |
C<starttls>. |
1320 |
|
1321 |
The first argument is the same as the C<tls> constructor argument (either |
1322 |
C<"connect">, C<"accept"> or an existing Net::SSLeay object). |
1323 |
|
1324 |
The second argument is the optional C<Net::SSLeay::CTX> object that is |
1325 |
used when AnyEvent::Handle has to create its own TLS connection object. |
1326 |
|
1327 |
The TLS connection object will end up in C<< $handle->{tls} >> after this |
1328 |
call and can be used or changed to your liking. Note that the handshake |
1329 |
might have already started when this function returns. |
1330 |
|
1331 |
=cut |
1332 |
|
1333 |
sub starttls { |
1334 |
my ($self, $ssl, $ctx) = @_; |
1335 |
|
1336 |
$self->stoptls; |
1337 |
|
1338 |
if ($ssl eq "accept") { |
1339 |
$ssl = Net::SSLeay::new ($ctx || TLS_CTX ()); |
1340 |
Net::SSLeay::set_accept_state ($ssl); |
1341 |
} elsif ($ssl eq "connect") { |
1342 |
$ssl = Net::SSLeay::new ($ctx || TLS_CTX ()); |
1343 |
Net::SSLeay::set_connect_state ($ssl); |
1344 |
} |
1345 |
|
1346 |
$self->{tls} = $ssl; |
1347 |
|
1348 |
# basically, this is deep magic (because SSL_read should have the same issues) |
1349 |
# but the openssl maintainers basically said: "trust us, it just works". |
1350 |
# (unfortunately, we have to hardcode constants because the abysmally misdesigned |
1351 |
# and mismaintained ssleay-module doesn't even offer them). |
1352 |
# http://www.mail-archive.com/openssl-dev@openssl.org/msg22420.html |
1353 |
Net::SSLeay::CTX_set_mode ($self->{tls}, |
1354 |
(eval { local $SIG{__DIE__}; Net::SSLeay::MODE_ENABLE_PARTIAL_WRITE () } || 1) |
1355 |
| (eval { local $SIG{__DIE__}; Net::SSLeay::MODE_ACCEPT_MOVING_WRITE_BUFFER () } || 2)); |
1356 |
|
1357 |
$self->{_rbio} = Net::SSLeay::BIO_new (Net::SSLeay::BIO_s_mem ()); |
1358 |
$self->{_wbio} = Net::SSLeay::BIO_new (Net::SSLeay::BIO_s_mem ()); |
1359 |
|
1360 |
Net::SSLeay::set_bio ($ssl, $self->{_rbio}, $self->{_wbio}); |
1361 |
|
1362 |
$self->{filter_w} = sub { |
1363 |
$_[0]{_tls_wbuf} .= ${$_[1]}; |
1364 |
&_dotls; |
1365 |
}; |
1366 |
$self->{filter_r} = sub { |
1367 |
Net::SSLeay::BIO_write ($_[0]{_rbio}, ${$_[1]}); |
1368 |
&_dotls; |
1369 |
}; |
1370 |
} |
1371 |
|
1372 |
=item $handle->stoptls |
1373 |
|
1374 |
Destroys the SSL connection, if any. Partial read or write data will be |
1375 |
lost. |
1376 |
|
1377 |
=cut |
1378 |
|
1379 |
sub stoptls { |
1380 |
my ($self) = @_; |
1381 |
|
1382 |
Net::SSLeay::free (delete $self->{tls}) if $self->{tls}; |
1383 |
|
1384 |
delete $self->{_rbio}; |
1385 |
delete $self->{_wbio}; |
1386 |
delete $self->{_tls_wbuf}; |
1387 |
delete $self->{filter_r}; |
1388 |
delete $self->{filter_w}; |
1389 |
} |
1390 |
|
1391 |
sub DESTROY { |
1392 |
my $self = shift; |
1393 |
|
1394 |
$self->stoptls; |
1395 |
|
1396 |
my $linger = exists $self->{linger} ? $self->{linger} : 3600; |
1397 |
|
1398 |
if ($linger && length $self->{wbuf}) { |
1399 |
my $fh = delete $self->{fh}; |
1400 |
my $wbuf = delete $self->{wbuf}; |
1401 |
|
1402 |
my @linger; |
1403 |
|
1404 |
push @linger, AnyEvent->io (fh => $fh, poll => "w", cb => sub { |
1405 |
my $len = syswrite $fh, $wbuf, length $wbuf; |
1406 |
|
1407 |
if ($len > 0) { |
1408 |
substr $wbuf, 0, $len, ""; |
1409 |
} else { |
1410 |
@linger = (); # end |
1411 |
} |
1412 |
}); |
1413 |
push @linger, AnyEvent->timer (after => $linger, cb => sub { |
1414 |
@linger = (); |
1415 |
}); |
1416 |
} |
1417 |
} |
1418 |
|
1419 |
=item AnyEvent::Handle::TLS_CTX |
1420 |
|
1421 |
This function creates and returns the Net::SSLeay::CTX object used by |
1422 |
default for TLS mode. |
1423 |
|
1424 |
The context is created like this: |
1425 |
|
1426 |
Net::SSLeay::load_error_strings; |
1427 |
Net::SSLeay::SSLeay_add_ssl_algorithms; |
1428 |
Net::SSLeay::randomize; |
1429 |
|
1430 |
my $CTX = Net::SSLeay::CTX_new; |
1431 |
|
1432 |
Net::SSLeay::CTX_set_options $CTX, Net::SSLeay::OP_ALL |
1433 |
|
1434 |
=cut |
1435 |
|
1436 |
our $TLS_CTX; |
1437 |
|
1438 |
sub TLS_CTX() { |
1439 |
$TLS_CTX || do { |
1440 |
require Net::SSLeay; |
1441 |
|
1442 |
Net::SSLeay::load_error_strings (); |
1443 |
Net::SSLeay::SSLeay_add_ssl_algorithms (); |
1444 |
Net::SSLeay::randomize (); |
1445 |
|
1446 |
$TLS_CTX = Net::SSLeay::CTX_new (); |
1447 |
|
1448 |
Net::SSLeay::CTX_set_options ($TLS_CTX, Net::SSLeay::OP_ALL ()); |
1449 |
|
1450 |
$TLS_CTX |
1451 |
} |
1452 |
} |
1453 |
|
1454 |
=back |
1455 |
|
1456 |
=head1 SUBCLASSING AnyEvent::Handle |
1457 |
|
1458 |
In many cases, you might want to subclass AnyEvent::Handle. |
1459 |
|
1460 |
To make this easier, a given version of AnyEvent::Handle uses these |
1461 |
conventions: |
1462 |
|
1463 |
=over 4 |
1464 |
|
1465 |
=item * all constructor arguments become object members. |
1466 |
|
1467 |
At least initially, when you pass a C<tls>-argument to the constructor it |
1468 |
will end up in C<< $handle->{tls} >>. Those members might be changed or |
1469 |
mutated later on (for example C<tls> will hold the TLS connection object). |
1470 |
|
1471 |
=item * other object member names are prefixed with an C<_>. |
1472 |
|
1473 |
All object members not explicitly documented (internal use) are prefixed |
1474 |
with an underscore character, so the remaining non-C<_>-namespace is free |
1475 |
for use for subclasses. |
1476 |
|
1477 |
=item * all members not documented here and not prefixed with an underscore |
1478 |
are free to use in subclasses. |
1479 |
|
1480 |
Of course, new versions of AnyEvent::Handle may introduce more "public" |
1481 |
member variables, but thats just life, at least it is documented. |
1482 |
|
1483 |
=back |
1484 |
|
1485 |
=head1 AUTHOR |
1486 |
|
1487 |
Robin Redeker C<< <elmex at ta-sa.org> >>, Marc Lehmann <schmorp@schmorp.de>. |
1488 |
|
1489 |
=cut |
1490 |
|
1491 |
1; # End of AnyEvent::Handle |