Deliantra-Client/DC/MapWidget.pm

package CFClient::MapWidget;

use strict;
use utf8;

use List::Util qw(min max);

use CFClient::OpenGL;

our @ISA = CFClient::UI::Base::;

sub new {
   my $class = shift;

   my $self = $class->SUPER::new (
      z         => -1,
      can_focus => 1,
      list      => glGenList,

      smooth_matrix => [
         0.05, 0.13, 0.05,
         0.13, 0.30, 0.13,
         0.05, 0.13, 0.05,
      ],

      @_
   );

   $self->{completer} = new CFClient::MapWidget::Command::
      command   => $self->{command},
      can_focus => 1,
      tooltip   => "<b>The Command Completer</b>\n\n"
                 . "This is your central interface to send text commands to the server. "
                 . "To enter a verbatim command to send to the server, just type the command, "
                 . "followed by a space, and press return. "
                 . "Typing the initial letters of words (or just any letters) displays guesses "
                 . "for commands you might want to use.\n"
                 . "You can use the cursor-up and cursor-down keys to select between those guesses.\n"
                 . "<b>Right-Click</b> opens a menu where you cna select further options, sich as redefining keybindings.",
   ;

   $self
}

sub add_command {
   my ($self, $command, $tooltip, $widget, $cb) = @_;

   (my $data = $command) =~ s/\\//g;

   $tooltip =~ s/^\s+//;
   $tooltip = "<big>$data</big>\n\n$tooltip";
   $tooltip =~ s/\s+$//;

   $self->{completer}{command}{$command} = [$data, $tooltip, $widget, $cb, ++$self->{command_id}];
}

sub clr_commands {
   my ($self) = @_;

   %{$self->{completer}{command}} = ();
}

sub button_down {
   my ($self, $ev, $x, $y) = @_;

   $self->focus_in;

   if ($ev->{button} == 1) {
      my $x = int +($ev->{x} - $::CFG->{map_shift_x}) / (32 * $::CFG->{map_scale});
      my $y = int +($ev->{y} - $::CFG->{map_shift_y}) / (32 * $::CFG->{map_scale});
      
      $x += int 0.5 * ($::MAP->w - $self->{sw} - 1);
      $y += int 0.5 * ($::MAP->h - $self->{sh} - 1);

      $x -= int 0.5 * $::MAP->w;
      $y -= int 0.5 * $::MAP->h;

      $x += 1;
      $y += 1;

      $::CONN->lookat ($x, $y)
         if $::CONN;

   } elsif ($ev->{button} == 2) {
      my ($ox, $oy) = ($ev->{x}, $ev->{y});
      my ($bw, $bh) = ($::CFG->{map_shift_x}, $::CFG->{map_shift_y});

      $self->{motion} = sub {
         my ($ev, $x, $y) = @_;

         ($x, $y) = ($ev->{x}, $ev->{y});

         $::CFG->{map_shift_x} = $bw + $x - $ox;
         $::CFG->{map_shift_y} = $bh + $y - $oy;

         $self->update;
      };
   }

   1
}

sub button_up {
   my ($self, $ev, $x, $y) = @_;

   delete $self->{motion};

   1
}

sub mouse_motion {
   my ($self, $ev, $x, $y) = @_;

   if ($self->{motion}) {
      $self->{motion}->($ev, $x, $y);
   } else {
      return 0;
   }

   1
}

sub size_request {
   (
      1 + 32 * int $::WIDTH  / 32,
      1 + 32 * int $::HEIGHT / 32,
   )
}

sub update {
   my ($self) = @_;

   $self->{need_update} = 1;
   $self->SUPER::update;
}

my %DIR = (
   CFClient::SDLK_KP8, [1, "north"],
   CFClient::SDLK_KP9, [2, "northeast"],
   CFClient::SDLK_KP6, [3, "east"],
   CFClient::SDLK_KP3, [4, "southeast"],
   CFClient::SDLK_KP2, [5, "south"],
   CFClient::SDLK_KP1, [6, "southwest"],
   CFClient::SDLK_KP4, [7, "west"],
   CFClient::SDLK_KP7, [8, "northwest"],

   CFClient::SDLK_UP,    [1, "north"],
   CFClient::SDLK_RIGHT, [3, "east"],
   CFClient::SDLK_DOWN,  [5, "south"],
   CFClient::SDLK_LEFT,  [7, "west"],
);

sub key_down {
   my ($self, $ev) = @_;

   return 0 unless $::CONN;

   my $mod = $ev->{mod};
   my $sym = $ev->{sym};
   my $uni = $ev->{unicode};

   if ($sym == CFClient::SDLK_KP5) {
      $::CONN->user_send ("stay fire");
   } elsif ($uni == ord ",") {
      $::CONN->user_send ("take");
   } elsif ($uni == ord " ") {
      $::CONN->user_send ("apply");
   } elsif ($uni == ord ".") {
      $::CONN->user_send ($self->{completer}{last_command})
         if exists $self->{completer}{last_command};
   } elsif ($uni == ord "\t") {
      $::INV_WINDOW->toggle_visibility;
   } elsif ($sym == CFClient::SDLK_KP_PLUS  || $uni == ord "+") {
      $::CONN->user_send ("rotateshoottype +");
   } elsif ($sym == CFClient::SDLK_KP_MINUS || $uni == ord "-") {
      $::CONN->user_send ("rotateshoottype -");
   } elsif ($uni == ord '"') {
      $self->{completer}->set_prefix ("$::CFG->{say_command} ");
      $self->{completer}->show;
   } elsif ($uni == ord "'") {
      $self->{completer}->set_prefix ("");
      $self->{completer}->show;
   } elsif (exists $DIR{$sym}) {
      if ($mod & CFClient::KMOD_SHIFT) {
         $self->{shft}++;
         $::CONN->user_send ("fire $DIR{$sym}[0]");
      } elsif ($mod & CFClient::KMOD_CTRL) {
         $self->{ctrl}++;
         $::CONN->user_send ("run $DIR{$sym}[0]");
      } else {
         $::CONN->user_send ("$DIR{$sym}[1]");
      }
   } elsif ($sym == CFClient::SDLK_INSERT && $mod & CFClient::KMOD_CTRL) {
      $::BIND_EDITOR->set_binding (undef, undef, [],
         sub {
            my ($mod, $sym, $cmds) = @_;
            $::CFG->{bindings}->{$mod}->{$sym} = $cmds;
         });
      $::BIND_EDITOR->start;
      $::BIND_EDITOR->show;
   } elsif ($sym == CFClient::SDLK_INSERT && not ($mod & CFClient::KMOD_CTRL)) {
      $::BIND_EDITOR->stop;
      $::BIND_EDITOR->ask_for_bind_and_commit;
      $::BIND_EDITOR->hide;
   } elsif (my $bind_cmd = $::CFG->{bindings}->{$mod}->{$sym}) {
      $::CONN->user_send ($_) for @$bind_cmd;
   } elsif ((ord 'a') <= $uni && $uni <= (ord 'z')) {
      $self->{completer}->key_down ($ev);
      $self->{completer}->show;
   } else {
      return 0;
   }

   1
}

sub key_up {
   my ($self, $ev) = @_;

   my $res = 0;
   my $mod = $ev->{mod};
   my $sym = $ev->{sym};

   if (!($mod & CFClient::KMOD_SHIFT) && delete $self->{shft}) {
      $::CONN->user_send ("fire_stop");
      $res = 1;
   }

   if (!($mod & CFClient::KMOD_CTRL ) && delete $self->{ctrl}) {
      $::CONN->user_send ("run_stop");
      $res = 1;
   }

   $res
}

sub draw {
   my ($self) = @_;

   my $focused = $CFClient::UI::FOCUS == $self
                 || $CFClient::UI::FOCUS == $self->{completer}{entry};

   return
      unless $focused || !$::FAST;

   if (delete $self->{need_update}) {
      glNewList $self->{list};

      if ($::MAP) {
         my $sw = $self->{sw} = int $::WIDTH  / (32 * $::CFG->{map_scale}) + 0.99;
         my $sh = $self->{sh} = int $::HEIGHT / (32 * $::CFG->{map_scale}) + 0.99;

         my $sx = $::CFG->{map_shift_x} / $::CFG->{map_scale};
         my $sy = $::CFG->{map_shift_y} / $::CFG->{map_scale};
         my $sx0 = $self->{sx0} = ($sx & 31) - 32; $sx = $self->{sx} = ($sx - $sx0) / 32;
         my $sy0 = $self->{sy0} = ($sy & 31) - 32; $sy = $self->{sy} = ($sy - $sy0) / 32;

         glPushMatrix;
         glScale $::CFG->{map_scale}, $::CFG->{map_scale};

         glTranslate $sx0, $sy0;

         my ($w, $h, $data) = $::MAP->draw ($sx, $sy, 0, 0, $sw + 1, $sh + 1);

         if ($::CFG->{fow_enable}) {
            if ($::CFG->{fow_smooth} && $CFClient::OpenGL::GL_VERSION >= 1.2) { # smooth fog of war
               glConvolutionParameter (GL_CONVOLUTION_2D, GL_CONVOLUTION_BORDER_MODE, GL_CONSTANT_BORDER);
               glConvolutionFilter2D (
                  GL_CONVOLUTION_2D,
                  GL_ALPHA,
                  3, 3,
                  GL_ALPHA, GL_FLOAT,
                  (pack "f*", @{ $self->{smooth_matrix} }),
               );
               glEnable GL_CONVOLUTION_2D;
            }

            $self->{fow_texture_name} ||= glGenTexture;
            # try to re-use the texture name: TODO improve texture class instead

            $self->{fow_texture} = new CFClient::Texture
               w              => $w,
               h              => $h,
               data           => $data,
               name           => $self->{fow_texture_name},
               internalformat => GL_ALPHA,
               format         => GL_ALPHA;

            glDisable GL_CONVOLUTION_2D if $::CFG->{fow_smooth};

            glEnable GL_TEXTURE_2D;
            glTexEnv GL_TEXTURE_ENV, GL_TEXTURE_ENV_MODE, GL_MODULATE;

            glColor +($::CFG->{fow_intensity}) x 3, 0.8;
            $self->{fow_texture}->draw_quad_alpha (0, 0, $w * 32, $h * 32);

            glDisable GL_TEXTURE_2D;
         }

         glPopMatrix;
      }

      glEndList;
   }

   glPushMatrix;
   glCallList $self->{list};
   glPopMatrix;

   # TNT2 emulates logops in software (or worse :)
   if ($focused) {
      (delete $self->{out_of_focus})->destroy
         if $self->{out_of_focus};
   } else {
      glColor 0.4, 0.2, 0.2, 0.6;
      glEnable GL_BLEND;
      glBlendFunc GL_SRC_ALPHA, GL_ONE_MINUS_SRC_ALPHA;
      glBegin GL_QUADS;
      glVertex 0, 0;
      glVertex 0, $::HEIGHT;
      glVertex $::WIDTH, $::HEIGHT;
      glVertex $::WIDTH, 0;
      glEnd;
      glDisable GL_BLEND;

#      $self->{out_of_focus} ||= do {
#         my $label = new CFClient::UI::Label
#            x         => 0,
#            y         => 0,
#            z         => 1,
#            ellipsise => 0,
#            text      => "map out of focus (click map to play)";
#
#         $label->show;
#         $label->update;
#
#         $CFClient::UI::ROOT->on_post_alloc ("$self$label" => sub {
#            $label->move_abs (
#               ($::WIDTH  - $label->{w}) * 0.5,
#               ($::HEIGHT - $label->{h}) * 0.5,
#            );
#         });
#
#         $label
#      };
   }
}

sub DESTROY {
   my $self = shift;

   glDeleteList $self->{list};

   $self->SUPER::DESTROY;
}

package CFClient::MapWidget::MapMap;

our @ISA = CFClient::UI::Base::;

use Time::HiRes qw(time);
use CFClient::OpenGL;

sub size_request {
   ($::HEIGHT * 0.25, $::HEIGHT * 0.25)
}

sub size_allocate {
   my ($self, $w, $h) = @_;

   $self->SUPER::size_allocate ($w, $h);
   $self->update;
}

sub update {
   my ($self) = @_;

   delete $self->{texture_atime};
   $self->SUPER::update;
}

sub _draw {
   my ($self) = @_;

   $::MAP or return;

   my ($w, $h) = @$self{qw(w h)};

   my $sw = int $::WIDTH  / (32 * $::CFG->{map_scale}) + 0.99;
   my $sh = int $::HEIGHT / (32 * $::CFG->{map_scale}) + 0.99;

   my $sx = int $::CFG->{map_shift_x} / 32;
   my $sy = int $::CFG->{map_shift_y} / 32;

   my $ox = 0.5 * ($w - $sw);
   my $oy = 0.5 * ($h - $sh);

   glEnable GL_BLEND;
   glBlendFunc GL_SRC_ALPHA, GL_ONE_MINUS_SRC_ALPHA;
   glEnable GL_TEXTURE_2D;
   glTexEnv GL_TEXTURE_ENV, GL_TEXTURE_ENV_MODE, GL_REPLACE;

   if ($self->{texture_atime} < time) {
      $self->{texture_atime} = time + 1/3;

      $self->{texture} =
         new CFClient::Texture
            w    => $w,
            h    => $h,
            data => $::MAP->mapmap (-$ox, -$oy, $w, $h),
            type => $CFClient::GL_VERSION >= 1.2 ? GL_UNSIGNED_INT_8_8_8_8_REV : GL_UNSIGNED_BYTE;
   }

   $self->{texture}->draw_quad (0, 0);

   glDisable GL_TEXTURE_2D;

   glTranslate 0.375, 0.375;

   #TODO: map scale is completely borked

   my $x0 = int $ox - $sx + 0.5;
   my $y0 = int $oy - $sy + 0.5;

   glColor 1, 1, 0, 1;
   glBegin GL_LINE_LOOP;
   glVertex $x0      , $y0      ;
   glVertex $x0      , $y0 + $sh;
   glVertex $x0 + $sw, $y0 + $sh;
   glVertex $x0 + $sw, $y0      ;
   glEnd;
   
   glDisable GL_BLEND;
}

package CFClient::MapWidget::Command;

use strict;

use CFClient::OpenGL;

our @ISA = CFClient::UI::Frame::;

sub new {
   my $class = shift;

   my $self = $class->SUPER::new (
      bg => [0, 0, 0, 0.8],
      @_,
   );

   $self->add ($self->{vbox} = new CFClient::UI::VBox);

   $self->{label} = [
      map
         CFClient::UI::Label->new (
            can_hover     => 1,
            can_events    => 1,
            tooltip_width => 0.33,
            fontsize      => $_,
         ), (0.8) x 16
   ];

   $self->{entry} = new CFClient::UI::Entry
      on_changed => sub {
         $self->update_labels;
      },
      on_button_down => sub {
         my ($entry, $ev, $x, $y) = @_;

         if ($ev->{button} == 3) {
            (new CFClient::UI::Menu
               items => [
                  ["bind to a key" => sub { $::BIND_EDITOR->do_quick_binding ([$self->{select}], sub { $entry->focus_in }) }]
               ],
            )->popup ($ev);
            return 1;
         }
         0
      },
      on_key_down => sub {
         my ($entry, $ev) = @_;

         my $self = $entry->{parent}{parent};

         if ($ev->{sym} == 13) {
            if (exists $self->{select}) {
               $self->{last_command} = $self->{select};
               $::CONN->user_send ($self->{select});

               unshift @{$self->{history}}, $self->{select};
               $self->{hist_ptr} = 0;

               $self->hide;
            }
         } elsif ($ev->{sym} == 27) {
            $self->{hist_ptr} = 0;
            $self->hide;
            return;
         } elsif ($ev->{sym} == CFClient::SDLK_DOWN) {
            if ($self->{hist_ptr} > 1) {
               $self->{hist_ptr}--;
               $self->{entry}->set_text ($self->{history}->[$self->{hist_ptr} - 1]);
            } elsif ($self->{hist_ptr} > 0) {
               $self->{hist_ptr}--;
               $self->{entry}->set_text ($self->{hist_saveback});
            } else {
               ++$self->{select_offset}
                  if $self->{select_offset} < $#{ $self->{last_match} || [] };
            }
            $self->update_labels;
         } elsif ($ev->{sym} == CFClient::SDLK_UP) {
            if ($self->{select_offset}) {
               --$self->{select_offset}
            } else {
               unless ($self->{hist_ptr}) {
                  $self->{hist_saveback} = $self->{entry}->get_text;
               }
               if ($self->{hist_ptr} <= $#{$self->{history}}) {
                  $self->{hist_ptr}++;
               }
               $self->{entry}->set_text ($self->{history}->[$self->{hist_ptr} - 1])
                  if exists $self->{history}->[$self->{hist_ptr} - 1];
            }
            $self->update_labels;
         } else {
            return 0;
         }

         1
      }
   ;

   $self->{vbox}->add (
      $self->{entry},
      @{$self->{label}},
   );

   $self
}

sub set_prefix {
   my ($self, $prefix) = @_;

   $self->{entry}->set_text ($prefix);
   $self->show;
}

sub size_allocate {
   my ($self, $w, $h) = @_;

   $self->SUPER::size_allocate ($w, $h);
   $self->move_abs (($::WIDTH - $w) * 0.5, ($::HEIGHT - $h) * 0.6, 10);
}

sub show {
   my ($self) = @_;

   $self->SUPER::show;
   $self->{entry}->focus_in;
}

sub hide {
   my ($self) = @_;

   $self->SUPER::hide;
   $self->{entry}->set_text ("");
}

sub key_down {
   my ($self, $ev) = @_;

   $self->{entry}->key_down ($ev)
}

sub update_labels {
   my ($self) = @_;

   my $text = $self->{entry}->get_text;

   length $text
      or return $self->hide;

   my ($cmd, $arg) = $text =~ /^\s*([^[:space:]]*)(.*)$/;

   if ($text ne $self->{last_search}) {
      my @match;

      if ($text =~ /^(.*?)\s+$/) {
         @match = [$cmd, "(appended whitespace suppresses completion)"];
      } else {
         my $regexp = do {
            my ($beg, @chr) = split //, lc $cmd;

            # the following regex is used to match our "completion entry"
            # to an actual command - the parentheses match kind of "overhead"
            # - the more characters the parentheses match, the less attractive
            # is the match.
            my $regexp = "^\Q$beg\E"
                       . join "", map "(?:.*?[ \\\\]\Q$_\E|(.*?)\Q$_\E)", @chr;
            qr<$regexp>
         };

         my @penalty;

         for (keys %{$self->{command}}) {
            if (@penalty = $_ =~ $regexp) {
               push @match, [$_, length join "", map "::$_", grep defined, @penalty];
            }
         }

         @match = map $self->{command}{$_->[0]},
                     sort {
                        $a->[1] <=> $b->[1]
                           or $self->{command}{$a->[0]}[4] <=> $self->{command}{$b->[0]}[4]
                           or (length $b->[0]) <=> (length $a->[0])
                     } @match;
      }

      $self->{last_search} = $text;
      $self->{last_match} = \@match;

      $self->{select_offset} = 0;
   }

   my @labels = @{ $self->{label} };
   my @matches = @{ $self->{last_match} || [] };

   if ($self->{select_offset}) {
      splice @matches, 0, $self->{select_offset}, ();

      my $label = shift @labels;
      $label->set_text ("...");
      $label->set_tooltip ("Use Cursor-Up to view previous matches");
   }

   for my $label (@labels) {
      $label->{fg} = [1, 1, 1, 1];
      $label->{bg} = [0, 0, 0, 0];
   }

   if (@matches) {
      $self->{select} = "$matches[0][0]$arg";

      $labels[0]->{fg} = [0, 0, 0, 1];
      $labels[0]->{bg} = [1, 1, 1, 0.8];
   } else {
      $self->{select} = "$cmd$arg";
   }

   for my $match (@matches) {
      my $label = shift @labels;

      if (@labels) {
         $label->set_text ("$match->[0]$arg");
         $label->set_tooltip ($match->[1]);
      } else {
         $label->set_text ("...");
         $label->set_tooltip ("Use Cursor-Down to view more matches");
         last;
      }
   }

   for my $label (@labels) {
      $label->set_text ("");
      $label->set_tooltip ("");
   }

   $self->update;
   ###
}

sub _draw {
   my ($self) = @_;

   # hack
   local $CFClient::UI::FOCUS = $self->{entry};

   $self->SUPER::_draw;
}

1
Revision:	1.57
Committed:	Tue Jun 13 11:01:04 2006 UTC (17 years, 11 months ago) by elmex
Branch:	MAIN
Changes since 1.56:	+13 -0 lines
Log Message:	- IMPORTANT: bind keys using the completer - implemented by opening a context menu like the spell list has.
#	User	Rev	Content
1	root	1.1	package CFClient::MapWidget;
2
3			use strict;
4	root	1.14	use utf8;
5	root	1.1
6			use List::Util qw(min max);
7
8	root	1.4	use CFClient::OpenGL;
9	root	1.1
10			our @ISA = CFClient::UI::Base::;
11
12			sub new {
13			my $class = shift;
14
15	root	1.20	my $self = $class->SUPER::new (
16	root	1.1	z => -1,
17			can_focus => 1,
18	root	1.4	list => glGenList,
19	root	1.51
20			smooth_matrix => [
21			0.05, 0.13, 0.05,
22			0.13, 0.30, 0.13,
23			0.05, 0.13, 0.05,
24			],
25
26	root	1.1	@_
27	root	1.20	);
28
29	root	1.36	$self->{completer} = new CFClient::MapWidget::Command::
30			command => $self->{command},
31			can_focus => 1,
32	root	1.37	tooltip => "<b>The Command Completer</b>\n\n"
33			. "This is your central interface to send text commands to the server. "
34			. "To enter a verbatim command to send to the server, just type the command, "
35			. "followed by a space, and press return. "
36			. "Typing the initial letters of words (or just any letters) displays guesses "
37			. "for commands you might want to use.\n"
38			. "You can use the cursor-up and cursor-down keys to select between those guesses.\n"
39			. "<b>Right-Click</b> opens a menu where you cna select further options, sich as redefining keybindings.",
40	root	1.36	;
41
42	root	1.20	$self
43	root	1.1	}
44
45	root	1.36	sub add_command {
46			my ($self, $command, $tooltip, $widget, $cb) = @_;
47
48			(my $data = $command) =~ s/\\//g;
49
50			$tooltip =~ s/^\s+//;
51			$tooltip = "<big>$data</big>\n\n$tooltip";
52			$tooltip =~ s/\s+$//;
53
54			$self->{completer}{command}{$command} = [$data, $tooltip, $widget, $cb, ++$self->{command_id}];
55			}
56	root	1.4
57	root	1.36	sub clr_commands {
58			my ($self) = @_;
59	root	1.4
60	root	1.36	%{$self->{completer}{command}} = ();
61	root	1.4	}
62
63	root	1.1	sub button_down {
64			my ($self, $ev, $x, $y) = @_;
65
66			$self->focus_in;
67
68	root	1.49	if ($ev->{button} == 1) {
69	root	1.54	my $x = int +($ev->{x} - $::CFG->{map_shift_x}) / (32 * $::CFG->{map_scale});
70			my $y = int +($ev->{y} - $::CFG->{map_shift_y}) / (32 * $::CFG->{map_scale});
71
72			$x += int 0.5 * ($::MAP->w - $self->{sw} - 1);
73			$y += int 0.5 * ($::MAP->h - $self->{sh} - 1);
74	root	1.49
75	root	1.54	$x -= int 0.5 * $::MAP->w;
76			$y -= int 0.5 * $::MAP->h;
77	root	1.49
78	root	1.54	$x += 1;
79			$y += 1;
80
81	root	1.56	$::CONN->lookat ($x, $y)
82	root	1.53	if $::CONN;
83	root	1.49
84			} elsif ($ev->{button} == 2) {
85	root	1.5	my ($ox, $oy) = ($ev->{x}, $ev->{y});
86	root	1.1	my ($bw, $bh) = ($::CFG->{map_shift_x}, $::CFG->{map_shift_y});
87
88			$self->{motion} = sub {
89			my ($ev, $x, $y) = @_;
90
91	root	1.5	($x, $y) = ($ev->{x}, $ev->{y});
92	root	1.1
93			$::CFG->{map_shift_x} = $bw + $x - $ox;
94			$::CFG->{map_shift_y} = $bh + $y - $oy;
95
96			$self->update;
97			};
98			}
99	root	1.47
100			1
101	root	1.1	}
102
103			sub button_up {
104			my ($self, $ev, $x, $y) = @_;
105
106			delete $self->{motion};
107	root	1.47
108			1
109	root	1.1	}
110
111			sub mouse_motion {
112			my ($self, $ev, $x, $y) = @_;
113
114	root	1.47	if ($self->{motion}) {
115			$self->{motion}->($ev, $x, $y);
116			} else {
117			return 0;
118			}
119
120			1
121	root	1.1	}
122
123			sub size_request {
124			(
125			1 + 32 * int $::WIDTH / 32,
126			1 + 32 * int $::HEIGHT / 32,
127			)
128			}
129
130			sub update {
131			my ($self) = @_;
132
133			$self->{need_update} = 1;
134			$self->SUPER::update;
135			}
136
137	root	1.36	my %DIR = (
138			CFClient::SDLK_KP8, [1, "north"],
139			CFClient::SDLK_KP9, [2, "northeast"],
140			CFClient::SDLK_KP6, [3, "east"],
141			CFClient::SDLK_KP3, [4, "southeast"],
142			CFClient::SDLK_KP2, [5, "south"],
143			CFClient::SDLK_KP1, [6, "southwest"],
144			CFClient::SDLK_KP4, [7, "west"],
145			CFClient::SDLK_KP7, [8, "northwest"],
146
147			CFClient::SDLK_UP, [1, "north"],
148			CFClient::SDLK_RIGHT, [3, "east"],
149			CFClient::SDLK_DOWN, [5, "south"],
150			CFClient::SDLK_LEFT, [7, "west"],
151			);
152
153			sub key_down {
154			my ($self, $ev) = @_;
155
156	root	1.47	return 0 unless $::CONN;
157	root	1.36
158			my $mod = $ev->{mod};
159			my $sym = $ev->{sym};
160			my $uni = $ev->{unicode};
161
162			if ($sym == CFClient::SDLK_KP5) {
163			$::CONN->user_send ("stay fire");
164			} elsif ($uni == ord ",") {
165			$::CONN->user_send ("take");
166			} elsif ($uni == ord " ") {
167			$::CONN->user_send ("apply");
168	root	1.37	} elsif ($uni == ord ".") {
169			$::CONN->user_send ($self->{completer}{last_command})
170			if exists $self->{completer}{last_command};
171	root	1.36	} elsif ($uni == ord "\t") {
172	root	1.41	$::INV_WINDOW->toggle_visibility;
173	root	1.36	} elsif ($sym == CFClient::SDLK_KP_PLUS \|\| $uni == ord "+") {
174			$::CONN->user_send ("rotateshoottype +");
175			} elsif ($sym == CFClient::SDLK_KP_MINUS \|\| $uni == ord "-") {
176			$::CONN->user_send ("rotateshoottype -");
177			} elsif ($uni == ord '"') {
178			$self->{completer}->set_prefix ("$::CFG->{say_command} ");
179			$self->{completer}->show;
180			} elsif ($uni == ord "'") {
181			$self->{completer}->set_prefix ("");
182			$self->{completer}->show;
183			} elsif (exists $DIR{$sym}) {
184			if ($mod & CFClient::KMOD_SHIFT) {
185			$self->{shft}++;
186			$::CONN->user_send ("fire $DIR{$sym}[0]");
187			} elsif ($mod & CFClient::KMOD_CTRL) {
188			$self->{ctrl}++;
189			$::CONN->user_send ("run $DIR{$sym}[0]");
190			} else {
191			$::CONN->user_send ("$DIR{$sym}[1]");
192			}
193	elmex	1.43	} elsif ($sym == CFClient::SDLK_INSERT && $mod & CFClient::KMOD_CTRL) {
194	elmex	1.45	$::BIND_EDITOR->set_binding (undef, undef, [],
195			sub {
196			my ($mod, $sym, $cmds) = @_;
197			$::CFG->{bindings}->{$mod}->{$sym} = $cmds;
198			});
199			$::BIND_EDITOR->start;
200			$::BIND_EDITOR->show;
201	elmex	1.43	} elsif ($sym == CFClient::SDLK_INSERT && not ($mod & CFClient::KMOD_CTRL)) {
202	elmex	1.45	$::BIND_EDITOR->stop;
203	elmex	1.46	$::BIND_EDITOR->ask_for_bind_and_commit;
204	elmex	1.45	$::BIND_EDITOR->hide;
205	elmex	1.43	} elsif (my $bind_cmd = $::CFG->{bindings}->{$mod}->{$sym}) {
206			$::CONN->user_send ($_) for @$bind_cmd;
207	root	1.42	} elsif ((ord 'a') <= $uni && $uni <= (ord 'z')) {
208	root	1.36	$self->{completer}->key_down ($ev);
209			$self->{completer}->show;
210	root	1.47	} else {
211			return 0;
212	root	1.36	}
213	root	1.47
214			1
215	root	1.36	}
216
217			sub key_up {
218			my ($self, $ev) = @_;
219
220	root	1.47	my $res = 0;
221	root	1.36	my $mod = $ev->{mod};
222			my $sym = $ev->{sym};
223
224			if (!($mod & CFClient::KMOD_SHIFT) && delete $self->{shft}) {
225			$::CONN->user_send ("fire_stop");
226	root	1.47	$res = 1;
227	root	1.36	}
228	root	1.47
229	root	1.36	if (!($mod & CFClient::KMOD_CTRL ) && delete $self->{ctrl}) {
230			$::CONN->user_send ("run_stop");
231	root	1.47	$res = 1;
232	root	1.36	}
233	root	1.47
234			$res
235	root	1.36	}
236
237	root	1.1	sub draw {
238			my ($self) = @_;
239
240	root	1.36	my $focused = $CFClient::UI::FOCUS == $self
241			\|\| $CFClient::UI::FOCUS == $self->{completer}{entry};
242
243	root	1.26	return
244	root	1.36	unless $focused \|\| !$::FAST;
245	root	1.26
246	root	1.1	if (delete $self->{need_update}) {
247	root	1.4	glNewList $self->{list};
248	root	1.1
249			if ($::MAP) {
250	root	1.54	my $sw = $self->{sw} = int $::WIDTH / (32 * $::CFG->{map_scale}) + 0.99;
251			my $sh = $self->{sh} = int $::HEIGHT / (32 * $::CFG->{map_scale}) + 0.99;
252	root	1.1
253	root	1.54	my $sx = $::CFG->{map_shift_x} / $::CFG->{map_scale};
254			my $sy = $::CFG->{map_shift_y} / $::CFG->{map_scale};
255			my $sx0 = $self->{sx0} = ($sx & 31) - 32; $sx = $self->{sx} = ($sx - $sx0) / 32;
256			my $sy0 = $self->{sy0} = ($sy & 31) - 32; $sy = $self->{sy} = ($sy - $sy0) / 32;
257	root	1.18
258	root	1.16	glPushMatrix;
259	root	1.9	glScale $::CFG->{map_scale}, $::CFG->{map_scale};
260
261	root	1.54	glTranslate $sx0, $sy0;
262	root	1.1
263			my ($w, $h, $data) = $::MAP->draw ($sx, $sy, 0, 0, $sw + 1, $sh + 1);
264
265			if ($::CFG->{fow_enable}) {
266	root	1.39	if ($::CFG->{fow_smooth} && $CFClient::OpenGL::GL_VERSION >= 1.2) { # smooth fog of war
267	root	1.1	glConvolutionParameter (GL_CONVOLUTION_2D, GL_CONVOLUTION_BORDER_MODE, GL_CONSTANT_BORDER);
268			glConvolutionFilter2D (
269			GL_CONVOLUTION_2D,
270			GL_ALPHA,
271			3, 3,
272			GL_ALPHA, GL_FLOAT,
273	root	1.51	(pack "f*", @{ $self->{smooth_matrix} }),
274	root	1.1	);
275			glEnable GL_CONVOLUTION_2D;
276			}
277
278	root	1.35	$self->{fow_texture_name} \|\|= glGenTexture;
279	root	1.31	# try to re-use the texture name: TODO improve texture class instead
280
281	root	1.1	$self->{fow_texture} = new CFClient::Texture
282			w => $w,
283			h => $h,
284			data => $data,
285	root	1.35	name => $self->{fow_texture_name},
286	root	1.1	internalformat => GL_ALPHA,
287			format => GL_ALPHA;
288
289			glDisable GL_CONVOLUTION_2D if $::CFG->{fow_smooth};
290
291			glEnable GL_TEXTURE_2D;
292			glTexEnv GL_TEXTURE_ENV, GL_TEXTURE_ENV_MODE, GL_MODULATE;
293
294	root	1.7	glColor +($::CFG->{fow_intensity}) x 3, 0.8;
295	root	1.31	$self->{fow_texture}->draw_quad_alpha (0, 0, $w * 32, $h * 32);
296	root	1.1
297			glDisable GL_TEXTURE_2D;
298			}
299
300	root	1.18	glPopMatrix;
301	root	1.1	}
302
303			glEndList;
304			}
305
306			glPushMatrix;
307			glCallList $self->{list};
308			glPopMatrix;
309
310	root	1.29	# TNT2 emulates logops in software (or worse :)
311	root	1.36	if ($focused) {
312	root	1.32	(delete $self->{out_of_focus})->destroy
313			if $self->{out_of_focus};
314			} else {
315			glColor 0.4, 0.2, 0.2, 0.6;
316	root	1.29	glEnable GL_BLEND;
317			glBlendFunc GL_SRC_ALPHA, GL_ONE_MINUS_SRC_ALPHA;
318	root	1.1	glBegin GL_QUADS;
319			glVertex 0, 0;
320			glVertex 0, $::HEIGHT;
321			glVertex $::WIDTH, $::HEIGHT;
322			glVertex $::WIDTH, 0;
323			glEnd;
324	root	1.29	glDisable GL_BLEND;
325	root	1.32
326	root	1.38	# $self->{out_of_focus} \|\|= do {
327			# my $label = new CFClient::UI::Label
328			# x => 0,
329			# y => 0,
330			# z => 1,
331			# ellipsise => 0,
332			# text => "map out of focus (click map to play)";
333			#
334			# $label->show;
335			# $label->update;
336			#
337			# $CFClient::UI::ROOT->on_post_alloc ("$self$label" => sub {
338	root	1.44	# $label->move_abs (
339	root	1.38	# ($::WIDTH - $label->{w}) * 0.5,
340			# ($::HEIGHT - $label->{h}) * 0.5,
341			# );
342			# });
343			#
344			# $label
345			# };
346	root	1.1	}
347			}
348
349	root	1.36	sub DESTROY {
350			my $self = shift;
351	root	1.3
352	root	1.36	glDeleteList $self->{list};
353	root	1.1
354	root	1.36	$self->SUPER::DESTROY;
355	root	1.8	}
356
357	root	1.18	package CFClient::MapWidget::MapMap;
358
359	root	1.19	our @ISA = CFClient::UI::Base::;
360	root	1.18
361			use Time::HiRes qw(time);
362			use CFClient::OpenGL;
363
364			sub size_request {
365			($::HEIGHT * 0.25, $::HEIGHT * 0.25)
366			}
367
368			sub size_allocate {
369			my ($self, $w, $h) = @_;
370
371			$self->SUPER::size_allocate ($w, $h);
372			$self->update;
373			}
374
375			sub update {
376			my ($self) = @_;
377
378			delete $self->{texture_atime};
379			$self->SUPER::update;
380			}
381
382			sub _draw {
383			my ($self) = @_;
384
385			$::MAP or return;
386
387			my ($w, $h) = @$self{qw(w h)};
388
389			my $sw = int $::WIDTH / (32 * $::CFG->{map_scale}) + 0.99;
390			my $sh = int $::HEIGHT / (32 * $::CFG->{map_scale}) + 0.99;
391
392			my $sx = int $::CFG->{map_shift_x} / 32;
393			my $sy = int $::CFG->{map_shift_y} / 32;
394
395			my $ox = 0.5 * ($w - $sw);
396			my $oy = 0.5 * ($h - $sh);
397
398			glEnable GL_BLEND;
399			glBlendFunc GL_SRC_ALPHA, GL_ONE_MINUS_SRC_ALPHA;
400			glEnable GL_TEXTURE_2D;
401			glTexEnv GL_TEXTURE_ENV, GL_TEXTURE_ENV_MODE, GL_REPLACE;
402
403			if ($self->{texture_atime} < time) {
404			$self->{texture_atime} = time + 1/3;
405
406			$self->{texture} =
407			new CFClient::Texture
408			w => $w,
409			h => $h,
410			data => $::MAP->mapmap (-$ox, -$oy, $w, $h),
411			type => $CFClient::GL_VERSION >= 1.2 ? GL_UNSIGNED_INT_8_8_8_8_REV : GL_UNSIGNED_BYTE;
412			}
413
414			$self->{texture}->draw_quad (0, 0);
415
416			glDisable GL_TEXTURE_2D;
417
418			glTranslate 0.375, 0.375;
419
420			#TODO: map scale is completely borked
421
422			my $x0 = int $ox - $sx + 0.5;
423			my $y0 = int $oy - $sy + 0.5;
424
425			glColor 1, 1, 0, 1;
426			glBegin GL_LINE_LOOP;
427			glVertex $x0 , $y0 ;
428			glVertex $x0 , $y0 + $sh;
429			glVertex $x0 + $sw, $y0 + $sh;
430			glVertex $x0 + $sw, $y0 ;
431			glEnd;
432
433			glDisable GL_BLEND;
434			}
435
436	root	1.8	package CFClient::MapWidget::Command;
437
438			use strict;
439
440			use CFClient::OpenGL;
441
442	root	1.23	our @ISA = CFClient::UI::Frame::;
443	root	1.8
444			sub new {
445			my $class = shift;
446
447			my $self = $class->SUPER::new (
448	root	1.23	bg => [0, 0, 0, 0.8],
449	root	1.8	@_,
450	root	1.23	);
451
452			$self->add ($self->{vbox} = new CFClient::UI::VBox);
453
454			$self->{label} = [
455			map
456	root	1.8	CFClient::UI::Label->new (
457	root	1.25	can_hover => 1,
458			can_events => 1,
459			tooltip_width => 0.33,
460			fontsize => $_,
461	root	1.27	), (0.8) x 16
462	root	1.23	];
463
464			$self->{entry} = new CFClient::UI::Entry
465	root	1.40	on_changed => sub {
466	root	1.23	$self->update_labels;
467	root	1.36	},
468	elmex	1.57	on_button_down => sub {
469			my ($entry, $ev, $x, $y) = @_;
470
471			if ($ev->{button} == 3) {
472			(new CFClient::UI::Menu
473			items => [
474			["bind to a key" => sub { $::BIND_EDITOR->do_quick_binding ([$self->{select}], sub { $entry->focus_in }) }]
475			],
476			)->popup ($ev);
477			return 1;
478			}
479			0
480			},
481	root	1.40	on_key_down => sub {
482	root	1.36	my ($entry, $ev) = @_;
483
484			my $self = $entry->{parent}{parent};
485
486			if ($ev->{sym} == 13) {
487			if (exists $self->{select}) {
488	root	1.37	$self->{last_command} = $self->{select};
489	root	1.36	$::CONN->user_send ($self->{select});
490	elmex	1.52
491			unshift @{$self->{history}}, $self->{select};
492			$self->{hist_ptr} = 0;
493
494	root	1.36	$self->hide;
495			}
496			} elsif ($ev->{sym} == 27) {
497	elmex	1.52	$self->{hist_ptr} = 0;
498	root	1.36	$self->hide;
499			return;
500			} elsif ($ev->{sym} == CFClient::SDLK_DOWN) {
501	elmex	1.52	if ($self->{hist_ptr} > 1) {
502			$self->{hist_ptr}--;
503			$self->{entry}->set_text ($self->{history}->[$self->{hist_ptr} - 1]);
504			} elsif ($self->{hist_ptr} > 0) {
505			$self->{hist_ptr}--;
506			$self->{entry}->set_text ($self->{hist_saveback});
507			} else {
508			++$self->{select_offset}
509			if $self->{select_offset} < $#{ $self->{last_match} \|\| [] };
510			}
511	root	1.36	$self->update_labels;
512			} elsif ($ev->{sym} == CFClient::SDLK_UP) {
513	elmex	1.52	if ($self->{select_offset}) {
514			--$self->{select_offset}
515			} else {
516			unless ($self->{hist_ptr}) {
517			$self->{hist_saveback} = $self->{entry}->get_text;
518			}
519			if ($self->{hist_ptr} <= $#{$self->{history}}) {
520			$self->{hist_ptr}++;
521			}
522			$self->{entry}->set_text ($self->{history}->[$self->{hist_ptr} - 1])
523			if exists $self->{history}->[$self->{hist_ptr} - 1];
524			}
525	root	1.36	$self->update_labels;
526			} else {
527			return 0;
528			}
529
530			1
531			}
532			;
533	root	1.23
534			$self->{vbox}->add (
535			$self->{entry},
536			@{$self->{label}},
537	root	1.8	);
538
539			$self
540			}
541
542	root	1.36	sub set_prefix {
543			my ($self, $prefix) = @_;
544
545			$self->{entry}->set_text ($prefix);
546			$self->show;
547			}
548
549	root	1.8	sub size_allocate {
550			my ($self, $w, $h) = @_;
551
552			$self->SUPER::size_allocate ($w, $h);
553	root	1.44	$self->move_abs (($::WIDTH - $w) * 0.5, ($::HEIGHT - $h) * 0.6, 10);
554	root	1.8	}
555
556	root	1.36	sub show {
557			my ($self) = @_;
558
559			$self->SUPER::show;
560			$self->{entry}->focus_in;
561			}
562
563			sub hide {
564			my ($self) = @_;
565
566			$self->SUPER::hide;
567			$self->{entry}->set_text ("");
568			}
569
570	root	1.23	sub key_down {
571			my ($self, $ev) = @_;
572
573	root	1.47	$self->{entry}->key_down ($ev)
574	root	1.23	}
575
576	root	1.8	sub update_labels {
577			my ($self) = @_;
578
579	root	1.23	my $text = $self->{entry}->get_text;
580
581			length $text
582	root	1.36	or return $self->hide;
583	root	1.23
584			my ($cmd, $arg) = $text =~ /^\s([^[:space:]])(.*)$/;
585
586	root	1.36	if ($text ne $self->{last_search}) {
587			my @match;
588	root	1.23
589	root	1.36	if ($text =~ /^(.*?)\s+$/) {
590			@match = [$cmd, "(appended whitespace suppresses completion)"];
591			} else {
592			my $regexp = do {
593			my ($beg, @chr) = split //, lc $cmd;
594	root	1.23
595	root	1.36	# the following regex is used to match our "completion entry"
596			# to an actual command - the parentheses match kind of "overhead"
597			# - the more characters the parentheses match, the less attractive
598			# is the match.
599			my $regexp = "^\Q$beg\E"
600			. join "", map "(?:.?[ \\\\]\Q$_\E\|(.?)\Q$_\E)", @chr;
601			qr<$regexp>
602			};
603
604			my @penalty;
605
606			for (keys %{$self->{command}}) {
607			if (@penalty = $_ =~ $regexp) {
608			push @match, [$_, length join "", map "::$_", grep defined, @penalty];
609			}
610	root	1.23	}
611	root	1.36
612			@match = map $self->{command}{$_->[0]},
613			sort {
614			$a->[1] <=> $b->[1]
615			or $self->{command}{$a->[0]}[4] <=> $self->{command}{$b->[0]}[4]
616	root	1.39	or (length $b->[0]) <=> (length $a->[0])
617	root	1.36	} @match;
618	root	1.8	}
619	root	1.23
620	root	1.39	$self->{last_search} = $text;
621	root	1.23	$self->{last_match} = \@match;
622
623			$self->{select_offset} = 0;
624	root	1.8	}
625
626	root	1.23	my @labels = @{ $self->{label} };
627			my @matches = @{ $self->{last_match} \|\| [] };
628	root	1.8
629	root	1.23	if ($self->{select_offset}) {
630			splice @matches, 0, $self->{select_offset}, ();
631	root	1.8
632	root	1.23	my $label = shift @labels;
633			$label->set_text ("...");
634			$label->set_tooltip ("Use Cursor-Up to view previous matches");
635	root	1.8	}
636
637	root	1.23	for my $label (@labels) {
638			$label->{fg} = [1, 1, 1, 1];
639			$label->{bg} = [0, 0, 0, 0];
640			}
641
642			if (@matches) {
643			$self->{select} = "$matches[0][0]$arg";
644
645			$labels[0]->{fg} = [0, 0, 0, 1];
646			$labels[0]->{bg} = [1, 1, 1, 0.8];
647			} else {
648	root	1.24	$self->{select} = "$cmd$arg";
649	root	1.23	}
650
651			for my $match (@matches) {
652			my $label = shift @labels;
653
654			if (@labels) {
655			$label->set_text ("$match->[0]$arg");
656			$label->set_tooltip ($match->[1]);
657			} else {
658			$label->set_text ("...");
659			$label->set_tooltip ("Use Cursor-Down to view more matches");
660			last;
661			}
662			}
663	root	1.8
664	root	1.23	for my $label (@labels) {
665			$label->set_text ("");
666			$label->set_tooltip ("");
667	root	1.8	}
668
669	root	1.23	$self->update;
670			###
671	root	1.8	}
672
673	root	1.23	sub _draw {
674			my ($self) = @_;
675	root	1.8
676	root	1.23	# hack
677			local $CFClient::UI::FOCUS = $self->{entry};
678	root	1.10
679	root	1.23	$self->SUPER::_draw;
680	root	1.2	}
681
682	root	1.1	1