server/ext/login.ext

#! perl # mandatory depends=highscore

# login handling

use Fcntl;
use Coro::AIO;

our $MAX_DISCONNECT_TIME = $cf::CFG{max_disconnect_time} || 3600;

# paranoia function to overwrite a string-in-place
sub nuke_str {
   substr $_[0], 0, (length $_[0]), "x" x length $_[0]
}

sub query {
   my ($ns, $flags, $text) = @_;

   $ns->query ($flags, $text, Coro::rouse_cb);
   Coro::rouse_wait
}

sub can_cleanup {
   my ($pl, $mtime) = @_;

   my $age = time - $mtime;
   my $level = $pl->ob->level;

   ($level <= 3 && $age > 7 * 86400)            # 7 days for level 0..3
   || ($level <= 9 && $age > 90 * 86400)        # 3 months for level 4..9
   || ($level <= 20 && $age > 180 * 86400)      # 6 months for level 10..20
   || $age > 700 * 86400                        # 2 years for everybody else
}

sub check_playing {
   my ($ns, $user) = @_;

   return unless cf::player::find_active $user;

   $ns->send_drawinfo (
      "That player is already logged in on this server. "
    . "If you want to create a new player, choose another name. "
    . "If you have already a registered, make sure nobody "
    . "else is using your account at this time. If you lost your connection "
    . "then the server will likely timeout within a minute. If you still "
    . "cannot log-in after a minute, you are still logged in. Make sure "
    . "you do not have another client running. If you use windows, reboot, "
    . "this will fix anything.",
      cf::NDI_RED
   );

   1
}

sub safe_spot($) {
   my ($pl) = @_;
   
   my $ob = $pl->ob;

   my $m = $ob->map
      or return;
   my $x = $ob->x;
   my $y = $ob->y;

#   return 0;#d#
#   warn join ":", $m->at ($x, $y);#d#
#   warn "FOO$m { ".scalar ($m->at ($x, $y))." }\n";
#   return 0;

   scalar grep $_->type == cf::SAVEBED, $m->at ($x, $y)
}

sub enter_map {
   my ($pl) = @_;

   my $ob = $pl->ob;

   my ($map, $x, $y)
      = $ob->{_link_pos}
        ? @{delete $ob->{_link_pos}}
        : ($pl->maplevel, $ob->x, $ob->y);

   $ob->enter_link;

   my $m = cf::map::find $map;
   my $time = delete $pl->{unclean_save};

   if ($time && $m) {
      if ($time < $m->{instantiate_time}) {
         # the map was reset in the meantime
         my $age = $cf::RUNTIME - $time;

         cf::info $ob->name, " map reset after logout, logout age $age (>= $MAX_DISCONNECT_TIME)\n";#d#

         if ($age >= $MAX_DISCONNECT_TIME) {
            $ob->message (
               "You didn't use a bed to reality to leave this realm, leaving your body in great danger. "
             . "Unfortunately, nobody was near to help you when the monsters arrived to eat you. "
             . "Maybe you can find comfort in the thought that your body was quite satisfying in taste... "
             . "H<You disconnected too long without having used a savebed.>",
               cf::NDI_RED
            );
            # kill them.
            # reminds me of the famous badness 10000 syndrome...
            $ob->stats->hp (-10000); #] if they survive this they deserved to live
            my $killer = cf::arch::get "killer_login"; $pl->killer ($killer); $killer->destroy;
         } else {
            ($map, $x, $y) = $pl->savebed;

            $ob->message (
               "You didn't use a bed to reality to leave this realm, leaving your body in great danger. "
             . "Fortunately, some friendly dwellers found you, checked your passport, and brought you to safety. "
             . "Better use a savebed next time, much worse things could have happened... "
             . "H<You disconnected without having used a savebed. When you do that for too long, you might die.>",
               cf::NDI_RED
            );
         }
      } else {
         $ob->message (
            "You didn't use a bed to reality to leave this realm. This is very dangerous, "
          . "as lots of things could happen when you leave by other means, such as cave-ins, "
          . "or monsters suddenly snapping your body. Better use a savebed next time. "
          . "H<Always apply a bed of reality to disconnect from the server.>",
            cf::NDI_RED
         );
      }
   }

   $ob->goto ($map, $x, $y);
}

sub encode_password($) {
#   crypt $_[0],
#      join '',
#         ('.', '/', 0..9, 'A'..'Z', 'a'..'z')[(cf::rndm 64), (cf::rndm 64)]
   "!" . unpack "H*", $_[0]
}

sub compare_password($$) {
   my ($pass, $token) = @_;

   if ($token =~ /\!(.*)/) {
      return $pass eq pack "H*", $1;
   } else {
      return $token eq crypt $pass, $token;
   }
}

# delete a player directory
sub nuke_playerdir {
   my ($user) = @_;

   my $lock = cf::lock_acquire "ext::login::nuke_playerdir";

   my $temp = "$PLAYERDIR/~$Coro::current~deleting~";
   aio_rename "$PLAYERDIR/$user", $temp;
   IO::AIO::aio_rmtree $temp;
}

cf::client->attach (on_addme => sub {
   my ($ns) = @_;

   $ns->pl and return $ns->destroy;

   $ns->async (sub {
      $Coro::current->{desc} = "addme init";

      my ($user, $pass);

      $ns->send_packet ("addme_success");

      for (;;) {
         $ns->send_drawinfo (
            "Please enter your username now. If you are a new user, "
          . "make one up that describes your character best. "
          . "Only letters and digits are allowed, though.",
            cf::NDI_BLUE
         );

         # read username
         while () {
            $user = query $ns, 0, "What is your name? (login names are case-sensitive)\n:";

            if ($cf::LOGIN_LOCK{$user}) {
               $ns->send_drawinfo (
                  "That username is currently used in another login session. "
                . "Chose another, or wait till the other session has ended.",
                  cf::NDI_RED
               );
            } elsif ($user =~ /^[a-zA-Z0-9][a-zA-Z0-9\-_]{2,19}\z/) {
               last;
            } else {
               $ns->send_drawinfo (
                  "Your username contains illegal characters "
                . "(only a-z, A-Z and 0-9 are allowed), "
                . "or is not between 3 and 20 characters in length.",
                  cf::NDI_RED
               );
            }
            Coro::Timer::sleep 0.4;
         }

         check_playing $ns, $user and next;

         $Coro::current->{desc} = "addme($user) pass";

         $ns->send_drawinfo (
            "Welcome $user, please enter your password now. "
          . "New users should now choose a password. "
          . "Anything your client lets you enter is fine.",
            cf::NDI_BLUE
         );

         # read password
         while () {
            $pass = query $ns, cf::CS_QUERY_HIDEINPUT, "What is your password?\n:";
            last if $pass =~ /.../;
            $ns->send_drawinfo (
               "Try to use at least three characters as your password please, "
             . "that cannot be too much to ask for :)",
               cf::NDI_RED
            );
            Coro::Timer::sleep 0.4;
         }

         # lock this username for the remainder of this login session
         if ($cf::LOGIN_LOCK{$user}) {
            $ns->send_drawinfo (
               "That username is currently used in another login session. "
             . "Chose another, or wait till the other session has ended.",
               cf::NDI_RED
            );
            next;
         }
         local $cf::LOGIN_LOCK{$user} = 1;

         check_playing $ns, $user and next;

         $Coro::current->{desc} = "addme($user) check";

         # try to read the user file and check the password
         if (my $pl = cf::player::find $user) {
            aio_stat $pl->path and next;
            my $mtime = (stat _)[9];
            my $token = $pl->password;

            if ($cf::CFG{ext_login_nocheck} or compare_password $pass, $token) {
               $pl->password (encode_password $pass); # make sure we store the new encoding #d#
               nuke_str $pass;
               # password matches, wonderful
               my $pl = cf::player::find $user or next;
               $pl->connect ($ns);
               enter_map $pl;
               last;
            } elsif (can_cleanup $pl, $mtime) {
               Coro::Timer::sleep 1;

               $ns->send_drawinfo (
                  "Player exists, but password does not match. If this is your account, "
                . "please try again. If not, you can now decide to take over this account "
                . "because it has not been in-use for some time.",
                  cf::NDI_RED
               );

               #TODO: nuke_str
               (query $ns, cf::CS_QUERY_SINGLECHAR, "Delete existing account and create a new one (Y/N)?") =~ /^[yY]/
                  or next;

               # check if the file hasn't changed
               aio_stat cf::player::path $user and next;
               $mtime == (stat _)[9] or next;

               $pl->quit_character;

               # fall through to creation
            } else {
               nuke_str $pass;

               Coro::Timer::sleep 1;

               $ns->send_drawinfo (
                  "Wrong username or password. Please try again "
                . "(check for Numlock and other semi-obvious error sources).",
                  cf::NDI_RED
               );
               next;
            }
         } else {
            # unable to load the playerfile:
            # check wether the player dir exists, which means the file is corrupted or
            # something very similar.
            if (!aio_stat cf::player::playerdir $user) {
               $ns->send_drawinfo (
                  "Unable to retrieve this player. It might be a locked or broken account. "
                . "If this is your account, ask a dungeon master for assistance. "
                . "Otherwise choose a different login name.",
                  cf::NDI_RED
               );
               next;
            }
         }

         # the rest of this function is character creation
         $Coro::current->{desc} = "addme($user) chargen";

         # just to make sure nothing is left over
         # normally, nothing is there.
         nuke_playerdir $user;

         my $pass2 = query $ns, cf::CS_QUERY_HIDEINPUT, "Please type your password again.";

         if ($pass2 ne $pass) {
            nuke_str $pass;
            nuke_str $pass2;
            $ns->send_drawinfo (
               "The passwords do not match, please try again.",
               cf::NDI_RED
            );
            Coro::Timer::sleep 0.5;
            next;
         }

         nuke_str $pass2;

         my $pl = cf::player::new $user;
         $pl->password (encode_password $pass);
         nuke_str $pass;
         $pl->connect ($ns);
         my $ob = $pl->ob;

         $ob->goto ($pl->maplevel, $ob->x, $ob->y);

         while () {
            $ob->update_stats;
            $pl->save_stats;

            my $res = query $ns, cf::CS_QUERY_SINGLECHAR,
                         "[y] to roll new stats [n] to use stats\n[1-7] [1-7] to swap stats.\nRoll again (y/n/1-7)?";

            if ($res =~ /^[Nn]/) {
               last;
            } elsif ($res > 0 && $res <= 7) {
               my $swap = query $ns, cf::CS_QUERY_SINGLECHAR, "Swap stat with (will not roll new stats) [1-7]?";

               if ($swap > 0 && $swap <= 7) {
                  $ob->swap_stats ($res - 1, $swap - 1);
               }
            } else {
               $ob->roll_stats;
            }

            Coro::Timer::sleep 0.05;
         }

         $ob->set_animation (2);
         $ob->add_statbonus;

         while () {
            $ns->send_msg ("chargen-race-title", ucfirst $pl->title, -1);
            my $msg = $ob->msg;
            $msg =~ s/(?<=\S)\n(?=\S)/ /g;
            $ns->send_msg ("chargen-race-description", $msg, cf::NDI_BLUE);

            my $res = query $ns, cf::CS_QUERY_SINGLECHAR,
                         "Now choose a character.\nPress any key to change outlook.\nPress `d' when you're pleased.\n";

            last if $res =~ /[dD]/;

            $pl->chargen_race_next;
            Coro::Timer::sleep 0.05;
         }

         # create the playerdir, if necessary, as chargen_race_done did it before
         # presumably because of unique maps
         aio_mkdir playerdir $pl, 0770;
         $pl->chargen_race_done;

         while () {
            my $res = query $ns, cf::CS_QUERY_SINGLECHAR,
                         "Now choose a gender.\nPress 'f' to become female, and 'm' to become male.\n";

            if ($res =~ /^[fF]/) {
               $pl->gender (1);
               last;
            } elsif ($res =~ /^[mM]/) {
               $pl->gender (0);
               last;
            }
            Coro::Timer::sleep 0.05;
         }

         $ob->reply (undef, "Welcome to Deliantra!");

         # XXX: Workaround for delayed client ext protocol handshake
         $pl->esrv_new_player;

         delete $pl->{deny_save};

         last;
      }

      if (0 < Coro::AIO::aio_load "$cf::CONFDIR/motd", my $motd) {
         $ns->send_msg ("c/motd" => $motd, cf::NDI_CLEAR);
      }
   });
});

cf::register_command password => sub {
   my ($pl, $arg) = @_;

   unless ($pl->flag (cf::FLAG_WIZ)) {
      $pl->message (
         "The password can currently only changed by a DM.",
         cf::NDI_UNIQUE | cf::NDI_REPLY);
      return;
   }

   my (@args) = split /\s+/, $arg;
   my ($player, $new_pw) = @args;

   if ($pl->flag (cf::FLAG_WIZ) && $player eq '') {
      $pl->message (
         "Usage: password <player> [<new password>]",
         cf::NDI_UNIQUE | cf::NDI_REPLY);
      return;
   }

   if ($new_pw eq '') {
      $new_pw =
         join '',
            map { ('.', '/', 0..9, 'A'..'Z', 'a'..'z')[(cf::rndm 64)] }
               1..9;
   }

   cf::async {
      my $plc = cf::player::find $player;
      if ($plc) {
         $plc->password (encode_password $new_pw);
         $pl->message (
            "Ok, changed password of '$player' to '$new_pw'!",
            cf::NDI_UNIQUE | cf::NDI_RED | cf::NDI_REPLY);
      } else {
         $pl->message (
            "Fail! Couldn't set password for '$player', "
            . "he doesn't seem to exist!",
            cf::NDI_UNIQUE | cf::NDI_RED | cf::NDI_REPLY);
      }
   };
};

cf::register_command quit => sub {
   my ($ob, $arg) = @_;

   $ob->send_msg (undef,
                  "Quitting will delete your character PERMANENTLY: It will be gone forever and any progress will be lost. "
                  . "If you are sure you want to do this, then use the quit_character command instead of quit.",
                  cf::NDI_UNIQUE | cf::NDI_RED | cf::NDI_REPLY);
};

cf::register_command quit_character => sub {
   my ($ob, $arg) = @_;

   my $pl = $ob->contr;

   $pl->ns->query (cf::CS_QUERY_SINGLECHAR, "Do you want to PERMANENTLY delete your character and all associated data (y/n)?", sub {
      if ($_[0] !~ /^[yY]/) {
         $ob->send_msg (undef, "Ok, not not quitting then.", cf::NDI_UNIQUE | cf::NDI_RED | cf::NDI_REPLY);
      } else {
         $ob->send_msg (undef, "Ok, quitting, hope to see you again.", cf::NDI_UNIQUE | cf::NDI_RED | cf::NDI_REPLY);
         cf::async {
            $pl->quit_character;
         };
      }
   });
};

cf::object->attach (
   type     => cf::SAVEBED,
   on_apply => sub {
      my ($bed, $ob) = @_;

      return cf::override 0 unless $ob->type == cf::PLAYER;

      my $pl = $ob->contr;

      # update respawn position
      $pl->savebed ($bed->map->path, $bed->x, $bed->y);

      cf::async {
         my $killer = cf::arch::get "killer_logout"; $pl->killer ($killer); $killer->destroy;
         ext::highscore::check $ob;

         $pl->save;

         $ob->send_msg ($cf::SAY_CHANNEL => "In the future, you will wake up here when you die.", cf::NDI_DEF | cf::NDI_REPLY);

         $pl->ns->query (cf::CS_QUERY_SINGLECHAR, "Do you want to continue playing (y/n)?", sub {
            if ($_[0] !~ /^[yY]/) {
               $pl->invoke (cf::EVENT_PLAYER_LOGOUT, 1);
               $pl->deactivate;
               $pl->ns->destroy;
            }
         });
      };
   },
);

cf::player->attach (
   on_login  => sub {
      my ($pl) = @_;
      my $name = $pl->ob->name;

      $_->ob->message ("$name has entered the game.", cf::NDI_DK_ORANGE | cf::NDI_UNIQUE) for cf::player::list;
   },
   on_logout => sub {
      my ($pl, $cleanly) = @_;
      my $name = $pl->ob->name;

      if ($cleanly) {
         $_->ob->message ("$name left the game.", cf::NDI_DK_ORANGE | cf::NDI_UNIQUE) for cf::player::list;
      } else {
         $_->ob->message ("$name uncerimoniously disconnected.", cf::NDI_DK_ORANGE | cf::NDI_UNIQUE) for cf::player::list;
         $pl->{unclean_save} = $cf::RUNTIME
            unless safe_spot $pl;
      }
   },
);

Revision:	1.112
Committed:	Mon May 10 15:54:40 2010 UTC (14 years ago) by elmex
Branch:	MAIN
CVS Tags:	rel-3_0
Changes since 1.111:	+22 -45 lines
Log Message:	make password command only usable for the DMs for the moment. too broken/insecure for users :-/
#	User	Rev	Content
1	root	1.102	#! perl # mandatory depends=highscore
2	root	1.1
3			# login handling
4
5			use Fcntl;
6			use Coro::AIO;
7	root	1.53
8	root	1.64	our $MAX_DISCONNECT_TIME = $cf::CFG{max_disconnect_time} \|\| 3600;
9
10	root	1.9	# paranoia function to overwrite a string-in-place
11			sub nuke_str {
12			substr $_[0], 0, (length $_[0]), "x" x length $_[0]
13			}
14	root	1.1
15			sub query {
16			my ($ns, $flags, $text) = @_;
17
18	root	1.94	$ns->query ($flags, $text, Coro::rouse_cb);
19			Coro::rouse_wait
20	root	1.1	}
21
22			sub can_cleanup {
23	root	1.19	my ($pl, $mtime) = @_;
24	root	1.1
25			my $age = time - $mtime;
26	root	1.19	my $level = $pl->ob->level;
27	root	1.1
28			($level <= 3 && $age > 7 * 86400) # 7 days for level 0..3
29			\|\| ($level <= 9 && $age > 90 * 86400) # 3 months for level 4..9
30			\|\| ($level <= 20 && $age > 180 * 86400) # 6 months for level 10..20
31			\|\| $age > 700 * 86400 # 2 years for everybody else
32			}
33
34			sub check_playing {
35			my ($ns, $user) = @_;
36
37	root	1.11	return unless cf::player::find_active $user;
38	root	1.1
39			$ns->send_drawinfo (
40			"That player is already logged in on this server. "
41			. "If you want to create a new player, choose another name. "
42	root	1.59	. "If you have already a registered, make sure nobody "
43			. "else is using your account at this time. If you lost your connection "
44	root	1.1	. "then the server will likely timeout within a minute. If you still "
45			. "cannot log-in after a minute, you are still logged in. Make sure "
46			. "you do not have another client running. If you use windows, reboot, "
47			. "this will fix anything.",
48			cf::NDI_RED
49			);
50
51			1
52			}
53
54	root	1.79	sub safe_spot($) {
55			my ($pl) = @_;
56
57			my $ob = $pl->ob;
58	root	1.76
59	root	1.79	my $m = $ob->map
60			or return;
61			my $x = $ob->x;
62			my $y = $ob->y;
63
64			# return 0;#d#
65			# warn join ":", $m->at ($x, $y);#d#
66			# warn "FOO$m { ".scalar ($m->at ($x, $y))." }\n";
67			# return 0;
68	root	1.78
69	root	1.76	scalar grep $_->type == cf::SAVEBED, $m->at ($x, $y)
70			}
71
72	root	1.48	sub enter_map {
73	root	1.11	my ($pl) = @_;
74
75	root	1.62	my $ob = $pl->ob;
76
77	root	1.48	my ($map, $x, $y)
78	root	1.62	= $ob->{_link_pos}
79			? @{delete $ob->{_link_pos}}
80			: ($pl->maplevel, $ob->x, $ob->y);
81	root	1.48
82	root	1.62	$ob->enter_link;
83	root	1.48
84	root	1.77	my $m = cf::map::find $map;
85			my $time = delete $pl->{unclean_save};
86
87	root	1.79	if ($time && $m) {
88	root	1.77	if ($time < $m->{instantiate_time}) {
89			# the map was reset in the meantime
90			my $age = $cf::RUNTIME - $time;
91
92	root	1.107	cf::info $ob->name, " map reset after logout, logout age $age (>= $MAX_DISCONNECT_TIME)\n";#d#
93	root	1.77
94			if ($age >= $MAX_DISCONNECT_TIME) {
95			$ob->message (
96			"You didn't use a bed to reality to leave this realm, leaving your body in great danger. "
97			. "Unfortunately, nobody was near to help you when the monsters arrived to eat you. "
98			. "Maybe you can find comfort in the thought that your body was quite satisfying in taste... "
99			. "H<You disconnected too long without having used a savebed.>",
100			cf::NDI_RED
101			);
102			# kill them.
103			# reminds me of the famous badness 10000 syndrome...
104			$ob->stats->hp (-10000); #] if they survive this they deserved to live
105	root	1.86	my $killer = cf::arch::get "killer_login"; $pl->killer ($killer); $killer->destroy;
106	root	1.48	} else {
107	root	1.81	($map, $x, $y) = $pl->savebed;
108
109	root	1.64	$ob->message (
110	root	1.77	"You didn't use a bed to reality to leave this realm, leaving your body in great danger. "
111			. "Fortunately, some friendly dwellers found you, checked your passport, and brought you to safety. "
112			. "Better use a savebed next time, much worse things could have happened... "
113			. "H<You disconnected without having used a savebed. When you do that for too long, you might die.>",
114	root	1.48	cf::NDI_RED
115			);
116			}
117	root	1.77	} else {
118			$ob->message (
119			"You didn't use a bed to reality to leave this realm. This is very dangerous, "
120			. "as lots of things could happen when you leave by other means, such as cave-ins, "
121			. "or monsters suddenly snapping your body. Better use a savebed next time. "
122			. "H<Always apply a bed of reality to disconnect from the server.>",
123			cf::NDI_RED
124			);
125	root	1.48	}
126	root	1.11	}
127	root	1.48
128	root	1.100	$ob->goto ($map, $x, $y);
129	root	1.11	}
130
131	root	1.110	sub encode_password($) {
132			# crypt $_[0],
133			# join '',
134			# ('.', '/', 0..9, 'A'..'Z', 'a'..'z')[(cf::rndm 64), (cf::rndm 64)]
135			"!" . unpack "H*", $_[0]
136			}
137
138			sub compare_password($$) {
139			my ($pass, $token) = @_;
140
141			if ($token =~ /\!(.*)/) {
142			return $pass eq pack "H*", $1;
143			} else {
144			return $token eq crypt $pass, $token;
145			}
146	elmex	1.106	}
147
148	root	1.111	# delete a player directory
149	root	1.1	sub nuke_playerdir {
150			my ($user) = @_;
151
152	root	1.111	my $lock = cf::lock_acquire "ext::login::nuke_playerdir";
153
154	root	1.71	my $temp = "$PLAYERDIR/~$Coro::current~deleting~";
155	root	1.111	aio_rename "$PLAYERDIR/$user", $temp;
156			IO::AIO::aio_rmtree $temp;
157	root	1.1	}
158
159	root	1.60	cf::client->attach (on_addme => sub {
160	root	1.1	my ($ns) = @_;
161
162	root	1.32	$ns->pl and return $ns->destroy;
163	root	1.1
164	root	1.10	$ns->async (sub {
165	root	1.72	$Coro::current->{desc} = "addme init";
166
167	root	1.1	my ($user, $pass);
168
169			$ns->send_packet ("addme_success");
170
171			for (;;) {
172			$ns->send_drawinfo (
173			"Please enter your username now. If you are a new user, "
174			. "make one up that describes your character best. "
175			. "Only letters and digits are allowed, though.",
176			cf::NDI_BLUE
177			);
178
179			# read username
180			while () {
181	root	1.89	$user = query $ns, 0, "What is your name? (login names are case-sensitive)\n:";
182	root	1.3
183			if ($cf::LOGIN_LOCK{$user}) {
184			$ns->send_drawinfo (
185			"That username is currently used in another login session. "
186			. "Chose another, or wait till the other session has ended.",
187			cf::NDI_RED
188			);
189	root	1.92	} elsif ($user =~ /^[a-zA-Z0-9][a-zA-Z0-9\-_]{2,19}\z/) {
190	root	1.3	last;
191			} else {
192			$ns->send_drawinfo (
193			"Your username contains illegal characters "
194			. "(only a-z, A-Z and 0-9 are allowed), "
195	root	1.92	. "or is not between 3 and 20 characters in length.",
196	root	1.3	cf::NDI_RED
197			);
198			}
199	root	1.61	Coro::Timer::sleep 0.4;
200	root	1.1	}
201
202			check_playing $ns, $user and next;
203
204	root	1.72	$Coro::current->{desc} = "addme($user) pass";
205
206	root	1.1	$ns->send_drawinfo (
207			"Welcome $user, please enter your password now. "
208			. "New users should now choose a password. "
209			. "Anything your client lets you enter is fine.",
210			cf::NDI_BLUE
211			);
212
213			# read password
214			while () {
215			$pass = query $ns, cf::CS_QUERY_HIDEINPUT, "What is your password?\n:";
216			last if $pass =~ /.../;
217			$ns->send_drawinfo (
218			"Try to use at least three characters as your password please, "
219			. "that cannot be too much to ask for :)",
220			cf::NDI_RED
221			);
222	root	1.61	Coro::Timer::sleep 0.4;
223	root	1.1	}
224
225	root	1.3	# lock this username for the remainder of this login session
226			if ($cf::LOGIN_LOCK{$user}) {
227			$ns->send_drawinfo (
228			"That username is currently used in another login session. "
229			. "Chose another, or wait till the other session has ended.",
230			cf::NDI_RED
231			);
232			next;
233			}
234			local $cf::LOGIN_LOCK{$user} = 1;
235
236			check_playing $ns, $user and next;
237
238	root	1.72	$Coro::current->{desc} = "addme($user) check";
239
240	root	1.1	# try to read the user file and check the password
241	root	1.19	if (my $pl = cf::player::find $user) {
242			aio_stat $pl->path and next;
243			my $mtime = (stat _)[9];
244	root	1.110	my $token = $pl->password;
245	root	1.1
246	root	1.110	if ($cf::CFG{ext_login_nocheck} or compare_password $pass, $token) {
247			$pl->password (encode_password $pass); # make sure we store the new encoding #d#
248	root	1.9	nuke_str $pass;
249	root	1.1	# password matches, wonderful
250	root	1.11	my $pl = cf::player::find $user or next;
251	root	1.1	$pl->connect ($ns);
252	root	1.48	enter_map $pl;
253	root	1.1	last;
254	root	1.19	} elsif (can_cleanup $pl, $mtime) {
255	root	1.1	Coro::Timer::sleep 1;
256
257			$ns->send_drawinfo (
258	root	1.3	"Player exists, but password does not match. If this is your account, "
259			. "please try again. If not, you can now decide to take over this account "
260	root	1.1	. "because it has not been in-use for some time.",
261			cf::NDI_RED
262			);
263
264	root	1.9	#TODO: nuke_str
265	root	1.1	(query $ns, cf::CS_QUERY_SINGLECHAR, "Delete existing account and create a new one (Y/N)?") =~ /^[yY]/
266			or next;
267
268			# check if the file hasn't changed
269	root	1.11	aio_stat cf::player::path $user and next;
270	root	1.1	$mtime == (stat _)[9] or next;
271
272	root	1.19	$pl->quit_character;
273	root	1.1
274			# fall through to creation
275			} else {
276	root	1.9	nuke_str $pass;
277
278	root	1.1	Coro::Timer::sleep 1;
279
280			$ns->send_drawinfo (
281			"Wrong username or password. Please try again "
282			. "(check for Numlock and other semi-obvious error sources).",
283			cf::NDI_RED
284			);
285			next;
286			}
287	root	1.37	} else {
288			# unable to load the playerfile:
289			# check wether the player dir exists, which means the file is corrupted or
290			# something very similar.
291			if (!aio_stat cf::player::playerdir $user) {
292			$ns->send_drawinfo (
293			"Unable to retrieve this player. It might be a locked or broken account. "
294			. "If this is your account, ask a dungeon master for assistance. "
295			. "Otherwise choose a different login name.",
296			cf::NDI_RED
297			);
298			next;
299			}
300	root	1.1	}
301
302			# the rest of this function is character creation
303	root	1.72	$Coro::current->{desc} = "addme($user) chargen";
304	root	1.1
305	root	1.3	# just to make sure nothing is left over
306	root	1.111	# normally, nothing is there.
307	root	1.1	nuke_playerdir $user;
308
309	root	1.3	my $pass2 = query $ns, cf::CS_QUERY_HIDEINPUT, "Please type your password again.";
310
311			if ($pass2 ne $pass) {
312	root	1.9	nuke_str $pass;
313			nuke_str $pass2;
314	root	1.3	$ns->send_drawinfo (
315			"The passwords do not match, please try again.",
316			cf::NDI_RED
317			);
318	root	1.61	Coro::Timer::sleep 0.5;
319	root	1.3	next;
320			}
321
322	root	1.9	nuke_str $pass2;
323
324	root	1.11	my $pl = cf::player::new $user;
325	elmex	1.106	$pl->password (encode_password $pass);
326	root	1.9	nuke_str $pass;
327	root	1.1	$pl->connect ($ns);
328	root	1.48	my $ob = $pl->ob;
329	root	1.3
330	root	1.48	$ob->goto ($pl->maplevel, $ob->x, $ob->y);
331	root	1.1
332			while () {
333			$ob->update_stats;
334			$pl->save_stats;
335
336			my $res = query $ns, cf::CS_QUERY_SINGLECHAR,
337			"[y] to roll new stats [n] to use stats\n[1-7] [1-7] to swap stats.\nRoll again (y/n/1-7)?";
338
339			if ($res =~ /^[Nn]/) {
340			last;
341			} elsif ($res > 0 && $res <= 7) {
342			my $swap = query $ns, cf::CS_QUERY_SINGLECHAR, "Swap stat with (will not roll new stats) [1-7]?";
343
344			if ($swap > 0 && $swap <= 7) {
345			$ob->swap_stats ($res - 1, $swap - 1);
346			}
347			} else {
348			$ob->roll_stats;
349			}
350	root	1.61
351	root	1.87	Coro::Timer::sleep 0.05;
352	root	1.1	}
353
354			$ob->set_animation (2);
355			$ob->add_statbonus;
356
357	root	1.45	while () {
358	root	1.67	$ns->send_msg ("chargen-race-title", ucfirst $pl->title, -1);
359	root	1.45	my $msg = $ob->msg;
360	root	1.46	$msg =~ s/(?<=\S)\n(?=\S)/ /g;
361	root	1.67	$ns->send_msg ("chargen-race-description", $msg, cf::NDI_BLUE);
362	root	1.45
363			my $res = query $ns, cf::CS_QUERY_SINGLECHAR,
364			"Now choose a character.\nPress any key to change outlook.\nPress `d' when you're pleased.\n";
365
366			last if $res =~ /[dD]/;
367
368			$pl->chargen_race_next;
369	root	1.103	Coro::Timer::sleep 0.05;
370	root	1.45	}
371
372	root	1.85	# create the playerdir, if necessary, as chargen_race_done did it before
373			# presumably because of unique maps
374			aio_mkdir playerdir $pl, 0770;
375	root	1.45	$pl->chargen_race_done;
376	root	1.1
377	root	1.55	while () {
378			my $res = query $ns, cf::CS_QUERY_SINGLECHAR,
379			"Now choose a gender.\nPress 'f' to become female, and 'm' to become male.\n";
380
381			if ($res =~ /^[fF]/) {
382			$pl->gender (1);
383			last;
384			} elsif ($res =~ /^[mM]/) {
385			$pl->gender (0);
386			last;
387			}
388	root	1.103	Coro::Timer::sleep 0.05;
389	root	1.55	}
390
391	root	1.75	$ob->reply (undef, "Welcome to Deliantra!");
392	root	1.55
393	elmex	1.93	# XXX: Workaround for delayed client ext protocol handshake
394			$pl->esrv_new_player;
395
396	root	1.45	delete $pl->{deny_save};
397	root	1.1
398			last;
399			}
400	root	1.101
401			if (0 < Coro::AIO::aio_load "$cf::CONFDIR/motd", my $motd) {
402			$ns->send_msg ("c/motd" => $motd, cf::NDI_CLEAR);
403			}
404	root	1.1	});
405	root	1.60	});
406	root	1.1
407	elmex	1.106	cf::register_command password => sub {
408			my ($pl, $arg) = @_;
409
410	elmex	1.112	unless ($pl->flag (cf::FLAG_WIZ)) {
411			$pl->message (
412			"The password can currently only changed by a DM.",
413			cf::NDI_UNIQUE \| cf::NDI_REPLY);
414			return;
415			}
416
417	elmex	1.106	my (@args) = split /\s+/, $arg;
418	elmex	1.112	my ($player, $new_pw) = @args;
419	elmex	1.106
420			if ($pl->flag (cf::FLAG_WIZ) && $player eq '') {
421			$pl->message (
422			"Usage: password <player> [<new password>]",
423			cf::NDI_UNIQUE \| cf::NDI_REPLY);
424			return;
425			}
426
427	elmex	1.112	if ($new_pw eq '') {
428			$new_pw =
429			join '',
430			map { ('.', '/', 0..9, 'A'..'Z', 'a'..'z')[(cf::rndm 64)] }
431			1..9;
432			}
433	elmex	1.106
434	elmex	1.112	cf::async {
435			my $plc = cf::player::find $player;
436			if ($plc) {
437			$plc->password (encode_password $new_pw);
438	elmex	1.106	$pl->message (
439	elmex	1.112	"Ok, changed password of '$player' to '$new_pw'!",
440	elmex	1.106	cf::NDI_UNIQUE \| cf::NDI_RED \| cf::NDI_REPLY);
441			} else {
442			$pl->message (
443	elmex	1.112	"Fail! Couldn't set password for '$player', "
444			. "he doesn't seem to exist!",
445	elmex	1.106	cf::NDI_UNIQUE \| cf::NDI_RED \| cf::NDI_REPLY);
446			}
447	elmex	1.112	};
448	elmex	1.106	};
449
450	root	1.12	cf::register_command quit => sub {
451			my ($ob, $arg) = @_;
452
453	root	1.95	$ob->send_msg (undef,
454			"Quitting will delete your character PERMANENTLY: It will be gone forever and any progress will be lost. "
455			. "If you are sure you want to do this, then use the quit_character command instead of quit.",
456			cf::NDI_UNIQUE \| cf::NDI_RED \| cf::NDI_REPLY);
457	root	1.12	};
458
459			cf::register_command quit_character => sub {
460			my ($ob, $arg) = @_;
461
462			my $pl = $ob->contr;
463
464			$pl->ns->query (cf::CS_QUERY_SINGLECHAR, "Do you want to PERMANENTLY delete your character and all associated data (y/n)?", sub {
465			if ($_[0] !~ /^[yY]/) {
466	root	1.95	$ob->send_msg (undef, "Ok, not not quitting then.", cf::NDI_UNIQUE \| cf::NDI_RED \| cf::NDI_REPLY);
467	root	1.12	} else {
468	root	1.95	$ob->send_msg (undef, "Ok, quitting, hope to see you again.", cf::NDI_UNIQUE \| cf::NDI_RED \| cf::NDI_REPLY);
469	root	1.105	cf::async {
470			$pl->quit_character;
471			};
472	root	1.12	}
473			});
474			};
475	root	1.11
476	root	1.1	cf::object->attach (
477			type => cf::SAVEBED,
478			on_apply => sub {
479			my ($bed, $ob) = @_;
480
481			return cf::override 0 unless $ob->type == cf::PLAYER;
482
483	root	1.15	my $pl = $ob->contr;
484	root	1.11
485	root	1.1	# update respawn position
486	root	1.11	$pl->savebed ($bed->map->path, $bed->x, $bed->y);
487	root	1.1
488	root	1.111	cf::async {
489			my $killer = cf::arch::get "killer_logout"; $pl->killer ($killer); $killer->destroy;
490			ext::highscore::check $ob;
491
492			$pl->save;
493	root	1.1
494	root	1.111	$ob->send_msg ($cf::SAY_CHANNEL => "In the future, you will wake up here when you die.", cf::NDI_DEF \| cf::NDI_REPLY);
495	root	1.1
496	root	1.111	$pl->ns->query (cf::CS_QUERY_SINGLECHAR, "Do you want to continue playing (y/n)?", sub {
497			if ($_[0] !~ /^[yY]/) {
498			$pl->invoke (cf::EVENT_PLAYER_LOGOUT, 1);
499			$pl->deactivate;
500			$pl->ns->destroy;
501			}
502			});
503			};
504	root	1.1	},
505			);
506
507	root	1.8	cf::player->attach (
508			on_login => sub {
509			my ($pl) = @_;
510			my $name = $pl->ob->name;
511
512			$_->ob->message ("$name has entered the game.", cf::NDI_DK_ORANGE \| cf::NDI_UNIQUE) for cf::player::list;
513			},
514			on_logout => sub {
515			my ($pl, $cleanly) = @_;
516			my $name = $pl->ob->name;
517
518			if ($cleanly) {
519			$_->ob->message ("$name left the game.", cf::NDI_DK_ORANGE \| cf::NDI_UNIQUE) for cf::player::list;
520			} else {
521			$_->ob->message ("$name uncerimoniously disconnected.", cf::NDI_DK_ORANGE \| cf::NDI_UNIQUE) for cf::player::list;
522	root	1.79	$pl->{unclean_save} = $cf::RUNTIME
523			unless safe_spot $pl;
524	root	1.8	}
525			},
526			);
527