| 1 |
=head1 NAME |
| 2 |
|
| 3 |
Deliantra - Deliantra suppport module to read/write archetypes, maps etc. |
| 4 |
|
| 5 |
=over 4 |
| 6 |
|
| 7 |
=cut |
| 8 |
|
| 9 |
package Deliantra; |
| 10 |
|
| 11 |
our $VERSION = '1.25'; |
| 12 |
|
| 13 |
use common::sense; |
| 14 |
|
| 15 |
use base 'Exporter'; |
| 16 |
|
| 17 |
use Carp (); |
| 18 |
use File::Spec; |
| 19 |
use List::Util qw(min max); |
| 20 |
use Storable qw(freeze thaw); |
| 21 |
|
| 22 |
our @EXPORT = qw( |
| 23 |
read_pak read_arch |
| 24 |
*ARCH $TILE *FACE *FACEDATA |
| 25 |
TILESIZE CACHESTRIDE |
| 26 |
editor_archs arch_extents |
| 27 |
); |
| 28 |
|
| 29 |
use JSON::XS qw(decode_json encode_json); |
| 30 |
|
| 31 |
our $LIB = $ENV{DELIANTRA_LIBDIR}; |
| 32 |
|
| 33 |
our $VARDIR = $ENV{HOME} ? "$ENV{HOME}/.deliantra" |
| 34 |
: $ENV{AppData} ? "$ENV{APPDATA}/deliantra" |
| 35 |
: File::Spec->tmpdir . "/deliantra"; |
| 36 |
|
| 37 |
mkdir $VARDIR, 0777; |
| 38 |
|
| 39 |
sub TILESIZE (){ 32 } |
| 40 |
sub CACHESTRIDE (){ 64 } |
| 41 |
|
| 42 |
our %ARCH; |
| 43 |
our %FACE; # face32 |
| 44 |
our %FACEDATA; |
| 45 |
our $TILE; |
| 46 |
|
| 47 |
our %FIELD_MULTILINE = ( |
| 48 |
msg => "endmsg", |
| 49 |
lore => "endlore", |
| 50 |
maplore => "endmaplore", |
| 51 |
); |
| 52 |
|
| 53 |
# movement bit type, PITA |
| 54 |
our %FIELD_MOVEMENT = map +($_ => undef), |
| 55 |
qw(move_type move_block move_allow move_on move_off move_slow); |
| 56 |
|
| 57 |
# same as in server save routine, to (hopefully) be compatible |
| 58 |
# to the other editors. |
| 59 |
our @FIELD_ORDER_MAP = (qw( |
| 60 |
file_format_version |
| 61 |
name attach swap_time reset_timeout fixed_resettime difficulty region |
| 62 |
shopitems shopgreed shopmin shopmax shoprace |
| 63 |
darkness width height enter_x enter_y msg maplore |
| 64 |
unique template |
| 65 |
outdoor temp pressure humid windspeed winddir sky nosmooth |
| 66 |
tile_path_1 tile_path_2 tile_path_3 tile_path_4 |
| 67 |
)); |
| 68 |
|
| 69 |
our @FIELD_ORDER = (qw( |
| 70 |
inherit |
| 71 |
|
| 72 |
elevation |
| 73 |
|
| 74 |
name name_pl custom_name attach title race |
| 75 |
slaying skill msg lore other_arch |
| 76 |
sound sound_destroy face animation is_animated |
| 77 |
magicmap smoothlevel smoothface |
| 78 |
str dex con wis pow cha int |
| 79 |
hp maxhp sp maxsp grace maxgrace |
| 80 |
exp perm_exp expmul |
| 81 |
food dam luck wc ac x y speed speed_left move_state attack_movement |
| 82 |
nrof level direction type subtype attacktype |
| 83 |
|
| 84 |
resist_physical resist_magic resist_fire resist_electricity |
| 85 |
resist_cold resist_confusion resist_acid resist_drain |
| 86 |
resist_weaponmagic resist_ghosthit resist_poison resist_slow |
| 87 |
resist_paralyze resist_turn_undead resist_fear resist_cancellation |
| 88 |
resist_deplete resist_death resist_chaos resist_counterspell |
| 89 |
resist_godpower resist_holyword resist_blind resist_internal |
| 90 |
resist_life_stealing resist_disease |
| 91 |
|
| 92 |
path_attuned path_repelled path_denied material materialname |
| 93 |
value carrying weight invisible state magic |
| 94 |
last_heal last_sp last_grace last_eat |
| 95 |
connected glow_radius randomitems tresure_env npx_status npc_program |
| 96 |
run_away pick_up container will_apply smoothlevel |
| 97 |
current_weapon_script weapontype tooltype elevation client_type |
| 98 |
item_power duration range |
| 99 |
range_modifier duration_modifier dam_modifier gen_sp_armour |
| 100 |
move_type move_block move_allow move_on move_off move_on move_slow move_slow_penalty |
| 101 |
|
| 102 |
alive wiz was_wiz applied unpaid can_use_shield no_pick is_animated monster |
| 103 |
friendly generator is_thrown auto_apply treasure player sold see_invisible |
| 104 |
can_roll overlay_floor is_turnable is_used_up identified reflecting changing |
| 105 |
splitting hitback startequip blocksview undead scared unaggressive |
| 106 |
reflect_missile reflect_spell no_magic no_fix_player is_lightable tear_down |
| 107 |
run_away pick_up unique no_drop can_cast_spell can_use_scroll can_use_range |
| 108 |
can_use_bow can_use_armour can_use_weapon can_use_ring has_ready_range |
| 109 |
has_ready_bow xrays is_floor lifesave no_strength sleep stand_still |
| 110 |
random_move only_attack confused stealth cursed damned see_anywhere |
| 111 |
known_magical known_cursed can_use_skill been_applied has_ready_scroll |
| 112 |
can_use_rod can_use_horn make_invisible inv_locked is_wooded is_hilly |
| 113 |
has_ready_skill has_ready_weapon no_skill_ident is_blind can_see_in_dark |
| 114 |
is_cauldron is_dust no_steal one_hit berserk neutral no_attack no_damage |
| 115 |
activate_on_push activate_on_release is_water use_content_on_gen is_buildable |
| 116 |
precious |
| 117 |
|
| 118 |
body_range body_arm body_torso body_head body_neck body_skill |
| 119 |
body_finger body_shoulder body_foot body_hand body_wrist body_waist |
| 120 |
)); |
| 121 |
|
| 122 |
our %EVENT_TYPE = ( |
| 123 |
apply => 1, |
| 124 |
attack => 2, |
| 125 |
death => 3, |
| 126 |
drop => 4, |
| 127 |
pickup => 5, |
| 128 |
say => 6, |
| 129 |
stop => 7, |
| 130 |
time => 8, |
| 131 |
throw => 9, |
| 132 |
trigger => 10, |
| 133 |
close => 11, |
| 134 |
timer => 12, |
| 135 |
); |
| 136 |
|
| 137 |
sub MOVE_WALK (){ 0x01 } |
| 138 |
sub MOVE_FLY_LOW (){ 0x02 } |
| 139 |
sub MOVE_FLY_HIGH (){ 0x04 } |
| 140 |
sub MOVE_FLYING (){ 0x06 } |
| 141 |
sub MOVE_SWIM (){ 0x08 } |
| 142 |
sub MOVE_BOAT (){ 0x10 } |
| 143 |
sub MOVE_SHIP (){ 0x20 } |
| 144 |
sub MOVE_KNOWN (){ 0x3f } # all of above |
| 145 |
sub MOVE_ALL (){ 0x10000 } # very special value |
| 146 |
|
| 147 |
our %MOVE_TYPE = ( |
| 148 |
walk => MOVE_WALK, |
| 149 |
fly_low => MOVE_FLY_LOW, |
| 150 |
fly_high => MOVE_FLY_HIGH, |
| 151 |
flying => MOVE_FLYING, |
| 152 |
swim => MOVE_SWIM, |
| 153 |
boat => MOVE_BOAT, |
| 154 |
ship => MOVE_SHIP, |
| 155 |
all => MOVE_ALL, |
| 156 |
); |
| 157 |
|
| 158 |
our @MOVE_TYPE = qw(all walk flying fly_low fly_high swim boat ship); |
| 159 |
|
| 160 |
{ |
| 161 |
package Deliantra::MoveType; |
| 162 |
|
| 163 |
use overload |
| 164 |
'=' => sub { bless [@{$_[0]}], ref $_[0] }, |
| 165 |
'""' => \&as_string, |
| 166 |
'>=' => sub { $_[0][0] & $MOVE_TYPE{$_[1]} ? $_[0][1] & $MOVE_TYPE{$_[1]} : undef }, |
| 167 |
'+=' => sub { $_[0][0] |= $MOVE_TYPE{$_[1]}; $_[0][1] |= $MOVE_TYPE{$_[1]}; &normalise }, |
| 168 |
'-=' => sub { $_[0][0] |= $MOVE_TYPE{$_[1]}; $_[0][1] &= ~$MOVE_TYPE{$_[1]}; &normalise }, |
| 169 |
'/=' => sub { $_[0][0] &= ~$MOVE_TYPE{$_[1]}; &normalise }, |
| 170 |
'x=' => sub { |
| 171 |
my $cur = $_[0] >= $_[1]; |
| 172 |
if (!defined $cur) { |
| 173 |
if ($_[0] >= "all") { |
| 174 |
$_[0] -= $_[1]; |
| 175 |
} else { |
| 176 |
$_[0] += $_[1]; |
| 177 |
} |
| 178 |
} elsif ($cur) { |
| 179 |
$_[0] -= $_[1]; |
| 180 |
} else { |
| 181 |
$_[0] /= $_[1]; |
| 182 |
} |
| 183 |
|
| 184 |
$_[0] |
| 185 |
}, |
| 186 |
'eq' => sub { "$_[0]" eq "$_[1]" }, |
| 187 |
'ne' => sub { "$_[0]" ne "$_[1]" }, |
| 188 |
; |
| 189 |
|
| 190 |
sub TO_JSON { |
| 191 |
$_[0][0] |
| 192 |
} |
| 193 |
} |
| 194 |
|
| 195 |
sub Deliantra::MoveType::new { |
| 196 |
my ($class, $string) = @_; |
| 197 |
|
| 198 |
my $mask; |
| 199 |
my $value; |
| 200 |
|
| 201 |
if ($string =~ /^\s*\d+\s*$/) { |
| 202 |
$mask = MOVE_ALL; |
| 203 |
$value = $string+0; |
| 204 |
} else { |
| 205 |
for (split /\s+/, lc $string) { |
| 206 |
if (s/^-//) { |
| 207 |
$mask |= $MOVE_TYPE{$_}; |
| 208 |
$value &= ~$MOVE_TYPE{$_}; |
| 209 |
} else { |
| 210 |
$mask |= $MOVE_TYPE{$_}; |
| 211 |
$value |= $MOVE_TYPE{$_}; |
| 212 |
} |
| 213 |
} |
| 214 |
} |
| 215 |
|
| 216 |
(bless [$mask, $value], $class)->normalise |
| 217 |
} |
| 218 |
|
| 219 |
sub Deliantra::MoveType::normalise { |
| 220 |
my ($self) = @_; |
| 221 |
|
| 222 |
if ($self->[0] & MOVE_ALL) { |
| 223 |
my $mask = ~(($self->[1] & MOVE_ALL ? $self->[1] : ~$self->[1]) & $self->[0] & ~MOVE_ALL); |
| 224 |
$self->[0] &= $mask; |
| 225 |
$self->[1] &= $mask; |
| 226 |
} |
| 227 |
|
| 228 |
$self->[1] &= $self->[0]; |
| 229 |
|
| 230 |
$self |
| 231 |
} |
| 232 |
|
| 233 |
sub Deliantra::MoveType::as_string { |
| 234 |
my ($self) = @_; |
| 235 |
|
| 236 |
my @res; |
| 237 |
|
| 238 |
my ($mask, $value) = @$self; |
| 239 |
|
| 240 |
for (@Deliantra::MOVE_TYPE) { |
| 241 |
my $bit = $Deliantra::MOVE_TYPE{$_}; |
| 242 |
if (($mask & $bit) == $bit && (($value & $bit) == $bit || ($value & $bit) == 0)) { |
| 243 |
$mask &= ~$bit; |
| 244 |
push @res, $value & $bit ? $_ : "-$_"; |
| 245 |
} |
| 246 |
} |
| 247 |
|
| 248 |
join " ", @res |
| 249 |
} |
| 250 |
|
| 251 |
sub load_ref($) { |
| 252 |
my ($path) = @_; |
| 253 |
|
| 254 |
open my $fh, "<:raw:perlio", $path |
| 255 |
or die "$path: $!"; |
| 256 |
local $/; |
| 257 |
|
| 258 |
thaw <$fh> |
| 259 |
} |
| 260 |
|
| 261 |
sub save_ref($$) { |
| 262 |
my ($ref, $path) = @_; |
| 263 |
|
| 264 |
open my $fh, ">:raw:perlio", "$path~" |
| 265 |
or die "$path~: $!"; |
| 266 |
print $fh freeze $ref; |
| 267 |
close $fh; |
| 268 |
rename "$path~", $path |
| 269 |
or die "$path: $!"; |
| 270 |
} |
| 271 |
|
| 272 |
my %attack_mask = ( |
| 273 |
physical => 0x00000001, |
| 274 |
magic => 0x00000002, |
| 275 |
fire => 0x00000004, |
| 276 |
electricity => 0x00000008, |
| 277 |
cold => 0x00000010, |
| 278 |
confusion => 0x00000020, |
| 279 |
acid => 0x00000040, |
| 280 |
drain => 0x00000080, |
| 281 |
weaponmagic => 0x00000100, |
| 282 |
ghosthit => 0x00000200, |
| 283 |
poison => 0x00000400, |
| 284 |
slow => 0x00000800, |
| 285 |
paralyze => 0x00001000, |
| 286 |
turn_undead => 0x00002000, |
| 287 |
fear => 0x00004000, |
| 288 |
cancellation => 0x00008000, |
| 289 |
deplete => 0x00010000, |
| 290 |
death => 0x00020000, |
| 291 |
chaos => 0x00040000, |
| 292 |
counterspell => 0x00080000, |
| 293 |
godpower => 0x00100000, |
| 294 |
holyword => 0x00200000, |
| 295 |
blind => 0x00400000, |
| 296 |
internal => 0x00800000, |
| 297 |
life_stealing => 0x01000000, |
| 298 |
disease => 0x02000000, |
| 299 |
); |
| 300 |
|
| 301 |
sub _add_resist($$$) { |
| 302 |
my ($ob, $mask, $value) = @_; |
| 303 |
|
| 304 |
while (my ($k, $v) = each %attack_mask) { |
| 305 |
$ob->{"resist_$k"} = min 100, max -100, $ob->{"resist_$k"} + $value if $mask & $v; |
| 306 |
} |
| 307 |
} |
| 308 |
|
| 309 |
my %MATERIAL = reverse |
| 310 |
paper => 1, |
| 311 |
iron => 2, |
| 312 |
glass => 4, |
| 313 |
leather => 8, |
| 314 |
wood => 16, |
| 315 |
organic => 32, |
| 316 |
stone => 64, |
| 317 |
cloth => 128, |
| 318 |
adamant => 256, |
| 319 |
liquid => 512, |
| 320 |
tin => 1024, |
| 321 |
bone => 2048, |
| 322 |
ice => 4096, |
| 323 |
|
| 324 |
# guesses |
| 325 |
runestone => 12, |
| 326 |
bronze => 18, |
| 327 |
"ancient wood" => 20, |
| 328 |
glass => 36, |
| 329 |
marble => 66, |
| 330 |
ice => 68, |
| 331 |
stone => 70, |
| 332 |
stone => 80, |
| 333 |
cloth => 136, |
| 334 |
ironwood => 144, |
| 335 |
adamantium => 258, |
| 336 |
glacium => 260, |
| 337 |
blood => 544, |
| 338 |
; |
| 339 |
|
| 340 |
# object as in "Object xxx", i.e. archetypes |
| 341 |
sub normalize_object($) { |
| 342 |
my ($ob) = @_; |
| 343 |
|
| 344 |
delete $ob->{editable}; # deprecated |
| 345 |
|
| 346 |
# convert material bitset to materialname, if possible |
| 347 |
if (exists $ob->{material}) { |
| 348 |
if (!$ob->{material}) { |
| 349 |
delete $ob->{material}; |
| 350 |
} elsif (exists $ob->{materialname}) { |
| 351 |
if ($MATERIAL{$ob->{material}} eq $ob->{materialname}) { |
| 352 |
delete $ob->{material}; |
| 353 |
} else { |
| 354 |
warn "object $ob->{_name} has both materialname ($ob->{materialname}) and material ($ob->{material}) set.\n"; |
| 355 |
delete $ob->{material}; # assume materilname is more specific and nuke material |
| 356 |
} |
| 357 |
} elsif (my $name = $MATERIAL{$ob->{material}}) { |
| 358 |
delete $ob->{material}; |
| 359 |
$ob->{materialname} = $name; |
| 360 |
} else { |
| 361 |
warn "object $ob->{_name} has unknown material ($ob->{material}) set.\n"; |
| 362 |
} |
| 363 |
} |
| 364 |
|
| 365 |
# check whether attachment is the same as in the archetype |
| 366 |
if (exists $ob->{attach}) { |
| 367 |
my $arch = $ARCH{$ob->{_name}}; |
| 368 |
my $js = JSON::XS->new->utf8->canonical (1); |
| 369 |
|
| 370 |
if (defined $arch->{attach} |
| 371 |
&& $js->encode ($js->decode ($ob->{attach})) eq $js->encode ($arch->{attach})) { |
| 372 |
delete $ob->{attach} |
| 373 |
} |
| 374 |
} |
| 375 |
|
| 376 |
# color_fg is used as default for magicmap if magicmap does not exist |
| 377 |
$ob->{magicmap} ||= delete $ob->{color_fg} if exists $ob->{color_fg}; |
| 378 |
|
| 379 |
# nuke outdated or never supported fields |
| 380 |
delete @$ob{qw( |
| 381 |
can_knockback can_parry can_impale can_cut can_dam_armour |
| 382 |
can_apply pass_thru can_pass_thru color_bg color_fg |
| 383 |
)}; |
| 384 |
|
| 385 |
if (my $mask = delete $ob->{immune} ) { _add_resist $ob, $mask, 100; } |
| 386 |
if (my $mask = delete $ob->{protected} ) { _add_resist $ob, $mask, 30; } |
| 387 |
if (my $mask = delete $ob->{vulnerable}) { _add_resist $ob, $mask, -100; } |
| 388 |
|
| 389 |
# convert movement strings to bitsets |
| 390 |
for my $attr (keys %FIELD_MOVEMENT) { |
| 391 |
next unless exists $ob->{$attr}; |
| 392 |
|
| 393 |
$ob->{$attr} = new Deliantra::MoveType $ob->{$attr}; |
| 394 |
} |
| 395 |
|
| 396 |
# convert outdated movement flags to new movement sets |
| 397 |
if (defined (my $v = delete $ob->{no_pass})) { |
| 398 |
$ob->{move_block} = new Deliantra::MoveType $v ? "all" : "0"; |
| 399 |
} |
| 400 |
if (defined (my $v = delete $ob->{slow_move})) { |
| 401 |
$ob->{move_slow} += "walk"; |
| 402 |
$ob->{move_slow_penalty} = $v; |
| 403 |
} |
| 404 |
if (defined (my $v = delete $ob->{walk_on})) { |
| 405 |
$ob->{move_on} ||= new Deliantra::MoveType; if ($v) { $ob->{move_on} += "walk" } else { $ob->{move_on} -= "walk" } |
| 406 |
} |
| 407 |
if (defined (my $v = delete $ob->{walk_off})) { |
| 408 |
$ob->{move_off} ||= new Deliantra::MoveType; if ($v) { $ob->{move_off} += "walk" } else { $ob->{move_off} -= "walk" } |
| 409 |
} |
| 410 |
if (defined (my $v = delete $ob->{fly_on})) { |
| 411 |
$ob->{move_on} ||= new Deliantra::MoveType; if ($v) { $ob->{move_on} += "fly_low" } else { $ob->{move_on} -= "fly_low" } |
| 412 |
} |
| 413 |
if (defined (my $v = delete $ob->{fly_off})) { |
| 414 |
$ob->{move_off} ||= new Deliantra::MoveType; if ($v) { $ob->{move_off} += "fly_low" } else { $ob->{move_off} -= "fly_low" } |
| 415 |
} |
| 416 |
if (defined (my $v = delete $ob->{flying})) { |
| 417 |
$ob->{move_type} ||= new Deliantra::MoveType; if ($v) { $ob->{move_type} += "fly_low" } else { $ob->{move_type} -= "fly_low" } |
| 418 |
} |
| 419 |
|
| 420 |
# convert idiotic event_xxx things into objects |
| 421 |
while (my ($event, $subtype) = each %EVENT_TYPE) { |
| 422 |
if (exists $ob->{"event_${event}_plugin"}) { |
| 423 |
push @{$ob->{inventory}}, { |
| 424 |
_name => "event_$event", |
| 425 |
title => delete $ob->{"event_${event}_plugin"}, |
| 426 |
slaying => delete $ob->{"event_${event}"}, |
| 427 |
name => delete $ob->{"event_${event}_options"}, |
| 428 |
}; |
| 429 |
} |
| 430 |
} |
| 431 |
|
| 432 |
# some archetypes had "+3" instead of the canonical "3", so fix |
| 433 |
$ob->{dam} *= 1 if exists $ob->{dam}; |
| 434 |
|
| 435 |
$ob |
| 436 |
} |
| 437 |
|
| 438 |
# arch as in "arch xxx", ie.. objects |
| 439 |
sub normalize_arch($) { |
| 440 |
my ($ob) = @_; |
| 441 |
|
| 442 |
normalize_object $ob; |
| 443 |
|
| 444 |
return if $ob->{_atype} eq "object"; |
| 445 |
|
| 446 |
my $arch = $ARCH{$ob->{_name}} |
| 447 |
or (warn "$ob->{_name}: no such archetype", return $ob); |
| 448 |
|
| 449 |
if ($arch->{type} == 22) { # map |
| 450 |
my %normalize = ( |
| 451 |
"enter_x" => "hp", |
| 452 |
"enter_y" => "sp", |
| 453 |
"width" => "x", |
| 454 |
"height" => "y", |
| 455 |
"reset_timeout" => "weight", |
| 456 |
"swap_time" => "value", |
| 457 |
"difficulty" => "level", |
| 458 |
"darkness" => "invisible", |
| 459 |
"fixed_resettime" => "stand_still", |
| 460 |
); |
| 461 |
|
| 462 |
while (my ($k2, $k1) = each %normalize) { |
| 463 |
if (defined (my $v = delete $ob->{$k1})) { |
| 464 |
$ob->{$k2} = $v; |
| 465 |
} |
| 466 |
} |
| 467 |
} else { |
| 468 |
# if value matches archetype default, delete |
| 469 |
while (my ($k, $v) = each %$ob) { |
| 470 |
if (exists $arch->{$k} and $arch->{$k} eq $v) { |
| 471 |
next if $k eq "_name"; |
| 472 |
delete $ob->{$k}; |
| 473 |
} |
| 474 |
} |
| 475 |
} |
| 476 |
|
| 477 |
# a speciality for the editor |
| 478 |
if (exists $ob->{attack_movement}) { |
| 479 |
my $am = delete $ob->{attack_movement}; |
| 480 |
$ob->{attack_movement_bits_0_3} = $am & 15; |
| 481 |
$ob->{attack_movement_bits_4_7} = $am & 240; |
| 482 |
} |
| 483 |
|
| 484 |
$ob |
| 485 |
} |
| 486 |
|
| 487 |
sub attr_thaw($) { |
| 488 |
my ($ob) = @_; |
| 489 |
|
| 490 |
$ob->{attach} = decode_json $ob->{attach} |
| 491 |
if exists $ob->{attach}; |
| 492 |
|
| 493 |
$ob |
| 494 |
} |
| 495 |
|
| 496 |
sub attr_freeze($) { |
| 497 |
my ($ob) = @_; |
| 498 |
|
| 499 |
$ob->{attach} = JSON::XS->new->utf8->canonical->encode ($ob->{attach}) |
| 500 |
if exists $ob->{attach}; |
| 501 |
|
| 502 |
$ob |
| 503 |
} |
| 504 |
|
| 505 |
sub read_pak($) { |
| 506 |
my ($path) = @_; |
| 507 |
|
| 508 |
my %pak; |
| 509 |
|
| 510 |
open my $fh, "<:raw:perlio", $path |
| 511 |
or Carp::croak "$_[0]: $!"; |
| 512 |
binmode $fh; |
| 513 |
while (<$fh>) { |
| 514 |
my ($type, $id, $len, $path) = split; |
| 515 |
$path =~ s/.*\///; |
| 516 |
read $fh, $pak{$path}, $len; |
| 517 |
} |
| 518 |
|
| 519 |
\%pak |
| 520 |
} |
| 521 |
|
| 522 |
sub read_arch($;$) { |
| 523 |
my ($path, $toplevel) = @_; |
| 524 |
|
| 525 |
my %arc; |
| 526 |
my ($more, $prev); |
| 527 |
my $comment; |
| 528 |
|
| 529 |
open my $fh, "<:utf8", $path |
| 530 |
or Carp::croak "$path: $!"; |
| 531 |
|
| 532 |
# binmode $fh; |
| 533 |
|
| 534 |
my $parse_block; $parse_block = sub { |
| 535 |
my %arc = @_; |
| 536 |
|
| 537 |
while (<$fh>) { |
| 538 |
s/\s+$//; |
| 539 |
if (/^end$/i) { |
| 540 |
last; |
| 541 |
|
| 542 |
} elsif (/^arch (\S+)$/i) { |
| 543 |
push @{ $arc{inventory} }, attr_thaw normalize_arch $parse_block->(_name => $1); |
| 544 |
|
| 545 |
} elsif (/^lore$/i) { |
| 546 |
while (<$fh>) { |
| 547 |
last if /^endlore\s*$/i; |
| 548 |
$arc{lore} .= $_; |
| 549 |
} |
| 550 |
} elsif (/^msg$/i) { |
| 551 |
while (<$fh>) { |
| 552 |
last if /^endmsg\s*$/i; |
| 553 |
$arc{msg} .= $_; |
| 554 |
} |
| 555 |
} elsif (/^anim$/i) { |
| 556 |
while (<$fh>) { |
| 557 |
last if /^mina\s*$/i; |
| 558 |
chomp; |
| 559 |
push @{ $arc{anim} }, $_; |
| 560 |
} |
| 561 |
} elsif (/^(\S+)\s*(.*)$/) { |
| 562 |
$arc{lc $1} = $2; |
| 563 |
} elsif (/^\s*#/) { |
| 564 |
$arc{_comment} .= "$_\n"; |
| 565 |
|
| 566 |
} elsif (/^\s*$/) { |
| 567 |
# |
| 568 |
} else { |
| 569 |
warn "$path: unparsable line '$_' in arch $arc{_name}"; |
| 570 |
} |
| 571 |
} |
| 572 |
|
| 573 |
\%arc |
| 574 |
}; |
| 575 |
|
| 576 |
while (<$fh>) { |
| 577 |
s/\s+$//; |
| 578 |
if (/^more$/i) { |
| 579 |
$more = $prev; |
| 580 |
} elsif (/^object (\S+)$/i) { |
| 581 |
my $name = $1; |
| 582 |
my $arc = attr_thaw normalize_object $parse_block->(_name => $name, _comment => $comment); |
| 583 |
undef $comment; |
| 584 |
delete $arc{_comment} unless length $arc{_comment}; |
| 585 |
$arc->{_atype} = 'object'; |
| 586 |
|
| 587 |
if ($more) { |
| 588 |
$more->{more} = $arc; |
| 589 |
} else { |
| 590 |
$arc{$name} = $arc; |
| 591 |
} |
| 592 |
$prev = $arc; |
| 593 |
$more = undef; |
| 594 |
} elsif (/^arch (\S+)$/i) { |
| 595 |
my $name = $1; |
| 596 |
my $arc = attr_thaw normalize_arch $parse_block->(_name => $name, _comment => $comment); |
| 597 |
undef $comment; |
| 598 |
delete $arc{_comment} unless length $arc{_comment}; |
| 599 |
$arc->{_atype} = 'arch'; |
| 600 |
|
| 601 |
if ($more) { |
| 602 |
$more->{more} = $arc; |
| 603 |
} else { |
| 604 |
push @{ $arc{arch} }, $arc; |
| 605 |
} |
| 606 |
$prev = $arc; |
| 607 |
$more = undef; |
| 608 |
} elsif ($toplevel && /^(\S+)\s+(.*)$/) { |
| 609 |
if ($1 eq "lev_array") { |
| 610 |
while (<$fh>) { |
| 611 |
last if /^endplst\s*$/; |
| 612 |
push @{$toplevel->{lev_array}}, $_+0; |
| 613 |
} |
| 614 |
} else { |
| 615 |
$toplevel->{$1} = $2; |
| 616 |
} |
| 617 |
} elsif (/^\s*#/) { |
| 618 |
$comment .= "$_\n"; |
| 619 |
} elsif (/^\s*($|#)/) { |
| 620 |
# |
| 621 |
} else { |
| 622 |
die "$path: unparseable top-level line '$_'"; |
| 623 |
} |
| 624 |
} |
| 625 |
|
| 626 |
undef $parse_block; # work around bug in perl not freeing $fh etc. |
| 627 |
|
| 628 |
\%arc |
| 629 |
} |
| 630 |
|
| 631 |
sub archlist_to_string { |
| 632 |
my ($arch) = @_; |
| 633 |
|
| 634 |
my $str; |
| 635 |
|
| 636 |
my $append; $append = sub { |
| 637 |
my %a = %{$_[0]}; |
| 638 |
|
| 639 |
Deliantra::attr_freeze \%a; |
| 640 |
Deliantra::normalize_arch \%a; |
| 641 |
|
| 642 |
# undo the bit-split we did before |
| 643 |
if (exists $a{attack_movement_bits_0_3} or exists $a{attack_movement_bits_4_7}) { |
| 644 |
$a{attack_movement} = (delete $a{attack_movement_bits_0_3}) |
| 645 |
| (delete $a{attack_movement_bits_4_7}); |
| 646 |
} |
| 647 |
|
| 648 |
if (my $comment = delete $a{_comment}) { |
| 649 |
if ($comment =~ /[^\n\s#]/) { |
| 650 |
$str .= $comment; |
| 651 |
} |
| 652 |
} |
| 653 |
|
| 654 |
$str .= ((exists $a{_atype}) ? $a{_atype} : 'arch'). " $a{_name}\n"; |
| 655 |
|
| 656 |
my $inv = delete $a{inventory}; |
| 657 |
my $more = delete $a{more}; # arches do not support 'more', but old maps can contain some |
| 658 |
my $anim = delete $a{anim}; |
| 659 |
|
| 660 |
if ($a{_atype} eq 'object') { |
| 661 |
$str .= join "\n", "anim", @$anim, "mina\n" |
| 662 |
if $anim; |
| 663 |
} |
| 664 |
|
| 665 |
my @kv; |
| 666 |
|
| 667 |
for ($a{_name} eq "map" |
| 668 |
? @Deliantra::FIELD_ORDER_MAP |
| 669 |
: @Deliantra::FIELD_ORDER) { |
| 670 |
push @kv, [$_, delete $a{$_}] |
| 671 |
if exists $a{$_}; |
| 672 |
} |
| 673 |
|
| 674 |
for (sort keys %a) { |
| 675 |
next if /^_/; # ignore our _-keys |
| 676 |
push @kv, [$_, delete $a{$_}]; |
| 677 |
} |
| 678 |
|
| 679 |
for (@kv) { |
| 680 |
my ($k, $v) = @$_; |
| 681 |
|
| 682 |
if (my $end = $Deliantra::FIELD_MULTILINE{$k}) { |
| 683 |
$v =~ s/\n$//; |
| 684 |
$str .= "$k\n$v\n$end\n"; |
| 685 |
} else { |
| 686 |
$str .= "$k $v\n"; |
| 687 |
} |
| 688 |
} |
| 689 |
|
| 690 |
if ($inv) { |
| 691 |
$append->($_) for @$inv; |
| 692 |
} |
| 693 |
|
| 694 |
$str .= "end\n"; |
| 695 |
|
| 696 |
if ($a{_atype} eq 'object') { |
| 697 |
if ($more) { |
| 698 |
$str .= "more\n"; |
| 699 |
$append->($more) if $more; |
| 700 |
} else { |
| 701 |
$str .= "\n"; |
| 702 |
} |
| 703 |
} |
| 704 |
}; |
| 705 |
|
| 706 |
for (@$arch) { |
| 707 |
$append->($_); |
| 708 |
} |
| 709 |
|
| 710 |
$str |
| 711 |
} |
| 712 |
|
| 713 |
# put all archs into a hash with editor_face as it's key |
| 714 |
# NOTE: the arrays in the hash values are references to |
| 715 |
# the archs from $ARCH |
| 716 |
sub editor_archs { |
| 717 |
my %paths; |
| 718 |
|
| 719 |
for (keys %ARCH) { |
| 720 |
my $arch = $ARCH{$_}; |
| 721 |
push @{$paths{$arch->{editor_folder}}}, $arch; |
| 722 |
} |
| 723 |
|
| 724 |
\%paths |
| 725 |
} |
| 726 |
|
| 727 |
=item ($minx, $miny, $maxx, $maxy) = arch_extents $arch |
| 728 |
|
| 729 |
arch_extents determines the extents of the given arch's face(s), linked |
| 730 |
faces and single faces are handled here it returns (minx, miny, maxx, |
| 731 |
maxy) |
| 732 |
|
| 733 |
=cut |
| 734 |
|
| 735 |
sub arch_extents { |
| 736 |
my ($a) = @_; |
| 737 |
|
| 738 |
my $o = $ARCH{$a->{_name}} |
| 739 |
or return; |
| 740 |
|
| 741 |
my $face = $FACE{$a->{face} || $o->{face} || "blank.111"}; |
| 742 |
unless ($face) { |
| 743 |
$face = $FACE{"blank.x11"} |
| 744 |
or (warn "no face data found for arch '$a->{_name}'"), return; |
| 745 |
} |
| 746 |
|
| 747 |
if ($face->{w} > 1 || $face->{h} > 1) { |
| 748 |
# bigface |
| 749 |
return (0, 0, $face->{w} - 1, $face->{h} - 1); |
| 750 |
|
| 751 |
} elsif ($o->{more}) { |
| 752 |
# linked face |
| 753 |
my ($minx, $miny, $maxx, $maxy) = ($o->{x}, $o->{y}) x 2; |
| 754 |
|
| 755 |
for (; $o; $o = $o->{more}) { |
| 756 |
$minx = min $minx, $o->{x}; |
| 757 |
$miny = min $miny, $o->{y}; |
| 758 |
$maxx = max $maxx, $o->{x}; |
| 759 |
$maxy = max $maxy, $o->{y}; |
| 760 |
} |
| 761 |
|
| 762 |
return ($minx, $miny, $maxx, $maxy); |
| 763 |
|
| 764 |
} else { |
| 765 |
# single face |
| 766 |
return (0, 0, 0, 0); |
| 767 |
} |
| 768 |
} |
| 769 |
|
| 770 |
=item $type = arch_attr $arch |
| 771 |
|
| 772 |
Returns a hashref describing the object and its attributes. It can contain |
| 773 |
the following keys: |
| 774 |
|
| 775 |
name the name, suitable for display purposes |
| 776 |
ignore |
| 777 |
attr |
| 778 |
desc |
| 779 |
use |
| 780 |
section => [name => \%attr, name => \%attr] |
| 781 |
import |
| 782 |
|
| 783 |
=cut |
| 784 |
|
| 785 |
sub arch_attr($) { |
| 786 |
my ($obj) = @_; |
| 787 |
|
| 788 |
require Deliantra::Data; |
| 789 |
|
| 790 |
my $root; |
| 791 |
my $attr = { }; |
| 792 |
|
| 793 |
my $arch = $ARCH{ $obj->{_name} }; |
| 794 |
my $type = $obj->{type} || $arch->{type}; |
| 795 |
|
| 796 |
if ($type > 0) { |
| 797 |
$root = $Deliantra::Data::ATTR{$type}; |
| 798 |
} else { |
| 799 |
my %a = (%$arch, %$obj); |
| 800 |
|
| 801 |
if ($a{is_floor} && !$a{alive}) { |
| 802 |
$root = $Deliantra::Data::TYPE{Floor}; |
| 803 |
} elsif (!$a{is_floor} && $a{alive} && !$a{tear_down}) { |
| 804 |
$root = $Deliantra::Data::TYPE{"Monster & NPC"}; |
| 805 |
} elsif (!$a{is_floor} && !$a{alive} && $a{move_block}) { |
| 806 |
$root = $Deliantra::Data::TYPE{Wall}; |
| 807 |
} elsif (!$a{is_floor} && $a{alive} && $a{tear_down}) { |
| 808 |
$root = $Deliantra::Data::TYPE{"Weak Wall"}; |
| 809 |
} else { |
| 810 |
$root = $Deliantra::Data::TYPE{Misc}; |
| 811 |
} |
| 812 |
} |
| 813 |
|
| 814 |
my @import = ($root); |
| 815 |
|
| 816 |
unshift @import, \%Deliantra::Data::DEFAULT_ATTR |
| 817 |
unless $type == 116; |
| 818 |
|
| 819 |
my (%ignore); |
| 820 |
my (@section_order, %section, @attr_order); |
| 821 |
|
| 822 |
while (my $type = shift @import) { |
| 823 |
push @import, |
| 824 |
grep $_, |
| 825 |
map $Deliantra::Data::TYPE{$_}, |
| 826 |
@{$type->{import} || []}; |
| 827 |
|
| 828 |
$attr->{$_} ||= $type->{$_} |
| 829 |
for qw(name desc use); |
| 830 |
|
| 831 |
for (@{$type->{ignore} || []}) { |
| 832 |
$ignore{$_}++ for ref $_ ? @$_ : $_; |
| 833 |
} |
| 834 |
|
| 835 |
for ([general => ($type->{attr} || [])], @{$type->{section} || []}) { |
| 836 |
my ($name, $attr) = @$_; |
| 837 |
push @section_order, $name; |
| 838 |
for (@$attr) { |
| 839 |
my ($k, $v) = @$_; |
| 840 |
push @attr_order, $k; |
| 841 |
$section{$name}{$k} ||= $v; |
| 842 |
} |
| 843 |
} |
| 844 |
} |
| 845 |
|
| 846 |
$attr->{section} = [ |
| 847 |
map !exists $section{$_} ? () : do { |
| 848 |
my $attr = delete $section{$_}; |
| 849 |
|
| 850 |
[ |
| 851 |
$_, |
| 852 |
map exists $attr->{$_} && !$ignore{$_} |
| 853 |
? [$_ => delete $attr->{$_}] : (), |
| 854 |
@attr_order |
| 855 |
] |
| 856 |
}, |
| 857 |
|
| 858 |
exists $section{$_} ? [$_ => delete $section{$_}] : (), |
| 859 |
@section_order |
| 860 |
]; |
| 861 |
|
| 862 |
$attr |
| 863 |
} |
| 864 |
|
| 865 |
sub cache_file($$&&) { |
| 866 |
my ($src, $cache, $load, $create) = @_; |
| 867 |
|
| 868 |
my ($size, $mtime) = (stat $src)[7,9] |
| 869 |
or Carp::croak "$src: $!"; |
| 870 |
|
| 871 |
if (-e $cache) { |
| 872 |
my $ref = eval { load_ref $cache }; |
| 873 |
|
| 874 |
if ($ref->{version} == 1 |
| 875 |
&& $ref->{size} == $size |
| 876 |
&& $ref->{mtime} == $mtime |
| 877 |
&& eval { $load->($ref->{data}); 1 }) { |
| 878 |
return; |
| 879 |
} |
| 880 |
} |
| 881 |
|
| 882 |
my $ref = { |
| 883 |
version => 1, |
| 884 |
size => $size, |
| 885 |
mtime => $mtime, |
| 886 |
data => $create->(), |
| 887 |
}; |
| 888 |
|
| 889 |
$load->($ref->{data}); |
| 890 |
|
| 891 |
save_ref $ref, $cache; |
| 892 |
} |
| 893 |
|
| 894 |
=item set_libdir $path |
| 895 |
|
| 896 |
Sets the library directory to the given path |
| 897 |
(default: $ENV{CROSSFIRE_LIBDIR}). |
| 898 |
|
| 899 |
You have to (re-)load the archetypes and tilecache manually after steting |
| 900 |
the library path. |
| 901 |
|
| 902 |
=cut |
| 903 |
|
| 904 |
sub set_libdir($) { |
| 905 |
$LIB = $_[0]; |
| 906 |
} |
| 907 |
|
| 908 |
=item load_archetypes |
| 909 |
|
| 910 |
(Re-)Load archetypes into %ARCH. |
| 911 |
|
| 912 |
=cut |
| 913 |
|
| 914 |
sub load_archetypes() { |
| 915 |
cache_file "$LIB/archetypes", "$VARDIR/archetypes.pst", sub { |
| 916 |
*ARCH = $_[0]; |
| 917 |
}, sub { |
| 918 |
read_arch "$LIB/archetypes" |
| 919 |
}; |
| 920 |
} |
| 921 |
|
| 922 |
sub construct_tilecache_pb { |
| 923 |
my ($idx, $cache) = @_; |
| 924 |
|
| 925 |
my $pb = new Gtk2::Gdk::Pixbuf "rgb", 1, 8, CACHESTRIDE * TILESIZE, TILESIZE * int +($idx + CACHESTRIDE - 1) / CACHESTRIDE; |
| 926 |
|
| 927 |
while (my ($name, $tile) = each %$cache) { |
| 928 |
my $tpb = delete $tile->{pb}; |
| 929 |
my $ofs = $tile->{idx}; |
| 930 |
|
| 931 |
for my $x (0 .. $tile->{w} - 1) { |
| 932 |
for my $y (0 .. $tile->{h} - 1) { |
| 933 |
my $idx = $ofs + $x + $y * $tile->{w}; |
| 934 |
$tpb->copy_area ($x * TILESIZE, $y * TILESIZE, TILESIZE, TILESIZE, |
| 935 |
$pb, ($idx % CACHESTRIDE) * TILESIZE, TILESIZE * int $idx / CACHESTRIDE); |
| 936 |
} |
| 937 |
} |
| 938 |
} |
| 939 |
|
| 940 |
$pb->save ("$VARDIR/tilecache.png", "png", compression => 1); |
| 941 |
|
| 942 |
$cache |
| 943 |
} |
| 944 |
|
| 945 |
sub use_tilecache { |
| 946 |
my ($face) = @_; |
| 947 |
$TILE = new_from_file Gtk2::Gdk::Pixbuf "$VARDIR/tilecache.png" |
| 948 |
or die "$VARDIR/tilecache.png: $!"; |
| 949 |
*FACE = $_[0]; |
| 950 |
} |
| 951 |
|
| 952 |
=item load_tilecache |
| 953 |
|
| 954 |
(Re-)Load %TILE and %FACE. |
| 955 |
|
| 956 |
=cut |
| 957 |
|
| 958 |
sub load_tilecache() { |
| 959 |
require Gtk2; |
| 960 |
|
| 961 |
cache_file "$LIB/facedata", "$VARDIR/tilecache.pst", \&use_tilecache, |
| 962 |
sub { |
| 963 |
my %cache; |
| 964 |
my $facedata = Storable::retrieve "$LIB/facedata"; |
| 965 |
|
| 966 |
$facedata->{version} == 2 |
| 967 |
or die "$LIB/facedata: version mismatch, cannot proceed."; |
| 968 |
|
| 969 |
my $faces = $facedata->{faceinfo}; |
| 970 |
my $idx = 0; |
| 971 |
|
| 972 |
for (sort keys %$faces) { |
| 973 |
my ($face, $info) = ($_, $faces->{$_}); |
| 974 |
|
| 975 |
my $pb = new Gtk2::Gdk::PixbufLoader; |
| 976 |
$pb->write ($info->{data32}); |
| 977 |
$pb->close; |
| 978 |
my $pb = $pb->get_pixbuf; |
| 979 |
|
| 980 |
my $tile = $cache{$face} = { |
| 981 |
pb => $pb, |
| 982 |
idx => $idx, |
| 983 |
w => int $pb->get_width / TILESIZE, |
| 984 |
h => int $pb->get_height / TILESIZE, |
| 985 |
}; |
| 986 |
|
| 987 |
$idx += $tile->{w} * $tile->{h}; |
| 988 |
} |
| 989 |
|
| 990 |
construct_tilecache_pb $idx, \%cache; |
| 991 |
|
| 992 |
\%cache |
| 993 |
}; |
| 994 |
} |
| 995 |
|
| 996 |
=back |
| 997 |
|
| 998 |
=head1 AUTHOR |
| 999 |
|
| 1000 |
Marc Lehmann <schmorp@schmorp.de> |
| 1001 |
http://home.schmorp.de/ |
| 1002 |
|
| 1003 |
Robin Redeker <elmex@ta-sa.org> |
| 1004 |
http://www.ta-sa.org/ |
| 1005 |
|
| 1006 |
=cut |
| 1007 |
|
| 1008 |
1 |
| 1009 |
|
