server/ext/login.ext

#! perl # mandatory

# login handling

use Fcntl;
use Coro::AIO;

our $MAX_DISCONNECT_TIME = $cf::CFG{max_disconnect_time} || 3600;

# paranoia function to overwrite a string-in-place
sub nuke_str {
   substr $_[0], 0, (length $_[0]), "x" x length $_[0]
}

sub query {
   my ($ns, $flags, $text) = @_;

   my $current = $Coro::current;
   $ns->query ($flags, $text, sub { $current->ready; $current = $_[0] });
   Coro::schedule while ref $current;

   $current
}

sub can_cleanup {
   my ($pl, $mtime) = @_;

   my $age = time - $mtime;
   my $level = $pl->ob->level;

   ($level <= 3 && $age > 7 * 86400)            # 7 days for level 0..3
   || ($level <= 9 && $age > 90 * 86400)        # 3 months for level 4..9
   || ($level <= 20 && $age > 180 * 86400)      # 6 months for level 10..20
   || $age > 700 * 86400                        # 2 years for everybody else
}

sub check_playing {
   my ($ns, $user) = @_;

   return unless cf::player::find_active $user;

   $ns->send_drawinfo (
      "That player is already logged in on this server. "
    . "If you want to create a new player, choose another name. "
    . "If you have already a registered, make sure nobody "
    . "else is using your account at this time. If you lost your connection "
    . "then the server will likely timeout within a minute. If you still "
    . "cannot log-in after a minute, you are still logged in. Make sure "
    . "you do not have another client running. If you use windows, reboot, "
    . "this will fix anything.",
      cf::NDI_RED
   );

   1
}

sub enter_map {
   my ($pl) = @_;

   my $ob = $pl->ob;

   my ($map, $x, $y)
      = $ob->{_link_pos}
        ? @{delete $ob->{_link_pos}}
        : ($pl->maplevel, $ob->x, $ob->y);

   $ob->enter_link;

   if (my $time = delete $pl->{unclean_save}) {
      if (my $m = cf::map::find $map) {
         if ($time < $m->{instantiate_time}) {
            # the map was reset in the meantime
            my $age = $cf::RUNTIME - $time;

            warn $ob->name, " map reset after logout, logout age $age (>= $MAX_DISCONNECT_TIME)\n";#d#

            # for now, just go back to savebed
            ($map, $x, $y) = $pl->savebed;

            if ($age >= $MAX_DISCONNECT_TIME) {
               $ob->message (
                  "You didn't use a bed to reality to leave this realm, leaving your body in great danger. "
                . "Unfortunately, nobody was near to help you when the monsters arrived to eat you. "
                . "Maybe you can find comfort in the thought that your body was quite satisfying in taste... "
                . "H<You disconnected too long without having used a savebed.>",
                  cf::NDI_RED
               );
               # kill them.
               # reminds me of the famous badness 10000 syndrome...
               $ob->stats->hp (-10000); #] if they survive this they deserved to live
               $pl->killer ("a cave-in");
            } else {
               $ob->message (
                  "You didn't use a bed to reality to leave this realm, leaving your body in great danger. "
                . "Fortunately, some friendly dwellers found you, checked your passport, and brought you to safety. "
                . "Better use a savebed next time, much worse things could have happened... "
                . "H<You disconnected without having used a savebed. When you do that for too long, you might die.>",
                  cf::NDI_RED
               );
            }
         } else {
            $ob->message (
               "You didn't use a bed to reality to leave this realm. This is very dangerous, "
             . "as lots of things could happen when you leave by other means, such as cave-ins, "
             . "or monsters suddenly snapping your body. Better use a savebed next time. "
             . "H<Always apply a bed of reality to disconnect from the server.>",
               cf::NDI_RED
            );
         }
      }
   }

   $ob->goto ($map, $x, $y);
}

# delete a player directory, be non-blocking AND synchronous...
# (thats hard, so we crap out and fork).
sub nuke_playerdir {
   my ($user) = @_;

   aio_rename "$PLAYERDIR/$user", "$PLAYERDIR/~$Coro::current~deleting~";
   system "rm -rf \Q$PLAYERDIR/~$Coro::current~deleting~\E &";
}

cf::client->attach (on_addme => sub {
   my ($ns) = @_;

   if (!$ns->facecache)
     {
       $ns->send_drawinfo (<<EOF, cf::NDI_RED);


***
*** WARNING:
*** Your client does not support face/image caching,
*** or it has been disabled. Face caching is mandatory
*** so please enable it or use a newer client.
***
*** Look at your client preferences:
***
*** CFPlus: all known versions automatically enable the facecache.
*** cfclient: use the -cache commandline option.
*** cfclient: map will not redraw automatically (bug).
*** gcfclient: use -cache commandline option, or enable
*** gcfclient: Client => Configure => Map & Image => Cache Images.
*** jcrossclient: your client is broken, use CFPlus or gcfclient.
***
***
EOF
      if ($ns->version =~ /jcrossclient/) {
         # let them, for now
      } else {
        $ns->flush;
        return $ns->destroy;
      }

      # $ns->facecache = true;
   }

   if ($ns->mapmode < cf::Map1aCmd) {
      $ns->send_drawinfo (<<EOF, cf::NDI_RED);


***
*** WARNING:
*** Your client is too old. Please upgrade to a newer version.
EOF

      $ns->flush;
      return $ns->destroy;
   }

   $ns->pl and return $ns->destroy;

   $ns->async (sub {
      my ($user, $pass);

      $ns->send_packet ("addme_success");

      for (;;) {
         $ns->send_drawinfo (
            "Please enter your username now. If you are a new user, "
          . "make one up that describes your character best. "
          . "Only letters and digits are allowed, though.",
            cf::NDI_BLUE
         );

         # read username
         while () {
            $user = query $ns, 0, "What is your name?\n:";

            if ($cf::LOGIN_LOCK{$user}) {
               $ns->send_drawinfo (
                  "That username is currently used in another login session. "
                . "Chose another, or wait till the other session has ended.",
                  cf::NDI_RED
               );
            } elsif ($user =~ /^[a-zA-Z0-9][a-zA-Z0-9\-_]{2,17}\z/) {
               last;
            } else {
               $ns->send_drawinfo (
                  "Your username contains illegal characters "
                . "(only a-z, A-Z and 0-9 are allowed), "
                . "or is not between 3 and 18 characters in length.",
                  cf::NDI_RED
               );
            }
            Coro::Timer::sleep 0.4;
         }

         check_playing $ns, $user and next;

         $ns->send_drawinfo (
            "Welcome $user, please enter your password now. "
          . "New users should now choose a password. "
          . "Anything your client lets you enter is fine.",
            cf::NDI_BLUE
         );

         # read password
         while () {
            $pass = query $ns, cf::CS_QUERY_HIDEINPUT, "What is your password?\n:";
            last if $pass =~ /.../;
            $ns->send_drawinfo (
               "Try to use at least three characters as your password please, "
             . "that cannot be too much to ask for :)",
               cf::NDI_RED
            );
            Coro::Timer::sleep 0.4;
         }

         # lock this username for the remainder of this login session
         if ($cf::LOGIN_LOCK{$user}) {
            $ns->send_drawinfo (
               "That username is currently used in another login session. "
             . "Chose another, or wait till the other session has ended.",
               cf::NDI_RED
            );
            next;
         }
         local $cf::LOGIN_LOCK{$user} = 1;

         check_playing $ns, $user and next;

         # try to read the user file and check the password
         if (my $pl = cf::player::find $user) {
            aio_stat $pl->path and next;
            my $mtime = (stat _)[9];
            my $hash = $pl->password;

            if ($cf::CFG{ext_login_nocheck} or $hash eq crypt $pass, $hash) {
               nuke_str $pass;
               # password matches, wonderful
               my $pl = cf::player::find $user or next;
               $pl->connect ($ns);
               enter_map $pl;
               last;
            } elsif (can_cleanup $pl, $mtime) {
               Coro::Timer::sleep 1;

               $ns->send_drawinfo (
                  "Player exists, but password does not match. If this is your account, "
                . "please try again. If not, you can now decide to take over this account "
                . "because it has not been in-use for some time.",
                  cf::NDI_RED
               );

               #TODO: nuke_str
               (query $ns, cf::CS_QUERY_SINGLECHAR, "Delete existing account and create a new one (Y/N)?") =~ /^[yY]/
                  or next;

               # check if the file hasn't changed
               aio_stat cf::player::path $user and next;
               $mtime == (stat _)[9] or next;

               $pl->quit_character;

               # fall through to creation
            } else {
               nuke_str $pass;

               Coro::Timer::sleep 1;

               $ns->send_drawinfo (
                  "Wrong username or password. Please try again "
                . "(check for Numlock and other semi-obvious error sources).",
                  cf::NDI_RED
               );
               next;
            }
         } else {
            # unable to load the playerfile:
            # check wether the player dir exists, which means the file is corrupted or
            # something very similar.
            if (!aio_stat cf::player::playerdir $user) {
               $ns->send_drawinfo (
                  "Unable to retrieve this player. It might be a locked or broken account. "
                . "If this is your account, ask a dungeon master for assistance. "
                . "Otherwise choose a different login name.",
                  cf::NDI_RED
               );
               next;
            }
         }

         # the rest of this function is character creation

         # just to make sure nothing is left over
         nuke_playerdir $user;

         my $pass2 = query $ns, cf::CS_QUERY_HIDEINPUT, "Please type your password again.";

         if ($pass2 ne $pass) {
            nuke_str $pass;
            nuke_str $pass2;
            $ns->send_drawinfo (
               "The passwords do not match, please try again.",
               cf::NDI_RED
            );
            Coro::Timer::sleep 0.5;
            next;
         }

         nuke_str $pass2;

         my $pl = cf::player::new $user;
         $pl->password (crypt $pass, join '', ('.', '/', 0..9, 'A'..'Z', 'a'..'z')[rand 64, rand 64]);
         nuke_str $pass;
         $pl->connect ($ns);
         my $ob = $pl->ob;

         $ob->goto ($pl->maplevel, $ob->x, $ob->y);

         while () {
            $ob->update_stats;
            $pl->save_stats;

            my $res = query $ns, cf::CS_QUERY_SINGLECHAR,
                         "[y] to roll new stats [n] to use stats\n[1-7] [1-7] to swap stats.\nRoll again (y/n/1-7)?";

            if ($res =~ /^[Nn]/) {
               last;
            } elsif ($res > 0 && $res <= 7) {
               my $swap = query $ns, cf::CS_QUERY_SINGLECHAR, "Swap stat with (will not roll new stats) [1-7]?";

               if ($swap > 0 && $swap <= 7) {
                  $ob->swap_stats ($res - 1, $swap - 1);
               }
            } else {
               $ob->roll_stats;
            }

            Coro::Timer::sleep 0.2;
         }

         $ob->set_animation (2);
         $ob->add_statbonus;

         while () {
            $ns->send_msg ("chargen-race-title", ucfirst $pl->title, -1);
            my $msg = $ob->msg;
            $msg =~ s/(?<=\S)\n(?=\S)/ /g;
            $ns->send_msg ("chargen-race-description", $msg, cf::NDI_BLUE);

            my $res = query $ns, cf::CS_QUERY_SINGLECHAR,
                         "Now choose a character.\nPress any key to change outlook.\nPress `d' when you're pleased.\n";

            last if $res =~ /[dD]/;

            $pl->chargen_race_next;
            Coro::Timer::sleep 0.2;
         }

         $pl->chargen_race_done;

         while () {
            my $res = query $ns, cf::CS_QUERY_SINGLECHAR,
                         "Now choose a gender.\nPress 'f' to become female, and 'm' to become male.\n";

            if ($res =~ /^[fF]/) {
               $pl->gender (1);
               last;
            } elsif ($res =~ /^[mM]/) {
               $pl->gender (0);
               last;
            }
            Coro::Timer::sleep 0.2;
         }

         $ob->reply (undef, "Welcome to Crossfire!");

         delete $pl->{deny_save};

         last;
      }
   });
});

cf::register_command quit => sub {
   my ($ob, $arg) = @_;

   $ob->reply (undef,
               "Quitting will delete your character PERMANENTLY: It will be gone forever and any progress will be lost. "
               . "If you are sure you want to do this, then use the quit_character command instead of quit.",
               cf::NDI_UNIQUE | cf::NDI_RED);
};

cf::register_command quit_character => sub {
   my ($ob, $arg) = @_;

   my $pl = $ob->contr;

   $pl->ns->query (cf::CS_QUERY_SINGLECHAR, "Do you want to PERMANENTLY delete your character and all associated data (y/n)?", sub {
      if ($_[0] !~ /^[yY]/) {
         $ob->reply (undef,
                     "Ok, not not quitting then.",
                     cf::NDI_UNIQUE | cf::NDI_RED);
      } else {
         $ob->reply (undef,
                     "Ok, quitting, hope to see you again.",
                     cf::NDI_UNIQUE | cf::NDI_RED);
         $pl->ns->flush;
         cf::async { $pl->quit_character };
      }
   });
};

cf::object->attach (
   type     => cf::SAVEBED,
   on_apply => sub {
      my ($bed, $ob) = @_;

      return cf::override 0 unless $ob->type == cf::PLAYER;

      my $pl = $ob->contr;

      # update respawn position
      $pl->savebed ($bed->map->path, $bed->x, $bed->y);
      cf::async { $pl->save };

      $pl->killer ("left");
      $ob->check_score;

      $ob->reply (undef, "In the future, you will wake up here when you die.");

      $pl->ns->query (cf::CS_QUERY_SINGLECHAR, "Do you want to continue playing (y/n)?", sub {
         if ($_[0] !~ /^[yY]/) {
            $pl->invoke (cf::EVENT_PLAYER_LOGOUT, 1);
            $pl->deactivate;
            $pl->ns->destroy;
         } else {
            cf::async { $pl->save };
         }
      });
   },
);

cf::player->attach (
   on_login  => sub {
      my ($pl) = @_;
      my $name = $pl->ob->name;

      $_->ob->message ("$name has entered the game.", cf::NDI_DK_ORANGE | cf::NDI_UNIQUE) for cf::player::list;
   },
   on_logout => sub {
      my ($pl, $cleanly) = @_;
      my $name = $pl->ob->name;

      if ($cleanly) {
         $_->ob->message ("$name left the game.", cf::NDI_DK_ORANGE | cf::NDI_UNIQUE) for cf::player::list;
      } else {
         $_->ob->message ("$name uncerimoniously disconnected.", cf::NDI_DK_ORANGE | cf::NDI_UNIQUE) for cf::player::list;
         $pl->{unclean_save} = $cf::RUNTIME;
      }
   },
);

#############################################################################

our $SCHEDULE_INTERVAL  = $cf::CFG{player_schedule_interval} || 10; # time the player scheduler sleeps between runs
our $SAVE_TIMEOUT       = $cf::CFG{player_save_interval}     || 20; # save players every n seconds

our $SCHEDULER = cf::async_ext {
   my $schedule_interval = Coro::Event->timer (after => 1);
   while () {
      $schedule_interval->interval ($SCHEDULE_INTERVAL);
      $schedule_interval->next;

      # this weird form of iteration over values is used because
      # the hash changes underneath us frequently, and for
      # keeps a direct reference to the value without (in 5.8 perls)
      # keeping a reference, so this is prone to crashes or worse.
      my @players = keys %cf::PLAYER;
      for (@players) {
         my $pl = $cf::PLAYER{$_}
            or next;
         $pl->valid or next;

         eval {
            if ($pl->{last_save} + $SAVE_TIMEOUT <= $cf::RUNTIME) {
               $pl->save;

               unless ($pl->active || $pl->ns) {
                  # check refcounts, this is tricky and needs to be adjusted to fit server internals
                  my $ob = $pl->ob;

                  my $pl_ref = $pl->refcnt_cnt;
                  my $ob_ref = $ob->refcnt_cnt;

                  ## pl_ref == $pl + ob->contr   + %cf::PLAYER
                  ## ob_ref == $ob + pl->observe + simply being an object
                  if ($pl_ref == 3 && $ob_ref == 3) {
                     warn "player-scheduler destroy ", $ob->name;#d#

                     # remove from sight and get fresh "copies"
                     $pl = delete $cf::PLAYER{$ob->name};
                     $ob = $pl->ob;

                     $pl->destroy; # destroys $ob
                  } else {
                     my $a_ = $pl->refcnt;#d#
                     my $b_ = $ob->refcnt;#d#

                     warn "player-scheduler refcnt ", $ob->name, " pl $pl_ref ob $ob_ref (C pl $a_ ob $b_)\n";#d#
                  }
               }
            }
         };
         warn $@ if $@;
         Coro::cede;
      };
   }
};

$SCHEDULER->prio (1);

Revision:	1.70
Committed:	Sun Sep 2 12:37:10 2007 UTC (16 years, 8 months ago) by root
Branch:	MAIN
Changes since 1.69:	+3 -5 lines
Log Message:	be less blocking when nuking players
#	Content
1	#! perl # mandatory
2
3	# login handling
4
5	use Fcntl;
6	use Coro::AIO;
7
8	our $MAX_DISCONNECT_TIME = $cf::CFG{max_disconnect_time} \|\| 3600;
9
10	# paranoia function to overwrite a string-in-place
11	sub nuke_str {
12	substr $_[0], 0, (length $_[0]), "x" x length $_[0]
13	}
14
15	sub query {
16	my ($ns, $flags, $text) = @_;
17
18	my $current = $Coro::current;
19	$ns->query ($flags, $text, sub { $current->ready; $current = $_[0] });
20	Coro::schedule while ref $current;
21
22	$current
23	}
24
25	sub can_cleanup {
26	my ($pl, $mtime) = @_;
27
28	my $age = time - $mtime;
29	my $level = $pl->ob->level;
30
31	($level <= 3 && $age > 7 * 86400) # 7 days for level 0..3
32	\|\| ($level <= 9 && $age > 90 * 86400) # 3 months for level 4..9
33	\|\| ($level <= 20 && $age > 180 * 86400) # 6 months for level 10..20
34	\|\| $age > 700 * 86400 # 2 years for everybody else
35	}
36
37	sub check_playing {
38	my ($ns, $user) = @_;
39
40	return unless cf::player::find_active $user;
41
42	$ns->send_drawinfo (
43	"That player is already logged in on this server. "
44	. "If you want to create a new player, choose another name. "
45	. "If you have already a registered, make sure nobody "
46	. "else is using your account at this time. If you lost your connection "
47	. "then the server will likely timeout within a minute. If you still "
48	. "cannot log-in after a minute, you are still logged in. Make sure "
49	. "you do not have another client running. If you use windows, reboot, "
50	. "this will fix anything.",
51	cf::NDI_RED
52	);
53
54	1
55	}
56
57	sub enter_map {
58	my ($pl) = @_;
59
60	my $ob = $pl->ob;
61
62	my ($map, $x, $y)
63	= $ob->{_link_pos}
64	? @{delete $ob->{_link_pos}}
65	: ($pl->maplevel, $ob->x, $ob->y);
66
67	$ob->enter_link;
68
69	if (my $time = delete $pl->{unclean_save}) {
70	if (my $m = cf::map::find $map) {
71	if ($time < $m->{instantiate_time}) {
72	# the map was reset in the meantime
73	my $age = $cf::RUNTIME - $time;
74
75	warn $ob->name, " map reset after logout, logout age $age (>= $MAX_DISCONNECT_TIME)\n";#d#
76
77	# for now, just go back to savebed
78	($map, $x, $y) = $pl->savebed;
79
80	if ($age >= $MAX_DISCONNECT_TIME) {
81	$ob->message (
82	"You didn't use a bed to reality to leave this realm, leaving your body in great danger. "
83	. "Unfortunately, nobody was near to help you when the monsters arrived to eat you. "
84	. "Maybe you can find comfort in the thought that your body was quite satisfying in taste... "
85	. "H<You disconnected too long without having used a savebed.>",
86	cf::NDI_RED
87	);
88	# kill them.
89	# reminds me of the famous badness 10000 syndrome...
90	$ob->stats->hp (-10000); #] if they survive this they deserved to live
91	$pl->killer ("a cave-in");
92	} else {
93	$ob->message (
94	"You didn't use a bed to reality to leave this realm, leaving your body in great danger. "
95	. "Fortunately, some friendly dwellers found you, checked your passport, and brought you to safety. "
96	. "Better use a savebed next time, much worse things could have happened... "
97	. "H<You disconnected without having used a savebed. When you do that for too long, you might die.>",
98	cf::NDI_RED
99	);
100	}
101	} else {
102	$ob->message (
103	"You didn't use a bed to reality to leave this realm. This is very dangerous, "
104	. "as lots of things could happen when you leave by other means, such as cave-ins, "
105	. "or monsters suddenly snapping your body. Better use a savebed next time. "
106	. "H<Always apply a bed of reality to disconnect from the server.>",
107	cf::NDI_RED
108	);
109	}
110	}
111	}
112
113	$ob->goto ($map, $x, $y);
114	}
115
116	# delete a player directory, be non-blocking AND synchronous...
117	# (thats hard, so we crap out and fork).
118	sub nuke_playerdir {
119	my ($user) = @_;
120
121	aio_rename "$PLAYERDIR/$user", "$PLAYERDIR/~$Coro::current~deleting~";
122	system "rm -rf \Q$PLAYERDIR/~$Coro::current~deleting~\E &";
123	}
124
125	cf::client->attach (on_addme => sub {
126	my ($ns) = @_;
127
128	if (!$ns->facecache)
129	{
130	$ns->send_drawinfo (<<EOF, cf::NDI_RED);
131
132
133	***
134	*** WARNING:
135	*** Your client does not support face/image caching,
136	*** or it has been disabled. Face caching is mandatory
137	*** so please enable it or use a newer client.
138	***
139	*** Look at your client preferences:
140	***
141	*** CFPlus: all known versions automatically enable the facecache.
142	*** cfclient: use the -cache commandline option.
143	*** cfclient: map will not redraw automatically (bug).
144	*** gcfclient: use -cache commandline option, or enable
145	*** gcfclient: Client => Configure => Map & Image => Cache Images.
146	*** jcrossclient: your client is broken, use CFPlus or gcfclient.
147	***
148	***
149	EOF
150	if ($ns->version =~ /jcrossclient/) {
151	# let them, for now
152	} else {
153	$ns->flush;
154	return $ns->destroy;
155	}
156
157	# $ns->facecache = true;
158	}
159
160	if ($ns->mapmode < cf::Map1aCmd) {
161	$ns->send_drawinfo (<<EOF, cf::NDI_RED);
162
163
164	***
165	*** WARNING:
166	*** Your client is too old. Please upgrade to a newer version.
167	EOF
168
169	$ns->flush;
170	return $ns->destroy;
171	}
172
173	$ns->pl and return $ns->destroy;
174
175	$ns->async (sub {
176	my ($user, $pass);
177
178	$ns->send_packet ("addme_success");
179
180	for (;;) {
181	$ns->send_drawinfo (
182	"Please enter your username now. If you are a new user, "
183	. "make one up that describes your character best. "
184	. "Only letters and digits are allowed, though.",
185	cf::NDI_BLUE
186	);
187
188	# read username
189	while () {
190	$user = query $ns, 0, "What is your name?\n:";
191
192	if ($cf::LOGIN_LOCK{$user}) {
193	$ns->send_drawinfo (
194	"That username is currently used in another login session. "
195	. "Chose another, or wait till the other session has ended.",
196	cf::NDI_RED
197	);
198	} elsif ($user =~ /^[a-zA-Z0-9][a-zA-Z0-9\-_]{2,17}\z/) {
199	last;
200	} else {
201	$ns->send_drawinfo (
202	"Your username contains illegal characters "
203	. "(only a-z, A-Z and 0-9 are allowed), "
204	. "or is not between 3 and 18 characters in length.",
205	cf::NDI_RED
206	);
207	}
208	Coro::Timer::sleep 0.4;
209	}
210
211	check_playing $ns, $user and next;
212
213	$ns->send_drawinfo (
214	"Welcome $user, please enter your password now. "
215	. "New users should now choose a password. "
216	. "Anything your client lets you enter is fine.",
217	cf::NDI_BLUE
218	);
219
220	# read password
221	while () {
222	$pass = query $ns, cf::CS_QUERY_HIDEINPUT, "What is your password?\n:";
223	last if $pass =~ /.../;
224	$ns->send_drawinfo (
225	"Try to use at least three characters as your password please, "
226	. "that cannot be too much to ask for :)",
227	cf::NDI_RED
228	);
229	Coro::Timer::sleep 0.4;
230	}
231
232	# lock this username for the remainder of this login session
233	if ($cf::LOGIN_LOCK{$user}) {
234	$ns->send_drawinfo (
235	"That username is currently used in another login session. "
236	. "Chose another, or wait till the other session has ended.",
237	cf::NDI_RED
238	);
239	next;
240	}
241	local $cf::LOGIN_LOCK{$user} = 1;
242
243	check_playing $ns, $user and next;
244
245	# try to read the user file and check the password
246	if (my $pl = cf::player::find $user) {
247	aio_stat $pl->path and next;
248	my $mtime = (stat _)[9];
249	my $hash = $pl->password;
250
251	if ($cf::CFG{ext_login_nocheck} or $hash eq crypt $pass, $hash) {
252	nuke_str $pass;
253	# password matches, wonderful
254	my $pl = cf::player::find $user or next;
255	$pl->connect ($ns);
256	enter_map $pl;
257	last;
258	} elsif (can_cleanup $pl, $mtime) {
259	Coro::Timer::sleep 1;
260
261	$ns->send_drawinfo (
262	"Player exists, but password does not match. If this is your account, "
263	. "please try again. If not, you can now decide to take over this account "
264	. "because it has not been in-use for some time.",
265	cf::NDI_RED
266	);
267
268	#TODO: nuke_str
269	(query $ns, cf::CS_QUERY_SINGLECHAR, "Delete existing account and create a new one (Y/N)?") =~ /^[yY]/
270	or next;
271
272	# check if the file hasn't changed
273	aio_stat cf::player::path $user and next;
274	$mtime == (stat _)[9] or next;
275
276	$pl->quit_character;
277
278	# fall through to creation
279	} else {
280	nuke_str $pass;
281
282	Coro::Timer::sleep 1;
283
284	$ns->send_drawinfo (
285	"Wrong username or password. Please try again "
286	. "(check for Numlock and other semi-obvious error sources).",
287	cf::NDI_RED
288	);
289	next;
290	}
291	} else {
292	# unable to load the playerfile:
293	# check wether the player dir exists, which means the file is corrupted or
294	# something very similar.
295	if (!aio_stat cf::player::playerdir $user) {
296	$ns->send_drawinfo (
297	"Unable to retrieve this player. It might be a locked or broken account. "
298	. "If this is your account, ask a dungeon master for assistance. "
299	. "Otherwise choose a different login name.",
300	cf::NDI_RED
301	);
302	next;
303	}
304	}
305
306	# the rest of this function is character creation
307
308	# just to make sure nothing is left over
309	nuke_playerdir $user;
310
311	my $pass2 = query $ns, cf::CS_QUERY_HIDEINPUT, "Please type your password again.";
312
313	if ($pass2 ne $pass) {
314	nuke_str $pass;
315	nuke_str $pass2;
316	$ns->send_drawinfo (
317	"The passwords do not match, please try again.",
318	cf::NDI_RED
319	);
320	Coro::Timer::sleep 0.5;
321	next;
322	}
323
324	nuke_str $pass2;
325
326	my $pl = cf::player::new $user;
327	$pl->password (crypt $pass, join '', ('.', '/', 0..9, 'A'..'Z', 'a'..'z')[rand 64, rand 64]);
328	nuke_str $pass;
329	$pl->connect ($ns);
330	my $ob = $pl->ob;
331
332	$ob->goto ($pl->maplevel, $ob->x, $ob->y);
333
334	while () {
335	$ob->update_stats;
336	$pl->save_stats;
337
338	my $res = query $ns, cf::CS_QUERY_SINGLECHAR,
339	"[y] to roll new stats [n] to use stats\n[1-7] [1-7] to swap stats.\nRoll again (y/n/1-7)?";
340
341	if ($res =~ /^[Nn]/) {
342	last;
343	} elsif ($res > 0 && $res <= 7) {
344	my $swap = query $ns, cf::CS_QUERY_SINGLECHAR, "Swap stat with (will not roll new stats) [1-7]?";
345
346	if ($swap > 0 && $swap <= 7) {
347	$ob->swap_stats ($res - 1, $swap - 1);
348	}
349	} else {
350	$ob->roll_stats;
351	}
352
353	Coro::Timer::sleep 0.2;
354	}
355
356	$ob->set_animation (2);
357	$ob->add_statbonus;
358
359	while () {
360	$ns->send_msg ("chargen-race-title", ucfirst $pl->title, -1);
361	my $msg = $ob->msg;
362	$msg =~ s/(?<=\S)\n(?=\S)/ /g;
363	$ns->send_msg ("chargen-race-description", $msg, cf::NDI_BLUE);
364
365	my $res = query $ns, cf::CS_QUERY_SINGLECHAR,
366	"Now choose a character.\nPress any key to change outlook.\nPress `d' when you're pleased.\n";
367
368	last if $res =~ /[dD]/;
369
370	$pl->chargen_race_next;
371	Coro::Timer::sleep 0.2;
372	}
373
374	$pl->chargen_race_done;
375
376	while () {
377	my $res = query $ns, cf::CS_QUERY_SINGLECHAR,
378	"Now choose a gender.\nPress 'f' to become female, and 'm' to become male.\n";
379
380	if ($res =~ /^[fF]/) {
381	$pl->gender (1);
382	last;
383	} elsif ($res =~ /^[mM]/) {
384	$pl->gender (0);
385	last;
386	}
387	Coro::Timer::sleep 0.2;
388	}
389
390	$ob->reply (undef, "Welcome to Crossfire!");
391
392	delete $pl->{deny_save};
393
394	last;
395	}
396	});
397	});
398
399	cf::register_command quit => sub {
400	my ($ob, $arg) = @_;
401
402	$ob->reply (undef,
403	"Quitting will delete your character PERMANENTLY: It will be gone forever and any progress will be lost. "
404	. "If you are sure you want to do this, then use the quit_character command instead of quit.",
405	cf::NDI_UNIQUE \| cf::NDI_RED);
406	};
407
408	cf::register_command quit_character => sub {
409	my ($ob, $arg) = @_;
410
411	my $pl = $ob->contr;
412
413	$pl->ns->query (cf::CS_QUERY_SINGLECHAR, "Do you want to PERMANENTLY delete your character and all associated data (y/n)?", sub {
414	if ($_[0] !~ /^[yY]/) {
415	$ob->reply (undef,
416	"Ok, not not quitting then.",
417	cf::NDI_UNIQUE \| cf::NDI_RED);
418	} else {
419	$ob->reply (undef,
420	"Ok, quitting, hope to see you again.",
421	cf::NDI_UNIQUE \| cf::NDI_RED);
422	$pl->ns->flush;
423	cf::async { $pl->quit_character };
424	}
425	});
426	};
427
428	cf::object->attach (
429	type => cf::SAVEBED,
430	on_apply => sub {
431	my ($bed, $ob) = @_;
432
433	return cf::override 0 unless $ob->type == cf::PLAYER;
434
435	my $pl = $ob->contr;
436
437	# update respawn position
438	$pl->savebed ($bed->map->path, $bed->x, $bed->y);
439	cf::async { $pl->save };
440
441	$pl->killer ("left");
442	$ob->check_score;
443
444	$ob->reply (undef, "In the future, you will wake up here when you die.");
445
446	$pl->ns->query (cf::CS_QUERY_SINGLECHAR, "Do you want to continue playing (y/n)?", sub {
447	if ($_[0] !~ /^[yY]/) {
448	$pl->invoke (cf::EVENT_PLAYER_LOGOUT, 1);
449	$pl->deactivate;
450	$pl->ns->destroy;
451	} else {
452	cf::async { $pl->save };
453	}
454	});
455	},
456	);
457
458	cf::player->attach (
459	on_login => sub {
460	my ($pl) = @_;
461	my $name = $pl->ob->name;
462
463	$_->ob->message ("$name has entered the game.", cf::NDI_DK_ORANGE \| cf::NDI_UNIQUE) for cf::player::list;
464	},
465	on_logout => sub {
466	my ($pl, $cleanly) = @_;
467	my $name = $pl->ob->name;
468
469	if ($cleanly) {
470	$_->ob->message ("$name left the game.", cf::NDI_DK_ORANGE \| cf::NDI_UNIQUE) for cf::player::list;
471	} else {
472	$_->ob->message ("$name uncerimoniously disconnected.", cf::NDI_DK_ORANGE \| cf::NDI_UNIQUE) for cf::player::list;
473	$pl->{unclean_save} = $cf::RUNTIME;
474	}
475	},
476	);
477
478	#############################################################################
479
480	our $SCHEDULE_INTERVAL = $cf::CFG{player_schedule_interval} \|\| 10; # time the player scheduler sleeps between runs
481	our $SAVE_TIMEOUT = $cf::CFG{player_save_interval} \|\| 20; # save players every n seconds
482
483	our $SCHEDULER = cf::async_ext {
484	my $schedule_interval = Coro::Event->timer (after => 1);
485	while () {
486	$schedule_interval->interval ($SCHEDULE_INTERVAL);
487	$schedule_interval->next;
488
489	# this weird form of iteration over values is used because
490	# the hash changes underneath us frequently, and for
491	# keeps a direct reference to the value without (in 5.8 perls)
492	# keeping a reference, so this is prone to crashes or worse.
493	my @players = keys %cf::PLAYER;
494	for (@players) {
495	my $pl = $cf::PLAYER{$_}
496	or next;
497	$pl->valid or next;
498
499	eval {
500	if ($pl->{last_save} + $SAVE_TIMEOUT <= $cf::RUNTIME) {
501	$pl->save;
502
503	unless ($pl->active \|\| $pl->ns) {
504	# check refcounts, this is tricky and needs to be adjusted to fit server internals
505	my $ob = $pl->ob;
506
507	my $pl_ref = $pl->refcnt_cnt;
508	my $ob_ref = $ob->refcnt_cnt;
509
510	## pl_ref == $pl + ob->contr + %cf::PLAYER
511	## ob_ref == $ob + pl->observe + simply being an object
512	if ($pl_ref == 3 && $ob_ref == 3) {
513	warn "player-scheduler destroy ", $ob->name;#d#
514
515	# remove from sight and get fresh "copies"
516	$pl = delete $cf::PLAYER{$ob->name};
517	$ob = $pl->ob;
518
519	$pl->destroy; # destroys $ob
520	} else {
521	my $a_ = $pl->refcnt;#d#
522	my $b_ = $ob->refcnt;#d#
523
524	warn "player-scheduler refcnt ", $ob->name, " pl $pl_ref ob $ob_ref (C pl $a_ ob $b_)\n";#d#
525	}
526	}
527	}
528	};
529	warn $@ if $@;
530	Coro::cede;
531	};
532	}
533	};
534
535	$SCHEDULER->prio (1);
536