server/ext/login.ext

#! perl # mandatory depends=highscore

# login handling

use Fcntl;
use Coro::AIO;
use Deliantra::Util ();

CONF MAX_DISCONNECT_TIME = 3600;

our $VALID_LOGIN = qr<^[a-zA-Z0-9][a-zA-Z0-9\-_]{2,19}\z>;
our %LOGIN_LOCK;

sub query {
   my ($ns, $flags, $text) = @_;

   $ns->query ($flags, $text, Coro::rouse_cb);
   Coro::rouse_wait
}

sub can_cleanup {
   my ($pl, $mtime) = @_;

   my $age = time - $mtime;
   my $level = $pl->ob->level;

   ($level <= 3 && $age > 7 * 86400)            # 7 days for level 0..3
   || ($level <= 9 && $age > 90 * 86400)        # 3 months for level 4..9
   || ($level <= 20 && $age > 180 * 86400)      # 6 months for level 10..20
   || $age > 700 * 86400                        # 2 years for everybody else
}

# return a guard object for a lock on the given username, if available
sub login_guard {
   my ($user) = @_;

   exists $LOGIN_LOCK{$user}
      and return undef;

   cf::player::find_active $user
      and return undef;

   undef $LOGIN_LOCK{$user};
   Guard::guard { delete $LOGIN_LOCK{$user} }
}

sub safe_spot($) {
   my ($pl) = @_;
   
   my $ob = $pl->ob;

   my $m = $ob->map
      or return;
   my $x = $ob->x;
   my $y = $ob->y;

   # never happens normally, but helps when shell users make mistakes
   $m->linkable
      or return 1;

   scalar grep $_->type == cf::SAVEBED, $m->at ($x, $y)
}

sub enter_map {
   my ($pl) = @_;

   my $ob = $pl->ob;

   my ($map, $x, $y)
      = $ob->{_link_pos}
        ? @{delete $ob->{_link_pos}}
        : ($pl->maplevel, $ob->x, $ob->y);

   $ob->enter_link;

   my $m = cf::map::find $map;
   my $time = delete $pl->{unclean_save};

   if ($time && $m) {
      if ($time < $m->{instantiate_time}) {
         # the map was reset in the meantime
         my $age = $cf::RUNTIME - $time;

         cf::info $ob->name, " map reset after logout, logout age $age (>= $MAX_DISCONNECT_TIME)\n";#d#

         if ($age >= $MAX_DISCONNECT_TIME) {
            $ob->message (
               "You didn't use a bed to reality to leave this realm, leaving your body in great danger. "
             . "Unfortunately, nobody was near to help you when the monsters arrived to eat you. "
             . "Maybe you can find comfort in the thought that your body was quite satisfying in taste... "
             . "H<You disconnected too long without having used a savebed.>",
               cf::NDI_RED | cf::NDI_REPLY
            );
            # kill them.
            # reminds me of the famous badness 10000 syndrome...
            $ob->stats->hp (-10000); #] if they survive this they deserved to live
            my $killer = cf::arch::get "killer_login"; $pl->killer ($killer); $killer->destroy;
         } else {
            ($map, $x, $y) = $pl->savebed;

            $ob->message (
               "You didn't use a bed to reality to leave this realm, leaving your body in great danger. "
             . "Fortunately, some friendly dwellers found you, checked your passport, and brought you to safety. "
             . "Better use a savebed next time, much worse things could have happened... "
             . "H<You disconnected without having used a savebed. When you do that for too long, you might die.>",
               cf::NDI_RED | cf::NDI_REPLY
            );
         }
      } else {
         $ob->message (
            "You didn't use a bed to reality to leave this realm. This is very dangerous, "
          . "as lots of things could happen when you leave by other means, such as cave-ins, "
          . "or monsters suddenly snapping your body. Better use a savebed next time. "
          . "H<Always apply a bed of reality to disconnect from the server.>",
            cf::NDI_RED | cf::NDI_REPLY
         );
      }
   }

   $ob->goto ($map, $x, $y);
}

sub encode_password($) {
   unpack "H*", Deliantra::Util::hash_pw $_[0]
}

sub compare_password($$) {
   my ($pass, $token) = @_;

   if ($token =~ /!!(.*)/) {
      return +(substr $pass, 0, 8) eq pack "H*", $1;
   } elsif ($token =~ /!(.*)/) {
      return $pass eq pack "H*", $1;
   } else {
      return $token eq crypt $pass, $token;
   }
}

# delete a player directory
sub nuke_playerdir {
   my ($user) = @_;

   my $lock = cf::lock_acquire "ext::login::nuke_playerdir";

   my $temp = "$PLAYERDIR/~$Coro::current~deleting~";
   aio_rename "$PLAYERDIR/$user", $temp;
   IO::AIO::aio_rmtree $temp;
}

sub login {
   my ($pl) = @_;

   # handle character creation, if neccessary
   # the rest of this function is character creation

   my $ns = $pl->ns;
   my $ob = $pl->ob;

   if ($pl->{chargen} eq "init") {
      $ob->goto ($pl->maplevel, $ob->x, $ob->y);

      # create the playerdir, if necessary, as chargen_race_done did it before
      # presumably because of unique maps
      aio_mkdir playerdir $pl, 0770;
      delete $pl->{deny_save}; # set by new
      $pl->save;

      $pl->{chargen} = "stats";
   }

   if ($pl->{chargen} eq "stats") {
      while () {
         $ob->update_stats;
         $pl->save_stats;

         my $res = query $ns, cf::CS_QUERY_SINGLECHAR,
                      "[y] to roll new stats [n] to use stats\n[1-7] [1-7] to swap stats.\nRoll again (y/n/1-7)?";

         if ($res =~ /^[Nn]/) {
            last;
         } elsif ($res > 0 && $res <= 7) {
            my $swap = query $ns, cf::CS_QUERY_SINGLECHAR, "Swap stat with (will not roll new stats) [1-7]?";

            if ($swap > 0 && $swap <= 7) {
               $ob->swap_stats ($res - 1, $swap - 1);
            }
         } else {
            $ob->roll_stats;
         }

         Coro::Timer::sleep 0.05;
      }

      $ob->set_animation (2);
      $ob->add_statbonus;

      $pl->{chargen} = "race";
   }

   if ($pl->{chargen} eq "race") {
      while () {
         $ns->send_msg ("chargen-race-title", ucfirst $pl->title, -1);
         my $msg = $ob->msg;
         $msg =~ s/(?<=\S)\n(?=\S)/ /g;
         $ns->send_msg ("chargen-race-description", $msg, cf::NDI_BLUE);

         my $res = query $ns, cf::CS_QUERY_SINGLECHAR,
                      "Now choose a character.\nPress any key to change outlook.\nPress `d' when you're pleased.\n";

         last if $res =~ /[dD]/;

         $pl->chargen_race_next;
         Coro::Timer::sleep 0.05;
      }

      $pl->chargen_race_done;
      $pl->{chargen} = "gender";
   }

   if ($pl->{chargen} eq "race") {
      while () {
         my $res = query $ns, cf::CS_QUERY_SINGLECHAR,
                      "Now choose a gender.\nPress 'f' to become female, and 'm' to become male.\n";

         if ($res =~ /^[fF]/) {
            $pl->gender (1);
            last;
         } elsif ($res =~ /^[mM]/) {
            $pl->gender (0);
            last;
         }
         Coro::Timer::sleep 0.05;
      }
      $pl->{chargen} = "done";
   }

   $ns->state (cf::ST_PLAYING);

   if ($pl->{chargen} eq "done") {
      # XXX: Workaround for delayed client ext protocol handshake
      $pl->esrv_new_player;

      $pl->{chargen} = "done";
   }

   $ob->reply (undef, "Welcome to Deliantra!");

   if (0 < Coro::AIO::aio_load "$cf::CONFDIR/motd", my $motd) {
      $pl->ns->send_msg ("c/motd" => $motd, cf::NDI_CLEAR);
   }
}

sub chargen {
   my ($ns, $user, $hash) = @_;

   # just to make sure nothing is left over
   # normally, nothing is there.
   nuke_playerdir $user;

   my $pl = cf::player::new $user;
   $pl->password (unpack "H*", $hash);
   $pl->connect ($ns);

   $pl->{chargen} = "init";

   login $pl;
}

cf::client->attach (on_addme => sub {
   my ($ns) = @_;

   $ns->{addme}++ and return $ns->destroy;

   $ns->async (sub {
      $Coro::current->{desc} = "addme init";

      my ($user, $pass);

      $ns->send_packet ("addme_success");

      for (;;) {
         delete $ns->{login_guard};

         $ns->send_msg (log =>
            "Please enter your username now. If you are a new user, "
          . "make one up that describes your character best. "
          . "Only letters and digits are allowed, though.",
            cf::NDI_BLUE | cf::NDI_REPLY
         );

         # read username
         while () {
            $user = query $ns, 0, "What is your name? (login names are case-sensitive)\n:";

            if ($user =~ $VALID_LOGIN) {
               last;
            } else {
               $ns->send_msg (log =>
                  "Your username contains illegal characters "
                . "(only a-z, A-Z and 0-9 are allowed), "
                . "or is not between 3 and 20 characters in length.",
                  cf::NDI_RED | cf::NDI_REPLY
               );
            }
            Coro::Timer::sleep 0.4;
         }

         $Coro::current->{desc} = "addme($user)";

         $ns->send_msg (log =>
            "Welcome $user, please enter your password now. "
          . "New users should now choose a password. "
          . "Anything your client lets you enter is fine.",
            cf::NDI_BLUE | cf::NDI_REPLY
         );

         # read password
         while () {
            $pass = query $ns, cf::CS_QUERY_HIDEINPUT, "What is your password?\n:";
            last if $pass =~ /.../;
            $ns->send_msg (log =>
               "Try to use at least three characters as your password please, "
             . "that cannot be too much to ask for :)",
               cf::NDI_RED | cf::NDI_REPLY
            );
            Coro::Timer::sleep 0.4;
         }

         $ns->{login_guard} = login_guard $user
            or do {
               $ns->send_msg (log =>
                  "That user is already logged in (or is logging in)."
                . "Chose another, or wait till the other session has ended.",
                  cf::NDI_RED | cf::NDI_REPLY
               );
               next;
            };

         # try to read the user file and check the password
         if (my $pl = cf::player::find $user) {
            aio_stat $pl->path and next;
            my $mtime = (stat _)[9];
            my $token = $pl->password;

            if ($cf::CFG{ext_login_nocheck} or compare_password $pass, $token) {
               # player exists and passwords match - we can proceed

               # password matches, wonderful
               my $pl = cf::player::find $user or next;
               $pl->connect ($ns);
               enter_map $pl;
               login $pl;
               return;
            } elsif (can_cleanup $pl, $mtime) {
               Coro::Timer::sleep 1;

               $ns->send_msg (log =>
                  "Player exists, but password does not match. If this is your account, "
                . "please try again. If not, you can now decide to take over this account "
                . "because it has not been in-use for some time.",
                  cf::NDI_RED | cf::NDI_REPLY
               );

               (query $ns, cf::CS_QUERY_SINGLECHAR, "Delete existing account and create a new one (Y/N)?") =~ /^[yY]/
                  or next;

               # check if the file hasn't changed
               aio_stat cf::player::path $user and next;
               $mtime == (stat _)[9] or next;

               $pl->quit_character;

               # fall through to creation
            } else {
               Coro::Timer::sleep 1;

               $ns->send_msg (log =>
                  "Wrong username or password. Please try again "
                . "(check for Numlock and other semi-obvious error sources).",
                  cf::NDI_RED | cf::NDI_REPLY
               );
               next;
            }
         } else {
            # unable to load the playerfile:
            # check whether the player dir exists, which means the file is corrupted or
            # something very similar.
            if (!aio_stat cf::player::playerdir $user) {
               $ns->send_msg ( log =>
                  "Unable to retrieve this player. It might be a locked or broken account. "
                . "If this is your account, ask a dungeon master for assistance. "
                . "Otherwise choose a different login name.",
                  cf::NDI_RED | cf::NDI_REPLY
               );
               next;
            }
         }

         my $pass2 = query $ns, cf::CS_QUERY_HIDEINPUT, "Please type your password again.";

         if ($pass2 ne $pass) {
            $ns->send_msg (log =>
               "The passwords do not match, please try again.",
               cf::NDI_RED | cf::NDI_REPLY
            );
            Coro::Timer::sleep 0.5;
            next;
         }

         last;
      }

      chargen $ns, $user, Deliantra::Util::hash_pw $pass;
   });
});

cf::client->attach (
   on_version => sub {
      my ($ns, $arg) = @_;

      # perl probably uses lrand48, which is not secure at all
      # maybe require linux and use /dev/urandom.
      $ns->{nonces} = [map { join "", map { chr rand 256 } 0..63  } 1..2];
      $ns->ext_msg (nonces => @{ $ns->{nonces} });
   },
);

cf::register_async_exticmd create_login => sub {
   my ($ns, $reply, $user, $pass) = @_;

   $ns->{addme}++ and return $ns->destroy;

   $ns->async (sub {
      my $fail = sub {
         $reply->(0, $_[0]);
         $ns->flush; # does not ensure that the data reaches the client - TODO
         # need to do this in another thread, as this one gets canceled
         Coro::async_pool {
            Coro::AnyEvent::sleep 0.1; # TODO, see above, extra hack
            $ns->destroy if $ns->valid;
         };
         Coro::schedule; # do the destroy, should not return
      };

      $user =~ $VALID_LOGIN
         or return $fail (
               "Your username contains illegal characters (only a-z, A-Z and 0-9 are allowed), "
             . "or is not between 3 and 20 characters in length."
            );

      $ns->{login_guard} = login_guard $user
         or return $fail->("User name '$user' is in use - try another login name.");

      cf::player::find $user
         and return $fail->("User name '$user' is already registered - choose another login name.");

      $reply->(1, "Account Created");

      chargen $ns, $user, $pass;
   });
};

cf::register_async_exticmd login => sub {
   my ($ns, $reply, $user, $hash) = @_;

   $ns->{addme}++ and return $ns->destroy;

   $ns->async (sub {
      $Coro::current->{desc} = "login($user)";

      my $fail = sub {
         $reply->(0, $_[0]);
         $ns->flush; # does not ensure that the data reaches the client - TODO
         # need to do this in another thread, as this one gets canceled
         Coro::async_pool {
            Coro::AnyEvent::sleep 0.1; # TODO, see above, extra hack
            $ns->destroy if $ns->valid;
         };
         Coro::schedule; # do the destroy, should not return
      };

      $ns->{login_guard} = login_guard $user
         or return $fail->("User '$user' is currently playing or logging in in another session. If that is your "
                           . "user name, make sure you are not running two clients. When in doubt, reboot.");

      # try to read the user file and check the password
      my $pl = cf::player::find $user
         or return $fail->("User '$user' does not exist - wrong spelling?");

      aio_stat $pl->path
         and return $ns->destroy;

      my $mtime = (stat _)[9];
      my $token = $pl->password;

      $token = $token =~ /^!/
               ? Deliantra::Util::hash_pw pack "H*", substr $token, 1
               : pack "H*", $token;

      $token = Deliantra::Util::auth_pw $token, $ns->{nonces}[0], $ns->{nonces}[1];

      $token eq $hash
         or $cf::CFG{ext_login_nocheck}
         or return $fail->("User exists, but the password doesn't match - check your spelling, NumLock/CapsLock etc.");
      
      # player exists and passwords match - we can proceed

      $reply->(1, "Success");

      $pl->connect ($ns);
      enter_map $pl;
      login $pl;
   });
};

cf::register_command password => sub {
   my ($pl, $arg) = @_;

   unless ($pl->flag (cf::FLAG_WIZ)) {
      $pl->message (
         "The password can currently only changed by a DM.",
         cf::NDI_UNIQUE | cf::NDI_REPLY);
      return;
   }

   $pl->message (#d#
      "Passwords cannot currently be changed.",#d#
      cf::NDI_UNIQUE | cf::NDI_REPLY);#d#
   return;#d#

   my (@args) = split /\s+/, $arg;
   my ($player, $new_pw) = @args;

   if ($pl->flag (cf::FLAG_WIZ) && $player eq '') {
      $pl->message (
         "Usage: password <player> [<new password>]",
         cf::NDI_UNIQUE | cf::NDI_REPLY);
      return;
   }

   if ($new_pw eq '') {
      $new_pw =
         join '',
            map { ('.', '/', 0..9, 'A'..'Z', 'a'..'z')[(cf::rndm 64)] }
               1..9;
   }

   cf::async {
      my $plc = cf::player::find $player;
      if ($plc) {
         $plc->password (encode_password $new_pw);
         $pl->message (
            "Ok, changed password of '$player' to '$new_pw'!",
            cf::NDI_UNIQUE | cf::NDI_RED | cf::NDI_REPLY);
      } else {
         $pl->message (
            "Fail! Couldn't set password for '$player', "
            . "he doesn't seem to exist!",
            cf::NDI_UNIQUE | cf::NDI_RED | cf::NDI_REPLY);
      }
   };
};

cf::register_command quit => sub {
   my ($ob, $arg) = @_;

   $ob->send_msg (undef,
                  "Quitting will delete your character PERMANENTLY: It will be gone forever and any progress will be lost. "
                  . "If you are sure you want to do this, then use the quit_character command instead of quit.",
                  cf::NDI_UNIQUE | cf::NDI_RED | cf::NDI_REPLY);
};

cf::register_command quit_character => sub {
   my ($ob, $arg) = @_;

   my $pl = $ob->contr;

   $pl->ns->query (cf::CS_QUERY_SINGLECHAR, "Do you want to PERMANENTLY delete your character and all associated data (y/n)?", sub {
      if ($_[0] !~ /^[yY]/) {
         $ob->send_msg (undef, "Ok, not not quitting then.", cf::NDI_UNIQUE | cf::NDI_RED | cf::NDI_REPLY);
      } else {
         $ob->send_msg (undef, "Ok, quitting, hope to see you again.", cf::NDI_UNIQUE | cf::NDI_RED | cf::NDI_REPLY);
         cf::async {
            $pl->quit_character;
         };
      }
   });
};

cf::object->attach (
   type     => cf::SAVEBED,
   on_apply => sub {
      my ($bed, $ob) = @_;

      return cf::override 0 unless $ob->type == cf::PLAYER;

      my $pl = $ob->contr;

      # update respawn position
      $pl->savebed ($bed->map->path, $bed->x, $bed->y);

      cf::async {
         my $killer = cf::arch::get "killer_logout"; $pl->killer ($killer); $killer->destroy;
         ext::highscore::check $ob;

         $pl->save;

         $ob->send_msg ($cf::SAY_CHANNEL => "In the future, you will wake up here when you die.", cf::NDI_DEF | cf::NDI_REPLY);

         my $ns = $pl->ns
            or return;

         $ns->query (cf::CS_QUERY_SINGLECHAR, "Do you want to continue playing (y/n)?", sub {
            if ($_[0] !~ /^[yY]/) {
               $pl->invoke (cf::EVENT_PLAYER_LOGOUT, 1);
               $pl->deactivate;
               $pl->ns->destroy;
            }
         });
      };
   },
);

cf::player->attach (
   on_login  => sub {
      my ($pl) = @_;
      my $name = $pl->ob->name;

      $_->ob->message ("$name has entered the game.", cf::NDI_DK_ORANGE | cf::NDI_UNIQUE) for cf::player::list;
   },
   on_logout => sub {
      my ($pl, $cleanly) = @_;
      my $name = $pl->ob->name;

      if ($cleanly) {
         $_->ob->message ("$name left the game.", cf::NDI_DK_ORANGE | cf::NDI_UNIQUE) for cf::player::list;
      } else {
         $_->ob->message ("$name uncerimoniously disconnected.", cf::NDI_DK_ORANGE | cf::NDI_UNIQUE) for cf::player::list;
         $pl->{unclean_save} = $cf::RUNTIME
            unless safe_spot $pl;
      }
   },
);

Revision:	1.130
Committed:	Sun Nov 18 10:00:55 2012 UTC (11 years, 6 months ago) by root
Branch:	MAIN
Changes since 1.129:	+21 -29 lines
Log Message:	drawinfo
#	User	Rev	Content
1	root	1.102	#! perl # mandatory depends=highscore
2	root	1.1
3			# login handling
4
5			use Fcntl;
6			use Coro::AIO;
7	root	1.120	use Deliantra::Util ();
8	root	1.53
9	root	1.117	CONF MAX_DISCONNECT_TIME = 3600;
10	root	1.64
11	root	1.125	our $VALID_LOGIN = qr<^[a-zA-Z0-9][a-zA-Z0-9\-_]{2,19}\z>;
12	root	1.129	our %LOGIN_LOCK;
13
14	root	1.1	sub query {
15			my ($ns, $flags, $text) = @_;
16
17	root	1.94	$ns->query ($flags, $text, Coro::rouse_cb);
18			Coro::rouse_wait
19	root	1.1	}
20
21			sub can_cleanup {
22	root	1.19	my ($pl, $mtime) = @_;
23	root	1.1
24			my $age = time - $mtime;
25	root	1.19	my $level = $pl->ob->level;
26	root	1.1
27			($level <= 3 && $age > 7 * 86400) # 7 days for level 0..3
28			\|\| ($level <= 9 && $age > 90 * 86400) # 3 months for level 4..9
29			\|\| ($level <= 20 && $age > 180 * 86400) # 6 months for level 10..20
30			\|\| $age > 700 * 86400 # 2 years for everybody else
31			}
32
33	root	1.129	# return a guard object for a lock on the given username, if available
34			sub login_guard {
35			my ($user) = @_;
36	root	1.1
37	root	1.129	exists $LOGIN_LOCK{$user}
38			and return undef;
39	root	1.1
40	root	1.129	cf::player::find_active $user
41			and return undef;
42	root	1.1
43	root	1.129	undef $LOGIN_LOCK{$user};
44			Guard::guard { delete $LOGIN_LOCK{$user} }
45	root	1.1	}
46
47	root	1.79	sub safe_spot($) {
48			my ($pl) = @_;
49
50			my $ob = $pl->ob;
51	root	1.76
52	root	1.79	my $m = $ob->map
53			or return;
54			my $x = $ob->x;
55			my $y = $ob->y;
56
57	root	1.113	# never happens normally, but helps when shell users make mistakes
58	root	1.116	$m->linkable
59	root	1.113	or return 1;
60
61	root	1.76	scalar grep $_->type == cf::SAVEBED, $m->at ($x, $y)
62			}
63
64	root	1.48	sub enter_map {
65	root	1.11	my ($pl) = @_;
66
67	root	1.62	my $ob = $pl->ob;
68
69	root	1.48	my ($map, $x, $y)
70	root	1.62	= $ob->{_link_pos}
71			? @{delete $ob->{_link_pos}}
72			: ($pl->maplevel, $ob->x, $ob->y);
73	root	1.48
74	root	1.62	$ob->enter_link;
75	root	1.48
76	root	1.77	my $m = cf::map::find $map;
77			my $time = delete $pl->{unclean_save};
78
79	root	1.79	if ($time && $m) {
80	root	1.77	if ($time < $m->{instantiate_time}) {
81			# the map was reset in the meantime
82			my $age = $cf::RUNTIME - $time;
83
84	root	1.107	cf::info $ob->name, " map reset after logout, logout age $age (>= $MAX_DISCONNECT_TIME)\n";#d#
85	root	1.77
86			if ($age >= $MAX_DISCONNECT_TIME) {
87			$ob->message (
88			"You didn't use a bed to reality to leave this realm, leaving your body in great danger. "
89			. "Unfortunately, nobody was near to help you when the monsters arrived to eat you. "
90			. "Maybe you can find comfort in the thought that your body was quite satisfying in taste... "
91			. "H<You disconnected too long without having used a savebed.>",
92	root	1.130	cf::NDI_RED \| cf::NDI_REPLY
93	root	1.77	);
94			# kill them.
95			# reminds me of the famous badness 10000 syndrome...
96			$ob->stats->hp (-10000); #] if they survive this they deserved to live
97	root	1.86	my $killer = cf::arch::get "killer_login"; $pl->killer ($killer); $killer->destroy;
98	root	1.48	} else {
99	root	1.81	($map, $x, $y) = $pl->savebed;
100
101	root	1.64	$ob->message (
102	root	1.77	"You didn't use a bed to reality to leave this realm, leaving your body in great danger. "
103			. "Fortunately, some friendly dwellers found you, checked your passport, and brought you to safety. "
104			. "Better use a savebed next time, much worse things could have happened... "
105			. "H<You disconnected without having used a savebed. When you do that for too long, you might die.>",
106	root	1.130	cf::NDI_RED \| cf::NDI_REPLY
107	root	1.48	);
108			}
109	root	1.77	} else {
110			$ob->message (
111			"You didn't use a bed to reality to leave this realm. This is very dangerous, "
112			. "as lots of things could happen when you leave by other means, such as cave-ins, "
113			. "or monsters suddenly snapping your body. Better use a savebed next time. "
114			. "H<Always apply a bed of reality to disconnect from the server.>",
115	root	1.130	cf::NDI_RED \| cf::NDI_REPLY
116	root	1.77	);
117	root	1.48	}
118	root	1.11	}
119	root	1.48
120	root	1.100	$ob->goto ($map, $x, $y);
121	root	1.11	}
122
123	root	1.110	sub encode_password($) {
124	root	1.127	unpack "H*", Deliantra::Util::hash_pw $_[0]
125	root	1.110	}
126
127			sub compare_password($$) {
128			my ($pass, $token) = @_;
129
130	root	1.118	if ($token =~ /!!(.*)/) {
131			return +(substr $pass, 0, 8) eq pack "H*", $1;
132			} elsif ($token =~ /!(.*)/) {
133	root	1.110	return $pass eq pack "H*", $1;
134			} else {
135			return $token eq crypt $pass, $token;
136			}
137	elmex	1.106	}
138
139	root	1.111	# delete a player directory
140	root	1.1	sub nuke_playerdir {
141			my ($user) = @_;
142
143	root	1.111	my $lock = cf::lock_acquire "ext::login::nuke_playerdir";
144
145	root	1.71	my $temp = "$PLAYERDIR/~$Coro::current~deleting~";
146	root	1.111	aio_rename "$PLAYERDIR/$user", $temp;
147			IO::AIO::aio_rmtree $temp;
148	root	1.1	}
149
150	root	1.125	sub login {
151	root	1.119	my ($pl) = @_;
152
153	root	1.125	# handle character creation, if neccessary
154			# the rest of this function is character creation
155	root	1.119
156	root	1.125	my $ns = $pl->ns;
157			my $ob = $pl->ob;
158	root	1.119
159	root	1.127	if ($pl->{chargen} eq "init") {
160			$ob->goto ($pl->maplevel, $ob->x, $ob->y);
161	root	1.119
162	root	1.125	# create the playerdir, if necessary, as chargen_race_done did it before
163			# presumably because of unique maps
164			aio_mkdir playerdir $pl, 0770;
165	root	1.127	delete $pl->{deny_save}; # set by new
166	root	1.125	$pl->save;
167	root	1.119
168	root	1.125	$pl->{chargen} = "stats";
169			}
170	root	1.119
171	root	1.125	if ($pl->{chargen} eq "stats") {
172			while () {
173			$ob->update_stats;
174			$pl->save_stats;
175
176			my $res = query $ns, cf::CS_QUERY_SINGLECHAR,
177			"[y] to roll new stats [n] to use stats\n[1-7] [1-7] to swap stats.\nRoll again (y/n/1-7)?";
178
179			if ($res =~ /^[Nn]/) {
180			last;
181			} elsif ($res > 0 && $res <= 7) {
182			my $swap = query $ns, cf::CS_QUERY_SINGLECHAR, "Swap stat with (will not roll new stats) [1-7]?";
183	root	1.119
184	root	1.125	if ($swap > 0 && $swap <= 7) {
185			$ob->swap_stats ($res - 1, $swap - 1);
186			}
187			} else {
188			$ob->roll_stats;
189			}
190	root	1.119
191	root	1.125	Coro::Timer::sleep 0.05;
192	root	1.119	}
193
194	root	1.125	$ob->set_animation (2);
195			$ob->add_statbonus;
196
197			$pl->{chargen} = "race";
198	root	1.119	}
199
200	root	1.125	if ($pl->{chargen} eq "race") {
201			while () {
202			$ns->send_msg ("chargen-race-title", ucfirst $pl->title, -1);
203			my $msg = $ob->msg;
204			$msg =~ s/(?<=\S)\n(?=\S)/ /g;
205			$ns->send_msg ("chargen-race-description", $msg, cf::NDI_BLUE);
206	root	1.119
207	root	1.125	my $res = query $ns, cf::CS_QUERY_SINGLECHAR,
208			"Now choose a character.\nPress any key to change outlook.\nPress `d' when you're pleased.\n";
209	root	1.119
210	root	1.125	last if $res =~ /[dD]/;
211	root	1.119
212	root	1.125	$pl->chargen_race_next;
213			Coro::Timer::sleep 0.05;
214			}
215
216			$pl->chargen_race_done;
217			$pl->{chargen} = "gender";
218			}
219	root	1.119
220	root	1.125	if ($pl->{chargen} eq "race") {
221			while () {
222			my $res = query $ns, cf::CS_QUERY_SINGLECHAR,
223			"Now choose a gender.\nPress 'f' to become female, and 'm' to become male.\n";
224
225			if ($res =~ /^[fF]/) {
226			$pl->gender (1);
227			last;
228			} elsif ($res =~ /^[mM]/) {
229			$pl->gender (0);
230			last;
231			}
232			Coro::Timer::sleep 0.05;
233			}
234			$pl->{chargen} = "done";
235	root	1.119	}
236
237	root	1.125	$ns->state (cf::ST_PLAYING);
238	root	1.119
239	root	1.125	if ($pl->{chargen} eq "done") {
240			# XXX: Workaround for delayed client ext protocol handshake
241			$pl->esrv_new_player;
242	root	1.119
243	root	1.125	$pl->{chargen} = "done";
244	root	1.119	}
245
246			$ob->reply (undef, "Welcome to Deliantra!");
247
248	root	1.125	if (0 < Coro::AIO::aio_load "$cf::CONFDIR/motd", my $motd) {
249			$pl->ns->send_msg ("c/motd" => $motd, cf::NDI_CLEAR);
250			}
251			}
252
253			sub chargen {
254	root	1.127	my ($ns, $user, $hash) = @_;
255	root	1.125
256			# just to make sure nothing is left over
257			# normally, nothing is there.
258			nuke_playerdir $user;
259
260			my $pl = cf::player::new $user;
261	root	1.127	$pl->password (unpack "H*", $hash);
262	root	1.125	$pl->connect ($ns);
263	root	1.119
264	root	1.125	$pl->{chargen} = "init";
265
266			login $pl;
267	root	1.119	}
268
269	root	1.60	cf::client->attach (on_addme => sub {
270	root	1.1	my ($ns) = @_;
271
272	root	1.123	$ns->{addme}++ and return $ns->destroy;
273	root	1.1
274	root	1.10	$ns->async (sub {
275	root	1.72	$Coro::current->{desc} = "addme init";
276
277	root	1.1	my ($user, $pass);
278
279			$ns->send_packet ("addme_success");
280
281			for (;;) {
282	root	1.129	delete $ns->{login_guard};
283
284	root	1.130	$ns->send_msg (log =>
285	root	1.1	"Please enter your username now. If you are a new user, "
286			. "make one up that describes your character best. "
287			. "Only letters and digits are allowed, though.",
288	root	1.130	cf::NDI_BLUE \| cf::NDI_REPLY
289	root	1.1	);
290
291			# read username
292			while () {
293	root	1.89	$user = query $ns, 0, "What is your name? (login names are case-sensitive)\n:";
294	root	1.3
295	root	1.129	if ($user =~ $VALID_LOGIN) {
296	root	1.3	last;
297			} else {
298	root	1.130	$ns->send_msg (log =>
299	root	1.3	"Your username contains illegal characters "
300			. "(only a-z, A-Z and 0-9 are allowed), "
301	root	1.92	. "or is not between 3 and 20 characters in length.",
302	root	1.130	cf::NDI_RED \| cf::NDI_REPLY
303	root	1.3	);
304			}
305	root	1.61	Coro::Timer::sleep 0.4;
306	root	1.1	}
307
308	root	1.129	$Coro::current->{desc} = "addme($user)";
309	root	1.72
310	root	1.130	$ns->send_msg (log =>
311	root	1.1	"Welcome $user, please enter your password now. "
312			. "New users should now choose a password. "
313			. "Anything your client lets you enter is fine.",
314	root	1.130	cf::NDI_BLUE \| cf::NDI_REPLY
315	root	1.1	);
316
317			# read password
318			while () {
319			$pass = query $ns, cf::CS_QUERY_HIDEINPUT, "What is your password?\n:";
320			last if $pass =~ /.../;
321	root	1.130	$ns->send_msg (log =>
322	root	1.1	"Try to use at least three characters as your password please, "
323			. "that cannot be too much to ask for :)",
324	root	1.130	cf::NDI_RED \| cf::NDI_REPLY
325	root	1.1	);
326	root	1.61	Coro::Timer::sleep 0.4;
327	root	1.1	}
328
329	root	1.129	$ns->{login_guard} = login_guard $user
330			or do {
331	root	1.130	$ns->send_msg (log =>
332	root	1.129	"That user is already logged in (or is logging in)."
333			. "Chose another, or wait till the other session has ended.",
334	root	1.130	cf::NDI_RED \| cf::NDI_REPLY
335	root	1.129	);
336			next;
337			};
338	root	1.72
339	root	1.1	# try to read the user file and check the password
340	root	1.19	if (my $pl = cf::player::find $user) {
341			aio_stat $pl->path and next;
342			my $mtime = (stat _)[9];
343	root	1.110	my $token = $pl->password;
344	root	1.1
345	root	1.110	if ($cf::CFG{ext_login_nocheck} or compare_password $pass, $token) {
346	root	1.119	# player exists and passwords match - we can proceed
347
348	root	1.1	# password matches, wonderful
349	root	1.11	my $pl = cf::player::find $user or next;
350	root	1.1	$pl->connect ($ns);
351	root	1.48	enter_map $pl;
352	root	1.125	login $pl;
353	root	1.119	return;
354	root	1.19	} elsif (can_cleanup $pl, $mtime) {
355	root	1.1	Coro::Timer::sleep 1;
356
357	root	1.130	$ns->send_msg (log =>
358	root	1.3	"Player exists, but password does not match. If this is your account, "
359			. "please try again. If not, you can now decide to take over this account "
360	root	1.1	. "because it has not been in-use for some time.",
361	root	1.130	cf::NDI_RED \| cf::NDI_REPLY
362	root	1.1	);
363
364			(query $ns, cf::CS_QUERY_SINGLECHAR, "Delete existing account and create a new one (Y/N)?") =~ /^[yY]/
365			or next;
366
367			# check if the file hasn't changed
368	root	1.11	aio_stat cf::player::path $user and next;
369	root	1.1	$mtime == (stat _)[9] or next;
370
371	root	1.19	$pl->quit_character;
372	root	1.1
373			# fall through to creation
374			} else {
375			Coro::Timer::sleep 1;
376
377	root	1.130	$ns->send_msg (log =>
378	root	1.1	"Wrong username or password. Please try again "
379			. "(check for Numlock and other semi-obvious error sources).",
380	root	1.130	cf::NDI_RED \| cf::NDI_REPLY
381	root	1.1	);
382			next;
383			}
384	root	1.37	} else {
385			# unable to load the playerfile:
386	root	1.114	# check whether the player dir exists, which means the file is corrupted or
387	root	1.37	# something very similar.
388			if (!aio_stat cf::player::playerdir $user) {
389	root	1.130	$ns->send_msg ( log =>
390	root	1.37	"Unable to retrieve this player. It might be a locked or broken account. "
391			. "If this is your account, ask a dungeon master for assistance. "
392			. "Otherwise choose a different login name.",
393	root	1.130	cf::NDI_RED \| cf::NDI_REPLY
394	root	1.37	);
395			next;
396			}
397	root	1.1	}
398
399	root	1.120	my $pass2 = query $ns, cf::CS_QUERY_HIDEINPUT, "Please type your password again.";
400
401			if ($pass2 ne $pass) {
402	root	1.130	$ns->send_msg (log =>
403	root	1.120	"The passwords do not match, please try again.",
404	root	1.130	cf::NDI_RED \| cf::NDI_REPLY
405	root	1.120	);
406			Coro::Timer::sleep 0.5;
407			next;
408			}
409
410	root	1.1	last;
411			}
412	root	1.101
413	root	1.125	chargen $ns, $user, Deliantra::Util::hash_pw $pass;
414	root	1.1	});
415	root	1.60	});
416	root	1.1
417	root	1.121	cf::client->attach (
418			on_version => sub {
419			my ($ns, $arg) = @_;
420
421	root	1.125	# perl probably uses lrand48, which is not secure at all
422			# maybe require linux and use /dev/urandom.
423	root	1.123	$ns->{nonces} = [map { join "", map { chr rand 256 } 0..63 } 1..2];
424			$ns->ext_msg (nonces => @{ $ns->{nonces} });
425	root	1.121	},
426			);
427
428	root	1.125	cf::register_async_exticmd create_login => sub {
429			my ($ns, $reply, $user, $pass) = @_;
430
431			$ns->{addme}++ and return $ns->destroy;
432
433			$ns->async (sub {
434			my $fail = sub {
435			$reply->(0, $_[0]);
436			$ns->flush; # does not ensure that the data reaches the client - TODO
437			# need to do this in another thread, as this one gets canceled
438			Coro::async_pool {
439			Coro::AnyEvent::sleep 0.1; # TODO, see above, extra hack
440	root	1.126	$ns->destroy if $ns->valid;
441	root	1.125	};
442			Coro::schedule; # do the destroy, should not return
443			};
444
445			$user =~ $VALID_LOGIN
446			or return $fail (
447			"Your username contains illegal characters (only a-z, A-Z and 0-9 are allowed), "
448			. "or is not between 3 and 20 characters in length."
449			);
450
451	root	1.129	$ns->{login_guard} = login_guard $user
452			or return $fail->("User name '$user' is in use - try another login name.");
453
454	root	1.125	cf::player::find $user
455	root	1.129	and return $fail->("User name '$user' is already registered - choose another login name.");
456	root	1.125
457	root	1.128	$reply->(1, "Account Created");
458
459	root	1.127	chargen $ns, $user, $pass;
460	root	1.125	});
461			};
462	root	1.121
463			cf::register_async_exticmd login => sub {
464			my ($ns, $reply, $user, $hash) = @_;
465
466	root	1.123	$ns->{addme}++ and return $ns->destroy;
467
468			$ns->async (sub {
469	root	1.129	$Coro::current->{desc} = "login($user)";
470	root	1.123
471			my $fail = sub {
472			$reply->(0, $_[0]);
473			$ns->flush; # does not ensure that the data reaches the client - TODO
474			# need to do this in another thread, as this one gets canceled
475			Coro::async_pool {
476			Coro::AnyEvent::sleep 0.1; # TODO, see above, extra hack
477	root	1.126	$ns->destroy if $ns->valid;
478	root	1.123	};
479			Coro::schedule; # do the destroy, should not return
480			};
481
482	root	1.129	$ns->{login_guard} = login_guard $user
483			or return $fail->("User '$user' is currently playing or logging in in another session. If that is your "
484			. "user name, make sure you are not running two clients. When in doubt, reboot.");
485
486	root	1.123	# try to read the user file and check the password
487			my $pl = cf::player::find $user
488			or return $fail->("User '$user' does not exist - wrong spelling?");
489
490			aio_stat $pl->path
491			and return $ns->destroy;
492
493			my $mtime = (stat _)[9];
494			my $token = $pl->password;
495
496			$token = $token =~ /^!/
497			? Deliantra::Util::hash_pw pack "H*", substr $token, 1
498			: pack "H*", $token;
499
500			$token = Deliantra::Util::auth_pw $token, $ns->{nonces}[0], $ns->{nonces}[1];
501
502			$token eq $hash
503			or $cf::CFG{ext_login_nocheck}
504			or return $fail->("User exists, but the password doesn't match - check your spelling, NumLock/CapsLock etc.");
505
506			# player exists and passwords match - we can proceed
507
508	root	1.125	$reply->(1, "Success");
509
510	root	1.123	$pl->connect ($ns);
511			enter_map $pl;
512	root	1.125	login $pl;
513	root	1.123	});
514	root	1.121	};
515
516	elmex	1.106	cf::register_command password => sub {
517			my ($pl, $arg) = @_;
518
519	elmex	1.112	unless ($pl->flag (cf::FLAG_WIZ)) {
520			$pl->message (
521			"The password can currently only changed by a DM.",
522			cf::NDI_UNIQUE \| cf::NDI_REPLY);
523			return;
524			}
525
526	root	1.124	$pl->message (#d#
527			"Passwords cannot currently be changed.",#d#
528			cf::NDI_UNIQUE \| cf::NDI_REPLY);#d#
529			return;#d#
530
531	elmex	1.106	my (@args) = split /\s+/, $arg;
532	elmex	1.112	my ($player, $new_pw) = @args;
533	elmex	1.106
534			if ($pl->flag (cf::FLAG_WIZ) && $player eq '') {
535			$pl->message (
536			"Usage: password <player> [<new password>]",
537			cf::NDI_UNIQUE \| cf::NDI_REPLY);
538			return;
539			}
540
541	elmex	1.112	if ($new_pw eq '') {
542			$new_pw =
543			join '',
544			map { ('.', '/', 0..9, 'A'..'Z', 'a'..'z')[(cf::rndm 64)] }
545			1..9;
546			}
547	elmex	1.106
548	elmex	1.112	cf::async {
549			my $plc = cf::player::find $player;
550			if ($plc) {
551			$plc->password (encode_password $new_pw);
552	elmex	1.106	$pl->message (
553	elmex	1.112	"Ok, changed password of '$player' to '$new_pw'!",
554	elmex	1.106	cf::NDI_UNIQUE \| cf::NDI_RED \| cf::NDI_REPLY);
555			} else {
556			$pl->message (
557	elmex	1.112	"Fail! Couldn't set password for '$player', "
558			. "he doesn't seem to exist!",
559	elmex	1.106	cf::NDI_UNIQUE \| cf::NDI_RED \| cf::NDI_REPLY);
560			}
561	elmex	1.112	};
562	elmex	1.106	};
563
564	root	1.12	cf::register_command quit => sub {
565			my ($ob, $arg) = @_;
566
567	root	1.95	$ob->send_msg (undef,
568			"Quitting will delete your character PERMANENTLY: It will be gone forever and any progress will be lost. "
569			. "If you are sure you want to do this, then use the quit_character command instead of quit.",
570			cf::NDI_UNIQUE \| cf::NDI_RED \| cf::NDI_REPLY);
571	root	1.12	};
572
573			cf::register_command quit_character => sub {
574			my ($ob, $arg) = @_;
575
576			my $pl = $ob->contr;
577
578			$pl->ns->query (cf::CS_QUERY_SINGLECHAR, "Do you want to PERMANENTLY delete your character and all associated data (y/n)?", sub {
579			if ($_[0] !~ /^[yY]/) {
580	root	1.95	$ob->send_msg (undef, "Ok, not not quitting then.", cf::NDI_UNIQUE \| cf::NDI_RED \| cf::NDI_REPLY);
581	root	1.12	} else {
582	root	1.95	$ob->send_msg (undef, "Ok, quitting, hope to see you again.", cf::NDI_UNIQUE \| cf::NDI_RED \| cf::NDI_REPLY);
583	root	1.105	cf::async {
584			$pl->quit_character;
585			};
586	root	1.12	}
587			});
588			};
589	root	1.11
590	root	1.1	cf::object->attach (
591			type => cf::SAVEBED,
592			on_apply => sub {
593			my ($bed, $ob) = @_;
594
595			return cf::override 0 unless $ob->type == cf::PLAYER;
596
597	root	1.15	my $pl = $ob->contr;
598	root	1.11
599	root	1.1	# update respawn position
600	root	1.11	$pl->savebed ($bed->map->path, $bed->x, $bed->y);
601	root	1.1
602	root	1.111	cf::async {
603			my $killer = cf::arch::get "killer_logout"; $pl->killer ($killer); $killer->destroy;
604			ext::highscore::check $ob;
605
606			$pl->save;
607	root	1.1
608	root	1.111	$ob->send_msg ($cf::SAY_CHANNEL => "In the future, you will wake up here when you die.", cf::NDI_DEF \| cf::NDI_REPLY);
609	root	1.1
610	root	1.115	my $ns = $pl->ns
611			or return;
612
613			$ns->query (cf::CS_QUERY_SINGLECHAR, "Do you want to continue playing (y/n)?", sub {
614	root	1.111	if ($_[0] !~ /^[yY]/) {
615			$pl->invoke (cf::EVENT_PLAYER_LOGOUT, 1);
616			$pl->deactivate;
617			$pl->ns->destroy;
618			}
619			});
620			};
621	root	1.1	},
622			);
623
624	root	1.8	cf::player->attach (
625			on_login => sub {
626			my ($pl) = @_;
627			my $name = $pl->ob->name;
628
629			$_->ob->message ("$name has entered the game.", cf::NDI_DK_ORANGE \| cf::NDI_UNIQUE) for cf::player::list;
630			},
631			on_logout => sub {
632			my ($pl, $cleanly) = @_;
633			my $name = $pl->ob->name;
634
635			if ($cleanly) {
636			$_->ob->message ("$name left the game.", cf::NDI_DK_ORANGE \| cf::NDI_UNIQUE) for cf::player::list;
637			} else {
638			$_->ob->message ("$name uncerimoniously disconnected.", cf::NDI_DK_ORANGE \| cf::NDI_UNIQUE) for cf::player::list;
639	root	1.79	$pl->{unclean_save} = $cf::RUNTIME
640			unless safe_spot $pl;
641	root	1.8	}
642			},
643			);
644