Linux-Inotify2/Inotify2.pm

=head1 NAME

Linux::Inotify2 - scalable directory/file change notification

=head1 SYNOPSIS

=head2 Callback Interface

 use Linux::Inotify2;

 # create a new object
 my $inotify = new Linux::Inotify2
    or die "unable to create new inotify object: $!";
 
 # add watchers
 $inotify->watch ("/etc/passwd", IN_ACCESS, sub {
    my $e = shift;
    my $name = $e->fullname;
    print "$name was accessed\n" if $e->IN_ACCESS;
    print "$name is no longer mounted\n" if $e->IN_UNMOUNT;
    print "$name is gone\n" if $e->IN_IGNORED;
    print "events for $name have been lost\n" if $e->IN_Q_OVERFLOW;
 
    # cancel this watcher: remove no further events
    $e->w->cancel;
 });

 # integration into AnyEvent (works with EV, Glib, Tk, POE...)
 my $inotify_w = AE::io $inotify->fileno, 0, sub { $inotify->poll };

 # manual event loop
 $inotify->poll while 1;

=head2 Streaming Interface

 use Linux::Inotify2;

 # create a new object
 my $inotify = new Linux::Inotify2
    or die "Unable to create new inotify object: $!";

 # create watch
 $inotify->watch ("/etc/passwd", IN_ACCESS)
    or die "watch creation failed";

 while () {
   my @events = $inotify->read;
   printf "mask\t%d\n", $_->mask foreach @events;
 }

=head1 DESCRIPTION

This module implements an interface to the Linux 2.6.13 and later Inotify
file/directory change notification system.

It has a number of advantages over the Linux::Inotify module:

   - it is portable (Linux::Inotify only works on x86)
   - the equivalent of fullname works correctly
   - it is better documented
   - it has callback-style interface, which is better suited for
     integration.

As for the inotify API itself - it is a very tricky, and somewhat
unreliable API. For a good overview of the challenges you might run into,
see this LWN article: L<https://lwn.net/Articles/605128/>.

=head2 The Linux::Inotify2 Class

=over 4

=cut

package Linux::Inotify2;

use Scalar::Util ();

use common::sense;

use Exporter qw(import);

BEGIN {
   our $VERSION = '2.3';
   our @EXPORT = qw(
      IN_ACCESS IN_MODIFY IN_ATTRIB IN_CLOSE_WRITE
      IN_CLOSE_NOWRITE IN_OPEN IN_MOVED_FROM IN_MOVED_TO
      IN_CREATE IN_DELETE IN_DELETE_SELF IN_MOVE_SELF
      IN_ALL_EVENTS
      IN_UNMOUNT IN_Q_OVERFLOW IN_IGNORED
      IN_CLOSE IN_MOVE
      IN_ISDIR IN_ONESHOT IN_MASK_ADD
      IN_DONT_FOLLOW IN_EXCL_UNLINK IN_ONLYDIR
   );

   require XSLoader;
   XSLoader::load Linux::Inotify2, $VERSION;
}

=item my $inotify = new Linux::Inotify2

Create a new notify object and return it. A notify object is kind of a
container that stores watches on file system names and is responsible for
handling event data.

On error, C<undef> is returned and C<$!> will be set accordingly. The
following errors are documented:

 ENFILE   The system limit on the total number of file descriptors has been reached.
 EMFILE   The user limit on the total number of inotify instances has been reached.
 ENOMEM   Insufficient kernel memory is available.

Example:

   my $inotify = new Linux::Inotify2
      or die "Unable to create new inotify object: $!";

=cut

sub new {
   my ($class) = @_;

   my $fd = inotify_init;

   return unless $fd >= 0;

   open my $fh, "<&=", $fd
      or die "cannot open fd $fd as perl handle\n";

   bless { fd => $fd, fh => $fh }, $class
}

=item $watch = $inotify->watch ($name, $mask[, $cb])

Add a new watcher to the given notifier. The watcher will create events
on the pathname C<$name> as given in C<$mask>, which can be any of the
following constants (all exported by default) ORed together. Constants
unavailable on your system will evaluate to C<0>.

"file" refers to any file system object in the watched object (always a
directory), that is files, directories, symlinks, device nodes etc., while
"object" refers to the object the watcher has been set on itself:

 IN_ACCESS            object was accessed
 IN_MODIFY            object was modified
 IN_ATTRIB            object metadata changed
 IN_CLOSE_WRITE       writable fd to file / to object was closed
 IN_CLOSE_NOWRITE     readonly fd to file / to object closed
 IN_OPEN              object was opened
 IN_MOVED_FROM        file was moved from this object (directory)
 IN_MOVED_TO          file was moved to this object (directory)
 IN_CREATE            file was created in this object (directory)
 IN_DELETE            file was deleted from this object (directory)
 IN_DELETE_SELF       object itself was deleted
 IN_MOVE_SELF         object itself was moved
 IN_ALL_EVENTS        all of the above events

 IN_ONESHOT           only send event once
 IN_ONLYDIR           only watch the path if it is a directory
 IN_DONT_FOLLOW       don't follow a sym link (Linux 2.6.15+)
 IN_EXCL_UNLINK       don't create events for unlinked objects (Linux 2.6.36+)
 IN_MASK_ADD          not supported with the current version of this module

 IN_CLOSE             same as IN_CLOSE_WRITE | IN_CLOSE_NOWRITE
 IN_MOVE              same as IN_MOVED_FROM | IN_MOVED_TO

C<$cb> is a perl code reference that, if given, is called for each
event. It receives a C<Linux::Inotify2::Event> object.

The returned C<$watch> object is of class C<Linux::Inotify2::Watch>.

On error, C<undef> is returned and C<$!> will be set accordingly. The
following errors are documented:

 EBADF    The given file descriptor is not valid.
 EINVAL   The given event mask contains no legal events.
 ENOMEM   Insufficient kernel memory was available.
 ENOSPC   The user limit on the total number of inotify watches was reached or the kernel failed to allocate a needed resource.
 EACCESS  Read access to the given file is not permitted.

Example, show when C</etc/passwd> gets accessed and/or modified once:

   $inotify->watch ("/etc/passwd", IN_ACCESS | IN_MODIFY, sub {
      my $e = shift;
      print "$e->{w}{name} was accessed\n" if $e->IN_ACCESS;
      print "$e->{w}{name} was modified\n" if $e->IN_MODIFY;
      print "$e->{w}{name} is no longer mounted\n" if $e->IN_UNMOUNT;
      print "events for $e->{w}{name} have been lost\n" if $e->IN_Q_OVERFLOW;

      $e->w->cancel;
   });

=cut

sub watch {
   my ($self, $name, $mask, $cb) = @_;

   my $wd = inotify_add_watch $self->{fd}, $name, $mask;

   return unless $wd >= 0;
   
   my $w = $self->{w}{$wd} = bless {
      inotify => $self,
      wd      => $wd,
      name    => $name,
      mask    => $mask,
      cb      => $cb,
   }, "Linux::Inotify2::Watch";

   Scalar::Util::weaken $w->{inotify};

   $w
}

=item $inotify->fileno

Returns the file descriptor for this notify object. When in non-blocking
mode, you are responsible for calling the C<poll> method when this file
descriptor becomes ready for reading.

=item $inotify->fh

Similar to C<fileno>, but returns a perl file handle instead.

=cut

sub fileno {
   $_[0]{fd}
}

sub fh {
   $_[0]{fh}
}

=item $inotify->blocking ($blocking)

Clears ($blocking true) or sets ($blocking false) the C<O_NONBLOCK> flag on the file descriptor.

=cut

sub blocking {
   my ($self, $blocking) = @_;

   inotify_blocking $self->{fd}, $blocking;
}

=item $count = $inotify->poll

Reads events from the kernel and handles them. If the notify file
descriptor is blocking (the default), then this method waits for at least
one event. Otherwise it returns immediately when no pending events could
be read.

Returns the count of events that have been handled (which can be C<0> in case
events have been received but have been ignored or handled internally).

Croaks when an error occurs.

=cut

sub poll {
   scalar &read
}

=item @events = $inotify->read

Reads events from the kernel. Blocks when the file descriptor is in
blocking mode (default) until any event arrives. Returns list of
C<Linux::Inotify2::Event> objects or empty list if none (non-blocking
mode or events got ignored).

Croaks on error.

Normally you shouldn't use this function, but instead use watcher
callbacks and call C<< ->poll >>.

=cut

sub read {
   my ($self) = @_;

   my @ev = inotify_read $self->{fd};
   my @res;

   for (@ev) {
      exists $self->{ignore}{$_->{wd}}
         and next; # watcher has been canceled

      push @res, bless $_, "Linux::Inotify2::Event";

      my $w = $_->{w} = $self->{w}{$_->{wd}}
         or do {
            # no such watcher, but maybe we can do overflow handling
            if ($_->{mask} & IN_Q_OVERFLOW) {
               if ($self->{on_overflow}) {
                  $self->{on_overflow}($_);
               } else {
                  $self->broadcast ($_);
               }
            }
            next;
         };

      $w->{cb}($_) if $w->{cb};
      $w->cancel if $_->{mask} & (IN_IGNORED | IN_UNMOUNT | IN_ONESHOT | IN_DELETE_SELF);
   }

   delete $self->{ignore};

   wantarray ? @res : scalar @res
}

=item $inotify->on_overflow ($cb->($ev))

Sets the callback to be used for overflow handling
(default: C<undef>): When C<read> receives an event with C<IN_Q_OVERFLOW>
set, it will invoke this callback with the event.

When the callback is C<undef>, then it broadcasts the event to all
registered watchers, i.e., C<undef> is equivalent to:

   sub { $inotify->broadcast ($_[0]) }

=cut

sub on_overflow {
   my $prev = $_[0]{on_overflow};

   $_[0]{on_overflow} = $_[1]
      if @_ >= 2;

   $prev
}

=item $inotify->broadcast ($ev)

Invokes all registered watcher callbacks and passes the given event to
them. Most useful in overflow handlers.

=cut

sub broadcast {
   my ($self, $ev) = @_;

   for my $w (values %{ $self->{w} }) {
      local $ev->{w} = $w;
      $w->{cb}($ev) if $w->{cb};
   }
}

=back

=head2 The Linux::Inotify2::Event Class

Objects of this class are handed as first argument to the watcher
callback. It has the following members and methods:

=over 4

=item $event->w

=item $event->{w}

The watcher object for this event, if one is available. Generally, you cna
only rely on the value of this member inside watcher callbacks.

=item $event->name

=item $event->{name}

The path of the file system object, relative to the watched name.

=item $event->fullname

Returns the "full" name of the relevant object, i.e. including the C<name>
member of the watcher (if the watch object is on a directory and a
directory entry is affected), or simply the C<name> member itself when the
object is the watch object itself.

This call requires C<< $event->{w} >> to be valid, which is generally only
the case within watcher callbacks.

=item $event->mask

=item $event->{mask}

The received event mask. In addition to the events described for C<<
$inotify->watch >>, the following flags (exported by default) can be set:

 IN_ISDIR             event object is a directory
 IN_Q_OVERFLOW        event queue overflowed

 # when any of the following flags are set,
 # then watchers for this event are automatically canceled
 IN_UNMOUNT           filesystem for watched object was unmounted
 IN_IGNORED           file was ignored/is gone (no more events are delivered)
 IN_ONESHOT           only one event was generated
 IN_Q_OVERFLOW        queue overflow - event might not be specific to a watcher

=item $event->IN_xxx

Returns a boolean that returns true if the event mask contains any events
specified by the mask. All of the C<IN_xxx> constants can be used as
methods.

=item $event->cookie

=item $event->{cookie}

The event cookie to "synchronize two events". Normally zero, this value is
set when two events relating to the same file are generated. As far as I
know, this only happens for C<IN_MOVED_FROM> and C<IN_MOVED_TO> events, to
identify the old and new name of a file.

Note that the inotify API makes it impossible to know whether there will
be a C<IN_MOVED_TO> event - you might receive only one of the events,
and even if you receive both, there might be any number of events in
between. The best approach seems to be to implement a small timeout
after C<IN_MOVED_FROM> to see if a matching C<IN_MOVED_TO> event will be
received - 2ms seem to work relatively well.

=back

=cut

package Linux::Inotify2::Event;

sub w       { $_[0]{w}      }
sub name    { $_[0]{name}   }
sub mask    { $_[0]{mask}   }
sub cookie  { $_[0]{cookie} }

sub fullname {
   length $_[0]{name}
      ? "$_[0]{w}{name}/$_[0]{name}"
      : $_[0]{w}{name};
}

for my $name (@Linux::Inotify2::EXPORT) {
   my $mask = &{"Linux::Inotify2::$name"};

   *$name = sub { $_[0]{mask} & $mask };
}

=head2 The Linux::Inotify2::Watch Class

Watcher objects are created by calling the C<watch> method of a notifier.

It has the following members and methods:

=over 4

=item $watch->name

=item $watch->{name}

The name as specified in the C<watch> call. For the object itself, this is
the empty string.  For directory watches, this is the name of the entry
without leading path elements.

=item $watch->mask

=item $watch->{mask}

The mask as specified in the C<watch> call.

=item $watch->cb ([new callback])

=item $watch->{cb}

The callback as specified in the C<watch> call. Can optionally be changed.

=item $watch->cancel

Cancels/removes this watcher. Future events, even if already queued queued,
will not be handled and resources will be freed.

=back

=cut

package Linux::Inotify2::Watch;

sub name    { $_[0]{name} }
sub mask    { $_[0]{mask} }

sub cb {
   $_[0]{cb} = $_[1] if @_ > 1;
   $_[0]{cb}
}

sub cancel {
   my ($self) = @_;

   my $inotify = delete $self->{inotify}
      or return 1; # already canceled

   delete $inotify->{w}{$self->{wd}}; # we are no longer there
   $inotify->{ignore}{$self->{wd}} = 1; # ignore further events for one poll

   (Linux::Inotify2::inotify_rm_watch $inotify->{fd}, $self->{wd})
      ? 1 : undef
}

=head1 SEE ALSO

L<AnyEvent>, L<Linux::Inotify>.

=head1 AUTHOR

 Marc Lehmann <schmorp@schmorp.de>
 http://home.schmorp.de/

=cut

1
Revision:	1.34
Committed:	Sat Jul 31 11:47:05 2021 UTC (2 years, 10 months ago) by root
Branch:	MAIN
CVS Tags:	rel-2_3, HEAD
Changes since 1.33:	+13 -6 lines
Log Message:	2.3
#	User	Rev	Content
1	root	1.1	=head1 NAME
2
3			Linux::Inotify2 - scalable directory/file change notification
4
5			=head1 SYNOPSIS
6
7	root	1.19	=head2 Callback Interface
8	root	1.11
9	root	1.1	use Linux::Inotify2;
10
11	root	1.4	# create a new object
12			my $inotify = new Linux::Inotify2
13	root	1.19	or die "unable to create new inotify object: $!";
14	root	1.4
15			# add watchers
16			$inotify->watch ("/etc/passwd", IN_ACCESS, sub {
17			my $e = shift;
18			my $name = $e->fullname;
19			print "$name was accessed\n" if $e->IN_ACCESS;
20			print "$name is no longer mounted\n" if $e->IN_UNMOUNT;
21			print "$name is gone\n" if $e->IN_IGNORED;
22			print "events for $name have been lost\n" if $e->IN_Q_OVERFLOW;
23
24	root	1.11	# cancel this watcher: remove no further events
25	root	1.4	$e->w->cancel;
26			});
27
28	root	1.20	# integration into AnyEvent (works with EV, Glib, Tk, POE...)
29	root	1.25	my $inotify_w = AE::io $inotify->fileno, 0, sub { $inotify->poll };
30	root	1.17
31			# manual event loop
32	root	1.31	$inotify->poll while 1;
33	root	1.17
34	root	1.11	=head2 Streaming Interface
35
36	root	1.27	use Linux::Inotify2;
37	root	1.11
38			# create a new object
39			my $inotify = new Linux::Inotify2
40	root	1.27	or die "Unable to create new inotify object: $!";
41	root	1.11
42			# create watch
43			$inotify->watch ("/etc/passwd", IN_ACCESS)
44	root	1.27	or die "watch creation failed";
45	root	1.11
46			while () {
47			my @events = $inotify->read;
48	root	1.27	printf "mask\t%d\n", $_->mask foreach @events;
49	root	1.11	}
50
51	root	1.1	=head1 DESCRIPTION
52
53	root	1.3	This module implements an interface to the Linux 2.6.13 and later Inotify
54	root	1.24	file/directory change notification system.
55	root	1.2
56	root	1.3	It has a number of advantages over the Linux::Inotify module:
57	root	1.2
58			- it is portable (Linux::Inotify only works on x86)
59			- the equivalent of fullname works correctly
60			- it is better documented
61			- it has callback-style interface, which is better suited for
62			integration.
63
64	root	1.30	As for the inotify API itself - it is a very tricky, and somewhat
65			unreliable API. For a good overview of the challenges you might run into,
66			see this LWN article: L<https://lwn.net/Articles/605128/>.
67
68	root	1.6	=head2 The Linux::Inotify2 Class
69
70	root	1.1	=over 4
71
72			=cut
73
74			package Linux::Inotify2;
75
76			use Scalar::Util ();
77
78	root	1.20	use common::sense;
79
80	root	1.26	use Exporter qw(import);
81	root	1.1
82			BEGIN {
83	root	1.34	our $VERSION = '2.3';
84	root	1.20	our @EXPORT = qw(
85	root	1.1	IN_ACCESS IN_MODIFY IN_ATTRIB IN_CLOSE_WRITE
86			IN_CLOSE_NOWRITE IN_OPEN IN_MOVED_FROM IN_MOVED_TO
87	root	1.9	IN_CREATE IN_DELETE IN_DELETE_SELF IN_MOVE_SELF
88	root	1.1	IN_ALL_EVENTS
89			IN_UNMOUNT IN_Q_OVERFLOW IN_IGNORED
90			IN_CLOSE IN_MOVE
91	root	1.28	IN_ISDIR IN_ONESHOT IN_MASK_ADD
92			IN_DONT_FOLLOW IN_EXCL_UNLINK IN_ONLYDIR
93	root	1.1	);
94
95			require XSLoader;
96			XSLoader::load Linux::Inotify2, $VERSION;
97			}
98
99			=item my $inotify = new Linux::Inotify2
100
101			Create a new notify object and return it. A notify object is kind of a
102	root	1.24	container that stores watches on file system names and is responsible for
103	root	1.1	handling event data.
104
105	root	1.22	On error, C<undef> is returned and C<$!> will be set accordingly. The
106			following errors are documented:
107	root	1.1
108			ENFILE The system limit on the total number of file descriptors has been reached.
109			EMFILE The user limit on the total number of inotify instances has been reached.
110			ENOMEM Insufficient kernel memory is available.
111
112	root	1.4	Example:
113
114			my $inotify = new Linux::Inotify2
115			or die "Unable to create new inotify object: $!";
116
117	root	1.1	=cut
118
119			sub new {
120			my ($class) = @_;
121
122			my $fd = inotify_init;
123
124			return unless $fd >= 0;
125
126	root	1.34	open my $fh, "<&=", $fd
127			or die "cannot open fd $fd as perl handle\n";
128
129			bless { fd => $fd, fh => $fh }, $class
130	root	1.1	}
131
132	root	1.11	=item $watch = $inotify->watch ($name, $mask[, $cb])
133	root	1.1
134			Add a new watcher to the given notifier. The watcher will create events
135			on the pathname C<$name> as given in C<$mask>, which can be any of the
136	root	1.33	following constants (all exported by default) ORed together. Constants
137			unavailable on your system will evaluate to C<0>.
138	root	1.4
139	root	1.24	"file" refers to any file system object in the watched object (always a
140	root	1.4	directory), that is files, directories, symlinks, device nodes etc., while
141	root	1.24	"object" refers to the object the watcher has been set on itself:
142	root	1.4
143			IN_ACCESS object was accessed
144			IN_MODIFY object was modified
145			IN_ATTRIB object metadata changed
146			IN_CLOSE_WRITE writable fd to file / to object was closed
147			IN_CLOSE_NOWRITE readonly fd to file / to object closed
148			IN_OPEN object was opened
149			IN_MOVED_FROM file was moved from this object (directory)
150			IN_MOVED_TO file was moved to this object (directory)
151			IN_CREATE file was created in this object (directory)
152			IN_DELETE file was deleted from this object (directory)
153			IN_DELETE_SELF object itself was deleted
154	root	1.9	IN_MOVE_SELF object itself was moved
155	root	1.4	IN_ALL_EVENTS all of the above events
156	root	1.1
157			IN_ONESHOT only send event once
158	root	1.15	IN_ONLYDIR only watch the path if it is a directory
159	root	1.28	IN_DONT_FOLLOW don't follow a sym link (Linux 2.6.15+)
160			IN_EXCL_UNLINK don't create events for unlinked objects (Linux 2.6.36+)
161	root	1.15	IN_MASK_ADD not supported with the current version of this module
162	root	1.1
163	root	1.4	IN_CLOSE same as IN_CLOSE_WRITE \| IN_CLOSE_NOWRITE
164			IN_MOVE same as IN_MOVED_FROM \| IN_MOVED_TO
165	root	1.1
166	root	1.11	C<$cb> is a perl code reference that, if given, is called for each
167			event. It receives a C<Linux::Inotify2::Event> object.
168	root	1.1
169			The returned C<$watch> object is of class C<Linux::Inotify2::Watch>.
170
171			On error, C<undef> is returned and C<$!> will be set accordingly. The
172			following errors are documented:
173
174			EBADF The given file descriptor is not valid.
175			EINVAL The given event mask contains no legal events.
176			ENOMEM Insufficient kernel memory was available.
177			ENOSPC The user limit on the total number of inotify watches was reached or the kernel failed to allocate a needed resource.
178			EACCESS Read access to the given file is not permitted.
179
180			Example, show when C</etc/passwd> gets accessed and/or modified once:
181
182			$inotify->watch ("/etc/passwd", IN_ACCESS \| IN_MODIFY, sub {
183			my $e = shift;
184			print "$e->{w}{name} was accessed\n" if $e->IN_ACCESS;
185			print "$e->{w}{name} was modified\n" if $e->IN_MODIFY;
186			print "$e->{w}{name} is no longer mounted\n" if $e->IN_UNMOUNT;
187			print "events for $e->{w}{name} have been lost\n" if $e->IN_Q_OVERFLOW;
188
189			$e->w->cancel;
190			});
191
192			=cut
193
194			sub watch {
195			my ($self, $name, $mask, $cb) = @_;
196
197			my $wd = inotify_add_watch $self->{fd}, $name, $mask;
198
199			return unless $wd >= 0;
200
201			my $w = $self->{w}{$wd} = bless {
202			inotify => $self,
203			wd => $wd,
204			name => $name,
205			mask => $mask,
206			cb => $cb,
207	root	1.13	}, "Linux::Inotify2::Watch";
208	root	1.1
209			Scalar::Util::weaken $w->{inotify};
210
211			$w
212			}
213
214	root	1.4	=item $inotify->fileno
215	root	1.1
216	root	1.24	Returns the file descriptor for this notify object. When in non-blocking
217			mode, you are responsible for calling the C<poll> method when this file
218			descriptor becomes ready for reading.
219	root	1.1
220	root	1.34	=item $inotify->fh
221
222			Similar to C<fileno>, but returns a perl file handle instead.
223
224	root	1.1	=cut
225
226			sub fileno {
227			$_[0]{fd}
228			}
229
230	root	1.34	sub fh {
231			$_[0]{fh}
232			}
233
234	root	1.11	=item $inotify->blocking ($blocking)
235
236			Clears ($blocking true) or sets ($blocking false) the C<O_NONBLOCK> flag on the file descriptor.
237
238			=cut
239
240			sub blocking {
241			my ($self, $blocking) = @_;
242
243			inotify_blocking $self->{fd}, $blocking;
244			}
245
246	root	1.4	=item $count = $inotify->poll
247	root	1.1
248	root	1.24	Reads events from the kernel and handles them. If the notify file
249			descriptor is blocking (the default), then this method waits for at least
250	root	1.31	one event. Otherwise it returns immediately when no pending events could
251			be read.
252
253			Returns the count of events that have been handled (which can be C<0> in case
254			events have been received but have been ignored or handled internally).
255	root	1.1
256	root	1.31	Croaks when an error occurs.
257	root	1.1
258			=cut
259
260			sub poll {
261	root	1.11	scalar &read
262			}
263
264	root	1.24	=item @events = $inotify->read
265	root	1.11
266	root	1.24	Reads events from the kernel. Blocks when the file descriptor is in
267			blocking mode (default) until any event arrives. Returns list of
268			C<Linux::Inotify2::Event> objects or empty list if none (non-blocking
269	root	1.31	mode or events got ignored).
270
271			Croaks on error.
272	root	1.24
273			Normally you shouldn't use this function, but instead use watcher
274			callbacks and call C<< ->poll >>.
275	root	1.11
276			=cut
277
278			sub read {
279	root	1.1	my ($self) = @_;
280
281	root	1.4	my @ev = inotify_read $self->{fd};
282	root	1.11	my @res;
283	root	1.4
284			for (@ev) {
285			exists $self->{ignore}{$_->{wd}}
286			and next; # watcher has been canceled
287
288	root	1.29	push @res, bless $_, "Linux::Inotify2::Event";
289	root	1.12
290	root	1.29	my $w = $_->{w} = $self->{w}{$_->{wd}}
291			or do {
292			# no such watcher, but maybe we can do overflow handling
293			if ($_->{mask} & IN_Q_OVERFLOW) {
294			if ($self->{on_overflow}) {
295			$self->{on_overflow}($_);
296			} else {
297			$self->broadcast ($_);
298			}
299			}
300			next;
301			};
302	root	1.11
303	root	1.29	$w->{cb}($_) if $w->{cb};
304	root	1.16	$w->cancel if $_->{mask} & (IN_IGNORED \| IN_UNMOUNT \| IN_ONESHOT \| IN_DELETE_SELF);
305	root	1.1	}
306	root	1.4
307			delete $self->{ignore};
308
309	root	1.29	wantarray ? @res : scalar @res
310			}
311
312			=item $inotify->on_overflow ($cb->($ev))
313
314			Sets the callback to be used for overflow handling
315			(default: C<undef>): When C<read> receives an event with C<IN_Q_OVERFLOW>
316			set, it will invoke this callback with the event.
317
318			When the callback is C<undef>, then it broadcasts the event to all
319			registered watchers, i.e., C<undef> is equivalent to:
320
321			sub { $inotify->broadcast ($_[0]) }
322
323			=cut
324
325			sub on_overflow {
326			my $prev = $_[0]{on_overflow};
327
328			$_[0]{on_overflow} = $_[1]
329			if @_ >= 2;
330
331			$prev
332			}
333
334			=item $inotify->broadcast ($ev)
335
336			Invokes all registered watcher callbacks and passes the given event to
337			them. Most useful in overflow handlers.
338
339			=cut
340
341			sub broadcast {
342			my ($self, $ev) = @_;
343
344			for my $w (values %{ $self->{w} }) {
345			local $ev->{w} = $w;
346			$w->{cb}($ev) if $w->{cb};
347			}
348	root	1.1	}
349
350			=back
351
352			=head2 The Linux::Inotify2::Event Class
353
354	root	1.24	Objects of this class are handed as first argument to the watcher
355	root	1.1	callback. It has the following members and methods:
356
357			=over 4
358
359			=item $event->w
360
361			=item $event->{w}
362
363	root	1.29	The watcher object for this event, if one is available. Generally, you cna
364			only rely on the value of this member inside watcher callbacks.
365	root	1.1
366			=item $event->name
367
368			=item $event->{name}
369
370	root	1.24	The path of the file system object, relative to the watched name.
371	root	1.1
372	root	1.23	=item $event->fullname
373	root	1.1
374			Returns the "full" name of the relevant object, i.e. including the C<name>
375	root	1.24	member of the watcher (if the watch object is on a directory and a
376			directory entry is affected), or simply the C<name> member itself when the
377			object is the watch object itself.
378	root	1.1
379	root	1.29	This call requires C<< $event->{w} >> to be valid, which is generally only
380			the case within watcher callbacks.
381
382	root	1.1	=item $event->mask
383
384			=item $event->{mask}
385
386	root	1.24	The received event mask. In addition to the events described for C<<
387			$inotify->watch >>, the following flags (exported by default) can be set:
388	root	1.1
389	root	1.4	IN_ISDIR event object is a directory
390			IN_Q_OVERFLOW event queue overflowed
391
392	root	1.10	# when any of the following flags are set,
393			# then watchers for this event are automatically canceled
394	root	1.24	IN_UNMOUNT filesystem for watched object was unmounted
395	root	1.4	IN_IGNORED file was ignored/is gone (no more events are delivered)
396	root	1.10	IN_ONESHOT only one event was generated
397	root	1.29	IN_Q_OVERFLOW queue overflow - event might not be specific to a watcher
398	root	1.1
399			=item $event->IN_xxx
400
401	root	1.24	Returns a boolean that returns true if the event mask contains any events
402			specified by the mask. All of the C<IN_xxx> constants can be used as
403			methods.
404	root	1.1
405			=item $event->cookie
406
407			=item $event->{cookie}
408
409	root	1.10	The event cookie to "synchronize two events". Normally zero, this value is
410			set when two events relating to the same file are generated. As far as I
411			know, this only happens for C<IN_MOVED_FROM> and C<IN_MOVED_TO> events, to
412			identify the old and new name of a file.
413	root	1.1
414	root	1.29	Note that the inotify API makes it impossible to know whether there will
415			be a C<IN_MOVED_TO> event - you might receive only one of the events,
416			and even if you receive both, there might be any number of events in
417			between. The best approach seems to be to implement a small timeout
418			after C<IN_MOVED_FROM> to see if a matching C<IN_MOVED_TO> event will be
419			received - 2ms seem to work relatively well.
420
421	root	1.1	=back
422
423			=cut
424
425			package Linux::Inotify2::Event;
426
427			sub w { $_[0]{w} }
428			sub name { $_[0]{name} }
429			sub mask { $_[0]{mask} }
430			sub cookie { $_[0]{cookie} }
431
432			sub fullname {
433			length $_[0]{name}
434			? "$_[0]{w}{name}/$_[0]{name}"
435			: $_[0]{w}{name};
436			}
437
438	root	1.20	for my $name (@Linux::Inotify2::EXPORT) {
439	root	1.1	my $mask = &{"Linux::Inotify2::$name"};
440
441	root	1.24	*$name = sub { $_[0]{mask} & $mask };
442	root	1.1	}
443
444			=head2 The Linux::Inotify2::Watch Class
445
446	root	1.24	Watcher objects are created by calling the C<watch> method of a notifier.
447	root	1.1
448			It has the following members and methods:
449
450	root	1.14	=over 4
451
452	root	1.1	=item $watch->name
453
454			=item $watch->{name}
455
456			The name as specified in the C<watch> call. For the object itself, this is
457			the empty string. For directory watches, this is the name of the entry
458			without leading path elements.
459
460			=item $watch->mask
461
462			=item $watch->{mask}
463
464			The mask as specified in the C<watch> call.
465
466			=item $watch->cb ([new callback])
467
468			=item $watch->{cb}
469
470			The callback as specified in the C<watch> call. Can optionally be changed.
471
472			=item $watch->cancel
473
474	root	1.24	Cancels/removes this watcher. Future events, even if already queued queued,
475	root	1.1	will not be handled and resources will be freed.
476
477	root	1.14	=back
478
479	root	1.1	=cut
480
481			package Linux::Inotify2::Watch;
482
483			sub name { $_[0]{name} }
484			sub mask { $_[0]{mask} }
485
486			sub cb {
487			$_[0]{cb} = $_[1] if @_ > 1;
488			$_[0]{cb}
489			}
490
491			sub cancel {
492			my ($self) = @_;
493
494	root	1.4	my $inotify = delete $self->{inotify}
495			or return 1; # already canceled
496
497			delete $inotify->{w}{$self->{wd}}; # we are no longer there
498			$inotify->{ignore}{$self->{wd}} = 1; # ignore further events for one poll
499
500			(Linux::Inotify2::inotify_rm_watch $inotify->{fd}, $self->{wd})
501	root	1.1	? 1 : undef
502			}
503
504			=head1 SEE ALSO
505
506	root	1.19	L<AnyEvent>, L<Linux::Inotify>.
507	root	1.1
508			=head1 AUTHOR
509
510			Marc Lehmann <schmorp@schmorp.de>
511			http://home.schmorp.de/
512
513			=cut
514
515			1