Net-Knuddels/Net/Knuddels.pm

=head1 NAME

Net::Knuddels - www.knuddels.de protocol implementation.

=head1 SYNOPSIS

 use Net::Knuddels;

=head1 DESCRIPTION

RTSL.

=cut

package Net::Knuddels;

use Net::Knuddels::Dictionary;

use strict;
use utf8;

use Carp;
use Math::BigInt;

sub _to32($) {
   unpack "l", pack "L", (new Math::BigInt $_[0]) & 0xffffffff
}

sub hash_pw($$) {
   my ($challenge, $pw) = @_;

   my $l1 = length $pw;
   my $l2 = length $challenge;

   my $k = chr ($l1 ^ ($l2 << 4));

   my $l = $l1 < $l2 ? $l2 : $l1;

   my $xor = substr +($pw x 100) ^ ($challenge x 100) ^ ($k x 100), 0, $l;

   my ($i, $j);

   --$l;

   if ($l <= 17) {
      for (0 .. $l) {
         $i = _to32 $i * 3 + ord substr $xor, $l - $_;
         $j = _to32 $j * 5 + ord substr $xor, $_;
      }
   } else {
      for ($_ = $l; $_ >= 0; $_ -= int $_/19) {
         $i = _to32 $i * 5 + ord substr $xor, $_;
         $j = _to32 $j * 3 + ord substr $xor, $l - $_;
      }
   }

   $i ^= $j;
   _to32 (($i & 0xffffff) ^ ($i >> 24))
}

my $RE_dec = join "|", keys %$Net::Knuddels::Dictionary;

sub decode {
   my $bin = unpack "b*", $_[0];
   my $res = "";

   while ($bin =~ /\G($RE_dec)/cog) {
      my $frag = $Net::Knuddels::Dictionary->{$1};
      $frag = chr unpack "v", pack "b*", $bin =~ /\G(.{16})/cg && $1 if $frag eq "\\\\\\";
      $res .= $frag;
   }
   $bin =~ /\G(.*[^0].*)$/ and die "Net::Knuddels::Receiver: undecodable message tail '$1'";

   $res
}

my %encode = reverse %$Net::Knuddels::Dictionary;

my $RE_enc = join "|", map quotemeta, sort { (length $b) <=> (length $a) } keys %encode;

sub encode($) {
   my ($msg) = @_;

   my $data = "";

   while () {
      $data .= $encode{$1} while $msg =~ /\G($RE_enc)/cog;

      $msg =~ /\G./csog
         or last;

      $data .= $encode{"\\\\\\"} . unpack "b*", pack "v", ord $1;
   }

   pack "b*", $data
}

=head2 CLASS Net::Knuddels::Protocol

You B<must> call the C<destroy> method of this class when you no longer
use it, as circular references will keep the object alive otherwise.

=over 4

=cut

package Net::Knuddels::Protocol;

=item new

Create a new C<Net::Knuddels::Protocol> object.

=cut

sub new {
   my $class = shift;

   my %data;

   my $self = bless {
      @_
   }, $class;

   $self;
}

=item $protocol->feed_data ($octets)

Feed raw protocol data into the decoder.

=cut

sub feed_data($$) {
   my ($self, $data) = @_;

   # split data stream into packets

   $data = "$self->{rbuf}$data";

   while () {
      1 <= length $data or last;
      my $len = ord substr $data, 0, 1;

      my $skip;
      if ($len & 0x80) {
         my $tail = (($len >> 5) & 3) - 1;
         $len = ($len & 0x1f) + 1;

         $tail < length $data or last;
         $len += (ord substr $data, $_ + 1, 1) << ($_ * 8 + 5)
            for 0 .. $tail;

         $skip = 2 + $tail;
      } else {
         $skip = 1;
         $len++;
      }

      $len + $skip <= length $data or last;
      substr $data, 0, $skip, "";
      my $msg = substr $data, 0, $len, "";

      $self->feed_msg ($msg);
   }

   $self->{rbuf} = $data;
}

sub feed_msg($$) {
   my ($self, $msg) = @_;

   $self->feed_event (split /\0/, Net::Knuddels::decode $msg);
}

sub feed_event($@) {
   my ($self, @cmd) = @_;

   my $ev = $self->{cb}{ALL};
   $_->(@cmd) for values %$ev;

   unless ($self->{cb}{$cmd[0]}) {
      my $ev = $self->{cb}{UNHANDLED};
      $_->(@cmd) for values %$ev;
   }

   my $ev = $self->{cb}{shift @cmd};
   $_->(@cmd) for values %$ev;
}

=item $msg = $protocol->encode_msg (@strings)

Join the strings with C<\0>, encode the result into a protocol packet and
return it.

=cut

sub encode_msg($@) {
   my ($self, @args) = @_;
   my $msg = Net::Knuddels::encode join "\0", @args;
   my $len = (length $msg) - 1;

   if ($len < 0x80) {
      (chr $len) . $msg
   } else {
      (chr 0x80 | 0x40 | ($len & 0x1f))
      . (chr +($len >>  5) % 0xff)
      . (chr +($len >> 13) % 0xff)
      . $msg
   }
}

=item $protocol->register ($type => $callback)

Register a callback for events of type C<$type>, which is either the name
of a low-level event sent by the server (such as "k" for dialog box) or
the name of a generated event, such as C<login>.

=cut

sub register {
   my ($self, $type, $cb) = @_;

   $self->{cb}{$type}{$cb} = $cb;
}

=item $protocol->destroy

I<MUST> be called to destroy the object, otherwise it will leak (no automatic cleanup).

=cut

sub destroy {
   my ($self) = @_;

   delete $self->{cb};
}

=back

=head2 CLASS Net::Knuddels::Client

Implement a Knuddels client connection.

=over 4

=cut

package Net::Knuddels::Client;

sub handle_room {
  my ($self, $room) = @_;

  if ($room eq "-") {
    if (defined $self->{only_room}) {
      return $self->{only_room};
    } else {
      warn "Couldn't assign '-' room to a room!";
      return '-';
    }
  } else {
    return $room;
  }
}

sub calc_user_stats {
  my ($self, $user) = @_;

  if ($user->{name} =~ s/\cJ(\d+)$//) {
    $user->{age} = $1 
  }

  if ($user->{picture} =~ m/\bmale/) {
    $user->{gender} = 'm'; 
  } elsif ($user->{picture} =~ m/female/) {
    $user->{gender} = 'f';
  }
  return $user;
}

=item new Net::Knuddels::Client [IO::Socket::new arguments]

Create a new client connection.

=cut

use IO::Socket::INET;

sub new {
   my ($class, @arg) = @_;

   my $fh = new IO::Socket::INET @arg
     or Carp::croak "Net::Knuddels::Client::new: $!";

   my $self = bless {
      fh    => $fh,
      proto => (new Net::Knuddels::Protocol),
   }, $class;

   syswrite $fh, "\0";

   $self->register ("(" => sub {
      $self->{login_challenge} = $_[0];
      $self->{login_room}      = $_[1];
      $self->{proto}->feed_event ("login");
   });
   $self->register (r => sub {
      $self->{proto}->feed_event (msg_priv => $self->handle_room ($_[2]), $_[0], $_[1], $_[3]);
   });
   $self->register (e => sub {
      $self->{proto}->feed_event (msg_room => $self->handle_room ($_[1]), $_[0], $_[2]);
   });
   $self->register (l => sub {
      my $room = $self->handle_room ($_[0]);
      return if $room eq "-"; # things that shouln't happen

      my $user = {
        name => $_[1],
        flag => $_[2],
        color => $_[3],
        picture => $_[4]
      };

      $self->calc_user_stats ($user);

      my $rl = $self->{user_lists}->{lc $room}->{lc $user->{name}} = $user;
      
      $self->{proto}->feed_event (join_room => $room, $user);
   });
   $self->register (w => sub {
      my $room = $self->handle_room ($_[1]);
      return if $room eq "-"; # things that shouln't happen

      my $username = $_[0];

      my $u = delete $self->{user_lists}->{lc $room}->{lc $username};

      if (not defined $u) {
        warn "User $username wasn't in room $room, trying to fix... but be careful!!!\n";
        $u = { name => $username };
      }

      $self->{proto}->feed_event (part_room => $room, $u);
   });
   $self->register (a => sub {
      # the only_room stuff is from java-code, which has naughy semantics
      if (not defined $self->{only_room}) {
        $self->{only_room} = $_[0];
      } else {
        $self->{only_room} = "-";
      }

      $self->{my_nick} = $_[1]; # i'm really _not_ shure about this

      my $ri = $self->{room}->{lc $_[0]} = { 
        picture => $_[7],
      };

      $self->{proto}->feed_event (room_info => $_[0], $ri);
   });
   $self->register (u => sub {
      my $room = shift;
      my $rl = $self->{user_lists}->{lc $room} = {};
      my $cur_u = {};

      while (@_) {
        $cur_u->{name} = shift;
        $cur_u->{flag} = shift;
        $cur_u->{color} = shift;
        
        my $i = 0;

        while ((my $nxt = shift) ne "-") {
          if ($i == 0) {
            $cur_u->{picture} = $nxt;
          }
          $i++;
        }

        $self->calc_user_stats ($cur_u);
        $rl->{lc $cur_u->{name}} = $cur_u;
        $cur_u = {};
      }
      $self->{proto}->feed_event (user_list => $room, $rl);
   });

   $self
}

=item $client->fh

Return the fh used for communications. You are responsible for calling C<<
$client->ready >> whenever the fh becomes ready for reading.

=cut

sub fh {
   $_[0]->{fh}
}

=item $client->ready

To be called then the filehandle is ready for reading. Returns false if
the server closed the connection, true otherwise.

=cut

sub ready {
   my ($self) = @_;

   sysread $self->{fh}, my $buf, 8192
      or return;

   $self->{proto}->feed_data ($buf);

   1;
}

=item $client->command ($type => @args)

Send a message of type C<$type> and the given arguments to the server.

=cut

sub command {
   my ($self, $type, @args) = @_;

   #use Dumpvalue; Dumpvalue->new (compactDump => 1, veryCompact => 1, quoteHighBit => 1, tick => '"')->dumpValue ([$type, @args]);

   syswrite $self->{fh}, $self->{proto}->encode_msg ($type, @args);
}

=item $client->login ($url, $unknown)

Send a 't' message. The default for C<$url> is
C<http://www.knuddels.de/applet.html?v=86a&c=0> and C<$unknown> is C<6>.

=cut

sub login {
   my ($self, $url, $unknown) = @_;

   $self->command ("t", "V8.6a", $url || "http://www.knuddels.de/applet.html?v=86a&c=0", $unknown || 3);
}

=item $client->set_nick ($room, $nick, $password)

Registers the nick with the given password.

=cut

sub set_nick {
   my ($self, $room, $nick, $password) = @_;

   exists $self->{login_challenge} or Carp::croak "set_nick can only be called after a login event";

   $self->command ("n", $room, $nick, Net::Knuddels::hash_pw $self->{login_challenge}, $password);
}

=item $client->register ($type => $cb)

See L<Net::Knuddels::Protocol::register>. The following extra events will
be generated by this class:

   login
      set_nick can only be called _after_ a login event has occured.

   msg_room => $room, $user, $msg
      produced when a public message is uttered :)

   msg_room => $room, $src, $dst, $msg
      personal message from $src to $dst

   user_list => $room, $list
      the userlist of a channel named $room, a elmement of the list (a user)
      looks like: 
         {
           name => <name>, 
           flag => <some flag i don't know what it means>, 
           color => like /\d+.\d+.\d+/,
           age   => /\d+/,
           gender => /(f|m)/, 
           picture => <the picture file to put behind the nick> 
         }

   room_info => $room, $room_info
      some information about the $room:
      $room_info =
      {
         picture => <some picturefile>
      }

   join_room => $room, $user
      join message of $user joined the room $room
      $user contains the user structure (see user_list).
      
   part_room => $room, $user
      part message of $user who left the room $room
      $user contains the user structure (see user_list).
=cut

sub register {
   my ($self, $type, $cb) = @_;

   $self->{proto}->register ($type, $cb);
}

=back

=head1 AUTHOR

 Marc Lehmann <pcg@goof.com>
 http://home.schmorp.de/
  
=cut

1;

Revision:	1.16
Committed:	Thu Jan 13 18:50:36 2005 UTC (19 years, 4 months ago) by root
Branch:	MAIN
Changes since 1.15:	+155 -156 lines
Log Message:	* empty log message *
#	User	Rev	Content
1	root	1.8	=head1 NAME
2
3			Net::Knuddels - www.knuddels.de protocol implementation.
4
5			=head1 SYNOPSIS
6
7			use Net::Knuddels;
8
9			=head1 DESCRIPTION
10
11			RTSL.
12
13			=cut
14
15	root	1.1	package Net::Knuddels;
16
17	root	1.3	use Net::Knuddels::Dictionary;
18
19	root	1.2	use strict;
20			use utf8;
21
22	root	1.4	use Carp;
23			use Math::BigInt;
24
25	root	1.14	sub _to32($) {
26			unpack "l", pack "L", (new Math::BigInt $_[0]) & 0xffffffff
27			}
28
29	root	1.4	sub hash_pw($$) {
30			my ($challenge, $pw) = @_;
31
32			my $l1 = length $pw;
33			my $l2 = length $challenge;
34
35			my $k = chr ($l1 ^ ($l2 << 4));
36
37			my $l = $l1 < $l2 ? $l2 : $l1;
38
39			my $xor = substr +($pw x 100) ^ ($challenge x 100) ^ ($k x 100), 0, $l;
40
41			my ($i, $j);
42
43			--$l;
44
45			if ($l <= 17) {
46			for (0 .. $l) {
47	root	1.14	$i = _to32 $i * 3 + ord substr $xor, $l - $_;
48			$j = _to32 $j * 5 + ord substr $xor, $_;
49	root	1.4	}
50			} else {
51			for ($_ = $l; $_ >= 0; $_ -= int $_/19) {
52	root	1.14	$i = _to32 $i * 5 + ord substr $xor, $_;
53			$j = _to32 $j * 3 + ord substr $xor, $l - $_;
54	root	1.4	}
55			}
56
57			$i ^= $j;
58	root	1.14	_to32 (($i & 0xffffff) ^ ($i >> 24))
59	root	1.4	}
60
61	root	1.10	my $RE_dec = join "\|", keys %$Net::Knuddels::Dictionary;
62
63			sub decode {
64			my $bin = unpack "b*", $_[0];
65			my $res = "";
66
67			while ($bin =~ /\G($RE_dec)/cog) {
68			my $frag = $Net::Knuddels::Dictionary->{$1};
69	root	1.14	$frag = chr unpack "v", pack "b*", $bin =~ /\G(.{16})/cg && $1 if $frag eq "\\\\\\";
70	root	1.10	$res .= $frag;
71			}
72			$bin =~ /\G(.[^0].)$/ and die "Net::Knuddels::Receiver: undecodable message tail '$1'";
73
74			$res
75			}
76
77	root	1.9	my %encode = reverse %$Net::Knuddels::Dictionary;
78
79	root	1.10	my $RE_enc = join "\|", map quotemeta, sort { (length $b) <=> (length $a) } keys %encode;
80	root	1.9
81	root	1.10	sub encode($) {
82	root	1.9	my ($msg) = @_;
83
84			my $data = "";
85
86			while () {
87			$data .= $encode{$1} while $msg =~ /\G($RE_enc)/cog;
88
89			$msg =~ /\G./csog
90			or last;
91
92			$data .= $encode{"\\\\\\"} . unpack "b*", pack "v", ord $1;
93			}
94
95			pack "b*", $data
96			}
97
98	root	1.5	=head2 CLASS Net::Knuddels::Protocol
99
100			You B<must> call the C<destroy> method of this class when you no longer
101			use it, as circular references will keep the object alive otherwise.
102
103	root	1.6	=over 4
104
105	root	1.8	=cut
106
107			package Net::Knuddels::Protocol;
108
109	root	1.6	=item new
110
111			Create a new C<Net::Knuddels::Protocol> object.
112
113	root	1.5	=cut
114	root	1.2
115			sub new {
116			my $class = shift;
117
118	root	1.4	my %data;
119
120			my $self = bless {
121			@_
122			}, $class;
123
124			$self;
125	root	1.2	}
126
127	root	1.6	=item $protocol->feed_data ($octets)
128
129			Feed raw protocol data into the decoder.
130
131			=cut
132
133	root	1.2	sub feed_data($$) {
134			my ($self, $data) = @_;
135
136			# split data stream into packets
137
138			$data = "$self->{rbuf}$data";
139
140			while () {
141			1 <= length $data or last;
142			my $len = ord substr $data, 0, 1;
143
144			my $skip;
145			if ($len & 0x80) {
146			my $tail = (($len >> 5) & 3) - 1;
147			$len = ($len & 0x1f) + 1;
148
149			$tail < length $data or last;
150			$len += (ord substr $data, $_ + 1, 1) << ($_ * 8 + 5)
151			for 0 .. $tail;
152
153			$skip = 2 + $tail;
154			} else {
155			$skip = 1;
156			$len++;
157			}
158
159			$len + $skip <= length $data or last;
160			substr $data, 0, $skip, "";
161			my $msg = substr $data, 0, $len, "";
162
163			$self->feed_msg ($msg);
164			}
165
166			$self->{rbuf} = $data;
167			}
168
169			sub feed_msg($$) {
170			my ($self, $msg) = @_;
171	root	1.1
172	root	1.10	$self->feed_event (split /\0/, Net::Knuddels::decode $msg);
173	root	1.1	}
174
175	root	1.2	sub feed_event($@) {
176	root	1.14	my ($self, @cmd) = @_;
177	root	1.1
178	root	1.14	my $ev = $self->{cb}{ALL};
179			$_->(@cmd) for values %$ev;
180
181			unless ($self->{cb}{$cmd[0]}) {
182			my $ev = $self->{cb}{UNHANDLED};
183			$_->(@cmd) for values %$ev;
184	root	1.1	}
185	root	1.14
186			my $ev = $self->{cb}{shift @cmd};
187			$_->(@cmd) for values %$ev;
188	root	1.2	}
189	root	1.1
190	root	1.11	=item $msg = $protocol->encode_msg (@strings)
191
192			Join the strings with C<\0>, encode the result into a protocol packet and
193			return it.
194
195			=cut
196
197			sub encode_msg($@) {
198			my ($self, @args) = @_;
199			my $msg = Net::Knuddels::encode join "\0", @args;
200	root	1.12	my $len = (length $msg) - 1;
201
202			if ($len < 0x80) {
203			(chr $len) . $msg
204			} else {
205			(chr 0x80 \| 0x40 \| ($len & 0x1f))
206			. (chr +($len >> 5) % 0xff)
207			. (chr +($len >> 13) % 0xff)
208			. $msg
209			}
210	root	1.11	}
211
212	root	1.6	=item $protocol->register ($type => $callback)
213
214			Register a callback for events of type C<$type>, which is either the name
215			of a low-level event sent by the server (such as "k" for dialog box) or
216	root	1.16	the name of a generated event, such as C<login>.
217	root	1.6
218			=cut
219
220	root	1.2	sub register {
221			my ($self, $type, $cb) = @_;
222	root	1.1
223	root	1.2	$self->{cb}{$type}{$cb} = $cb;
224	root	1.1	}
225
226	root	1.8	=item $protocol->destroy
227
228	root	1.9	I<MUST> be called to destroy the object, otherwise it will leak (no automatic cleanup).
229	root	1.8
230			=cut
231
232	root	1.5	sub destroy {
233			my ($self) = @_;
234
235			delete $self->{cb};
236			}
237
238	root	1.6	=back
239
240	root	1.8	=head2 CLASS Net::Knuddels::Client
241
242	root	1.9	Implement a Knuddels client connection.
243
244	root	1.8	=over 4
245
246			=cut
247
248			package Net::Knuddels::Client;
249
250	root	1.16	sub handle_room {
251			my ($self, $room) = @_;
252
253			if ($room eq "-") {
254			if (defined $self->{only_room}) {
255			return $self->{only_room};
256			} else {
257			warn "Couldn't assign '-' room to a room!";
258			return '-';
259			}
260			} else {
261			return $room;
262			}
263			}
264
265			sub calc_user_stats {
266			my ($self, $user) = @_;
267
268			if ($user->{name} =~ s/\cJ(\d+)$//) {
269			$user->{age} = $1
270			}
271
272			if ($user->{picture} =~ m/\bmale/) {
273			$user->{gender} = 'm';
274			} elsif ($user->{picture} =~ m/female/) {
275			$user->{gender} = 'f';
276			}
277			return $user;
278			}
279
280	root	1.9	=item new Net::Knuddels::Client [IO::Socket::new arguments]
281
282			Create a new client connection.
283
284			=cut
285
286			use IO::Socket::INET;
287
288			sub new {
289			my ($class, @arg) = @_;
290
291			my $fh = new IO::Socket::INET @arg
292			or Carp::croak "Net::Knuddels::Client::new: $!";
293
294			my $self = bless {
295			fh => $fh,
296			proto => (new Net::Knuddels::Protocol),
297			}, $class;
298
299			syswrite $fh, "\0";
300
301	root	1.16	$self->register ("(" => sub {
302			$self->{login_challenge} = $_[0];
303			$self->{login_room} = $_[1];
304			$self->{proto}->feed_event ("login");
305			});
306			$self->register (r => sub {
307			$self->{proto}->feed_event (msg_priv => $self->handle_room ($_[2]), $_[0], $_[1], $_[3]);
308			});
309			$self->register (e => sub {
310			$self->{proto}->feed_event (msg_room => $self->handle_room ($_[1]), $_[0], $_[2]);
311			});
312			$self->register (l => sub {
313			my $room = $self->handle_room ($_[0]);
314			return if $room eq "-"; # things that shouln't happen
315
316			my $user = {
317			name => $_[1],
318			flag => $_[2],
319			color => $_[3],
320			picture => $_[4]
321			};
322
323			$self->calc_user_stats ($user);
324
325			my $rl = $self->{user_lists}->{lc $room}->{lc $user->{name}} = $user;
326
327			$self->{proto}->feed_event (join_room => $room, $user);
328			});
329			$self->register (w => sub {
330			my $room = $self->handle_room ($_[1]);
331			return if $room eq "-"; # things that shouln't happen
332
333			my $username = $_[0];
334
335			my $u = delete $self->{user_lists}->{lc $room}->{lc $username};
336
337			if (not defined $u) {
338			warn "User $username wasn't in room $room, trying to fix... but be careful!!!\n";
339			$u = { name => $username };
340			}
341
342			$self->{proto}->feed_event (part_room => $room, $u);
343			});
344			$self->register (a => sub {
345			# the only_room stuff is from java-code, which has naughy semantics
346			if (not defined $self->{only_room}) {
347			$self->{only_room} = $_[0];
348			} else {
349			$self->{only_room} = "-";
350			}
351
352			$self->{my_nick} = $_[1]; # i'm really _not_ shure about this
353
354			my $ri = $self->{room}->{lc $_[0]} = {
355			picture => $_[7],
356			};
357
358			$self->{proto}->feed_event (room_info => $_[0], $ri);
359			});
360			$self->register (u => sub {
361			my $room = shift;
362			my $rl = $self->{user_lists}->{lc $room} = {};
363			my $cur_u = {};
364
365			while (@_) {
366			$cur_u->{name} = shift;
367			$cur_u->{flag} = shift;
368			$cur_u->{color} = shift;
369
370			my $i = 0;
371
372			while ((my $nxt = shift) ne "-") {
373			if ($i == 0) {
374			$cur_u->{picture} = $nxt;
375			}
376			$i++;
377			}
378
379			$self->calc_user_stats ($cur_u);
380			$rl->{lc $cur_u->{name}} = $cur_u;
381			$cur_u = {};
382			}
383			$self->{proto}->feed_event (user_list => $room, $rl);
384			});
385
386	root	1.9	$self
387			}
388
389			=item $client->fh
390
391			Return the fh used for communications. You are responsible for calling C<<
392	root	1.13	$client->ready >> whenever the fh becomes ready for reading.
393	root	1.9
394			=cut
395
396			sub fh {
397			$_[0]->{fh}
398			}
399
400	root	1.13	=item $client->ready
401
402			To be called then the filehandle is ready for reading. Returns false if
403			the server closed the connection, true otherwise.
404
405			=cut
406
407			sub ready {
408			my ($self) = @_;
409
410			sysread $self->{fh}, my $buf, 8192
411			or return;
412
413			$self->{proto}->feed_data ($buf);
414
415			1;
416			}
417
418	root	1.9	=item $client->command ($type => @args)
419
420			Send a message of type C<$type> and the given arguments to the server.
421
422			=cut
423
424			sub command {
425			my ($self, $type, @args) = @_;
426
427	root	1.14	#use Dumpvalue; Dumpvalue->new (compactDump => 1, veryCompact => 1, quoteHighBit => 1, tick => '"')->dumpValue ([$type, @args]);
428	root	1.13
429			syswrite $self->{fh}, $self->{proto}->encode_msg ($type, @args);
430	root	1.9	}
431
432			=item $client->login ($url, $unknown)
433
434			Send a 't' message. The default for C<$url> is
435			C<http://www.knuddels.de/applet.html?v=86a&c=0> and C<$unknown> is C<6>.
436
437			=cut
438
439			sub login {
440	root	1.13	my ($self, $url, $unknown) = @_;
441
442			$self->command ("t", "V8.6a", $url \|\| "http://www.knuddels.de/applet.html?v=86a&c=0", $unknown \|\| 3);
443			}
444
445			=item $client->set_nick ($room, $nick, $password)
446
447			Registers the nick with the given password.
448
449			=cut
450
451			sub set_nick {
452			my ($self, $room, $nick, $password) = @_;
453
454	root	1.16	exists $self->{login_challenge} or Carp::croak "set_nick can only be called after a login event";
455	root	1.13
456	root	1.16	$self->command ("n", $room, $nick, Net::Knuddels::hash_pw $self->{login_challenge}, $password);
457	root	1.9	}
458
459			=item $client->register ($type => $cb)
460
461	root	1.16	See L<Net::Knuddels::Protocol::register>. The following extra events will
462			be generated by this class:
463	root	1.9
464	root	1.16	login
465			set_nick can only be called _after_ a login event has occured.
466
467			msg_room => $room, $user, $msg
468			produced when a public message is uttered :)
469
470			msg_room => $room, $src, $dst, $msg
471			personal message from $src to $dst
472
473			user_list => $room, $list
474			the userlist of a channel named $room, a elmement of the list (a user)
475			looks like:
476			{
477			name => <name>,
478			flag => <some flag i don't know what it means>,
479			color => like /\d+.\d+.\d+/,
480			age => /\d+/,
481			gender => /(f\|m)/,
482			picture => <the picture file to put behind the nick>
483			}
484
485			room_info => $room, $room_info
486			some information about the $room:
487			$room_info =
488			{
489			picture => <some picturefile>
490			}
491
492			join_room => $room, $user
493			join message of $user joined the room $room
494			$user contains the user structure (see user_list).
495
496			part_room => $room, $user
497			part message of $user who left the room $room
498			$user contains the user structure (see user_list).
499	root	1.9	=cut
500
501			sub register {
502			my ($self, $type, $cb) = @_;
503
504	root	1.13	$self->{proto}->register ($type, $cb);
505	root	1.9	}
506
507	root	1.8	=back
508
509			=head1 AUTHOR
510
511			Marc Lehmann <pcg@goof.com>
512			http://home.schmorp.de/
513
514	root	1.6	=cut
515
516	root	1.2	1;
517