server/ext/map-scheduler.ext

#! perl # mandatory

# this extension swaps out maps and resets them, in essence managing
# the reset/swap policy of the server.
# it also contains the map prefetching logic

#our $DEACTIVATE_TIMEOUT =   20; # number of seconds after which maps get deactivated to save cpu
our $SWAP_TIMEOUT       = $cf::CFG{swap_timeout}      || 300; # number of seconds after which inactive maps get swapped out
our $SCHEDULE_INTERVAL  = $cf::CFG{schedule_interval} ||  .8; # time the map scheduler sleeps between runs
our $SAVE_TIMEOUT       = $cf::CFG{save_timeout}      ||  30; # save maps every n seconds
our $SWAP_LOAD1         = $cf::CFG{swap_load1}        ||  .1; # start aggressively swapping at this load
our $SWAP_LOAD2         = $cf::CFG{swap_load2}        ||  .4; # swap as fast as possible at this load

cf::async_ext {
   $Coro::current->{desc} = "startup map scanner";
   $Coro::current->prio (Coro::PRIO_MIN);

   # load the header of swapped-out maps.
   # this is not a correctness issue, it simply saves diskspace
   # because old files will get cleaned up on reset time
   Coro::Timer::sleep 0.25;

   for my $path (@{ cf::map::tmp_maps or [] }, @{ cf::map::random_maps or [] }) {
      cf::cede_to_tick;
      cf::map::find $path;
   }

   # now hunt for resettable per-player maps
   for my $login (@{ cf::player::list_logins or [] }) {
      for my $path (@{ cf::player::maps $login or [] }) {
         cf::cede_to_tick;

         $path =~ /^~[^\/]+(\/.*)$/
            or next; # doh

         my $base = cf::map::find $1;

         # skip maps without base maps on the assumption
         # that those are old, unresettable maps
         next unless $base;

         # skip unresettable maps, for speed
         next if $base->{deny_reset};

         my $map = cf::map::find $path;

         if ($map->{deny_reset}) {
            warn "found noreset map with resettable base map, resetting: $path\n";
            delete $map->{deny_reset};
         }
      }
   }
};

our $SCHEDULER = cf::async_ext {
   $Coro::current->{desc} = "map scheduler";
   my $timer = Coro::Event->timer (after => 1);

   while () {
      $timer->interval ($SCHEDULE_INTERVAL);
      $timer->next unless $cf::LOADAVG > $SWAP_LOAD2;

      # this weird form of iteration over values is used because
      # the hash changes underneath us frequently, and for
      # keeps a direct reference to the value without (in 5.8 perls)
      # keeping a reference, so this is prone to crashes or worse.
      my @maps = keys %cf::MAP;
      for (@maps) {
         my $map = $cf::MAP{$_}
            or next;
         $map->valid or next;

         eval {
            # not yet, because maps might become visible to players nearby
            # we need to remove the map from %cf::MAP and all tiled map links
#         if ($last_access + $DEACTIVATE_TIMEOUT <= $cf::RUNTIME) {
#            $map->deactivate;
#            delete $map->{active};
#         }
            if ($map->should_reset) {
               $map->reset;
            } elsif ($map->in_memory == cf::MAP_IN_MEMORY) {
               my $max_idle = cf::clamp +(cf::lerp $cf::LOADAVG, $SWAP_LOAD1, $SWAP_LOAD2, $SWAP_TIMEOUT, $cf::TICK * 1.5),
                                        $cf::TICK * 1.5, $SWAP_TIMEOUT;

               if ($map->last_access + $max_idle <= $cf::RUNTIME && !$map->players) {
                  $map->swap_out;
               } elsif ($map->{last_save} + $SAVE_TIMEOUT <= $cf::RUNTIME) {
                  $map->save;
                  $map->{last_save} -= rand; # randomise map save times a bit
               }
            }
         };
         warn $@ if $@;
         cf::cede_to_tick;
      };
   }
};

$SCHEDULER->prio (-2);

Revision:	1.43
Committed:	Wed Sep 19 21:57:26 2007 UTC (16 years, 8 months ago) by root
Branch:	MAIN
Changes since 1.42:	+1 -1 lines
Log Message:	name your coroutines
#	User	Rev	Content
1	root	1.37	#! perl # mandatory
2	root	1.1
3			# this extension swaps out maps and resets them, in essence managing
4			# the reset/swap policy of the server.
5	root	1.18	# it also contains the map prefetching logic
6	root	1.1
7	root	1.24	#our $DEACTIVATE_TIMEOUT = 20; # number of seconds after which maps get deactivated to save cpu
8	root	1.34	our $SWAP_TIMEOUT = $cf::CFG{swap_timeout} \|\| 300; # number of seconds after which inactive maps get swapped out
9			our $SCHEDULE_INTERVAL = $cf::CFG{schedule_interval} \|\| .8; # time the map scheduler sleeps between runs
10			our $SAVE_TIMEOUT = $cf::CFG{save_timeout} \|\| 30; # save maps every n seconds
11			our $SWAP_LOAD1 = $cf::CFG{swap_load1} \|\| .1; # start aggressively swapping at this load
12			our $SWAP_LOAD2 = $cf::CFG{swap_load2} \|\| .4; # swap as fast as possible at this load
13	root	1.1
14	root	1.17	cf::async_ext {
15	root	1.43	$Coro::current->{desc} = "startup map scanner";
16	root	1.12	$Coro::current->prio (Coro::PRIO_MIN);
17	root	1.35
18	root	1.14	# load the header of swapped-out maps.
19	root	1.12	# this is not a correctness issue, it simply saves diskspace
20			# because old files will get cleaned up on reset time
21	root	1.35	Coro::Timer::sleep 0.25;
22	root	1.12
23	root	1.36	for my $path (@{ cf::map::tmp_maps or [] }, @{ cf::map::random_maps or [] }) {
24	root	1.38	cf::cede_to_tick;
25	root	1.36	cf::map::find $path;
26	root	1.12	}
27
28	root	1.35	# now hunt for resettable per-player maps
29			for my $login (@{ cf::player::list_logins or [] }) {
30			for my $path (@{ cf::player::maps $login or [] }) {
31	root	1.38	cf::cede_to_tick;
32	root	1.35
33			$path =~ /^~[^\/]+(\/.*)$/
34			or next; # doh
35
36			my $base = cf::map::find $1;
37
38			# skip maps without base maps on the assumption
39			# that those are old, unresettable maps
40			next unless $base;
41
42			# skip unresettable maps, for speed
43			next if $base->{deny_reset};
44
45			my $map = cf::map::find $path;
46
47			if ($map->{deny_reset}) {
48			warn "found noreset map with resettable base map, resetting: $path\n";
49			delete $map->{deny_reset};
50			}
51			}
52			}
53	root	1.12	};
54
55	root	1.17	our $SCHEDULER = cf::async_ext {
56	root	1.42	$Coro::current->{desc} = "map scheduler";
57	root	1.38	my $timer = Coro::Event->timer (after => 1);
58
59	root	1.1	while () {
60	root	1.38	$timer->interval ($SCHEDULE_INTERVAL);
61			$timer->next unless $cf::LOADAVG > $SWAP_LOAD2;
62	root	1.1
63	root	1.9	# this weird form of iteration over values is used because
64			# the hash changes underneath us frequently, and for
65			# keeps a direct reference to the value without (in 5.8 perls)
66			# keeping a reference, so this is prone to crashes or worse.
67	root	1.8	my @maps = keys %cf::MAP;
68			for (@maps) {
69			my $map = $cf::MAP{$_}
70			or next;
71			$map->valid or next;
72	root	1.9
73	root	1.1	eval {
74			# not yet, because maps might become visible to players nearby
75	root	1.3	# we need to remove the map from %cf::MAP and all tiled map links
76	root	1.1	# if ($last_access + $DEACTIVATE_TIMEOUT <= $cf::RUNTIME) {
77			# $map->deactivate;
78			# delete $map->{active};
79			# }
80			if ($map->should_reset) {
81			$map->reset;
82	root	1.3	} elsif ($map->in_memory == cf::MAP_IN_MEMORY) {
83	root	1.41	my $max_idle = cf::clamp +(cf::lerp $cf::LOADAVG, $SWAP_LOAD1, $SWAP_LOAD2, $SWAP_TIMEOUT, $cf::TICK * 1.5),
84			$cf::TICK * 1.5, $SWAP_TIMEOUT;
85	root	1.34
86	root	1.26	if ($map->last_access + $max_idle <= $cf::RUNTIME && !$map->players) {
87	root	1.25	$map->swap_out;
88	root	1.3	} elsif ($map->{last_save} + $SAVE_TIMEOUT <= $cf::RUNTIME) {
89	root	1.25	$map->save;
90	root	1.39	$map->{last_save} -= rand; # randomise map save times a bit
91	root	1.3	}
92	root	1.1	}
93			};
94			warn $@ if $@;
95	root	1.34	cf::cede_to_tick;
96	root	1.8	};
97	root	1.1	}
98			};
99	root	1.5
100	root	1.1	$SCHEDULER->prio (-2);
101