| 1 |
=head1 NAME |
| 2 |
|
| 3 |
Deliantra - Deliantra suppport module to read/write archetypes, maps etc. |
| 4 |
|
| 5 |
=over 4 |
| 6 |
|
| 7 |
=cut |
| 8 |
|
| 9 |
package Deliantra; |
| 10 |
|
| 11 |
our $VERSION = '1.30'; |
| 12 |
|
| 13 |
use common::sense; |
| 14 |
|
| 15 |
use base 'Exporter'; |
| 16 |
|
| 17 |
use Carp (); |
| 18 |
use File::Spec; |
| 19 |
use List::Util qw(min max); |
| 20 |
use Storable qw(freeze thaw); |
| 21 |
|
| 22 |
our @EXPORT = qw( |
| 23 |
read_pak read_arch |
| 24 |
*ARCH $TILE *FACE *FACEDATA |
| 25 |
TILESIZE CACHESTRIDE |
| 26 |
editor_archs arch_extents |
| 27 |
); |
| 28 |
|
| 29 |
use JSON::XS qw(decode_json encode_json); |
| 30 |
|
| 31 |
our $LIB = $ENV{DELIANTRA_LIBDIR}; |
| 32 |
|
| 33 |
our $VARDIR = $ENV{HOME} ? "$ENV{HOME}/.deliantra" |
| 34 |
: $ENV{AppData} ? "$ENV{APPDATA}/deliantra" |
| 35 |
: File::Spec->tmpdir . "/deliantra"; |
| 36 |
|
| 37 |
mkdir $VARDIR, 0777; |
| 38 |
|
| 39 |
sub TILESIZE (){ 32 } |
| 40 |
sub CACHESTRIDE (){ 64 } |
| 41 |
|
| 42 |
our %ARCH; |
| 43 |
our %FACE; # face32 |
| 44 |
our %FACEDATA; |
| 45 |
our $TILE; |
| 46 |
|
| 47 |
our %FIELD_MULTILINE = ( |
| 48 |
msg => "endmsg", |
| 49 |
lore => "endlore", |
| 50 |
maplore => "endmaplore", |
| 51 |
); |
| 52 |
|
| 53 |
# movement bit type, PITA |
| 54 |
our %FIELD_MOVEMENT = map +($_ => undef), |
| 55 |
qw(move_type move_block move_allow move_on move_off move_slow); |
| 56 |
|
| 57 |
# same as in server save routine, to (hopefully) be compatible |
| 58 |
# to the other editors. |
| 59 |
our @FIELD_ORDER_MAP = (qw( |
| 60 |
file_format_version |
| 61 |
name attach swap_time reset_timeout fixed_resettime difficulty |
| 62 |
region music |
| 63 |
shopitems shopgreed shopmin shopmax shoprace |
| 64 |
darkness width height enter_x enter_y msg maplore |
| 65 |
unique template |
| 66 |
outdoor temp pressure humid windspeed winddir sky nosmooth |
| 67 |
tile_path_1 tile_path_2 tile_path_3 tile_path_4 |
| 68 |
)); |
| 69 |
|
| 70 |
our @FIELD_ORDER = (qw( |
| 71 |
inherit |
| 72 |
|
| 73 |
elevation |
| 74 |
|
| 75 |
name name_pl custom_name attach title race |
| 76 |
slaying skill msg lore other_arch |
| 77 |
sound sound_destroy face animation is_animated |
| 78 |
magicmap smoothlevel smoothface |
| 79 |
str dex con wis pow cha int |
| 80 |
hp maxhp sp maxsp grace maxgrace |
| 81 |
exp perm_exp expmul |
| 82 |
food dam luck wc ac x y speed speed_left move_state attack_movement |
| 83 |
nrof level direction type subtype attacktype |
| 84 |
|
| 85 |
resist_physical resist_magic resist_fire resist_electricity |
| 86 |
resist_cold resist_confusion resist_acid resist_drain |
| 87 |
resist_weaponmagic resist_ghosthit resist_poison resist_slow |
| 88 |
resist_paralyze resist_turn_undead resist_fear resist_cancellation |
| 89 |
resist_deplete resist_death resist_chaos resist_counterspell |
| 90 |
resist_godpower resist_holyword resist_blind resist_internal |
| 91 |
resist_life_stealing resist_disease |
| 92 |
|
| 93 |
path_attuned path_repelled path_denied material materialname |
| 94 |
value carrying weight invisible state magic |
| 95 |
last_heal last_sp last_grace last_eat |
| 96 |
connected glow_radius randomitems tresure_env npx_status npc_program |
| 97 |
run_away pick_up container will_apply smoothlevel |
| 98 |
current_weapon_script weapontype tooltype elevation client_type |
| 99 |
item_power duration range |
| 100 |
range_modifier duration_modifier dam_modifier gen_sp_armour |
| 101 |
move_type move_block move_allow move_on move_off move_on move_slow move_slow_penalty |
| 102 |
|
| 103 |
alive wiz was_wiz applied unpaid can_use_shield no_pick is_animated monster |
| 104 |
friendly generator is_thrown auto_apply treasure player sold see_invisible |
| 105 |
can_roll overlay_floor is_turnable is_used_up identified reflecting changing |
| 106 |
splitting hitback startequip blocksview undead scared unaggressive |
| 107 |
reflect_missile reflect_spell no_magic no_fix_player is_lightable tear_down |
| 108 |
run_away pick_up unique no_drop can_cast_spell can_use_scroll can_use_range |
| 109 |
can_use_bow can_use_armour can_use_weapon can_use_ring has_ready_range |
| 110 |
has_ready_bow xrays is_floor lifesave no_strength sleep stand_still |
| 111 |
random_move only_attack confused stealth cursed damned see_anywhere |
| 112 |
known_magical known_cursed can_use_skill been_applied has_ready_scroll |
| 113 |
can_use_rod can_use_horn make_invisible inv_locked is_wooded is_hilly |
| 114 |
has_ready_skill has_ready_weapon no_skill_ident is_blind can_see_in_dark |
| 115 |
is_cauldron is_dust no_steal one_hit berserk neutral no_attack no_damage |
| 116 |
activate_on_push activate_on_release is_water use_content_on_gen is_buildable |
| 117 |
precious |
| 118 |
|
| 119 |
body_range body_arm body_torso body_head body_neck body_skill |
| 120 |
body_finger body_shoulder body_foot body_hand body_wrist body_waist |
| 121 |
)); |
| 122 |
|
| 123 |
our %EVENT_TYPE = ( |
| 124 |
apply => 1, |
| 125 |
attack => 2, |
| 126 |
death => 3, |
| 127 |
drop => 4, |
| 128 |
pickup => 5, |
| 129 |
say => 6, |
| 130 |
stop => 7, |
| 131 |
time => 8, |
| 132 |
throw => 9, |
| 133 |
trigger => 10, |
| 134 |
close => 11, |
| 135 |
timer => 12, |
| 136 |
); |
| 137 |
|
| 138 |
sub MOVE_WALK (){ 0x01 } |
| 139 |
sub MOVE_FLY_LOW (){ 0x02 } |
| 140 |
sub MOVE_FLY_HIGH (){ 0x04 } |
| 141 |
sub MOVE_FLYING (){ 0x06 } |
| 142 |
sub MOVE_SWIM (){ 0x08 } |
| 143 |
sub MOVE_BOAT (){ 0x10 } |
| 144 |
sub MOVE_SHIP (){ 0x20 } |
| 145 |
sub MOVE_KNOWN (){ 0x3f } # all of above |
| 146 |
sub MOVE_ALL (){ 0x10000 } # very special value |
| 147 |
|
| 148 |
our %MOVE_TYPE = ( |
| 149 |
walk => MOVE_WALK, |
| 150 |
fly_low => MOVE_FLY_LOW, |
| 151 |
fly_high => MOVE_FLY_HIGH, |
| 152 |
flying => MOVE_FLYING, |
| 153 |
swim => MOVE_SWIM, |
| 154 |
boat => MOVE_BOAT, |
| 155 |
ship => MOVE_SHIP, |
| 156 |
all => MOVE_ALL, |
| 157 |
); |
| 158 |
|
| 159 |
our @MOVE_TYPE = qw(all walk flying fly_low fly_high swim boat ship); |
| 160 |
|
| 161 |
{ |
| 162 |
package Deliantra::MoveType; |
| 163 |
|
| 164 |
use overload |
| 165 |
'=' => sub { bless [@{$_[0]}], ref $_[0] }, |
| 166 |
'""' => \&as_string, |
| 167 |
'>=' => sub { $_[0][0] & $MOVE_TYPE{$_[1]} ? $_[0][1] & $MOVE_TYPE{$_[1]} : undef }, |
| 168 |
'<=' => sub { |
| 169 |
($_[0][0] & $MOVE_TYPE{$_[1]}) == $MOVE_TYPE{$_[1]} |
| 170 |
? $_[0][1] & $MOVE_TYPE{$_[1]} |
| 171 |
: undef |
| 172 |
}, |
| 173 |
'+=' => sub { $_[0][0] |= $MOVE_TYPE{$_[1]}; $_[0][1] |= $MOVE_TYPE{$_[1]}; &normalise }, |
| 174 |
'-=' => sub { $_[0][0] |= $MOVE_TYPE{$_[1]}; $_[0][1] &= ~$MOVE_TYPE{$_[1]}; &normalise }, |
| 175 |
'/=' => sub { $_[0][0] &= ~$MOVE_TYPE{$_[1]}; &normalise }, |
| 176 |
'x=' => sub { # toggle between off, + and - |
| 177 |
my $cur = $_[0] >= $_[1]; |
| 178 |
if (!defined $cur) { |
| 179 |
if ($_[0] >= "all") { |
| 180 |
$_[0] -= $_[1]; |
| 181 |
} else { |
| 182 |
$_[0] += $_[1]; |
| 183 |
} |
| 184 |
} elsif ($cur) { |
| 185 |
$_[0] -= $_[1]; |
| 186 |
} else { |
| 187 |
$_[0] /= $_[1]; |
| 188 |
} |
| 189 |
|
| 190 |
$_[0] |
| 191 |
}, |
| 192 |
'eq' => sub { "$_[0]" eq "$_[1]" }, |
| 193 |
'ne' => sub { "$_[0]" ne "$_[1]" }, |
| 194 |
; |
| 195 |
|
| 196 |
sub TO_JSON { |
| 197 |
$_[0][0] |
| 198 |
} |
| 199 |
} |
| 200 |
|
| 201 |
sub Deliantra::MoveType::new { |
| 202 |
my ($class, $string) = @_; |
| 203 |
|
| 204 |
my $mask; |
| 205 |
my $value; |
| 206 |
|
| 207 |
if ($string =~ /^\s*\d+\s*$/) { |
| 208 |
$mask = MOVE_ALL; |
| 209 |
$value = $string+0; |
| 210 |
} else { |
| 211 |
for (split /\s+/, lc $string) { |
| 212 |
if (s/^-//) { |
| 213 |
$mask |= $MOVE_TYPE{$_}; |
| 214 |
$value &= ~$MOVE_TYPE{$_}; |
| 215 |
} else { |
| 216 |
$mask |= $MOVE_TYPE{$_}; |
| 217 |
$value |= $MOVE_TYPE{$_}; |
| 218 |
} |
| 219 |
} |
| 220 |
} |
| 221 |
|
| 222 |
(bless [$mask, $value], $class)->normalise |
| 223 |
} |
| 224 |
|
| 225 |
sub Deliantra::MoveType::normalise { |
| 226 |
my ($self) = @_; |
| 227 |
|
| 228 |
if ($self->[0] & MOVE_ALL) { |
| 229 |
my $mask = ~(($self->[1] & MOVE_ALL ? $self->[1] : ~$self->[1]) & $self->[0] & ~MOVE_ALL); |
| 230 |
$self->[0] &= $mask; |
| 231 |
$self->[1] &= $mask; |
| 232 |
} |
| 233 |
|
| 234 |
$self->[1] &= $self->[0]; |
| 235 |
|
| 236 |
$self |
| 237 |
} |
| 238 |
|
| 239 |
sub Deliantra::MoveType::as_string { |
| 240 |
my ($self) = @_; |
| 241 |
|
| 242 |
my @res; |
| 243 |
|
| 244 |
my ($mask, $value) = @$self; |
| 245 |
|
| 246 |
for (@Deliantra::MOVE_TYPE) { |
| 247 |
my $bit = $Deliantra::MOVE_TYPE{$_}; |
| 248 |
if (($mask & $bit) == $bit && (($value & $bit) == $bit || ($value & $bit) == 0)) { |
| 249 |
$mask &= ~$bit; |
| 250 |
push @res, $value & $bit ? $_ : "-$_"; |
| 251 |
} |
| 252 |
} |
| 253 |
|
| 254 |
join " ", @res |
| 255 |
} |
| 256 |
|
| 257 |
sub load_ref($) { |
| 258 |
my ($path) = @_; |
| 259 |
|
| 260 |
open my $fh, "<:raw:perlio", $path |
| 261 |
or die "$path: $!"; |
| 262 |
local $/; |
| 263 |
|
| 264 |
thaw <$fh> |
| 265 |
} |
| 266 |
|
| 267 |
sub save_ref($$) { |
| 268 |
my ($ref, $path) = @_; |
| 269 |
|
| 270 |
open my $fh, ">:raw:perlio", "$path~" |
| 271 |
or die "$path~: $!"; |
| 272 |
print $fh freeze $ref; |
| 273 |
close $fh; |
| 274 |
rename "$path~", $path |
| 275 |
or die "$path: $!"; |
| 276 |
} |
| 277 |
|
| 278 |
my %attack_mask = ( |
| 279 |
physical => 0x00000001, |
| 280 |
magic => 0x00000002, |
| 281 |
fire => 0x00000004, |
| 282 |
electricity => 0x00000008, |
| 283 |
cold => 0x00000010, |
| 284 |
confusion => 0x00000020, |
| 285 |
acid => 0x00000040, |
| 286 |
drain => 0x00000080, |
| 287 |
weaponmagic => 0x00000100, |
| 288 |
ghosthit => 0x00000200, |
| 289 |
poison => 0x00000400, |
| 290 |
slow => 0x00000800, |
| 291 |
paralyze => 0x00001000, |
| 292 |
turn_undead => 0x00002000, |
| 293 |
fear => 0x00004000, |
| 294 |
cancellation => 0x00008000, |
| 295 |
deplete => 0x00010000, |
| 296 |
death => 0x00020000, |
| 297 |
chaos => 0x00040000, |
| 298 |
counterspell => 0x00080000, |
| 299 |
godpower => 0x00100000, |
| 300 |
holyword => 0x00200000, |
| 301 |
blind => 0x00400000, |
| 302 |
internal => 0x00800000, |
| 303 |
life_stealing => 0x01000000, |
| 304 |
disease => 0x02000000, |
| 305 |
); |
| 306 |
|
| 307 |
sub _add_resist($$$) { |
| 308 |
my ($ob, $mask, $value) = @_; |
| 309 |
|
| 310 |
while (my ($k, $v) = each %attack_mask) { |
| 311 |
$ob->{"resist_$k"} = min 100, max -100, $ob->{"resist_$k"} + $value if $mask & $v; |
| 312 |
} |
| 313 |
} |
| 314 |
|
| 315 |
my %MATERIAL = reverse |
| 316 |
paper => 1, |
| 317 |
iron => 2, |
| 318 |
glass => 4, |
| 319 |
leather => 8, |
| 320 |
wood => 16, |
| 321 |
organic => 32, |
| 322 |
stone => 64, |
| 323 |
cloth => 128, |
| 324 |
adamant => 256, |
| 325 |
liquid => 512, |
| 326 |
tin => 1024, |
| 327 |
bone => 2048, |
| 328 |
ice => 4096, |
| 329 |
|
| 330 |
# guesses |
| 331 |
runestone => 12, |
| 332 |
bronze => 18, |
| 333 |
"ancient wood" => 20, |
| 334 |
glass => 36, |
| 335 |
marble => 66, |
| 336 |
ice => 68, |
| 337 |
stone => 70, |
| 338 |
stone => 80, |
| 339 |
cloth => 136, |
| 340 |
ironwood => 144, |
| 341 |
adamantium => 258, |
| 342 |
glacium => 260, |
| 343 |
blood => 544, |
| 344 |
; |
| 345 |
|
| 346 |
# object as in "Object xxx", i.e. archetypes |
| 347 |
sub normalize_object($) { |
| 348 |
my ($ob) = @_; |
| 349 |
|
| 350 |
delete $ob->{editable}; # deprecated |
| 351 |
|
| 352 |
# convert material bitset to materialname, if possible |
| 353 |
if (exists $ob->{material}) { |
| 354 |
if (!$ob->{material}) { |
| 355 |
delete $ob->{material}; |
| 356 |
} elsif (exists $ob->{materialname}) { |
| 357 |
if ($MATERIAL{$ob->{material}} eq $ob->{materialname}) { |
| 358 |
delete $ob->{material}; |
| 359 |
} else { |
| 360 |
warn "object $ob->{_name} has both materialname ($ob->{materialname}) and material ($ob->{material}) set.\n"; |
| 361 |
delete $ob->{material}; # assume materilname is more specific and nuke material |
| 362 |
} |
| 363 |
} elsif (my $name = $MATERIAL{$ob->{material}}) { |
| 364 |
delete $ob->{material}; |
| 365 |
$ob->{materialname} = $name; |
| 366 |
} else { |
| 367 |
warn "object $ob->{_name} has unknown material ($ob->{material}) set.\n"; |
| 368 |
} |
| 369 |
} |
| 370 |
|
| 371 |
# check whether attachment is the same as in the archetype |
| 372 |
if (exists $ob->{attach}) { |
| 373 |
my $arch = $ARCH{$ob->{_name}}; |
| 374 |
my $js = JSON::XS->new->utf8->canonical (1); |
| 375 |
|
| 376 |
if (defined $arch->{attach} |
| 377 |
&& $js->encode ($js->decode ($ob->{attach})) eq $js->encode ($arch->{attach})) { |
| 378 |
delete $ob->{attach} |
| 379 |
} |
| 380 |
} |
| 381 |
|
| 382 |
# color_fg is used as default for magicmap if magicmap does not exist |
| 383 |
$ob->{magicmap} ||= delete $ob->{color_fg} if exists $ob->{color_fg}; |
| 384 |
|
| 385 |
# nuke outdated or never supported fields |
| 386 |
delete @$ob{qw( |
| 387 |
can_knockback can_parry can_impale can_cut can_dam_armour |
| 388 |
can_apply pass_thru can_pass_thru color_bg color_fg |
| 389 |
)}; |
| 390 |
|
| 391 |
if (my $mask = delete $ob->{immune} ) { _add_resist $ob, $mask, 100; } |
| 392 |
if (my $mask = delete $ob->{protected} ) { _add_resist $ob, $mask, 30; } |
| 393 |
if (my $mask = delete $ob->{vulnerable}) { _add_resist $ob, $mask, -100; } |
| 394 |
|
| 395 |
# convert movement strings to bitsets |
| 396 |
for my $attr (keys %FIELD_MOVEMENT) { |
| 397 |
next unless exists $ob->{$attr}; |
| 398 |
|
| 399 |
$ob->{$attr} = new Deliantra::MoveType $ob->{$attr}; |
| 400 |
} |
| 401 |
|
| 402 |
# convert outdated movement flags to new movement sets |
| 403 |
if (defined (my $v = delete $ob->{no_pass})) { |
| 404 |
$ob->{move_block} = new Deliantra::MoveType $v ? "all" : "0"; |
| 405 |
} |
| 406 |
if (defined (my $v = delete $ob->{slow_move})) { |
| 407 |
$ob->{move_slow} += "walk"; |
| 408 |
$ob->{move_slow_penalty} = $v; |
| 409 |
} |
| 410 |
if (defined (my $v = delete $ob->{walk_on})) { |
| 411 |
$ob->{move_on} ||= new Deliantra::MoveType; if ($v) { $ob->{move_on} += "walk" } else { $ob->{move_on} -= "walk" } |
| 412 |
} |
| 413 |
if (defined (my $v = delete $ob->{walk_off})) { |
| 414 |
$ob->{move_off} ||= new Deliantra::MoveType; if ($v) { $ob->{move_off} += "walk" } else { $ob->{move_off} -= "walk" } |
| 415 |
} |
| 416 |
if (defined (my $v = delete $ob->{fly_on})) { |
| 417 |
$ob->{move_on} ||= new Deliantra::MoveType; if ($v) { $ob->{move_on} += "fly_low" } else { $ob->{move_on} -= "fly_low" } |
| 418 |
} |
| 419 |
if (defined (my $v = delete $ob->{fly_off})) { |
| 420 |
$ob->{move_off} ||= new Deliantra::MoveType; if ($v) { $ob->{move_off} += "fly_low" } else { $ob->{move_off} -= "fly_low" } |
| 421 |
} |
| 422 |
if (defined (my $v = delete $ob->{flying})) { |
| 423 |
$ob->{move_type} ||= new Deliantra::MoveType; if ($v) { $ob->{move_type} += "fly_low" } else { $ob->{move_type} -= "fly_low" } |
| 424 |
} |
| 425 |
|
| 426 |
# convert idiotic event_xxx things into objects |
| 427 |
while (my ($event, $subtype) = each %EVENT_TYPE) { |
| 428 |
if (exists $ob->{"event_${event}_plugin"}) { |
| 429 |
push @{$ob->{inventory}}, { |
| 430 |
_name => "event_$event", |
| 431 |
title => delete $ob->{"event_${event}_plugin"}, |
| 432 |
slaying => delete $ob->{"event_${event}"}, |
| 433 |
name => delete $ob->{"event_${event}_options"}, |
| 434 |
}; |
| 435 |
} |
| 436 |
} |
| 437 |
|
| 438 |
# some archetypes had "+3" instead of the canonical "3", so fix |
| 439 |
$ob->{dam} *= 1 if exists $ob->{dam}; |
| 440 |
|
| 441 |
$ob |
| 442 |
} |
| 443 |
|
| 444 |
# arch as in "arch xxx", ie.. objects |
| 445 |
sub normalize_arch($) { |
| 446 |
my ($ob) = @_; |
| 447 |
|
| 448 |
normalize_object $ob; |
| 449 |
|
| 450 |
return if $ob->{_atype} eq "object"; |
| 451 |
|
| 452 |
my $arch = $ARCH{$ob->{_name}} |
| 453 |
or (warn "$ob->{_name}: no such archetype", return $ob); |
| 454 |
|
| 455 |
if ($arch->{type} == 22) { # map |
| 456 |
my %normalize = ( |
| 457 |
"enter_x" => "hp", |
| 458 |
"enter_y" => "sp", |
| 459 |
"width" => "x", |
| 460 |
"height" => "y", |
| 461 |
"reset_timeout" => "weight", |
| 462 |
"swap_time" => "value", |
| 463 |
"difficulty" => "level", |
| 464 |
"darkness" => "invisible", |
| 465 |
"fixed_resettime" => "stand_still", |
| 466 |
); |
| 467 |
|
| 468 |
while (my ($k2, $k1) = each %normalize) { |
| 469 |
if (defined (my $v = delete $ob->{$k1})) { |
| 470 |
$ob->{$k2} = $v; |
| 471 |
} |
| 472 |
} |
| 473 |
} else { |
| 474 |
# if value matches archetype default, delete |
| 475 |
while (my ($k, $v) = each %$ob) { |
| 476 |
if (exists $arch->{$k} and $arch->{$k} eq $v) { |
| 477 |
next if $k eq "_name"; |
| 478 |
delete $ob->{$k}; |
| 479 |
} |
| 480 |
} |
| 481 |
} |
| 482 |
|
| 483 |
# a speciality for the editor |
| 484 |
if (exists $ob->{attack_movement}) { |
| 485 |
my $am = delete $ob->{attack_movement}; |
| 486 |
$ob->{attack_movement_bits_0_3} = $am & 15; |
| 487 |
$ob->{attack_movement_bits_4_7} = $am & 240; |
| 488 |
} |
| 489 |
|
| 490 |
$ob |
| 491 |
} |
| 492 |
|
| 493 |
sub attr_thaw($) { |
| 494 |
my ($ob) = @_; |
| 495 |
|
| 496 |
$ob->{attach} = decode_json $ob->{attach} |
| 497 |
if exists $ob->{attach}; |
| 498 |
|
| 499 |
$ob |
| 500 |
} |
| 501 |
|
| 502 |
sub attr_freeze($) { |
| 503 |
my ($ob) = @_; |
| 504 |
|
| 505 |
$ob->{attach} = JSON::XS->new->utf8->canonical->encode ($ob->{attach}) |
| 506 |
if exists $ob->{attach}; |
| 507 |
|
| 508 |
$ob |
| 509 |
} |
| 510 |
|
| 511 |
sub read_pak($) { |
| 512 |
my ($path) = @_; |
| 513 |
|
| 514 |
my %pak; |
| 515 |
|
| 516 |
open my $fh, "<:raw:perlio", $path |
| 517 |
or Carp::croak "$_[0]: $!"; |
| 518 |
binmode $fh; |
| 519 |
while (<$fh>) { |
| 520 |
my ($type, $id, $len, $path) = split; |
| 521 |
$path =~ s/.*\///; |
| 522 |
read $fh, $pak{$path}, $len; |
| 523 |
} |
| 524 |
|
| 525 |
\%pak |
| 526 |
} |
| 527 |
|
| 528 |
sub read_arch($;$) { |
| 529 |
my ($path, $toplevel) = @_; |
| 530 |
|
| 531 |
my %arc; |
| 532 |
my ($more, $prev); |
| 533 |
my $comment; |
| 534 |
|
| 535 |
open my $fh, "<:utf8", $path |
| 536 |
or Carp::croak "$path: $!"; |
| 537 |
|
| 538 |
# binmode $fh; |
| 539 |
|
| 540 |
my $parse_block; $parse_block = sub { |
| 541 |
my %arc = @_; |
| 542 |
|
| 543 |
while (<$fh>) { |
| 544 |
s/\s+$//; |
| 545 |
if (/^end$/i) { |
| 546 |
last; |
| 547 |
|
| 548 |
} elsif (/^arch (\S+)$/i) { |
| 549 |
push @{ $arc{inventory} }, attr_thaw normalize_arch $parse_block->(_name => $1); |
| 550 |
|
| 551 |
} elsif (/^lore$/i) { |
| 552 |
while (<$fh>) { |
| 553 |
last if /^endlore\s*$/i; |
| 554 |
$arc{lore} .= $_; |
| 555 |
} |
| 556 |
} elsif (/^msg$/i) { |
| 557 |
while (<$fh>) { |
| 558 |
last if /^endmsg\s*$/i; |
| 559 |
$arc{msg} .= $_; |
| 560 |
} |
| 561 |
} elsif (/^anim$/i) { |
| 562 |
while (<$fh>) { |
| 563 |
last if /^mina\s*$/i; |
| 564 |
chomp; |
| 565 |
push @{ $arc{anim} }, $_; |
| 566 |
} |
| 567 |
} elsif (/^(\S+)\s*(.*)$/) { |
| 568 |
$arc{lc $1} = $2; |
| 569 |
} elsif (/^\s*#/) { |
| 570 |
$arc{_comment} .= "$_\n"; |
| 571 |
|
| 572 |
} elsif (/^\s*$/) { |
| 573 |
# |
| 574 |
} else { |
| 575 |
warn "$path: unparsable line '$_' in arch $arc{_name}"; |
| 576 |
} |
| 577 |
} |
| 578 |
|
| 579 |
\%arc |
| 580 |
}; |
| 581 |
|
| 582 |
while (<$fh>) { |
| 583 |
s/\s+$//; |
| 584 |
if (/^more$/i) { |
| 585 |
$more = $prev; |
| 586 |
} elsif (/^object (\S+)$/i) { |
| 587 |
my $name = $1; |
| 588 |
my $arc = attr_thaw normalize_object $parse_block->(_name => $name, _comment => $comment); |
| 589 |
undef $comment; |
| 590 |
delete $arc{_comment} unless length $arc{_comment}; |
| 591 |
$arc->{_atype} = 'object'; |
| 592 |
|
| 593 |
if ($more) { |
| 594 |
$more->{more} = $arc; |
| 595 |
} else { |
| 596 |
$arc{$name} = $arc; |
| 597 |
} |
| 598 |
$prev = $arc; |
| 599 |
$more = undef; |
| 600 |
} elsif (/^arch (\S+)$/i) { |
| 601 |
my $name = $1; |
| 602 |
my $arc = attr_thaw normalize_arch $parse_block->(_name => $name, _comment => $comment); |
| 603 |
undef $comment; |
| 604 |
delete $arc{_comment} unless length $arc{_comment}; |
| 605 |
$arc->{_atype} = 'arch'; |
| 606 |
|
| 607 |
if ($more) { |
| 608 |
$more->{more} = $arc; |
| 609 |
} else { |
| 610 |
push @{ $arc{arch} }, $arc; |
| 611 |
} |
| 612 |
$prev = $arc; |
| 613 |
$more = undef; |
| 614 |
} elsif ($toplevel && /^(\S+)\s+(.*)$/) { |
| 615 |
if ($1 eq "lev_array") { |
| 616 |
while (<$fh>) { |
| 617 |
last if /^endplst\s*$/; |
| 618 |
push @{$toplevel->{lev_array}}, $_+0; |
| 619 |
} |
| 620 |
} else { |
| 621 |
$toplevel->{$1} = $2; |
| 622 |
} |
| 623 |
} elsif (/^\s*#/) { |
| 624 |
$comment .= "$_\n"; |
| 625 |
} elsif (/^\s*($|#)/) { |
| 626 |
# |
| 627 |
} else { |
| 628 |
die "$path: unparseable top-level line '$_'"; |
| 629 |
} |
| 630 |
} |
| 631 |
|
| 632 |
undef $parse_block; # work around bug in perl not freeing $fh etc. |
| 633 |
|
| 634 |
\%arc |
| 635 |
} |
| 636 |
|
| 637 |
sub archlist_to_string { |
| 638 |
my ($arch) = @_; |
| 639 |
|
| 640 |
my $str; |
| 641 |
|
| 642 |
my $append; $append = sub { |
| 643 |
my %a = %{$_[0]}; |
| 644 |
|
| 645 |
Deliantra::attr_freeze \%a; |
| 646 |
Deliantra::normalize_arch \%a; |
| 647 |
|
| 648 |
# undo the bit-split we did before |
| 649 |
if (exists $a{attack_movement_bits_0_3} or exists $a{attack_movement_bits_4_7}) { |
| 650 |
$a{attack_movement} = (delete $a{attack_movement_bits_0_3}) |
| 651 |
| (delete $a{attack_movement_bits_4_7}); |
| 652 |
} |
| 653 |
|
| 654 |
if (my $comment = delete $a{_comment}) { |
| 655 |
if ($comment =~ /[^\n\s#]/) { |
| 656 |
$str .= $comment; |
| 657 |
} |
| 658 |
} |
| 659 |
|
| 660 |
$str .= ((exists $a{_atype}) ? $a{_atype} : 'arch'). " $a{_name}\n"; |
| 661 |
|
| 662 |
my $inv = delete $a{inventory}; |
| 663 |
my $more = delete $a{more}; # arches do not support 'more', but old maps can contain some |
| 664 |
my $anim = delete $a{anim}; |
| 665 |
|
| 666 |
if ($a{_atype} eq 'object') { |
| 667 |
$str .= join "\n", "anim", @$anim, "mina\n" |
| 668 |
if $anim; |
| 669 |
} |
| 670 |
|
| 671 |
my @kv; |
| 672 |
|
| 673 |
for ($a{_name} eq "map" |
| 674 |
? @Deliantra::FIELD_ORDER_MAP |
| 675 |
: @Deliantra::FIELD_ORDER) { |
| 676 |
push @kv, [$_, delete $a{$_}] |
| 677 |
if exists $a{$_}; |
| 678 |
} |
| 679 |
|
| 680 |
for (sort keys %a) { |
| 681 |
next if /^_/; # ignore our _-keys |
| 682 |
push @kv, [$_, delete $a{$_}]; |
| 683 |
} |
| 684 |
|
| 685 |
for (@kv) { |
| 686 |
my ($k, $v) = @$_; |
| 687 |
|
| 688 |
if (my $end = $Deliantra::FIELD_MULTILINE{$k}) { |
| 689 |
$v =~ s/\n$//; |
| 690 |
$str .= "$k\n$v\n$end\n"; |
| 691 |
} else { |
| 692 |
$str .= "$k $v\n"; |
| 693 |
} |
| 694 |
} |
| 695 |
|
| 696 |
if ($inv) { |
| 697 |
$append->($_) for @$inv; |
| 698 |
} |
| 699 |
|
| 700 |
$str .= "end\n"; |
| 701 |
|
| 702 |
if ($a{_atype} eq 'object') { |
| 703 |
if ($more) { |
| 704 |
$str .= "more\n"; |
| 705 |
$append->($more) if $more; |
| 706 |
} else { |
| 707 |
$str .= "\n"; |
| 708 |
} |
| 709 |
} |
| 710 |
}; |
| 711 |
|
| 712 |
for (@$arch) { |
| 713 |
$append->($_); |
| 714 |
} |
| 715 |
|
| 716 |
$str |
| 717 |
} |
| 718 |
|
| 719 |
# put all archs into a hash with editor_face as it's key |
| 720 |
# NOTE: the arrays in the hash values are references to |
| 721 |
# the archs from $ARCH |
| 722 |
sub editor_archs { |
| 723 |
my %paths; |
| 724 |
|
| 725 |
for (keys %ARCH) { |
| 726 |
my $arch = $ARCH{$_}; |
| 727 |
push @{$paths{$arch->{editor_folder}}}, $arch; |
| 728 |
} |
| 729 |
|
| 730 |
\%paths |
| 731 |
} |
| 732 |
|
| 733 |
=item ($minx, $miny, $maxx, $maxy) = arch_extents $arch |
| 734 |
|
| 735 |
arch_extents determines the extents of the given arch's face(s), linked |
| 736 |
faces and single faces are handled here it returns (minx, miny, maxx, |
| 737 |
maxy) |
| 738 |
|
| 739 |
=cut |
| 740 |
|
| 741 |
sub arch_extents { |
| 742 |
my ($a) = @_; |
| 743 |
|
| 744 |
my $o = $ARCH{$a->{_name}} |
| 745 |
or return; |
| 746 |
|
| 747 |
my $face = $FACE{$a->{face} || $o->{face} || "blank.111"}; |
| 748 |
unless ($face) { |
| 749 |
$face = $FACE{"blank.x11"} |
| 750 |
or (warn "no face data found for arch '$a->{_name}'"), return; |
| 751 |
} |
| 752 |
|
| 753 |
if ($face->{w} > 1 || $face->{h} > 1) { |
| 754 |
# bigface |
| 755 |
return (0, 0, $face->{w} - 1, $face->{h} - 1); |
| 756 |
|
| 757 |
} elsif ($o->{more}) { |
| 758 |
# linked face |
| 759 |
my ($minx, $miny, $maxx, $maxy) = ($o->{x}, $o->{y}) x 2; |
| 760 |
|
| 761 |
for (; $o; $o = $o->{more}) { |
| 762 |
$minx = min $minx, $o->{x}; |
| 763 |
$miny = min $miny, $o->{y}; |
| 764 |
$maxx = max $maxx, $o->{x}; |
| 765 |
$maxy = max $maxy, $o->{y}; |
| 766 |
} |
| 767 |
|
| 768 |
return ($minx, $miny, $maxx, $maxy); |
| 769 |
|
| 770 |
} else { |
| 771 |
# single face |
| 772 |
return (0, 0, 0, 0); |
| 773 |
} |
| 774 |
} |
| 775 |
|
| 776 |
=item $type = arch_attr $arch |
| 777 |
|
| 778 |
Returns a hashref describing the object and its attributes. It can contain |
| 779 |
the following keys: |
| 780 |
|
| 781 |
name the name, suitable for display purposes |
| 782 |
ignore |
| 783 |
attr |
| 784 |
desc |
| 785 |
use |
| 786 |
section => [name => \%attr, name => \%attr] |
| 787 |
import |
| 788 |
|
| 789 |
=cut |
| 790 |
|
| 791 |
sub arch_attr($) { |
| 792 |
my ($obj) = @_; |
| 793 |
|
| 794 |
require Deliantra::Data; |
| 795 |
|
| 796 |
my $root; |
| 797 |
my $attr = { }; |
| 798 |
|
| 799 |
my $arch = $ARCH{ $obj->{_name} }; |
| 800 |
my $type = $obj->{type} || $arch->{type}; |
| 801 |
|
| 802 |
if ($type > 0) { |
| 803 |
$root = $Deliantra::Data::ATTR{$type}; |
| 804 |
} else { |
| 805 |
my %a = (%$arch, %$obj); |
| 806 |
|
| 807 |
if ($a{is_floor} && !$a{alive}) { |
| 808 |
$root = $Deliantra::Data::TYPE{Floor}; |
| 809 |
} elsif (!$a{is_floor} && $a{alive} && !$a{tear_down}) { |
| 810 |
$root = $Deliantra::Data::TYPE{"Monster & NPC"}; |
| 811 |
} elsif (!$a{is_floor} && !$a{alive} && $a{move_block}) { |
| 812 |
$root = $Deliantra::Data::TYPE{Wall}; |
| 813 |
} elsif (!$a{is_floor} && $a{alive} && $a{tear_down}) { |
| 814 |
$root = $Deliantra::Data::TYPE{"Weak Wall"}; |
| 815 |
} else { |
| 816 |
$root = $Deliantra::Data::TYPE{Misc}; |
| 817 |
} |
| 818 |
} |
| 819 |
|
| 820 |
my (%ignore); |
| 821 |
my @import = ($root); |
| 822 |
|
| 823 |
my @new_import; |
| 824 |
while (my $type = shift @import) { |
| 825 |
# first import everything we will need: |
| 826 |
push @import, |
| 827 |
grep $_, |
| 828 |
map $Deliantra::Data::TYPE{$_}, |
| 829 |
@{$type->{import} || []}; |
| 830 |
|
| 831 |
# and compute the ignored attributes |
| 832 |
for (@{$type->{ignore} || []}) { |
| 833 |
$ignore{$_}++ for ref $_ ? @$_ : $_; |
| 834 |
} |
| 835 |
|
| 836 |
push @new_import, $type; |
| 837 |
} |
| 838 |
(@import) = @new_import; |
| 839 |
|
| 840 |
# then add defaults to the back of the list, so they are added |
| 841 |
# as last resort. |
| 842 |
push @import, \%Deliantra::Data::DEFAULT_ATTR |
| 843 |
unless $type == 116; |
| 844 |
|
| 845 |
my (@section_order, %section, @attr_order); |
| 846 |
|
| 847 |
# @import = root, imported, default |
| 848 |
while (my $type = pop @import) { |
| 849 |
$attr->{$_} ||= $type->{$_} |
| 850 |
for qw(name desc use); |
| 851 |
|
| 852 |
for ([general => ($type->{attr} || [])], @{$type->{section} || []}) { |
| 853 |
my ($name, $attr) = @$_; |
| 854 |
push @section_order, $name; |
| 855 |
for (@$attr) { |
| 856 |
my ($k, $v) = @$_; |
| 857 |
push @attr_order, $k; |
| 858 |
$section{$name}{$k} = $v; # overwrite, so that the root decides |
| 859 |
} |
| 860 |
} |
| 861 |
} |
| 862 |
|
| 863 |
# remove ignores for "root" type |
| 864 |
for ( |
| 865 |
map @{$_->[1]}, # section attributes |
| 866 |
[general => ($root->{attr} || [])], |
| 867 |
@{$root->{section} || []} |
| 868 |
) { |
| 869 |
my ($k, $v) = @$_; |
| 870 |
# skip fixed attributes, if they are ignored thats fine |
| 871 |
next if $v->{type} eq 'fixed'; |
| 872 |
|
| 873 |
delete $ignore{$k}; # if the attributes are defined explicitly they |
| 874 |
# should NOT be ignored. ignore should mainly |
| 875 |
# hit imported/inherited attributes. |
| 876 |
} |
| 877 |
|
| 878 |
$attr->{section} = [ |
| 879 |
map !exists $section{$_} ? () : do { |
| 880 |
my $attr = delete $section{$_}; |
| 881 |
|
| 882 |
[ |
| 883 |
$_, |
| 884 |
map exists $attr->{$_} && !$ignore{$_} |
| 885 |
? [$_ => delete $attr->{$_}] : (), |
| 886 |
@attr_order |
| 887 |
] |
| 888 |
}, |
| 889 |
exists $section{$_} ? [$_ => delete $section{$_}] : (), |
| 890 |
@section_order |
| 891 |
]; |
| 892 |
|
| 893 |
$attr |
| 894 |
} |
| 895 |
|
| 896 |
sub cache_file($$&&) { |
| 897 |
my ($src, $cache, $load, $create) = @_; |
| 898 |
|
| 899 |
my ($size, $mtime) = (stat $src)[7,9] |
| 900 |
or Carp::croak "$src: $!"; |
| 901 |
|
| 902 |
if (-e $cache) { |
| 903 |
my $ref = eval { load_ref $cache }; |
| 904 |
|
| 905 |
if ($ref->{version} == 1 |
| 906 |
&& $ref->{size} == $size |
| 907 |
&& $ref->{mtime} == $mtime |
| 908 |
&& eval { $load->($ref->{data}); 1 }) { |
| 909 |
return; |
| 910 |
} |
| 911 |
} |
| 912 |
|
| 913 |
my $ref = { |
| 914 |
version => 1, |
| 915 |
size => $size, |
| 916 |
mtime => $mtime, |
| 917 |
data => $create->(), |
| 918 |
}; |
| 919 |
|
| 920 |
$load->($ref->{data}); |
| 921 |
|
| 922 |
save_ref $ref, $cache; |
| 923 |
} |
| 924 |
|
| 925 |
=item set_libdir $path |
| 926 |
|
| 927 |
Sets the library directory to the given path |
| 928 |
(default: $ENV{CROSSFIRE_LIBDIR}). |
| 929 |
|
| 930 |
You have to (re-)load the archetypes and tilecache manually after steting |
| 931 |
the library path. |
| 932 |
|
| 933 |
=cut |
| 934 |
|
| 935 |
sub set_libdir($) { |
| 936 |
$LIB = $_[0]; |
| 937 |
} |
| 938 |
|
| 939 |
=item load_archetypes |
| 940 |
|
| 941 |
(Re-)Load archetypes into %ARCH. |
| 942 |
|
| 943 |
=cut |
| 944 |
|
| 945 |
sub load_archetypes() { |
| 946 |
cache_file "$LIB/archetypes", "$VARDIR/archetypes.pst", sub { |
| 947 |
*ARCH = $_[0]; |
| 948 |
}, sub { |
| 949 |
read_arch "$LIB/archetypes" |
| 950 |
}; |
| 951 |
} |
| 952 |
|
| 953 |
sub construct_tilecache_pb { |
| 954 |
my ($idx, $cache) = @_; |
| 955 |
|
| 956 |
my $pb = new Gtk2::Gdk::Pixbuf "rgb", 1, 8, CACHESTRIDE * TILESIZE, TILESIZE * int +($idx + CACHESTRIDE - 1) / CACHESTRIDE; |
| 957 |
|
| 958 |
while (my ($name, $tile) = each %$cache) { |
| 959 |
my $tpb = delete $tile->{pb}; |
| 960 |
my $ofs = $tile->{idx}; |
| 961 |
|
| 962 |
for my $x (0 .. $tile->{w} - 1) { |
| 963 |
for my $y (0 .. $tile->{h} - 1) { |
| 964 |
my $idx = $ofs + $x + $y * $tile->{w}; |
| 965 |
$tpb->copy_area ($x * TILESIZE, $y * TILESIZE, TILESIZE, TILESIZE, |
| 966 |
$pb, ($idx % CACHESTRIDE) * TILESIZE, TILESIZE * int $idx / CACHESTRIDE); |
| 967 |
} |
| 968 |
} |
| 969 |
} |
| 970 |
|
| 971 |
$pb->save ("$VARDIR/tilecache.png", "png", compression => 1); |
| 972 |
|
| 973 |
$cache |
| 974 |
} |
| 975 |
|
| 976 |
sub use_tilecache { |
| 977 |
my ($face) = @_; |
| 978 |
$TILE = new_from_file Gtk2::Gdk::Pixbuf "$VARDIR/tilecache.png" |
| 979 |
or die "$VARDIR/tilecache.png: $!"; |
| 980 |
*FACE = $_[0]; |
| 981 |
} |
| 982 |
|
| 983 |
=item load_tilecache |
| 984 |
|
| 985 |
(Re-)Load %TILE and %FACE. |
| 986 |
|
| 987 |
=cut |
| 988 |
|
| 989 |
sub load_tilecache() { |
| 990 |
require Gtk2; |
| 991 |
|
| 992 |
cache_file "$LIB/facedata", "$VARDIR/tilecache.pst", \&use_tilecache, |
| 993 |
sub { |
| 994 |
my %cache; |
| 995 |
my $facedata = Storable::retrieve "$LIB/facedata"; |
| 996 |
|
| 997 |
$facedata->{version} == 2 |
| 998 |
or die "$LIB/facedata: version mismatch, cannot proceed."; |
| 999 |
|
| 1000 |
my $faces = $facedata->{faceinfo}; |
| 1001 |
my $idx = 0; |
| 1002 |
|
| 1003 |
for (sort keys %$faces) { |
| 1004 |
my ($face, $info) = ($_, $faces->{$_}); |
| 1005 |
|
| 1006 |
my $pb = new Gtk2::Gdk::PixbufLoader; |
| 1007 |
$pb->write ($info->{data32}); |
| 1008 |
$pb->close; |
| 1009 |
my $pb = $pb->get_pixbuf; |
| 1010 |
|
| 1011 |
my $tile = $cache{$face} = { |
| 1012 |
pb => $pb, |
| 1013 |
idx => $idx, |
| 1014 |
w => int $pb->get_width / TILESIZE, |
| 1015 |
h => int $pb->get_height / TILESIZE, |
| 1016 |
}; |
| 1017 |
|
| 1018 |
$idx += $tile->{w} * $tile->{h}; |
| 1019 |
} |
| 1020 |
|
| 1021 |
construct_tilecache_pb $idx, \%cache; |
| 1022 |
|
| 1023 |
\%cache |
| 1024 |
}; |
| 1025 |
} |
| 1026 |
|
| 1027 |
=back |
| 1028 |
|
| 1029 |
=head1 AUTHOR |
| 1030 |
|
| 1031 |
Marc Lehmann <schmorp@schmorp.de> |
| 1032 |
http://home.schmorp.de/ |
| 1033 |
|
| 1034 |
Robin Redeker <elmex@ta-sa.org> |
| 1035 |
http://www.ta-sa.org/ |
| 1036 |
|
| 1037 |
=cut |
| 1038 |
|
| 1039 |
1 |
| 1040 |
|
