| 1 |
=head1 NAME |
| 2 |
|
| 3 |
Crossfire - Crossfire maphandling |
| 4 |
|
| 5 |
=cut |
| 6 |
|
| 7 |
package Crossfire; |
| 8 |
|
| 9 |
our $VERSION = '0.98'; |
| 10 |
|
| 11 |
use strict; |
| 12 |
|
| 13 |
use base 'Exporter'; |
| 14 |
|
| 15 |
use Carp (); |
| 16 |
use File::Spec; |
| 17 |
use List::Util qw(min max); |
| 18 |
use Storable qw(freeze thaw); |
| 19 |
|
| 20 |
our @EXPORT = qw( |
| 21 |
read_pak read_arch *ARCH TILESIZE $TILE *FACE editor_archs arch_extents |
| 22 |
); |
| 23 |
|
| 24 |
use JSON::XS qw(from_json to_json); |
| 25 |
|
| 26 |
our $LIB = $ENV{CROSSFIRE_LIBDIR}; |
| 27 |
|
| 28 |
our $VARDIR = $ENV{HOME} ? "$ENV{HOME}/.crossfire" |
| 29 |
: $ENV{AppData} ? "$ENV{APPDATA}/crossfire" |
| 30 |
: File::Spec->tmpdir . "/crossfire"; |
| 31 |
|
| 32 |
mkdir $VARDIR, 0777; |
| 33 |
|
| 34 |
sub TILESIZE (){ 32 } |
| 35 |
|
| 36 |
our %ARCH; |
| 37 |
our %FACE; |
| 38 |
our $TILE; |
| 39 |
|
| 40 |
our %FIELD_MULTILINE = ( |
| 41 |
msg => "endmsg", |
| 42 |
lore => "endlore", |
| 43 |
maplore => "endmaplore", |
| 44 |
); |
| 45 |
|
| 46 |
# movement bit type, PITA |
| 47 |
our %FIELD_MOVEMENT = map +($_ => undef), |
| 48 |
qw(move_type move_block move_allow move_on move_off move_slow); |
| 49 |
|
| 50 |
# same as in server save routine, to (hopefully) be compatible |
| 51 |
# to the other editors. |
| 52 |
our @FIELD_ORDER_MAP = (qw( |
| 53 |
file_format_version |
| 54 |
name attach swap_time reset_timeout fixed_resettime difficulty region |
| 55 |
shopitems shopgreed shopmin shopmax shoprace |
| 56 |
darkness width height enter_x enter_y msg maplore |
| 57 |
unique template |
| 58 |
outdoor temp pressure humid windspeed winddir sky nosmooth |
| 59 |
tile_path_1 tile_path_2 tile_path_3 tile_path_4 |
| 60 |
)); |
| 61 |
|
| 62 |
our @FIELD_ORDER = (qw( |
| 63 |
inherit |
| 64 |
|
| 65 |
elevation |
| 66 |
|
| 67 |
name name_pl custom_name attach title race |
| 68 |
slaying skill msg lore other_arch |
| 69 |
face animation is_animated |
| 70 |
magicmap smoothlevel smoothface |
| 71 |
str dex con wis pow cha int |
| 72 |
hp maxhp sp maxsp grace maxgrace |
| 73 |
exp perm_exp expmul |
| 74 |
food dam luck wc ac x y speed speed_left move_state attack_movement |
| 75 |
nrof level direction type subtype attacktype |
| 76 |
|
| 77 |
resist_physical resist_magic resist_fire resist_electricity |
| 78 |
resist_cold resist_confusion resist_acid resist_drain |
| 79 |
resist_weaponmagic resist_ghosthit resist_poison resist_slow |
| 80 |
resist_paralyze resist_turn_undead resist_fear resist_cancellation |
| 81 |
resist_deplete resist_death resist_chaos resist_counterspell |
| 82 |
resist_godpower resist_holyword resist_blind resist_internal |
| 83 |
resist_life_stealing resist_disease |
| 84 |
|
| 85 |
path_attuned path_repelled path_denied material materialname |
| 86 |
value carrying weight invisible state magic |
| 87 |
last_heal last_sp last_grace last_eat |
| 88 |
connected glow_radius randomitems npx_status npc_program |
| 89 |
run_away pick_up container will_apply smoothlevel |
| 90 |
current_weapon_script weapontype tooltype elevation client_type |
| 91 |
item_power duration range |
| 92 |
range_modifier duration_modifier dam_modifier gen_sp_armour |
| 93 |
move_type move_block move_allow move_on move_off move_on move_slow move_slow_penalty |
| 94 |
|
| 95 |
alive wiz was_wiz applied unpaid can_use_shield no_pick is_animated monster |
| 96 |
friendly generator is_thrown auto_apply treasure player sold see_invisible |
| 97 |
can_roll overlay_floor is_turnable is_used_up identified reflecting changing |
| 98 |
splitting hitback startequip blocksview undead scared unaggressive |
| 99 |
reflect_missile reflect_spell no_magic no_fix_player is_lightable tear_down |
| 100 |
run_away pick_up unique no_drop can_cast_spell can_use_scroll can_use_range |
| 101 |
can_use_bow can_use_armour can_use_weapon can_use_ring has_ready_range |
| 102 |
has_ready_bow xrays is_floor lifesave no_strength sleep stand_still |
| 103 |
random_move only_attack confused stealth cursed damned see_anywhere |
| 104 |
known_magical known_cursed can_use_skill been_applied has_ready_scroll |
| 105 |
can_use_rod can_use_horn make_invisible inv_locked is_wooded is_hilly |
| 106 |
has_ready_skill has_ready_weapon no_skill_ident is_blind can_see_in_dark |
| 107 |
is_cauldron is_dust no_steal one_hit berserk neutral no_attack no_damage |
| 108 |
activate_on_push activate_on_release is_water use_content_on_gen is_buildable |
| 109 |
|
| 110 |
body_range body_arm body_torso body_head body_neck body_skill |
| 111 |
body_finger body_shoulder body_foot body_hand body_wrist body_waist |
| 112 |
)); |
| 113 |
|
| 114 |
our %EVENT_TYPE = ( |
| 115 |
apply => 1, |
| 116 |
attack => 2, |
| 117 |
death => 3, |
| 118 |
drop => 4, |
| 119 |
pickup => 5, |
| 120 |
say => 6, |
| 121 |
stop => 7, |
| 122 |
time => 8, |
| 123 |
throw => 9, |
| 124 |
trigger => 10, |
| 125 |
close => 11, |
| 126 |
timer => 12, |
| 127 |
); |
| 128 |
|
| 129 |
sub MOVE_WALK (){ 0x01 } |
| 130 |
sub MOVE_FLY_LOW (){ 0x02 } |
| 131 |
sub MOVE_FLY_HIGH (){ 0x04 } |
| 132 |
sub MOVE_FLYING (){ 0x06 } |
| 133 |
sub MOVE_SWIM (){ 0x08 } |
| 134 |
sub MOVE_BOAT (){ 0x10 } |
| 135 |
sub MOVE_SHIP (){ 0x20 } |
| 136 |
sub MOVE_KNOWN (){ 0x3f } # all of above |
| 137 |
sub MOVE_ALL (){ 0x10000 } # very special value |
| 138 |
|
| 139 |
our %MOVE_TYPE = ( |
| 140 |
walk => MOVE_WALK, |
| 141 |
fly_low => MOVE_FLY_LOW, |
| 142 |
fly_high => MOVE_FLY_HIGH, |
| 143 |
flying => MOVE_FLYING, |
| 144 |
swim => MOVE_SWIM, |
| 145 |
boat => MOVE_BOAT, |
| 146 |
ship => MOVE_SHIP, |
| 147 |
all => MOVE_ALL, |
| 148 |
); |
| 149 |
|
| 150 |
our @MOVE_TYPE = keys %MOVE_TYPE; |
| 151 |
|
| 152 |
{ |
| 153 |
package Crossfire::MoveType; |
| 154 |
|
| 155 |
use overload |
| 156 |
'=' => sub { bless [@{$_[0]}], ref $_[0] }, |
| 157 |
'""' => \&as_string, |
| 158 |
'>=' => sub { $_[0][0] & $MOVE_TYPE{$_[1]} ? $_[0][1] & $MOVE_TYPE{$_[1]} : undef }, |
| 159 |
'+=' => sub { $_[0][0] |= $MOVE_TYPE{$_[1]}; $_[0][1] |= $MOVE_TYPE{$_[1]}; &normalise }, |
| 160 |
'-=' => sub { $_[0][0] |= $MOVE_TYPE{$_[1]}; $_[0][1] &= ~$MOVE_TYPE{$_[1]}; &normalise }, |
| 161 |
'/=' => sub { $_[0][0] &= ~$MOVE_TYPE{$_[1]}; &normalise }, |
| 162 |
'x=' => sub { |
| 163 |
my $cur = $_[0] >= $_[1]; |
| 164 |
if (!defined $cur) { |
| 165 |
if ($_[0] >= "all") { |
| 166 |
$_[0] -= $_[1]; |
| 167 |
} else { |
| 168 |
$_[0] += $_[1]; |
| 169 |
} |
| 170 |
} elsif ($cur) { |
| 171 |
$_[0] -= $_[1]; |
| 172 |
} else { |
| 173 |
$_[0] /= $_[1]; |
| 174 |
} |
| 175 |
|
| 176 |
$_[0] |
| 177 |
}, |
| 178 |
'eq' => sub { "$_[0]" eq "$_[1]" }, |
| 179 |
'ne' => sub { "$_[0]" ne "$_[1]" }, |
| 180 |
; |
| 181 |
} |
| 182 |
|
| 183 |
sub Crossfire::MoveType::new { |
| 184 |
my ($class, $string) = @_; |
| 185 |
|
| 186 |
my $mask; |
| 187 |
my $value; |
| 188 |
|
| 189 |
if ($string =~ /^\s*\d+\s*$/) { |
| 190 |
$mask = MOVE_ALL; |
| 191 |
$value = $string+0; |
| 192 |
} else { |
| 193 |
for (split /\s+/, lc $string) { |
| 194 |
if (s/^-//) { |
| 195 |
$mask |= $MOVE_TYPE{$_}; |
| 196 |
$value &= ~$MOVE_TYPE{$_}; |
| 197 |
} else { |
| 198 |
$mask |= $MOVE_TYPE{$_}; |
| 199 |
$value |= $MOVE_TYPE{$_}; |
| 200 |
} |
| 201 |
} |
| 202 |
} |
| 203 |
|
| 204 |
(bless [$mask, $value], $class)->normalise |
| 205 |
} |
| 206 |
|
| 207 |
sub Crossfire::MoveType::normalise { |
| 208 |
my ($self) = @_; |
| 209 |
|
| 210 |
if ($self->[0] & MOVE_ALL) { |
| 211 |
my $mask = ~(($self->[1] & MOVE_ALL ? $self->[1] : ~$self->[1]) & $self->[0] & ~MOVE_ALL); |
| 212 |
$self->[0] &= $mask; |
| 213 |
$self->[1] &= $mask; |
| 214 |
} |
| 215 |
|
| 216 |
$self->[1] &= $self->[0]; |
| 217 |
|
| 218 |
$self |
| 219 |
} |
| 220 |
|
| 221 |
sub Crossfire::MoveType::as_string { |
| 222 |
my ($self) = @_; |
| 223 |
|
| 224 |
my @res; |
| 225 |
|
| 226 |
my ($mask, $value) = @$self; |
| 227 |
|
| 228 |
for (@Crossfire::MOVE_TYPE) { |
| 229 |
my $bit = $Crossfire::MOVE_TYPE{$_}; |
| 230 |
if (($mask & $bit) == $bit && (($value & $bit) == $bit || ($value & $bit) == 0)) { |
| 231 |
$mask &= ~$bit; |
| 232 |
push @res, $value & $bit ? $_ : "-$_"; |
| 233 |
} |
| 234 |
} |
| 235 |
|
| 236 |
join " ", @res |
| 237 |
} |
| 238 |
|
| 239 |
sub load_ref($) { |
| 240 |
my ($path) = @_; |
| 241 |
|
| 242 |
open my $fh, "<:raw:perlio", $path |
| 243 |
or die "$path: $!"; |
| 244 |
local $/; |
| 245 |
|
| 246 |
thaw <$fh> |
| 247 |
} |
| 248 |
|
| 249 |
sub save_ref($$) { |
| 250 |
my ($ref, $path) = @_; |
| 251 |
|
| 252 |
open my $fh, ">:raw:perlio", "$path~" |
| 253 |
or die "$path~: $!"; |
| 254 |
print $fh freeze $ref; |
| 255 |
close $fh; |
| 256 |
rename "$path~", $path |
| 257 |
or die "$path: $!"; |
| 258 |
} |
| 259 |
|
| 260 |
my %attack_mask = ( |
| 261 |
physical => 0x00000001, |
| 262 |
magic => 0x00000002, |
| 263 |
fire => 0x00000004, |
| 264 |
electricity => 0x00000008, |
| 265 |
cold => 0x00000010, |
| 266 |
confusion => 0x00000020, |
| 267 |
acid => 0x00000040, |
| 268 |
drain => 0x00000080, |
| 269 |
weaponmagic => 0x00000100, |
| 270 |
ghosthit => 0x00000200, |
| 271 |
poison => 0x00000400, |
| 272 |
slow => 0x00000800, |
| 273 |
paralyze => 0x00001000, |
| 274 |
turn_undead => 0x00002000, |
| 275 |
fear => 0x00004000, |
| 276 |
cancellation => 0x00008000, |
| 277 |
deplete => 0x00010000, |
| 278 |
death => 0x00020000, |
| 279 |
chaos => 0x00040000, |
| 280 |
counterspell => 0x00080000, |
| 281 |
godpower => 0x00100000, |
| 282 |
holyword => 0x00200000, |
| 283 |
blind => 0x00400000, |
| 284 |
internal => 0x00800000, |
| 285 |
life_stealing => 0x01000000, |
| 286 |
disease => 0x02000000, |
| 287 |
); |
| 288 |
|
| 289 |
sub _add_resist($$$) { |
| 290 |
my ($ob, $mask, $value) = @_; |
| 291 |
|
| 292 |
while (my ($k, $v) = each %attack_mask) { |
| 293 |
$ob->{"resist_$k"} = min 100, max -100, $ob->{"resist_$k"} + $value if $mask & $v; |
| 294 |
} |
| 295 |
} |
| 296 |
|
| 297 |
my %MATERIAL = reverse |
| 298 |
paper => 1, |
| 299 |
iron => 2, |
| 300 |
glass => 4, |
| 301 |
leather => 8, |
| 302 |
wood => 16, |
| 303 |
organic => 32, |
| 304 |
stone => 64, |
| 305 |
cloth => 128, |
| 306 |
adamant => 256, |
| 307 |
liquid => 512, |
| 308 |
tin => 1024, |
| 309 |
bone => 2048, |
| 310 |
ice => 4096, |
| 311 |
|
| 312 |
# guesses |
| 313 |
runestone => 12, |
| 314 |
bronze => 18, |
| 315 |
"ancient wood" => 20, |
| 316 |
glass => 36, |
| 317 |
marble => 66, |
| 318 |
ice => 68, |
| 319 |
stone => 70, |
| 320 |
stone => 80, |
| 321 |
cloth => 136, |
| 322 |
ironwood => 144, |
| 323 |
adamantium => 258, |
| 324 |
glacium => 260, |
| 325 |
blood => 544, |
| 326 |
; |
| 327 |
|
| 328 |
# object as in "Object xxx", i.e. archetypes |
| 329 |
sub normalize_object($) { |
| 330 |
my ($ob) = @_; |
| 331 |
|
| 332 |
# convert material bitset to materialname, if possible |
| 333 |
if (exists $ob->{material}) { |
| 334 |
if (!$ob->{material}) { |
| 335 |
delete $ob->{material}; |
| 336 |
} elsif (exists $ob->{materialname}) { |
| 337 |
if ($MATERIAL{$ob->{material}} eq $ob->{materialname}) { |
| 338 |
delete $ob->{material}; |
| 339 |
} else { |
| 340 |
warn "object $ob->{_name} has both materialname ($ob->{materialname}) and material ($ob->{material}) set.\n"; |
| 341 |
delete $ob->{material}; # assume materilname is more specific and nuke material |
| 342 |
} |
| 343 |
} elsif (my $name = $MATERIAL{$ob->{material}}) { |
| 344 |
delete $ob->{material}; |
| 345 |
$ob->{materialname} = $name; |
| 346 |
} else { |
| 347 |
warn "object $ob->{_name} has unknown material ($ob->{material}) set.\n"; |
| 348 |
} |
| 349 |
} |
| 350 |
|
| 351 |
# color_fg is used as default for magicmap if magicmap does not exist |
| 352 |
$ob->{magicmap} ||= delete $ob->{color_fg} if exists $ob->{color_fg}; |
| 353 |
|
| 354 |
# nuke outdated or never supported fields |
| 355 |
delete @$ob{qw( |
| 356 |
can_knockback can_parry can_impale can_cut can_dam_armour |
| 357 |
can_apply pass_thru can_pass_thru color_bg color_fg |
| 358 |
)}; |
| 359 |
|
| 360 |
if (my $mask = delete $ob->{immune} ) { _add_resist $ob, $mask, 100; } |
| 361 |
if (my $mask = delete $ob->{protected} ) { _add_resist $ob, $mask, 30; } |
| 362 |
if (my $mask = delete $ob->{vulnerable}) { _add_resist $ob, $mask, -100; } |
| 363 |
|
| 364 |
# convert movement strings to bitsets |
| 365 |
for my $attr (keys %FIELD_MOVEMENT) { |
| 366 |
next unless exists $ob->{$attr}; |
| 367 |
|
| 368 |
$ob->{$attr} = new Crossfire::MoveType $ob->{$attr}; |
| 369 |
} |
| 370 |
|
| 371 |
# convert outdated movement flags to new movement sets |
| 372 |
if (defined (my $v = delete $ob->{no_pass})) { |
| 373 |
$ob->{move_block} = new Crossfire::MoveType $v ? "all" : ""; |
| 374 |
} |
| 375 |
if (defined (my $v = delete $ob->{slow_move})) { |
| 376 |
$ob->{move_slow} += "walk"; |
| 377 |
$ob->{move_slow_penalty} = $v; |
| 378 |
} |
| 379 |
if (defined (my $v = delete $ob->{walk_on})) { |
| 380 |
$ob->{move_on} ||= new Crossfire::MoveType; if ($v) { $ob->{move_on} += "walk" } else { $ob->{move_on} -= "walk" } |
| 381 |
} |
| 382 |
if (defined (my $v = delete $ob->{walk_off})) { |
| 383 |
$ob->{move_off} ||= new Crossfire::MoveType; if ($v) { $ob->{move_off} += "walk" } else { $ob->{move_off} -= "walk" } |
| 384 |
} |
| 385 |
if (defined (my $v = delete $ob->{fly_on})) { |
| 386 |
$ob->{move_on} ||= new Crossfire::MoveType; if ($v) { $ob->{move_on} += "fly_low" } else { $ob->{move_on} -= "fly_low" } |
| 387 |
} |
| 388 |
if (defined (my $v = delete $ob->{fly_off})) { |
| 389 |
$ob->{move_off} ||= new Crossfire::MoveType; if ($v) { $ob->{move_off} += "fly_low" } else { $ob->{move_off} -= "fly_low" } |
| 390 |
} |
| 391 |
if (defined (my $v = delete $ob->{flying})) { |
| 392 |
$ob->{move_type} ||= new Crossfire::MoveType; if ($v) { $ob->{move_type} += "fly_low" } else { $ob->{move_type} -= "fly_low" } |
| 393 |
} |
| 394 |
|
| 395 |
# convert idiotic event_xxx things into objects |
| 396 |
while (my ($event, $subtype) = each %EVENT_TYPE) { |
| 397 |
if (exists $ob->{"event_${event}_plugin"}) { |
| 398 |
push @{$ob->{inventory}}, { |
| 399 |
_name => "event_$event", |
| 400 |
title => delete $ob->{"event_${event}_plugin"}, |
| 401 |
slaying => delete $ob->{"event_${event}"}, |
| 402 |
name => delete $ob->{"event_${event}_options"}, |
| 403 |
}; |
| 404 |
} |
| 405 |
} |
| 406 |
|
| 407 |
# some archetypes had "+3" instead of the canonical "3", so fix |
| 408 |
$ob->{dam} *= 1 if exists $ob->{dam}; |
| 409 |
|
| 410 |
$ob |
| 411 |
} |
| 412 |
|
| 413 |
# arch as in "arch xxx", ie.. objects |
| 414 |
sub normalize_arch($) { |
| 415 |
my ($ob) = @_; |
| 416 |
|
| 417 |
normalize_object $ob; |
| 418 |
|
| 419 |
my $arch = $ARCH{$ob->{_name}} |
| 420 |
or (warn "$ob->{_name}: no such archetype", return $ob); |
| 421 |
|
| 422 |
if ($arch->{type} == 22) { # map |
| 423 |
my %normalize = ( |
| 424 |
"enter_x" => "hp", |
| 425 |
"enter_y" => "sp", |
| 426 |
"width" => "x", |
| 427 |
"height" => "y", |
| 428 |
"reset_timeout" => "weight", |
| 429 |
"swap_time" => "value", |
| 430 |
"difficulty" => "level", |
| 431 |
"darkness" => "invisible", |
| 432 |
"fixed_resettime" => "stand_still", |
| 433 |
); |
| 434 |
|
| 435 |
while (my ($k2, $k1) = each %normalize) { |
| 436 |
if (defined (my $v = delete $ob->{$k1})) { |
| 437 |
$ob->{$k2} = $v; |
| 438 |
} |
| 439 |
} |
| 440 |
} else { |
| 441 |
# if value matches archetype default, delete |
| 442 |
while (my ($k, $v) = each %$ob) { |
| 443 |
if (exists $arch->{$k} and $arch->{$k} eq $v) { |
| 444 |
next if $k eq "_name"; |
| 445 |
delete $ob->{$k}; |
| 446 |
} |
| 447 |
} |
| 448 |
} |
| 449 |
|
| 450 |
# a speciality for the editor |
| 451 |
if (exists $ob->{attack_movement}) { |
| 452 |
my $am = delete $ob->{attack_movement}; |
| 453 |
$ob->{attack_movement_bits_0_3} = $am & 15; |
| 454 |
$ob->{attack_movement_bits_4_7} = $am & 240; |
| 455 |
} |
| 456 |
|
| 457 |
$ob |
| 458 |
} |
| 459 |
|
| 460 |
sub attr_thaw($) { |
| 461 |
my ($ob) = @_; |
| 462 |
|
| 463 |
$ob->{attach} = from_json $ob->{attach} |
| 464 |
if exists $ob->{attach}; |
| 465 |
|
| 466 |
$ob |
| 467 |
} |
| 468 |
|
| 469 |
sub attr_freeze($) { |
| 470 |
my ($ob) = @_; |
| 471 |
|
| 472 |
$ob->{attach} = Crossfire::to_json $ob->{attach} |
| 473 |
if exists $ob->{attach}; |
| 474 |
|
| 475 |
$ob |
| 476 |
} |
| 477 |
|
| 478 |
sub read_pak($) { |
| 479 |
my ($path) = @_; |
| 480 |
|
| 481 |
my %pak; |
| 482 |
|
| 483 |
open my $fh, "<:raw:perlio", $path |
| 484 |
or Carp::croak "$_[0]: $!"; |
| 485 |
binmode $fh; |
| 486 |
while (<$fh>) { |
| 487 |
my ($type, $id, $len, $path) = split; |
| 488 |
$path =~ s/.*\///; |
| 489 |
read $fh, $pak{$path}, $len; |
| 490 |
} |
| 491 |
|
| 492 |
\%pak |
| 493 |
} |
| 494 |
|
| 495 |
sub read_arch($;$) { |
| 496 |
my ($path, $toplevel) = @_; |
| 497 |
|
| 498 |
my %arc; |
| 499 |
my ($more, $prev); |
| 500 |
my $comment; |
| 501 |
|
| 502 |
open my $fh, "<:raw:perlio:utf8", $path |
| 503 |
or Carp::croak "$path: $!"; |
| 504 |
|
| 505 |
# binmode $fh; |
| 506 |
|
| 507 |
my $parse_block; $parse_block = sub { |
| 508 |
my %arc = @_; |
| 509 |
|
| 510 |
while (<$fh>) { |
| 511 |
s/\s+$//; |
| 512 |
if (/^end$/i) { |
| 513 |
last; |
| 514 |
|
| 515 |
} elsif (/^arch (\S+)$/i) { |
| 516 |
push @{ $arc{inventory} }, attr_thaw normalize_arch $parse_block->(_name => $1); |
| 517 |
|
| 518 |
} elsif (/^lore$/i) { |
| 519 |
while (<$fh>) { |
| 520 |
last if /^endlore\s*$/i; |
| 521 |
$arc{lore} .= $_; |
| 522 |
} |
| 523 |
} elsif (/^msg$/i) { |
| 524 |
while (<$fh>) { |
| 525 |
last if /^endmsg\s*$/i; |
| 526 |
$arc{msg} .= $_; |
| 527 |
} |
| 528 |
} elsif (/^anim$/i) { |
| 529 |
while (<$fh>) { |
| 530 |
last if /^mina\s*$/i; |
| 531 |
chomp; |
| 532 |
push @{ $arc{anim} }, $_; |
| 533 |
} |
| 534 |
} elsif (/^(\S+)\s*(.*)$/) { |
| 535 |
$arc{lc $1} = $2; |
| 536 |
} elsif (/^\s*#/) { |
| 537 |
$arc{_comment} .= "$_\n"; |
| 538 |
|
| 539 |
} elsif (/^\s*$/) { |
| 540 |
# |
| 541 |
} else { |
| 542 |
warn "$path: unparsable line '$_' in arch $arc{_name}"; |
| 543 |
} |
| 544 |
} |
| 545 |
|
| 546 |
\%arc |
| 547 |
}; |
| 548 |
|
| 549 |
while (<$fh>) { |
| 550 |
s/\s+$//; |
| 551 |
if (/^more$/i) { |
| 552 |
$more = $prev; |
| 553 |
} elsif (/^object (\S+)$/i) { |
| 554 |
my $name = $1; |
| 555 |
my $arc = attr_thaw normalize_object $parse_block->(_name => $name, _comment => $comment); |
| 556 |
undef $comment; |
| 557 |
delete $arc{_comment} unless length $arc{_comment}; |
| 558 |
$arc->{_atype} = 'object'; |
| 559 |
|
| 560 |
if ($more) { |
| 561 |
$more->{more} = $arc; |
| 562 |
} else { |
| 563 |
$arc{$name} = $arc; |
| 564 |
} |
| 565 |
$prev = $arc; |
| 566 |
$more = undef; |
| 567 |
} elsif (/^arch (\S+)$/i) { |
| 568 |
my $name = $1; |
| 569 |
my $arc = attr_thaw normalize_arch $parse_block->(_name => $name, _comment => $comment); |
| 570 |
undef $comment; |
| 571 |
delete $arc{_comment} unless length $arc{_comment}; |
| 572 |
$arc->{_atype} = 'arch'; |
| 573 |
|
| 574 |
if ($more) { |
| 575 |
$more->{more} = $arc; |
| 576 |
} else { |
| 577 |
push @{ $arc{arch} }, $arc; |
| 578 |
} |
| 579 |
$prev = $arc; |
| 580 |
$more = undef; |
| 581 |
} elsif ($toplevel && /^(\S+)\s+(.*)$/) { |
| 582 |
if ($1 eq "lev_array") { |
| 583 |
while (<$fh>) { |
| 584 |
last if /^endplst\s*$/; |
| 585 |
push @{$toplevel->{lev_array}}, $_+0; |
| 586 |
} |
| 587 |
} else { |
| 588 |
$toplevel->{$1} = $2; |
| 589 |
} |
| 590 |
} elsif (/^\s*#/) { |
| 591 |
$comment .= "$_\n"; |
| 592 |
} elsif (/^\s*($|#)/) { |
| 593 |
# |
| 594 |
} else { |
| 595 |
die "$path: unparseable top-level line '$_'"; |
| 596 |
} |
| 597 |
} |
| 598 |
|
| 599 |
undef $parse_block; # work around bug in perl not freeing $fh etc. |
| 600 |
|
| 601 |
\%arc |
| 602 |
} |
| 603 |
|
| 604 |
sub archlist_to_string { |
| 605 |
my ($arch) = @_; |
| 606 |
|
| 607 |
my $str; |
| 608 |
|
| 609 |
my $append; $append = sub { |
| 610 |
my %a = %{$_[0]}; |
| 611 |
|
| 612 |
Crossfire::attr_freeze \%a; |
| 613 |
Crossfire::normalize_arch \%a; |
| 614 |
|
| 615 |
# undo the bit-split we did before |
| 616 |
if (exists $a{attack_movement_bits_0_3} or exists $a{attack_movement_bits_4_7}) { |
| 617 |
$a{attack_movement} = (delete $a{attack_movement_bits_0_3}) |
| 618 |
| (delete $a{attack_movement_bits_4_7}); |
| 619 |
} |
| 620 |
|
| 621 |
if (my $comment = delete $a{_comment}) { |
| 622 |
if ($comment =~ /[^\n\s#]/) { |
| 623 |
$str .= $comment; |
| 624 |
} |
| 625 |
} |
| 626 |
|
| 627 |
$str .= ((exists $a{_atype}) ? $a{_atype} : 'arch'). " $a{_name}\n"; |
| 628 |
|
| 629 |
my $inv = delete $a{inventory}; |
| 630 |
my $more = delete $a{more}; # arches do not support 'more', but old maps can contain some |
| 631 |
my $anim = delete $a{anim}; |
| 632 |
|
| 633 |
if ($a{_atype} eq 'object') { |
| 634 |
$str .= join "\n", "anim", @$anim, "mina\n" |
| 635 |
if $anim; |
| 636 |
} |
| 637 |
|
| 638 |
my @kv; |
| 639 |
|
| 640 |
for ($a{_name} eq "map" |
| 641 |
? @Crossfire::FIELD_ORDER_MAP |
| 642 |
: @Crossfire::FIELD_ORDER) { |
| 643 |
push @kv, [$_, delete $a{$_}] |
| 644 |
if exists $a{$_}; |
| 645 |
} |
| 646 |
|
| 647 |
for (sort keys %a) { |
| 648 |
next if /^_/; # ignore our _-keys |
| 649 |
push @kv, [$_, delete $a{$_}]; |
| 650 |
} |
| 651 |
|
| 652 |
for (@kv) { |
| 653 |
my ($k, $v) = @$_; |
| 654 |
|
| 655 |
if (my $end = $Crossfire::FIELD_MULTILINE{$k}) { |
| 656 |
$v =~ s/\n$//; |
| 657 |
$str .= "$k\n$v\n$end\n"; |
| 658 |
} else { |
| 659 |
$str .= "$k $v\n"; |
| 660 |
} |
| 661 |
} |
| 662 |
|
| 663 |
if ($inv) { |
| 664 |
$append->($_) for @$inv; |
| 665 |
} |
| 666 |
|
| 667 |
$str .= "end\n"; |
| 668 |
|
| 669 |
if ($a{_atype} eq 'object') { |
| 670 |
if ($more) { |
| 671 |
$str .= "more\n"; |
| 672 |
$append->($more) if $more; |
| 673 |
} else { |
| 674 |
$str .= "\n"; |
| 675 |
} |
| 676 |
} |
| 677 |
}; |
| 678 |
|
| 679 |
for (@$arch) { |
| 680 |
$append->($_); |
| 681 |
} |
| 682 |
|
| 683 |
$str |
| 684 |
} |
| 685 |
|
| 686 |
# put all archs into a hash with editor_face as it's key |
| 687 |
# NOTE: the arrays in the hash values are references to |
| 688 |
# the archs from $ARCH |
| 689 |
sub editor_archs { |
| 690 |
my %paths; |
| 691 |
|
| 692 |
for (keys %ARCH) { |
| 693 |
my $arch = $ARCH{$_}; |
| 694 |
push @{$paths{$arch->{editor_folder}}}, $arch; |
| 695 |
} |
| 696 |
|
| 697 |
\%paths |
| 698 |
} |
| 699 |
|
| 700 |
=item ($minx, $miny, $maxx, $maxy) = arch_extents $arch |
| 701 |
|
| 702 |
arch_extents determines the extents of the given arch's face(s), linked |
| 703 |
faces and single faces are handled here it returns (minx, miny, maxx, |
| 704 |
maxy) |
| 705 |
|
| 706 |
=cut |
| 707 |
|
| 708 |
sub arch_extents { |
| 709 |
my ($a) = @_; |
| 710 |
|
| 711 |
my $o = $ARCH{$a->{_name}} |
| 712 |
or return; |
| 713 |
|
| 714 |
my $face = $FACE{$a->{face} || $o->{face} || "blank.111"}; |
| 715 |
unless ($face) { |
| 716 |
$face = $FACE{"blank.x11"} |
| 717 |
or (warn "no face data found for arch '$a->{_name}'"), return; |
| 718 |
} |
| 719 |
|
| 720 |
if ($face->{w} > 1 || $face->{h} > 1) { |
| 721 |
# bigface |
| 722 |
return (0, 0, $face->{w} - 1, $face->{h} - 1); |
| 723 |
|
| 724 |
} elsif ($o->{more}) { |
| 725 |
# linked face |
| 726 |
my ($minx, $miny, $maxx, $maxy) = ($o->{x}, $o->{y}) x 2; |
| 727 |
|
| 728 |
for (; $o; $o = $o->{more}) { |
| 729 |
$minx = min $minx, $o->{x}; |
| 730 |
$miny = min $miny, $o->{y}; |
| 731 |
$maxx = max $maxx, $o->{x}; |
| 732 |
$maxy = max $maxy, $o->{y}; |
| 733 |
} |
| 734 |
|
| 735 |
return ($minx, $miny, $maxx, $maxy); |
| 736 |
|
| 737 |
} else { |
| 738 |
# single face |
| 739 |
return (0, 0, 0, 0); |
| 740 |
} |
| 741 |
} |
| 742 |
|
| 743 |
=item $type = arch_attr $arch |
| 744 |
|
| 745 |
Returns a hashref describing the object and its attributes. It can contain |
| 746 |
the following keys: |
| 747 |
|
| 748 |
name the name, suitable for display purposes |
| 749 |
ignore |
| 750 |
attr |
| 751 |
desc |
| 752 |
use |
| 753 |
section => [name => \%attr, name => \%attr] |
| 754 |
import |
| 755 |
|
| 756 |
=cut |
| 757 |
|
| 758 |
sub arch_attr($) { |
| 759 |
my ($obj) = @_; |
| 760 |
|
| 761 |
require Crossfire::Data; |
| 762 |
|
| 763 |
my $root; |
| 764 |
my $attr = { }; |
| 765 |
|
| 766 |
my $arch = $ARCH{ $obj->{_name} }; |
| 767 |
my $type = $obj->{type} || $arch->{type}; |
| 768 |
|
| 769 |
if ($type > 0) { |
| 770 |
$root = $Crossfire::Data::ATTR{$type}; |
| 771 |
} else { |
| 772 |
my %a = (%$arch, %$obj); |
| 773 |
|
| 774 |
if ($a{is_floor} && !$a{alive}) { |
| 775 |
$root = $Crossfire::Data::TYPE{Floor}; |
| 776 |
} elsif (!$a{is_floor} && $a{alive} && !$a{tear_down}) { |
| 777 |
$root = $Crossfire::Data::TYPE{"Monster & NPC"}; |
| 778 |
} elsif (!$a{is_floor} && !$a{alive} && $a{move_block}) { |
| 779 |
$root = $Crossfire::Data::TYPE{Wall}; |
| 780 |
} elsif (!$a{is_floor} && $a{alive} && $a{tear_down}) { |
| 781 |
$root = $Crossfire::Data::TYPE{"Weak Wall"}; |
| 782 |
} else { |
| 783 |
$root = $Crossfire::Data::TYPE{Misc}; |
| 784 |
} |
| 785 |
} |
| 786 |
|
| 787 |
my @import = ($root); |
| 788 |
|
| 789 |
unshift @import, \%Crossfire::Data::DEFAULT_ATTR |
| 790 |
unless $type == 116; |
| 791 |
|
| 792 |
my (%ignore); |
| 793 |
my (@section_order, %section, @attr_order); |
| 794 |
|
| 795 |
while (my $type = shift @import) { |
| 796 |
push @import, @{$type->{import} || []}; |
| 797 |
|
| 798 |
$attr->{$_} ||= $type->{$_} |
| 799 |
for qw(name desc use); |
| 800 |
|
| 801 |
for (@{$type->{ignore} || []}) { |
| 802 |
$ignore{$_}++ for ref $_ ? @$_ : $_; |
| 803 |
} |
| 804 |
|
| 805 |
for ([general => ($type->{attr} || [])], @{$type->{section} || []}) { |
| 806 |
my ($name, $attr) = @$_; |
| 807 |
push @section_order, $name; |
| 808 |
for (@$attr) { |
| 809 |
my ($k, $v) = @$_; |
| 810 |
push @attr_order, $k; |
| 811 |
$section{$name}{$k} ||= $v; |
| 812 |
} |
| 813 |
} |
| 814 |
} |
| 815 |
|
| 816 |
$attr->{section} = [ |
| 817 |
map !exists $section{$_} ? () : do { |
| 818 |
my $attr = delete $section{$_}; |
| 819 |
|
| 820 |
[ |
| 821 |
$_, |
| 822 |
map exists $attr->{$_} && !$ignore{$_} |
| 823 |
? [$_ => delete $attr->{$_}] : (), |
| 824 |
@attr_order |
| 825 |
] |
| 826 |
}, |
| 827 |
|
| 828 |
exists $section{$_} ? [$_ => delete $section{$_}] : (), |
| 829 |
@section_order |
| 830 |
]; |
| 831 |
|
| 832 |
$attr |
| 833 |
} |
| 834 |
|
| 835 |
sub cache_file($$&&) { |
| 836 |
my ($src, $cache, $load, $create) = @_; |
| 837 |
|
| 838 |
my ($size, $mtime) = (stat $src)[7,9] |
| 839 |
or Carp::croak "$src: $!"; |
| 840 |
|
| 841 |
if (-e $cache) { |
| 842 |
my $ref = eval { load_ref $cache }; |
| 843 |
|
| 844 |
if ($ref->{version} == 1 |
| 845 |
&& $ref->{size} == $size |
| 846 |
&& $ref->{mtime} == $mtime |
| 847 |
&& eval { $load->($ref->{data}); 1 }) { |
| 848 |
return; |
| 849 |
} |
| 850 |
} |
| 851 |
|
| 852 |
my $ref = { |
| 853 |
version => 1, |
| 854 |
size => $size, |
| 855 |
mtime => $mtime, |
| 856 |
data => $create->(), |
| 857 |
}; |
| 858 |
|
| 859 |
$load->($ref->{data}); |
| 860 |
|
| 861 |
save_ref $ref, $cache; |
| 862 |
} |
| 863 |
|
| 864 |
=item set_libdir $path |
| 865 |
|
| 866 |
Sets the library directory to the given path |
| 867 |
(default: $ENV{CROSSFIRE_LIBDIR}). |
| 868 |
|
| 869 |
You have to (re-)load the archetypes and tilecache manually after steting |
| 870 |
the library path. |
| 871 |
|
| 872 |
=cut |
| 873 |
|
| 874 |
sub set_libdir($) { |
| 875 |
$LIB = $_[0]; |
| 876 |
} |
| 877 |
|
| 878 |
=item load_archetypes |
| 879 |
|
| 880 |
(Re-)Load archetypes into %ARCH. |
| 881 |
|
| 882 |
=cut |
| 883 |
|
| 884 |
sub load_archetypes() { |
| 885 |
cache_file "$LIB/archetypes", "$VARDIR/archetypes.pst", sub { |
| 886 |
*ARCH = $_[0]; |
| 887 |
}, sub { |
| 888 |
read_arch "$LIB/archetypes" |
| 889 |
}; |
| 890 |
} |
| 891 |
|
| 892 |
sub construct_tilecache_pb { |
| 893 |
my ($idx, $cache) = @_; |
| 894 |
|
| 895 |
my $pb = new Gtk2::Gdk::Pixbuf "rgb", 1, 8, 64 * TILESIZE, TILESIZE * int +($idx + 63) / 64; |
| 896 |
|
| 897 |
while (my ($name, $tile) = each %$cache) { |
| 898 |
my $tpb = delete $tile->{pb}; |
| 899 |
my $ofs = $tile->{idx}; |
| 900 |
|
| 901 |
for my $x (0 .. $tile->{w} - 1) { |
| 902 |
for my $y (0 .. $tile->{h} - 1) { |
| 903 |
my $idx = $ofs + $x + $y * $tile->{w}; |
| 904 |
$tpb->copy_area ($x * TILESIZE, $y * TILESIZE, TILESIZE, TILESIZE, |
| 905 |
$pb, ($idx % 64) * TILESIZE, TILESIZE * int $idx / 64); |
| 906 |
} |
| 907 |
} |
| 908 |
} |
| 909 |
|
| 910 |
$pb->save ("$VARDIR/tilecache.png", "png", compression => 1); |
| 911 |
|
| 912 |
$cache |
| 913 |
} |
| 914 |
|
| 915 |
sub use_tilecache { |
| 916 |
my ($face) = @_; |
| 917 |
$TILE = new_from_file Gtk2::Gdk::Pixbuf "$VARDIR/tilecache.png" |
| 918 |
or die "$VARDIR/tilecache.png: $!"; |
| 919 |
*FACE = $_[0]; |
| 920 |
} |
| 921 |
|
| 922 |
=item load_tilecache |
| 923 |
|
| 924 |
(Re-)Load %TILE and %FACE. |
| 925 |
|
| 926 |
=cut |
| 927 |
|
| 928 |
sub load_tilecache() { |
| 929 |
require Gtk2; |
| 930 |
|
| 931 |
if (-e "$LIB/crossfire.0") { # Crossfire1 version |
| 932 |
cache_file "$LIB/crossfire.0", "$VARDIR/tilecache.pst", \&use_tilecache, |
| 933 |
sub { |
| 934 |
my $tile = read_pak "$LIB/crossfire.0"; |
| 935 |
|
| 936 |
my %cache; |
| 937 |
|
| 938 |
my $idx = 0; |
| 939 |
|
| 940 |
for my $name (sort keys %$tile) { |
| 941 |
my $pb = new Gtk2::Gdk::PixbufLoader; |
| 942 |
$pb->write ($tile->{$name}); |
| 943 |
$pb->close; |
| 944 |
my $pb = $pb->get_pixbuf; |
| 945 |
|
| 946 |
my $tile = $cache{$name} = { |
| 947 |
pb => $pb, |
| 948 |
idx => $idx, |
| 949 |
w => int $pb->get_width / TILESIZE, |
| 950 |
h => int $pb->get_height / TILESIZE, |
| 951 |
}; |
| 952 |
|
| 953 |
$idx += $tile->{w} * $tile->{h}; |
| 954 |
} |
| 955 |
|
| 956 |
construct_tilecache_pb $idx, \%cache; |
| 957 |
|
| 958 |
\%cache |
| 959 |
}; |
| 960 |
|
| 961 |
} else { # Crossfire+ version |
| 962 |
cache_file "$LIB/facedata", "$VARDIR/tilecache.pst", \&use_tilecache, |
| 963 |
sub { |
| 964 |
my %cache; |
| 965 |
my $facedata = Storable::retrieve "$LIB/facedata"; |
| 966 |
|
| 967 |
$facedata->{version} == 2 |
| 968 |
or die "$LIB/facedata: version mismatch, cannot proceed."; |
| 969 |
|
| 970 |
my $faces = $facedata->{faceinfo}; |
| 971 |
my $idx = 0; |
| 972 |
|
| 973 |
for (sort keys %$faces) { |
| 974 |
my ($face, $info) = ($_, $faces->{$_}); |
| 975 |
|
| 976 |
my $pb = new Gtk2::Gdk::PixbufLoader; |
| 977 |
$pb->write ($info->{data32}); |
| 978 |
$pb->close; |
| 979 |
my $pb = $pb->get_pixbuf; |
| 980 |
|
| 981 |
my $tile = $cache{$face} = { |
| 982 |
pb => $pb, |
| 983 |
idx => $idx, |
| 984 |
w => int $pb->get_width / TILESIZE, |
| 985 |
h => int $pb->get_height / TILESIZE, |
| 986 |
}; |
| 987 |
|
| 988 |
$idx += $tile->{w} * $tile->{h}; |
| 989 |
} |
| 990 |
|
| 991 |
construct_tilecache_pb $idx, \%cache; |
| 992 |
|
| 993 |
\%cache |
| 994 |
}; |
| 995 |
} |
| 996 |
} |
| 997 |
|
| 998 |
=head1 AUTHOR |
| 999 |
|
| 1000 |
Marc Lehmann <schmorp@schmorp.de> |
| 1001 |
http://home.schmorp.de/ |
| 1002 |
|
| 1003 |
Robin Redeker <elmex@ta-sa.org> |
| 1004 |
http://www.ta-sa.org/ |
| 1005 |
|
| 1006 |
=cut |
| 1007 |
|
| 1008 |
1 |
