server/ext/login.ext

#! perl # mandatory depends=highscore

# login handling

use Fcntl;
use Coro::AIO;
use Deliantra::Util ();

CONF MAX_DISCONNECT_TIME = 3600;

our $VALID_LOGIN = qr<^[a-zA-Z0-9][a-zA-Z0-9\-_]{2,19}\z>;

sub query {
   my ($ns, $flags, $text) = @_;

   $ns->query ($flags, $text, Coro::rouse_cb);
   Coro::rouse_wait
}

sub can_cleanup {
   my ($pl, $mtime) = @_;

   my $age = time - $mtime;
   my $level = $pl->ob->level;

   ($level <= 3 && $age > 7 * 86400)            # 7 days for level 0..3
   || ($level <= 9 && $age > 90 * 86400)        # 3 months for level 4..9
   || ($level <= 20 && $age > 180 * 86400)      # 6 months for level 10..20
   || $age > 700 * 86400                        # 2 years for everybody else
}

sub check_playing {
   my ($ns, $user) = @_;

   return unless cf::player::find_active $user;

   $ns->send_drawinfo (
      "That player is already logged in on this server. "
    . "If you want to create a new player, choose another name. "
    . "If you have already a registered, make sure nobody "
    . "else is using your account at this time. If you lost your connection "
    . "then the server will likely timeout within a minute. If you still "
    . "cannot log-in after a minute, you are still logged in. Make sure "
    . "you do not have another client running. If you use windows, reboot, "
    . "this will fix anything.",
      cf::NDI_RED
   );

   1
}

sub safe_spot($) {
   my ($pl) = @_;
   
   my $ob = $pl->ob;

   my $m = $ob->map
      or return;
   my $x = $ob->x;
   my $y = $ob->y;

   # never happens normally, but helps when shell users make mistakes
   $m->linkable
      or return 1;

   scalar grep $_->type == cf::SAVEBED, $m->at ($x, $y)
}

sub enter_map {
   my ($pl) = @_;

   my $ob = $pl->ob;

   my ($map, $x, $y)
      = $ob->{_link_pos}
        ? @{delete $ob->{_link_pos}}
        : ($pl->maplevel, $ob->x, $ob->y);

   $ob->enter_link;

   my $m = cf::map::find $map;
   my $time = delete $pl->{unclean_save};

   if ($time && $m) {
      if ($time < $m->{instantiate_time}) {
         # the map was reset in the meantime
         my $age = $cf::RUNTIME - $time;

         cf::info $ob->name, " map reset after logout, logout age $age (>= $MAX_DISCONNECT_TIME)\n";#d#

         if ($age >= $MAX_DISCONNECT_TIME) {
            $ob->message (
               "You didn't use a bed to reality to leave this realm, leaving your body in great danger. "
             . "Unfortunately, nobody was near to help you when the monsters arrived to eat you. "
             . "Maybe you can find comfort in the thought that your body was quite satisfying in taste... "
             . "H<You disconnected too long without having used a savebed.>",
               cf::NDI_RED
            );
            # kill them.
            # reminds me of the famous badness 10000 syndrome...
            $ob->stats->hp (-10000); #] if they survive this they deserved to live
            my $killer = cf::arch::get "killer_login"; $pl->killer ($killer); $killer->destroy;
         } else {
            ($map, $x, $y) = $pl->savebed;

            $ob->message (
               "You didn't use a bed to reality to leave this realm, leaving your body in great danger. "
             . "Fortunately, some friendly dwellers found you, checked your passport, and brought you to safety. "
             . "Better use a savebed next time, much worse things could have happened... "
             . "H<You disconnected without having used a savebed. When you do that for too long, you might die.>",
               cf::NDI_RED
            );
         }
      } else {
         $ob->message (
            "You didn't use a bed to reality to leave this realm. This is very dangerous, "
          . "as lots of things could happen when you leave by other means, such as cave-ins, "
          . "or monsters suddenly snapping your body. Better use a savebed next time. "
          . "H<Always apply a bed of reality to disconnect from the server.>",
            cf::NDI_RED
         );
      }
   }

   $ob->goto ($map, $x, $y);
}

sub encode_password($) {
   "!" . unpack "H*", $_[0]
}

sub compare_password($$) {
   my ($pass, $token) = @_;

   if ($token =~ /!!(.*)/) {
      return +(substr $pass, 0, 8) eq pack "H*", $1;
   } elsif ($token =~ /!(.*)/) {
      return $pass eq pack "H*", $1;
   } else {
      return $token eq crypt $pass, $token;
   }
}

# delete a player directory
sub nuke_playerdir {
   my ($user) = @_;

   my $lock = cf::lock_acquire "ext::login::nuke_playerdir";

   my $temp = "$PLAYERDIR/~$Coro::current~deleting~";
   aio_rename "$PLAYERDIR/$user", $temp;
   IO::AIO::aio_rmtree $temp;
}

sub login {
   my ($pl) = @_;

   # handle character creation, if neccessary
   # the rest of this function is character creation

   my $ns = $pl->ns;
   my $ob = $pl->ob;

   $Coro::current->{desc} = "addme(" . $ob->name . ") login";

   delete $pl->{deny_save}; # set by new

   if ($pl->{chargen} eq "init") {
      # create the playerdir, if necessary, as chargen_race_done did it before
      # presumably because of unique maps
      aio_mkdir playerdir $pl, 0770;
      $pl->save;

      $ob->goto ($pl->maplevel, $ob->x, $ob->y);

      $pl->{chargen} = "stats";
   }

   if ($pl->{chargen} eq "stats") {
      while () {
         $ob->update_stats;
         $pl->save_stats;

         my $res = query $ns, cf::CS_QUERY_SINGLECHAR,
                      "[y] to roll new stats [n] to use stats\n[1-7] [1-7] to swap stats.\nRoll again (y/n/1-7)?";

         if ($res =~ /^[Nn]/) {
            last;
         } elsif ($res > 0 && $res <= 7) {
            my $swap = query $ns, cf::CS_QUERY_SINGLECHAR, "Swap stat with (will not roll new stats) [1-7]?";

            if ($swap > 0 && $swap <= 7) {
               $ob->swap_stats ($res - 1, $swap - 1);
            }
         } else {
            $ob->roll_stats;
         }

         Coro::Timer::sleep 0.05;
      }

      $ob->set_animation (2);
      $ob->add_statbonus;

      $pl->{chargen} = "race";
   }

   if ($pl->{chargen} eq "race") {
      while () {
         $ns->send_msg ("chargen-race-title", ucfirst $pl->title, -1);
         my $msg = $ob->msg;
         $msg =~ s/(?<=\S)\n(?=\S)/ /g;
         $ns->send_msg ("chargen-race-description", $msg, cf::NDI_BLUE);

         my $res = query $ns, cf::CS_QUERY_SINGLECHAR,
                      "Now choose a character.\nPress any key to change outlook.\nPress `d' when you're pleased.\n";

         last if $res =~ /[dD]/;

         $pl->chargen_race_next;
         Coro::Timer::sleep 0.05;
      }

      $pl->chargen_race_done;
      $pl->{chargen} = "gender";
   }

   if ($pl->{chargen} eq "race") {
      while () {
         my $res = query $ns, cf::CS_QUERY_SINGLECHAR,
                      "Now choose a gender.\nPress 'f' to become female, and 'm' to become male.\n";

         if ($res =~ /^[fF]/) {
            $pl->gender (1);
            last;
         } elsif ($res =~ /^[mM]/) {
            $pl->gender (0);
            last;
         }
         Coro::Timer::sleep 0.05;
      }
      $pl->{chargen} = "done";
   }

   $ns->state (cf::ST_PLAYING);

   if ($pl->{chargen} eq "done") {
      # XXX: Workaround for delayed client ext protocol handshake
      $pl->esrv_new_player;

      $pl->{chargen} = "done";
   }

   $ob->reply (undef, "Welcome to Deliantra!");

   if (0 < Coro::AIO::aio_load "$cf::CONFDIR/motd", my $motd) {
      $pl->ns->send_msg ("c/motd" => $motd, cf::NDI_CLEAR);
   }
}

sub chargen {
   my ($ns, $user, $hasah) = @_;

   # lock again, too lazy to make this nicer
   local $cf::LOGIN_LOCK{$user} = 1;

   # just to make sure nothing is left over
   # normally, nothing is there.
   nuke_playerdir $user;

   my $pl = cf::player::new $user;
   $pl->password (encode_password $pass);
   $pl->connect ($ns);

   $pl->{chargen} = "init";

   login $pl;
}

cf::client->attach (on_addme => sub {
   my ($ns) = @_;

   $ns->{addme}++ and return $ns->destroy;

   $ns->async (sub {
      $Coro::current->{desc} = "addme init";

      my ($user, $pass);

      $ns->send_packet ("addme_success");

      for (;;) {
         $ns->send_drawinfo (
            "Please enter your username now. If you are a new user, "
          . "make one up that describes your character best. "
          . "Only letters and digits are allowed, though.",
            cf::NDI_BLUE
         );

         # read username
         while () {
            $user = query $ns, 0, "What is your name? (login names are case-sensitive)\n:";

            if ($cf::LOGIN_LOCK{$user}) {
               $ns->send_drawinfo (
                  "That username is currently used in another login session. "
                . "Chose another, or wait till the other session has ended.",
                  cf::NDI_RED
               );
            } elsif ($user =~ $VALID_LOGIN) {
               last;
            } else {
               $ns->send_drawinfo (
                  "Your username contains illegal characters "
                . "(only a-z, A-Z and 0-9 are allowed), "
                . "or is not between 3 and 20 characters in length.",
                  cf::NDI_RED
               );
            }
            Coro::Timer::sleep 0.4;
         }

         check_playing $ns, $user and next;

         $Coro::current->{desc} = "addme($user) pass";

         $ns->send_drawinfo (
            "Welcome $user, please enter your password now. "
          . "New users should now choose a password. "
          . "Anything your client lets you enter is fine.",
            cf::NDI_BLUE
         );

         # read password
         while () {
            $pass = query $ns, cf::CS_QUERY_HIDEINPUT, "What is your password?\n:";
            last if $pass =~ /.../;
            $ns->send_drawinfo (
               "Try to use at least three characters as your password please, "
             . "that cannot be too much to ask for :)",
               cf::NDI_RED
            );
            Coro::Timer::sleep 0.4;
         }

         # lock this username for the remainder of this login session
         if ($cf::LOGIN_LOCK{$user}) {
            $ns->send_drawinfo (
               "That username is currently used in another login session. "
             . "Chose another, or wait till the other session has ended.",
               cf::NDI_RED
            );
            next;
         }
         local $cf::LOGIN_LOCK{$user} = 1;

         check_playing $ns, $user and next;

         $Coro::current->{desc} = "addme($user) check";

         # try to read the user file and check the password
         if (my $pl = cf::player::find $user) {
            aio_stat $pl->path and next;
            my $mtime = (stat _)[9];
            my $token = $pl->password;

            if ($cf::CFG{ext_login_nocheck} or compare_password $pass, $token) {
               # player exists and passwords match - we can proceed

               # password matches, wonderful
               my $pl = cf::player::find $user or next;
               $pl->connect ($ns);
               enter_map $pl;
               login $pl;
               return;
            } elsif (can_cleanup $pl, $mtime) {
               Coro::Timer::sleep 1;

               $ns->send_drawinfo (
                  "Player exists, but password does not match. If this is your account, "
                . "please try again. If not, you can now decide to take over this account "
                . "because it has not been in-use for some time.",
                  cf::NDI_RED
               );

               (query $ns, cf::CS_QUERY_SINGLECHAR, "Delete existing account and create a new one (Y/N)?") =~ /^[yY]/
                  or next;

               # check if the file hasn't changed
               aio_stat cf::player::path $user and next;
               $mtime == (stat _)[9] or next;

               $pl->quit_character;

               # fall through to creation
            } else {
               Coro::Timer::sleep 1;

               $ns->send_drawinfo (
                  "Wrong username or password. Please try again "
                . "(check for Numlock and other semi-obvious error sources).",
                  cf::NDI_RED
               );
               next;
            }
         } else {
            # unable to load the playerfile:
            # check whether the player dir exists, which means the file is corrupted or
            # something very similar.
            if (!aio_stat cf::player::playerdir $user) {
               $ns->send_drawinfo (
                  "Unable to retrieve this player. It might be a locked or broken account. "
                . "If this is your account, ask a dungeon master for assistance. "
                . "Otherwise choose a different login name.",
                  cf::NDI_RED
               );
               next;
            }
         }

         my $pass2 = query $ns, cf::CS_QUERY_HIDEINPUT, "Please type your password again.";

         if ($pass2 ne $pass) {
            $ns->send_drawinfo (
               "The passwords do not match, please try again.",
               cf::NDI_RED
            );
            Coro::Timer::sleep 0.5;
            next;
         }

         last;
      }

      chargen $ns, $user, Deliantra::Util::hash_pw $pass;
   });
});

cf::client->attach (
   on_version => sub {
      my ($ns, $arg) = @_;

      # perl probably uses lrand48, which is not secure at all
      # maybe require linux and use /dev/urandom.
      $ns->{nonces} = [map { join "", map { chr rand 256 } 0..63  } 1..2];
      $ns->ext_msg (nonces => @{ $ns->{nonces} });
   },
);

cf::register_async_exticmd create_login => sub {
   my ($ns, $reply, $user, $pass) = @_;

   $ns->{addme}++ and return $ns->destroy;

   $ns->async (sub {
      my $fail = sub {
         $reply->(0, $_[0]);
         $ns->flush; # does not ensure that the data reaches the client - TODO
         # need to do this in another thread, as this one gets canceled
         Coro::async_pool {
            Coro::AnyEvent::sleep 0.1; # TODO, see above, extra hack
            $ns->destroy if $ns->valid;
         };
         Coro::schedule; # do the destroy, should not return
      };

      $user =~ $VALID_LOGIN
         or return $fail (
               "Your username contains illegal characters (only a-z, A-Z and 0-9 are allowed), "
             . "or is not between 3 and 20 characters in length."
            );

      cf::player::find $user
         and return $fail->("User '$user' already exists - choose another login name.");

      chargen $ns, $user, Deliantra::Util::hash_pw $pass;
   });
};

cf::register_async_exticmd login => sub {
   my ($ns, $reply, $user, $hash) = @_;

   $ns->{addme}++ and return $ns->destroy;

   $ns->async (sub {
      local $cf::LOGIN_LOCK{$user} = 1;

      $Coro::current->{desc} = "login($user) check";

      my $fail = sub {
         $reply->(0, $_[0]);
         $ns->flush; # does not ensure that the data reaches the client - TODO
         # need to do this in another thread, as this one gets canceled
         Coro::async_pool {
            Coro::AnyEvent::sleep 0.1; # TODO, see above, extra hack
            $ns->destroy if $ns->valid;
         };
         Coro::schedule; # do the destroy, should not return
      };

      # try to read the user file and check the password
      my $pl = cf::player::find $user
         or return $fail->("User '$user' does not exist - wrong spelling?");

      aio_stat $pl->path
         and return $ns->destroy;

      my $mtime = (stat _)[9];
      my $token = $pl->password;

      $token = $token =~ /^!/
               ? Deliantra::Util::hash_pw pack "H*", substr $token, 1
               : pack "H*", $token;

      $token = Deliantra::Util::auth_pw $token, $ns->{nonces}[0], $ns->{nonces}[1];

      $token eq $hash
         or $cf::CFG{ext_login_nocheck}
         or return $fail->("User exists, but the password doesn't match - check your spelling, NumLock/CapsLock etc.");
      
      # player exists and passwords match - we can proceed

      $reply->(1, "Success");

      $pl->connect ($ns);
      enter_map $pl;
      login $pl;
   });
};

cf::register_command password => sub {
   my ($pl, $arg) = @_;

   unless ($pl->flag (cf::FLAG_WIZ)) {
      $pl->message (
         "The password can currently only changed by a DM.",
         cf::NDI_UNIQUE | cf::NDI_REPLY);
      return;
   }

   $pl->message (#d#
      "Passwords cannot currently be changed.",#d#
      cf::NDI_UNIQUE | cf::NDI_REPLY);#d#
   return;#d#

   my (@args) = split /\s+/, $arg;
   my ($player, $new_pw) = @args;

   if ($pl->flag (cf::FLAG_WIZ) && $player eq '') {
      $pl->message (
         "Usage: password <player> [<new password>]",
         cf::NDI_UNIQUE | cf::NDI_REPLY);
      return;
   }

   if ($new_pw eq '') {
      $new_pw =
         join '',
            map { ('.', '/', 0..9, 'A'..'Z', 'a'..'z')[(cf::rndm 64)] }
               1..9;
   }

   cf::async {
      my $plc = cf::player::find $player;
      if ($plc) {
         $plc->password (encode_password $new_pw);
         $pl->message (
            "Ok, changed password of '$player' to '$new_pw'!",
            cf::NDI_UNIQUE | cf::NDI_RED | cf::NDI_REPLY);
      } else {
         $pl->message (
            "Fail! Couldn't set password for '$player', "
            . "he doesn't seem to exist!",
            cf::NDI_UNIQUE | cf::NDI_RED | cf::NDI_REPLY);
      }
   };
};

cf::register_command quit => sub {
   my ($ob, $arg) = @_;

   $ob->send_msg (undef,
                  "Quitting will delete your character PERMANENTLY: It will be gone forever and any progress will be lost. "
                  . "If you are sure you want to do this, then use the quit_character command instead of quit.",
                  cf::NDI_UNIQUE | cf::NDI_RED | cf::NDI_REPLY);
};

cf::register_command quit_character => sub {
   my ($ob, $arg) = @_;

   my $pl = $ob->contr;

   $pl->ns->query (cf::CS_QUERY_SINGLECHAR, "Do you want to PERMANENTLY delete your character and all associated data (y/n)?", sub {
      if ($_[0] !~ /^[yY]/) {
         $ob->send_msg (undef, "Ok, not not quitting then.", cf::NDI_UNIQUE | cf::NDI_RED | cf::NDI_REPLY);
      } else {
         $ob->send_msg (undef, "Ok, quitting, hope to see you again.", cf::NDI_UNIQUE | cf::NDI_RED | cf::NDI_REPLY);
         cf::async {
            $pl->quit_character;
         };
      }
   });
};

cf::object->attach (
   type     => cf::SAVEBED,
   on_apply => sub {
      my ($bed, $ob) = @_;

      return cf::override 0 unless $ob->type == cf::PLAYER;

      my $pl = $ob->contr;

      # update respawn position
      $pl->savebed ($bed->map->path, $bed->x, $bed->y);

      cf::async {
         my $killer = cf::arch::get "killer_logout"; $pl->killer ($killer); $killer->destroy;
         ext::highscore::check $ob;

         $pl->save;

         $ob->send_msg ($cf::SAY_CHANNEL => "In the future, you will wake up here when you die.", cf::NDI_DEF | cf::NDI_REPLY);

         my $ns = $pl->ns
            or return;

         $ns->query (cf::CS_QUERY_SINGLECHAR, "Do you want to continue playing (y/n)?", sub {
            if ($_[0] !~ /^[yY]/) {
               $pl->invoke (cf::EVENT_PLAYER_LOGOUT, 1);
               $pl->deactivate;
               $pl->ns->destroy;
            }
         });
      };
   },
);

cf::player->attach (
   on_login  => sub {
      my ($pl) = @_;
      my $name = $pl->ob->name;

      $_->ob->message ("$name has entered the game.", cf::NDI_DK_ORANGE | cf::NDI_UNIQUE) for cf::player::list;
   },
   on_logout => sub {
      my ($pl, $cleanly) = @_;
      my $name = $pl->ob->name;

      if ($cleanly) {
         $_->ob->message ("$name left the game.", cf::NDI_DK_ORANGE | cf::NDI_UNIQUE) for cf::player::list;
      } else {
         $_->ob->message ("$name uncerimoniously disconnected.", cf::NDI_DK_ORANGE | cf::NDI_UNIQUE) for cf::player::list;
         $pl->{unclean_save} = $cf::RUNTIME
            unless safe_spot $pl;
      }
   },
);

Revision:	1.126
Committed:	Sat Nov 17 11:13:54 2012 UTC (11 years, 6 months ago) by root
Branch:	MAIN
Changes since 1.125:	+2 -2 lines
Log Message:	* empty log message *
#	Content
1	#! perl # mandatory depends=highscore
2
3	# login handling
4
5	use Fcntl;
6	use Coro::AIO;
7	use Deliantra::Util ();
8
9	CONF MAX_DISCONNECT_TIME = 3600;
10
11	our $VALID_LOGIN = qr<^[a-zA-Z0-9][a-zA-Z0-9\-_]{2,19}\z>;
12
13	sub query {
14	my ($ns, $flags, $text) = @_;
15
16	$ns->query ($flags, $text, Coro::rouse_cb);
17	Coro::rouse_wait
18	}
19
20	sub can_cleanup {
21	my ($pl, $mtime) = @_;
22
23	my $age = time - $mtime;
24	my $level = $pl->ob->level;
25
26	($level <= 3 && $age > 7 * 86400) # 7 days for level 0..3
27	\|\| ($level <= 9 && $age > 90 * 86400) # 3 months for level 4..9
28	\|\| ($level <= 20 && $age > 180 * 86400) # 6 months for level 10..20
29	\|\| $age > 700 * 86400 # 2 years for everybody else
30	}
31
32	sub check_playing {
33	my ($ns, $user) = @_;
34
35	return unless cf::player::find_active $user;
36
37	$ns->send_drawinfo (
38	"That player is already logged in on this server. "
39	. "If you want to create a new player, choose another name. "
40	. "If you have already a registered, make sure nobody "
41	. "else is using your account at this time. If you lost your connection "
42	. "then the server will likely timeout within a minute. If you still "
43	. "cannot log-in after a minute, you are still logged in. Make sure "
44	. "you do not have another client running. If you use windows, reboot, "
45	. "this will fix anything.",
46	cf::NDI_RED
47	);
48
49	1
50	}
51
52	sub safe_spot($) {
53	my ($pl) = @_;
54
55	my $ob = $pl->ob;
56
57	my $m = $ob->map
58	or return;
59	my $x = $ob->x;
60	my $y = $ob->y;
61
62	# never happens normally, but helps when shell users make mistakes
63	$m->linkable
64	or return 1;
65
66	scalar grep $_->type == cf::SAVEBED, $m->at ($x, $y)
67	}
68
69	sub enter_map {
70	my ($pl) = @_;
71
72	my $ob = $pl->ob;
73
74	my ($map, $x, $y)
75	= $ob->{_link_pos}
76	? @{delete $ob->{_link_pos}}
77	: ($pl->maplevel, $ob->x, $ob->y);
78
79	$ob->enter_link;
80
81	my $m = cf::map::find $map;
82	my $time = delete $pl->{unclean_save};
83
84	if ($time && $m) {
85	if ($time < $m->{instantiate_time}) {
86	# the map was reset in the meantime
87	my $age = $cf::RUNTIME - $time;
88
89	cf::info $ob->name, " map reset after logout, logout age $age (>= $MAX_DISCONNECT_TIME)\n";#d#
90
91	if ($age >= $MAX_DISCONNECT_TIME) {
92	$ob->message (
93	"You didn't use a bed to reality to leave this realm, leaving your body in great danger. "
94	. "Unfortunately, nobody was near to help you when the monsters arrived to eat you. "
95	. "Maybe you can find comfort in the thought that your body was quite satisfying in taste... "
96	. "H<You disconnected too long without having used a savebed.>",
97	cf::NDI_RED
98	);
99	# kill them.
100	# reminds me of the famous badness 10000 syndrome...
101	$ob->stats->hp (-10000); #] if they survive this they deserved to live
102	my $killer = cf::arch::get "killer_login"; $pl->killer ($killer); $killer->destroy;
103	} else {
104	($map, $x, $y) = $pl->savebed;
105
106	$ob->message (
107	"You didn't use a bed to reality to leave this realm, leaving your body in great danger. "
108	. "Fortunately, some friendly dwellers found you, checked your passport, and brought you to safety. "
109	. "Better use a savebed next time, much worse things could have happened... "
110	. "H<You disconnected without having used a savebed. When you do that for too long, you might die.>",
111	cf::NDI_RED
112	);
113	}
114	} else {
115	$ob->message (
116	"You didn't use a bed to reality to leave this realm. This is very dangerous, "
117	. "as lots of things could happen when you leave by other means, such as cave-ins, "
118	. "or monsters suddenly snapping your body. Better use a savebed next time. "
119	. "H<Always apply a bed of reality to disconnect from the server.>",
120	cf::NDI_RED
121	);
122	}
123	}
124
125	$ob->goto ($map, $x, $y);
126	}
127
128	sub encode_password($) {
129	"!" . unpack "H*", $_[0]
130	}
131
132	sub compare_password($$) {
133	my ($pass, $token) = @_;
134
135	if ($token =~ /!!(.*)/) {
136	return +(substr $pass, 0, 8) eq pack "H*", $1;
137	} elsif ($token =~ /!(.*)/) {
138	return $pass eq pack "H*", $1;
139	} else {
140	return $token eq crypt $pass, $token;
141	}
142	}
143
144	# delete a player directory
145	sub nuke_playerdir {
146	my ($user) = @_;
147
148	my $lock = cf::lock_acquire "ext::login::nuke_playerdir";
149
150	my $temp = "$PLAYERDIR/~$Coro::current~deleting~";
151	aio_rename "$PLAYERDIR/$user", $temp;
152	IO::AIO::aio_rmtree $temp;
153	}
154
155	sub login {
156	my ($pl) = @_;
157
158	# handle character creation, if neccessary
159	# the rest of this function is character creation
160
161	my $ns = $pl->ns;
162	my $ob = $pl->ob;
163
164	$Coro::current->{desc} = "addme(" . $ob->name . ") login";
165
166	delete $pl->{deny_save}; # set by new
167
168	if ($pl->{chargen} eq "init") {
169	# create the playerdir, if necessary, as chargen_race_done did it before
170	# presumably because of unique maps
171	aio_mkdir playerdir $pl, 0770;
172	$pl->save;
173
174	$ob->goto ($pl->maplevel, $ob->x, $ob->y);
175
176	$pl->{chargen} = "stats";
177	}
178
179	if ($pl->{chargen} eq "stats") {
180	while () {
181	$ob->update_stats;
182	$pl->save_stats;
183
184	my $res = query $ns, cf::CS_QUERY_SINGLECHAR,
185	"[y] to roll new stats [n] to use stats\n[1-7] [1-7] to swap stats.\nRoll again (y/n/1-7)?";
186
187	if ($res =~ /^[Nn]/) {
188	last;
189	} elsif ($res > 0 && $res <= 7) {
190	my $swap = query $ns, cf::CS_QUERY_SINGLECHAR, "Swap stat with (will not roll new stats) [1-7]?";
191
192	if ($swap > 0 && $swap <= 7) {
193	$ob->swap_stats ($res - 1, $swap - 1);
194	}
195	} else {
196	$ob->roll_stats;
197	}
198
199	Coro::Timer::sleep 0.05;
200	}
201
202	$ob->set_animation (2);
203	$ob->add_statbonus;
204
205	$pl->{chargen} = "race";
206	}
207
208	if ($pl->{chargen} eq "race") {
209	while () {
210	$ns->send_msg ("chargen-race-title", ucfirst $pl->title, -1);
211	my $msg = $ob->msg;
212	$msg =~ s/(?<=\S)\n(?=\S)/ /g;
213	$ns->send_msg ("chargen-race-description", $msg, cf::NDI_BLUE);
214
215	my $res = query $ns, cf::CS_QUERY_SINGLECHAR,
216	"Now choose a character.\nPress any key to change outlook.\nPress `d' when you're pleased.\n";
217
218	last if $res =~ /[dD]/;
219
220	$pl->chargen_race_next;
221	Coro::Timer::sleep 0.05;
222	}
223
224	$pl->chargen_race_done;
225	$pl->{chargen} = "gender";
226	}
227
228	if ($pl->{chargen} eq "race") {
229	while () {
230	my $res = query $ns, cf::CS_QUERY_SINGLECHAR,
231	"Now choose a gender.\nPress 'f' to become female, and 'm' to become male.\n";
232
233	if ($res =~ /^[fF]/) {
234	$pl->gender (1);
235	last;
236	} elsif ($res =~ /^[mM]/) {
237	$pl->gender (0);
238	last;
239	}
240	Coro::Timer::sleep 0.05;
241	}
242	$pl->{chargen} = "done";
243	}
244
245	$ns->state (cf::ST_PLAYING);
246
247	if ($pl->{chargen} eq "done") {
248	# XXX: Workaround for delayed client ext protocol handshake
249	$pl->esrv_new_player;
250
251	$pl->{chargen} = "done";
252	}
253
254	$ob->reply (undef, "Welcome to Deliantra!");
255
256	if (0 < Coro::AIO::aio_load "$cf::CONFDIR/motd", my $motd) {
257	$pl->ns->send_msg ("c/motd" => $motd, cf::NDI_CLEAR);
258	}
259	}
260
261	sub chargen {
262	my ($ns, $user, $hasah) = @_;
263
264	# lock again, too lazy to make this nicer
265	local $cf::LOGIN_LOCK{$user} = 1;
266
267	# just to make sure nothing is left over
268	# normally, nothing is there.
269	nuke_playerdir $user;
270
271	my $pl = cf::player::new $user;
272	$pl->password (encode_password $pass);
273	$pl->connect ($ns);
274
275	$pl->{chargen} = "init";
276
277	login $pl;
278	}
279
280	cf::client->attach (on_addme => sub {
281	my ($ns) = @_;
282
283	$ns->{addme}++ and return $ns->destroy;
284
285	$ns->async (sub {
286	$Coro::current->{desc} = "addme init";
287
288	my ($user, $pass);
289
290	$ns->send_packet ("addme_success");
291
292	for (;;) {
293	$ns->send_drawinfo (
294	"Please enter your username now. If you are a new user, "
295	. "make one up that describes your character best. "
296	. "Only letters and digits are allowed, though.",
297	cf::NDI_BLUE
298	);
299
300	# read username
301	while () {
302	$user = query $ns, 0, "What is your name? (login names are case-sensitive)\n:";
303
304	if ($cf::LOGIN_LOCK{$user}) {
305	$ns->send_drawinfo (
306	"That username is currently used in another login session. "
307	. "Chose another, or wait till the other session has ended.",
308	cf::NDI_RED
309	);
310	} elsif ($user =~ $VALID_LOGIN) {
311	last;
312	} else {
313	$ns->send_drawinfo (
314	"Your username contains illegal characters "
315	. "(only a-z, A-Z and 0-9 are allowed), "
316	. "or is not between 3 and 20 characters in length.",
317	cf::NDI_RED
318	);
319	}
320	Coro::Timer::sleep 0.4;
321	}
322
323	check_playing $ns, $user and next;
324
325	$Coro::current->{desc} = "addme($user) pass";
326
327	$ns->send_drawinfo (
328	"Welcome $user, please enter your password now. "
329	. "New users should now choose a password. "
330	. "Anything your client lets you enter is fine.",
331	cf::NDI_BLUE
332	);
333
334	# read password
335	while () {
336	$pass = query $ns, cf::CS_QUERY_HIDEINPUT, "What is your password?\n:";
337	last if $pass =~ /.../;
338	$ns->send_drawinfo (
339	"Try to use at least three characters as your password please, "
340	. "that cannot be too much to ask for :)",
341	cf::NDI_RED
342	);
343	Coro::Timer::sleep 0.4;
344	}
345
346	# lock this username for the remainder of this login session
347	if ($cf::LOGIN_LOCK{$user}) {
348	$ns->send_drawinfo (
349	"That username is currently used in another login session. "
350	. "Chose another, or wait till the other session has ended.",
351	cf::NDI_RED
352	);
353	next;
354	}
355	local $cf::LOGIN_LOCK{$user} = 1;
356
357	check_playing $ns, $user and next;
358
359	$Coro::current->{desc} = "addme($user) check";
360
361	# try to read the user file and check the password
362	if (my $pl = cf::player::find $user) {
363	aio_stat $pl->path and next;
364	my $mtime = (stat _)[9];
365	my $token = $pl->password;
366
367	if ($cf::CFG{ext_login_nocheck} or compare_password $pass, $token) {
368	# player exists and passwords match - we can proceed
369
370	# password matches, wonderful
371	my $pl = cf::player::find $user or next;
372	$pl->connect ($ns);
373	enter_map $pl;
374	login $pl;
375	return;
376	} elsif (can_cleanup $pl, $mtime) {
377	Coro::Timer::sleep 1;
378
379	$ns->send_drawinfo (
380	"Player exists, but password does not match. If this is your account, "
381	. "please try again. If not, you can now decide to take over this account "
382	. "because it has not been in-use for some time.",
383	cf::NDI_RED
384	);
385
386	(query $ns, cf::CS_QUERY_SINGLECHAR, "Delete existing account and create a new one (Y/N)?") =~ /^[yY]/
387	or next;
388
389	# check if the file hasn't changed
390	aio_stat cf::player::path $user and next;
391	$mtime == (stat _)[9] or next;
392
393	$pl->quit_character;
394
395	# fall through to creation
396	} else {
397	Coro::Timer::sleep 1;
398
399	$ns->send_drawinfo (
400	"Wrong username or password. Please try again "
401	. "(check for Numlock and other semi-obvious error sources).",
402	cf::NDI_RED
403	);
404	next;
405	}
406	} else {
407	# unable to load the playerfile:
408	# check whether the player dir exists, which means the file is corrupted or
409	# something very similar.
410	if (!aio_stat cf::player::playerdir $user) {
411	$ns->send_drawinfo (
412	"Unable to retrieve this player. It might be a locked or broken account. "
413	. "If this is your account, ask a dungeon master for assistance. "
414	. "Otherwise choose a different login name.",
415	cf::NDI_RED
416	);
417	next;
418	}
419	}
420
421	my $pass2 = query $ns, cf::CS_QUERY_HIDEINPUT, "Please type your password again.";
422
423	if ($pass2 ne $pass) {
424	$ns->send_drawinfo (
425	"The passwords do not match, please try again.",
426	cf::NDI_RED
427	);
428	Coro::Timer::sleep 0.5;
429	next;
430	}
431
432	last;
433	}
434
435	chargen $ns, $user, Deliantra::Util::hash_pw $pass;
436	});
437	});
438
439	cf::client->attach (
440	on_version => sub {
441	my ($ns, $arg) = @_;
442
443	# perl probably uses lrand48, which is not secure at all
444	# maybe require linux and use /dev/urandom.
445	$ns->{nonces} = [map { join "", map { chr rand 256 } 0..63 } 1..2];
446	$ns->ext_msg (nonces => @{ $ns->{nonces} });
447	},
448	);
449
450	cf::register_async_exticmd create_login => sub {
451	my ($ns, $reply, $user, $pass) = @_;
452
453	$ns->{addme}++ and return $ns->destroy;
454
455	$ns->async (sub {
456	my $fail = sub {
457	$reply->(0, $_[0]);
458	$ns->flush; # does not ensure that the data reaches the client - TODO
459	# need to do this in another thread, as this one gets canceled
460	Coro::async_pool {
461	Coro::AnyEvent::sleep 0.1; # TODO, see above, extra hack
462	$ns->destroy if $ns->valid;
463	};
464	Coro::schedule; # do the destroy, should not return
465	};
466
467	$user =~ $VALID_LOGIN
468	or return $fail (
469	"Your username contains illegal characters (only a-z, A-Z and 0-9 are allowed), "
470	. "or is not between 3 and 20 characters in length."
471	);
472
473	cf::player::find $user
474	and return $fail->("User '$user' already exists - choose another login name.");
475
476	chargen $ns, $user, Deliantra::Util::hash_pw $pass;
477	});
478	};
479
480	cf::register_async_exticmd login => sub {
481	my ($ns, $reply, $user, $hash) = @_;
482
483	$ns->{addme}++ and return $ns->destroy;
484
485	$ns->async (sub {
486	local $cf::LOGIN_LOCK{$user} = 1;
487
488	$Coro::current->{desc} = "login($user) check";
489
490	my $fail = sub {
491	$reply->(0, $_[0]);
492	$ns->flush; # does not ensure that the data reaches the client - TODO
493	# need to do this in another thread, as this one gets canceled
494	Coro::async_pool {
495	Coro::AnyEvent::sleep 0.1; # TODO, see above, extra hack
496	$ns->destroy if $ns->valid;
497	};
498	Coro::schedule; # do the destroy, should not return
499	};
500
501	# try to read the user file and check the password
502	my $pl = cf::player::find $user
503	or return $fail->("User '$user' does not exist - wrong spelling?");
504
505	aio_stat $pl->path
506	and return $ns->destroy;
507
508	my $mtime = (stat _)[9];
509	my $token = $pl->password;
510
511	$token = $token =~ /^!/
512	? Deliantra::Util::hash_pw pack "H*", substr $token, 1
513	: pack "H*", $token;
514
515	$token = Deliantra::Util::auth_pw $token, $ns->{nonces}[0], $ns->{nonces}[1];
516
517	$token eq $hash
518	or $cf::CFG{ext_login_nocheck}
519	or return $fail->("User exists, but the password doesn't match - check your spelling, NumLock/CapsLock etc.");
520
521	# player exists and passwords match - we can proceed
522
523	$reply->(1, "Success");
524
525	$pl->connect ($ns);
526	enter_map $pl;
527	login $pl;
528	});
529	};
530
531	cf::register_command password => sub {
532	my ($pl, $arg) = @_;
533
534	unless ($pl->flag (cf::FLAG_WIZ)) {
535	$pl->message (
536	"The password can currently only changed by a DM.",
537	cf::NDI_UNIQUE \| cf::NDI_REPLY);
538	return;
539	}
540
541	$pl->message (#d#
542	"Passwords cannot currently be changed.",#d#
543	cf::NDI_UNIQUE \| cf::NDI_REPLY);#d#
544	return;#d#
545
546	my (@args) = split /\s+/, $arg;
547	my ($player, $new_pw) = @args;
548
549	if ($pl->flag (cf::FLAG_WIZ) && $player eq '') {
550	$pl->message (
551	"Usage: password <player> [<new password>]",
552	cf::NDI_UNIQUE \| cf::NDI_REPLY);
553	return;
554	}
555
556	if ($new_pw eq '') {
557	$new_pw =
558	join '',
559	map { ('.', '/', 0..9, 'A'..'Z', 'a'..'z')[(cf::rndm 64)] }
560	1..9;
561	}
562
563	cf::async {
564	my $plc = cf::player::find $player;
565	if ($plc) {
566	$plc->password (encode_password $new_pw);
567	$pl->message (
568	"Ok, changed password of '$player' to '$new_pw'!",
569	cf::NDI_UNIQUE \| cf::NDI_RED \| cf::NDI_REPLY);
570	} else {
571	$pl->message (
572	"Fail! Couldn't set password for '$player', "
573	. "he doesn't seem to exist!",
574	cf::NDI_UNIQUE \| cf::NDI_RED \| cf::NDI_REPLY);
575	}
576	};
577	};
578
579	cf::register_command quit => sub {
580	my ($ob, $arg) = @_;
581
582	$ob->send_msg (undef,
583	"Quitting will delete your character PERMANENTLY: It will be gone forever and any progress will be lost. "
584	. "If you are sure you want to do this, then use the quit_character command instead of quit.",
585	cf::NDI_UNIQUE \| cf::NDI_RED \| cf::NDI_REPLY);
586	};
587
588	cf::register_command quit_character => sub {
589	my ($ob, $arg) = @_;
590
591	my $pl = $ob->contr;
592
593	$pl->ns->query (cf::CS_QUERY_SINGLECHAR, "Do you want to PERMANENTLY delete your character and all associated data (y/n)?", sub {
594	if ($_[0] !~ /^[yY]/) {
595	$ob->send_msg (undef, "Ok, not not quitting then.", cf::NDI_UNIQUE \| cf::NDI_RED \| cf::NDI_REPLY);
596	} else {
597	$ob->send_msg (undef, "Ok, quitting, hope to see you again.", cf::NDI_UNIQUE \| cf::NDI_RED \| cf::NDI_REPLY);
598	cf::async {
599	$pl->quit_character;
600	};
601	}
602	});
603	};
604
605	cf::object->attach (
606	type => cf::SAVEBED,
607	on_apply => sub {
608	my ($bed, $ob) = @_;
609
610	return cf::override 0 unless $ob->type == cf::PLAYER;
611
612	my $pl = $ob->contr;
613
614	# update respawn position
615	$pl->savebed ($bed->map->path, $bed->x, $bed->y);
616
617	cf::async {
618	my $killer = cf::arch::get "killer_logout"; $pl->killer ($killer); $killer->destroy;
619	ext::highscore::check $ob;
620
621	$pl->save;
622
623	$ob->send_msg ($cf::SAY_CHANNEL => "In the future, you will wake up here when you die.", cf::NDI_DEF \| cf::NDI_REPLY);
624
625	my $ns = $pl->ns
626	or return;
627
628	$ns->query (cf::CS_QUERY_SINGLECHAR, "Do you want to continue playing (y/n)?", sub {
629	if ($_[0] !~ /^[yY]/) {
630	$pl->invoke (cf::EVENT_PLAYER_LOGOUT, 1);
631	$pl->deactivate;
632	$pl->ns->destroy;
633	}
634	});
635	};
636	},
637	);
638
639	cf::player->attach (
640	on_login => sub {
641	my ($pl) = @_;
642	my $name = $pl->ob->name;
643
644	$_->ob->message ("$name has entered the game.", cf::NDI_DK_ORANGE \| cf::NDI_UNIQUE) for cf::player::list;
645	},
646	on_logout => sub {
647	my ($pl, $cleanly) = @_;
648	my $name = $pl->ob->name;
649
650	if ($cleanly) {
651	$_->ob->message ("$name left the game.", cf::NDI_DK_ORANGE \| cf::NDI_UNIQUE) for cf::player::list;
652	} else {
653	$_->ob->message ("$name uncerimoniously disconnected.", cf::NDI_DK_ORANGE \| cf::NDI_UNIQUE) for cf::player::list;
654	$pl->{unclean_save} = $cf::RUNTIME
655	unless safe_spot $pl;
656	}
657	},
658	);
659