server/lib/cf.pm

package cf;

use Symbol;
use List::Util;
use Storable;
use Opcode;
use Safe;
use Safe::Hole;

use Time::HiRes;
use Event;
$Event::Eval = 1; # no idea why this is required, but it is

use strict;

our %COMMAND = ();
our @EVENT;
our @PLUGIN_EVENT;
our %PROP_TYPE;
our %PROP_IDX;
our $LIBDIR = maps_directory "perl";

our $TICK = MAX_TIME * 1e-6;
our $TICK_WATCHER;
our $NEXT_TICK;

BEGIN {
   @PLUGIN_EVENT = map lc, @PLUGIN_EVENT;

   *CORE::GLOBAL::warn = sub {
      my $msg = join "", @_;
      $msg .= "\n"
         unless $msg =~ /\n$/;

      print STDERR "cfperl: $msg";
      LOG llevError, "cfperl: $msg";
   };
}

my %ignore_set = (MAP_PROP_PATH => 1); # I hate the plug-in api. Deeply!

# generate property mutators
sub prop_gen {
   my ($prefix, $class) = @_;

   no strict 'refs';

   for my $prop (keys %PROP_TYPE) {
      $prop =~ /^\Q$prefix\E_(.*$)/ or next;
      my $sub = lc $1;

      my $type = $PROP_TYPE{$prop};
      my $idx  = $PROP_IDX {$prop};

      *{"$class\::get_$sub"} = *{"$class\::$sub"} = sub {
         $_[0]->get_property ($type, $idx)
      };

      *{"$class\::set_$sub"} = sub {
         $_[0]->set_property ($type, $idx, $_[1]);
      } unless $ignore_set{$prop};
   }
}

# auto-generate most of the API

prop_gen OBJECT_PROP => "cf::object";
# CFAPI_OBJECT_ANIMATION?
prop_gen PLAYER_PROP => "cf::object::player";

prop_gen MAP_PROP    => "cf::map";
prop_gen ARCH_PROP   => "cf::arch";

# guessed hierarchies

@ext::cf::object::player::ISA = @cf::object::player::ISA = 'cf::object';
@ext::cf::object::map::ISA    = @cf::object::map::ISA    = 'cf::object';

# we bless all objects into derived classes to force a method lookup
# within the Safe compartment.
for my $pkg (qw(cf::object cf::object::map cf::object::player cf::player cf::map cf::party cf::region cf::arch)) {
   no strict 'refs';
   @{"ext::$pkg\::wrap::ISA"} = @{"$pkg\::wrap::ISA"} = $pkg;
}

$Event::DIED = sub {
   warn "error in event callback: @_";
};

my %ext_pkg;
my @exts;
my @hook;
my %command;
my %extcmd;

#############################################################################
# "new" plug-in system

=item cf::object::attach ... # NYI

=item cf::attach_global ...

=item cf::attach_to_type ...

=item cf::attach_to_objects ...

=item cf::attach_to_players ...

=item cf::attach_to_maps ...

   prio    => $number, # lower is earlier
   on_xxx  => \&cb,
   package => package::,

=cut

# the following variables are defined in .xs and must not be re-created
our @CB_GLOBAL = (); # registry for all global events
our @CB_OBJECT = ();
our @CB_PLAYER = ();
our @CB_TYPE   = (); # registry for type (cf-object class) based events
our @CB_MAP    = ();

sub _attach_cb($\%$$$) {
   my ($registry, $undo, $event, $prio, $cb) = @_;

   use sort 'stable';

   $cb = [$prio, $cb];

   @{$registry->[$event]} = sort
                           { $a->[0] cmp $b->[0] }
                           @{$registry->[$event] || []}, $cb;

   push @{$undo->{cb}}, [$event, $cb];
}

# attach handles attaching event callbacks
# the only thing the caller has to do is pass the correct
# registry (== where the callback attaches to).
sub _attach(\@$\@) {
   my ($registry, $klass, $arg) = @_;

   my $prio = 0;

   my %undo = (
      registry => $registry,
      cb       => [],
   );

   my %cb_id = map +("on_" . lc $EVENT[$_][0], $_) , grep $EVENT[$_][1] == $klass, 0 .. $#EVENT;

   while (@$arg) {
      my $type = shift @$arg;

      if ($type eq "prio") {
         $prio = shift @$arg;

      } elsif ($type eq "package") {
         my $pkg = shift @$arg;

         while (my ($name, $id) = each %cb_id) {
            if (my $cb = $pkg->can ($name)) {
               _attach_cb $registry, %undo, $id, $prio, $cb;
            }
         }

      } elsif (exists $cb_id{$type}) {
         _attach_cb $registry, %undo, $cb_id{$type}, $prio, shift @$arg;

      } elsif (ref $type) {
         warn "attaching objects not supported, ignoring.\n";

      } else {
         shift @$arg;
         warn "attach argument '$type' not supported, ignoring.\n";
      }
   }

   \%undo
}

sub cf::object::attach {
   die;
}

sub attach_global {
   _attach @CB_GLOBAL, KLASS_GLOBAL, @_
}

sub attach_to_type {
   my $type = shift;
   _attach @{$CB_TYPE[$type]}, KLASS_OBJECT, @_
}

sub attach_to_objects {
   _attach @CB_OBJECT, KLASS_OBJECT, @_
}

sub attach_to_players {
   _attach @CB_PLAYER, KLASS_PLAYER, @_
}

sub attach_to_maps {
   _attach @CB_MAP, KLASS_MAP, @_
}

our $override;

sub override() {
   $override = 1
}

sub invoke {
   my $event = shift;
   my $callbacks = shift;

   local $override;

   for (@$callbacks) {
      eval { &{$_->[1]} };

      if ($@) {
         warn "$@";
         warn "... while processing $EVENT[$event][0] event, skipping processing altogether.\n";
         override;
      }

      return 1 if $override;
   }

   0
}

#############################################################################
# old plug-in events

sub inject_event {
   my $extension = shift;
   my $event_code = shift;

   my $cb = $hook[$event_code]{$extension}
      or return;

   &$cb
}

sub inject_global_event {
   my $event = shift;

   my $cb = $hook[$event]
      or return;

   List::Util::max map &$_, values %$cb
}

sub inject_command {
   my ($name, $obj, $params) = @_;

   for my $cmd (@{ $command{$name} }) {
      $cmd->[1]->($obj, $params);
   }

   -1
}

sub register_command {
   my ($name, $time, $cb) = @_;

   my $caller = caller;
   #warn "registering command '$name/$time' to '$caller'";

   push @{ $command{$name} }, [$time, $cb, $caller];
   $COMMAND{"$name\000"} = List::Util::max map $_->[0], @{ $command{$name} };
}

sub register_extcmd {
   my ($name, $cb) = @_;

   my $caller = caller;
   #warn "registering extcmd '$name' to '$caller'";

   $extcmd{$name} = [$cb, $caller];
}

sub register {
   my ($base, $pkg) = @_;

   for my $idx (0 .. $#PLUGIN_EVENT) {
      if (my $ref = $pkg->can ("on_$PLUGIN_EVENT[$idx]")) {
         #warn "registering $PLUGIN_EVENT[$idx] hook to '$pkg'\n";
         $hook[$idx]{$base} = $ref;
      }
   }
}

sub load_extension {
   my ($path) = @_;

   $path =~ /([^\/\\]+)\.ext$/ or die "$path";
   my $base = $1;
   my $pkg = $1;
   $pkg =~ s/[^[:word:]]/_/g;
   $pkg = "cf::ext::$pkg";

   warn "loading '$path' into '$pkg'\n";

   open my $fh, "<:utf8", $path
      or die "$path: $!";

   my $source =
      "package $pkg; use strict; use utf8;\n"
      . "#line 1 \"$path\"\n{\n"
      . (do { local $/; <$fh> })
      . "\n};\n1";

   eval $source
      or die "$path: $@";

   push @exts, $pkg;
   $ext_pkg{$base} = $pkg;

#   no strict 'refs';
#   @{"$pkg\::ISA"} = ext::;

   register $base, $pkg;
}

sub unload_extension {
   my ($pkg) = @_;

   warn "removing extension $pkg\n";

   # remove hooks
   for my $idx (0 .. $#PLUGIN_EVENT) {
      delete $hook[$idx]{$pkg};
   }

   # remove commands
   for my $name (keys %command) {
      my @cb = grep $_->[2] ne $pkg, @{ $command{$name} };

      if (@cb) {
         $command{$name} = \@cb;
         $COMMAND{"$name\000"} = List::Util::max map $_->[0], @cb;
      } else {
         delete $command{$name};
         delete $COMMAND{"$name\000"};
      }
   }

   # remove extcmds
   for my $name (grep $extcmd{$_}[1] eq $pkg, keys %extcmd) {
      delete $extcmd{$name};
   }

   if (my $cb = $pkg->can ("on_unload")) {
      eval {
         $cb->($pkg);
         1
      } or warn "$pkg unloaded, but with errors: $@";
   }

   Symbol::delete_package $pkg;
}

sub load_extensions {
   my $LIBDIR = maps_directory "perl";

   for my $ext (<$LIBDIR/*.ext>) {
      next unless -r $ext;
      eval {
         load_extension $ext;
         1
      } or warn "$ext not loaded: $@";
   }
}

sub _perl_reload(&) {
   my ($msg) = @_;

   $msg->("reloading...");

   eval {
      # 1. cancel all watchers
      $_->cancel for Event::all_watchers;

      # 2. unload all extensions
      for (@exts) {
         $msg->("unloading <$_>");
         unload_extension $_;
      }

      # 3. unload all modules loaded from $LIBDIR
      while (my ($k, $v) = each %INC) {
         next unless $v =~ /^\Q$LIBDIR\E\/.*\.pm$/;

         $msg->("removing <$k>");
         delete $INC{$k};

         $k =~ s/\.pm$//;
         $k =~ s/\//::/g;

         if (my $cb = $k->can ("unload_module")) {
            $cb->();
         }

         Symbol::delete_package $k;
      }

      # 4. get rid of ext::, as good as possible
      Symbol::delete_package "ext::$_"
         for qw(cf::object cf::object::map cf::object::player cf::player cf::map cf::party cf::region);

      # 5. remove register_script_function callbacks
      # TODO
      
      # 6. unload cf.pm "a bit"
      delete $INC{"cf.pm"};

      # don't, removes xs symbols, too
      #Symbol::delete_package __PACKAGE__;

      # 7. reload cf.pm
      $msg->("reloading cf.pm");
      require cf;
   };
   $msg->($@) if $@;

   $msg->("reloaded");
};

sub perl_reload() {
   _perl_reload {
      warn $_[0];
      print "$_[0]\n";
   };
}

register_command "perl-reload", 0, sub {
   my ($who, $arg) = @_;

   if ($who->flag (FLAG_WIZ)) {
      _perl_reload {
         warn $_[0];
         $who->message ($_[0]);
      };
   }
};

#############################################################################
# utility functions

use JSON::Syck (); # TODO# replace by JSON::PC once working

sub from_json($) {
   $JSON::Syck::ImplicitUnicode = 1; # work around JSON::Syck bugs
   JSON::Syck::Load $_[0]
}

sub to_json($) {
   $JSON::Syck::ImplicitUnicode = 0;  # work around JSON::Syck bugs
   JSON::Syck::Dump $_[0]
}

#############################################################################
# extcmd framework, basically convert ext <msg>
# into pkg::->on_extcmd_arg1 (...) while shortcutting a few

sub on_extcmd {
   my ($pl, $buf) = @_;

   my $msg = eval { from_json $buf };

   if (ref $msg) {
      if (my $cb = $extcmd{$msg->{msgtype}}) {
         if (my %reply = $cb->[0]->($pl, $msg)) {
            $pl->ext_reply ($msg->{msgid}, %reply);
         }
      }
   } else {
      warn "player " . ($pl->ob->name) . " sent unparseable ext message: <$buf>\n";
   }

   1
}

#############################################################################
# load/save/clean perl data associated with a map

*cf::mapsupport::on_clean = sub {
   my ($map) = @_;

   my $path = $map->tmpname;
   defined $path or return;

   unlink "$path.cfperl";
};

*cf::mapsupport::on_swapin =
*cf::mapsupport::on_load = sub {
   my ($map) = @_;

   my $path = $map->tmpname;
   $path = $map->path unless defined $path;

   open my $fh, "<:raw", "$path.cfperl"
      or return; # no perl data

   my $data = Storable::thaw do { local $/; <$fh> };

   $data->{version} <= 1
      or return; # too new

   $map->_set_obs ($data->{obs});
};

*cf::mapsupport::on_swapout = sub {
   my ($map) = @_;

   my $path = $map->tmpname;
   $path = $map->path unless defined $path;

   my $obs = $map->_get_obs;

   if (defined $obs) {
      open my $fh, ">:raw", "$path.cfperl"
         or die "$path.cfperl: $!";

      stat $path;

      print $fh Storable::nfreeze {
         size    => (stat _)[7],
         time    => (stat _)[9],
         version => 1,
         obs     => $obs,
      };

      chmod SAVE_MODE, "$path.cfperl"; # very racy, but cf-compatible *g*
   } else {
      unlink "$path.cfperl";
   }
};

attach_to_maps prio => -10000, package => cf::mapsupport::;

#############################################################################
# load/save perl data associated with player->ob objects

sub all_objects(@) {
   @_, map all_objects ($_->inv), @_
}

attach_to_players
   on_load => sub {
      my ($pl, $path) = @_;

      for my $o (all_objects $pl->ob) {
         if (my $value = $o->get_ob_key_value ("_perl_data")) {
            $o->set_ob_key_value ("_perl_data");

            %$o = %{ Storable::thaw pack "H*", $value };
         }
      }
   },
   on_save => sub {
      my ($pl, $path) = @_;

      $_->set_ob_key_value (_perl_data => unpack "H*", Storable::nfreeze $_)
         for grep %$_, all_objects $pl->ob;
   },
;

#############################################################################
# core extensions - in perl

=item cf::player::exists $login

Returns true when the given account exists.

=cut

sub cf::player::exists($) {
   cf::player::find $_[0]
      or -f sprintf "%s/%s/%s/%s.pl", cf::localdir, cf::playerdir, ($_[0]) x 2;
}

=item $player->reply ($npc, $msg[, $flags])

Sends a message to the player, as if the npc C<$npc> replied. C<$npc>
can be C<undef>. Does the right thing when the player is currently in a
dialogue with the given NPC character.

=cut

# rough implementation of a future "reply" method that works
# with dialog boxes.
sub cf::object::player::reply($$$;$) {
   my ($self, $npc, $msg, $flags) = @_;

   $flags = cf::NDI_BROWN | cf::NDI_UNIQUE unless @_ >= 4;

   if ($self->{record_replies}) {
      push @{ $self->{record_replies} }, [$npc, $msg, $flags];
   } else {
      $msg = $npc->name . " says: $msg" if $npc;
      $self->message ($msg, $flags);
   }
}

=item $player->ext_reply ($msgid, $msgtype, %msg)

Sends an ext reply to the player.

=cut

sub cf::player::ext_reply($$$%) {
   my ($self, $id, %msg) = @_;

   $msg{msgid} = $id;

   $self->send ("ext " . to_json \%msg);
}

#############################################################################
# map scripting support

our $safe = new Safe "ext";
our $safe_hole = new Safe::Hole;

$SIG{FPE} = 'IGNORE';

$safe->permit_only (Opcode::opset qw(:base_core :base_mem :base_orig :base_math sort time));

# here we export the classes and methods available to script code

for (
   ["cf::object"         => qw(contr pay_amount pay_player)],
   ["cf::object::player" => qw(player)],
   ["cf::player"         => qw(peaceful)],
) {
   no strict 'refs';
   my ($pkg, @funs) = @$_;
   *{"ext::$pkg\::$_"} = $safe_hole->wrap (\&{"$pkg\::$_"})
      for @funs;
}

sub safe_eval($;@) {
   my ($code, %vars) = @_;

   my $qcode = $code;
   $qcode =~ s/"/‟/g; # not allowed in #line filenames
   $qcode =~ s/\n/\\n/g;

   local $_;
   local @ext::cf::_safe_eval_args = values %vars;

   $code =
      "do {\n"
      . "my (" . (join ",", map "\$$_", keys %vars) . ") = \@cf::_safe_eval_args;\n"
      . "#line 0 \"{$qcode}\"\n"
      . $code
      . "\n}"
   ;

   sub_generation_inc;
   my @res = wantarray ? $safe->reval ($code) : scalar $safe->reval ($code);
   sub_generation_inc;

   wantarray ? @res : $res[0]
}

sub register_script_function {
   my ($fun, $cb) = @_;

   no strict 'refs';
   *{"ext::$fun"} = $safe_hole->wrap ($cb);
}

#############################################################################
# the server's main()

sub main {
   Event::loop;
}

#############################################################################
# initialisation

register "<global>", __PACKAGE__;

unshift @INC, $LIBDIR;

load_extensions;

$TICK_WATCHER = Event->timer (
   prio => 1,
   at   => $NEXT_TICK || 1,
   cb   => sub {
      cf::server_tick; # one server iteration

      my $NOW = Event::time;
      $NEXT_TICK += $TICK;

      # if we are delayed by four ticks, skip them all
      $NEXT_TICK = $NOW if $NOW >= $NEXT_TICK + $TICK * 4;

      $TICK_WATCHER->at ($NEXT_TICK);
      $TICK_WATCHER->start;
   },
);

1

Revision:	1.40
Committed:	Fri Aug 25 15:21:57 2006 UTC (17 years, 9 months ago) by root
Branch:	MAIN
Changes since 1.39:	+17 -26 lines
Log Message:	Move callback checks to C++ and short-circuit when no callback exists for an event: No perl is touched when an event doesn't have a callback registered, so this is very fast (compared to the old way).
#	Content
1	package cf;
2
3	use Symbol;
4	use List::Util;
5	use Storable;
6	use Opcode;
7	use Safe;
8	use Safe::Hole;
9
10	use Time::HiRes;
11	use Event;
12	$Event::Eval = 1; # no idea why this is required, but it is
13
14	use strict;
15
16	our %COMMAND = ();
17	our @EVENT;
18	our @PLUGIN_EVENT;
19	our %PROP_TYPE;
20	our %PROP_IDX;
21	our $LIBDIR = maps_directory "perl";
22
23	our $TICK = MAX_TIME * 1e-6;
24	our $TICK_WATCHER;
25	our $NEXT_TICK;
26
27	BEGIN {
28	@PLUGIN_EVENT = map lc, @PLUGIN_EVENT;
29
30	*CORE::GLOBAL::warn = sub {
31	my $msg = join "", @_;
32	$msg .= "\n"
33	unless $msg =~ /\n$/;
34
35	print STDERR "cfperl: $msg";
36	LOG llevError, "cfperl: $msg";
37	};
38	}
39
40	my %ignore_set = (MAP_PROP_PATH => 1); # I hate the plug-in api. Deeply!
41
42	# generate property mutators
43	sub prop_gen {
44	my ($prefix, $class) = @_;
45
46	no strict 'refs';
47
48	for my $prop (keys %PROP_TYPE) {
49	$prop =~ /^\Q$prefix\E_(.*$)/ or next;
50	my $sub = lc $1;
51
52	my $type = $PROP_TYPE{$prop};
53	my $idx = $PROP_IDX {$prop};
54
55	{"$class\::get_$sub"} = {"$class\::$sub"} = sub {
56	$_[0]->get_property ($type, $idx)
57	};
58
59	*{"$class\::set_$sub"} = sub {
60	$_[0]->set_property ($type, $idx, $_[1]);
61	} unless $ignore_set{$prop};
62	}
63	}
64
65	# auto-generate most of the API
66
67	prop_gen OBJECT_PROP => "cf::object";
68	# CFAPI_OBJECT_ANIMATION?
69	prop_gen PLAYER_PROP => "cf::object::player";
70
71	prop_gen MAP_PROP => "cf::map";
72	prop_gen ARCH_PROP => "cf::arch";
73
74	# guessed hierarchies
75
76	@ext::cf::object::player::ISA = @cf::object::player::ISA = 'cf::object';
77	@ext::cf::object::map::ISA = @cf::object::map::ISA = 'cf::object';
78
79	# we bless all objects into derived classes to force a method lookup
80	# within the Safe compartment.
81	for my $pkg (qw(cf::object cf::object::map cf::object::player cf::player cf::map cf::party cf::region cf::arch)) {
82	no strict 'refs';
83	@{"ext::$pkg\::wrap::ISA"} = @{"$pkg\::wrap::ISA"} = $pkg;
84	}
85
86	$Event::DIED = sub {
87	warn "error in event callback: @_";
88	};
89
90	my %ext_pkg;
91	my @exts;
92	my @hook;
93	my %command;
94	my %extcmd;
95
96	#############################################################################
97	# "new" plug-in system
98
99	=item cf::object::attach ... # NYI
100
101	=item cf::attach_global ...
102
103	=item cf::attach_to_type ...
104
105	=item cf::attach_to_objects ...
106
107	=item cf::attach_to_players ...
108
109	=item cf::attach_to_maps ...
110
111	prio => $number, # lower is earlier
112	on_xxx => \&cb,
113	package => package::,
114
115	=cut
116
117	# the following variables are defined in .xs and must not be re-created
118	our @CB_GLOBAL = (); # registry for all global events
119	our @CB_OBJECT = ();
120	our @CB_PLAYER = ();
121	our @CB_TYPE = (); # registry for type (cf-object class) based events
122	our @CB_MAP = ();
123
124	sub _attach_cb($\%$$$) {
125	my ($registry, $undo, $event, $prio, $cb) = @_;
126
127	use sort 'stable';
128
129	$cb = [$prio, $cb];
130
131	@{$registry->[$event]} = sort
132	{ $a->[0] cmp $b->[0] }
133	@{$registry->[$event] \|\| []}, $cb;
134
135	push @{$undo->{cb}}, [$event, $cb];
136	}
137
138	# attach handles attaching event callbacks
139	# the only thing the caller has to do is pass the correct
140	# registry (== where the callback attaches to).
141	sub _attach(\@$\@) {
142	my ($registry, $klass, $arg) = @_;
143
144	my $prio = 0;
145
146	my %undo = (
147	registry => $registry,
148	cb => [],
149	);
150
151	my %cb_id = map +("on_" . lc $EVENT[$_][0], $_) , grep $EVENT[$_][1] == $klass, 0 .. $#EVENT;
152
153	while (@$arg) {
154	my $type = shift @$arg;
155
156	if ($type eq "prio") {
157	$prio = shift @$arg;
158
159	} elsif ($type eq "package") {
160	my $pkg = shift @$arg;
161
162	while (my ($name, $id) = each %cb_id) {
163	if (my $cb = $pkg->can ($name)) {
164	_attach_cb $registry, %undo, $id, $prio, $cb;
165	}
166	}
167
168	} elsif (exists $cb_id{$type}) {
169	_attach_cb $registry, %undo, $cb_id{$type}, $prio, shift @$arg;
170
171	} elsif (ref $type) {
172	warn "attaching objects not supported, ignoring.\n";
173
174	} else {
175	shift @$arg;
176	warn "attach argument '$type' not supported, ignoring.\n";
177	}
178	}
179
180	\%undo
181	}
182
183	sub cf::object::attach {
184	die;
185	}
186
187	sub attach_global {
188	_attach @CB_GLOBAL, KLASS_GLOBAL, @_
189	}
190
191	sub attach_to_type {
192	my $type = shift;
193	_attach @{$CB_TYPE[$type]}, KLASS_OBJECT, @_
194	}
195
196	sub attach_to_objects {
197	_attach @CB_OBJECT, KLASS_OBJECT, @_
198	}
199
200	sub attach_to_players {
201	_attach @CB_PLAYER, KLASS_PLAYER, @_
202	}
203
204	sub attach_to_maps {
205	_attach @CB_MAP, KLASS_MAP, @_
206	}
207
208	our $override;
209
210	sub override() {
211	$override = 1
212	}
213
214	sub invoke {
215	my $event = shift;
216	my $callbacks = shift;
217
218	local $override;
219
220	for (@$callbacks) {
221	eval { &{$_->[1]} };
222
223	if ($@) {
224	warn "$@";
225	warn "... while processing $EVENT[$event][0] event, skipping processing altogether.\n";
226	override;
227	}
228
229	return 1 if $override;
230	}
231
232	0
233	}
234
235	#############################################################################
236	# old plug-in events
237
238	sub inject_event {
239	my $extension = shift;
240	my $event_code = shift;
241
242	my $cb = $hook[$event_code]{$extension}
243	or return;
244
245	&$cb
246	}
247
248	sub inject_global_event {
249	my $event = shift;
250
251	my $cb = $hook[$event]
252	or return;
253
254	List::Util::max map &$_, values %$cb
255	}
256
257	sub inject_command {
258	my ($name, $obj, $params) = @_;
259
260	for my $cmd (@{ $command{$name} }) {
261	$cmd->[1]->($obj, $params);
262	}
263
264	-1
265	}
266
267	sub register_command {
268	my ($name, $time, $cb) = @_;
269
270	my $caller = caller;
271	#warn "registering command '$name/$time' to '$caller'";
272
273	push @{ $command{$name} }, [$time, $cb, $caller];
274	$COMMAND{"$name\000"} = List::Util::max map $_->[0], @{ $command{$name} };
275	}
276
277	sub register_extcmd {
278	my ($name, $cb) = @_;
279
280	my $caller = caller;
281	#warn "registering extcmd '$name' to '$caller'";
282
283	$extcmd{$name} = [$cb, $caller];
284	}
285
286	sub register {
287	my ($base, $pkg) = @_;
288
289	for my $idx (0 .. $#PLUGIN_EVENT) {
290	if (my $ref = $pkg->can ("on_$PLUGIN_EVENT[$idx]")) {
291	#warn "registering $PLUGIN_EVENT[$idx] hook to '$pkg'\n";
292	$hook[$idx]{$base} = $ref;
293	}
294	}
295	}
296
297	sub load_extension {
298	my ($path) = @_;
299
300	$path =~ /([^\/\\]+)\.ext$/ or die "$path";
301	my $base = $1;
302	my $pkg = $1;
303	$pkg =~ s/[^[:word:]]/_/g;
304	$pkg = "cf::ext::$pkg";
305
306	warn "loading '$path' into '$pkg'\n";
307
308	open my $fh, "<:utf8", $path
309	or die "$path: $!";
310
311	my $source =
312	"package $pkg; use strict; use utf8;\n"
313	. "#line 1 \"$path\"\n{\n"
314	. (do { local $/; <$fh> })
315	. "\n};\n1";
316
317	eval $source
318	or die "$path: $@";
319
320	push @exts, $pkg;
321	$ext_pkg{$base} = $pkg;
322
323	# no strict 'refs';
324	# @{"$pkg\::ISA"} = ext::;
325
326	register $base, $pkg;
327	}
328
329	sub unload_extension {
330	my ($pkg) = @_;
331
332	warn "removing extension $pkg\n";
333
334	# remove hooks
335	for my $idx (0 .. $#PLUGIN_EVENT) {
336	delete $hook[$idx]{$pkg};
337	}
338
339	# remove commands
340	for my $name (keys %command) {
341	my @cb = grep $_->[2] ne $pkg, @{ $command{$name} };
342
343	if (@cb) {
344	$command{$name} = \@cb;
345	$COMMAND{"$name\000"} = List::Util::max map $_->[0], @cb;
346	} else {
347	delete $command{$name};
348	delete $COMMAND{"$name\000"};
349	}
350	}
351
352	# remove extcmds
353	for my $name (grep $extcmd{$_}[1] eq $pkg, keys %extcmd) {
354	delete $extcmd{$name};
355	}
356
357	if (my $cb = $pkg->can ("on_unload")) {
358	eval {
359	$cb->($pkg);
360	1
361	} or warn "$pkg unloaded, but with errors: $@";
362	}
363
364	Symbol::delete_package $pkg;
365	}
366
367	sub load_extensions {
368	my $LIBDIR = maps_directory "perl";
369
370	for my $ext (<$LIBDIR/*.ext>) {
371	next unless -r $ext;
372	eval {
373	load_extension $ext;
374	1
375	} or warn "$ext not loaded: $@";
376	}
377	}
378
379	sub _perl_reload(&) {
380	my ($msg) = @_;
381
382	$msg->("reloading...");
383
384	eval {
385	# 1. cancel all watchers
386	$_->cancel for Event::all_watchers;
387
388	# 2. unload all extensions
389	for (@exts) {
390	$msg->("unloading <$_>");
391	unload_extension $_;
392	}
393
394	# 3. unload all modules loaded from $LIBDIR
395	while (my ($k, $v) = each %INC) {
396	next unless $v =~ /^\Q$LIBDIR\E\/.*\.pm$/;
397
398	$msg->("removing <$k>");
399	delete $INC{$k};
400
401	$k =~ s/\.pm$//;
402	$k =~ s/\//::/g;
403
404	if (my $cb = $k->can ("unload_module")) {
405	$cb->();
406	}
407
408	Symbol::delete_package $k;
409	}
410
411	# 4. get rid of ext::, as good as possible
412	Symbol::delete_package "ext::$_"
413	for qw(cf::object cf::object::map cf::object::player cf::player cf::map cf::party cf::region);
414
415	# 5. remove register_script_function callbacks
416	# TODO
417
418	# 6. unload cf.pm "a bit"
419	delete $INC{"cf.pm"};
420
421	# don't, removes xs symbols, too
422	#Symbol::delete_package __PACKAGE__;
423
424	# 7. reload cf.pm
425	$msg->("reloading cf.pm");
426	require cf;
427	};
428	$msg->($@) if $@;
429
430	$msg->("reloaded");
431	};
432
433	sub perl_reload() {
434	_perl_reload {
435	warn $_[0];
436	print "$_[0]\n";
437	};
438	}
439
440	register_command "perl-reload", 0, sub {
441	my ($who, $arg) = @_;
442
443	if ($who->flag (FLAG_WIZ)) {
444	_perl_reload {
445	warn $_[0];
446	$who->message ($_[0]);
447	};
448	}
449	};
450
451	#############################################################################
452	# utility functions
453
454	use JSON::Syck (); # TODO# replace by JSON::PC once working
455
456	sub from_json($) {
457	$JSON::Syck::ImplicitUnicode = 1; # work around JSON::Syck bugs
458	JSON::Syck::Load $_[0]
459	}
460
461	sub to_json($) {
462	$JSON::Syck::ImplicitUnicode = 0; # work around JSON::Syck bugs
463	JSON::Syck::Dump $_[0]
464	}
465
466	#############################################################################
467	# extcmd framework, basically convert ext <msg>
468	# into pkg::->on_extcmd_arg1 (...) while shortcutting a few
469
470	sub on_extcmd {
471	my ($pl, $buf) = @_;
472
473	my $msg = eval { from_json $buf };
474
475	if (ref $msg) {
476	if (my $cb = $extcmd{$msg->{msgtype}}) {
477	if (my %reply = $cb->[0]->($pl, $msg)) {
478	$pl->ext_reply ($msg->{msgid}, %reply);
479	}
480	}
481	} else {
482	warn "player " . ($pl->ob->name) . " sent unparseable ext message: <$buf>\n";
483	}
484
485	1
486	}
487
488	#############################################################################
489	# load/save/clean perl data associated with a map
490
491	*cf::mapsupport::on_clean = sub {
492	my ($map) = @_;
493
494	my $path = $map->tmpname;
495	defined $path or return;
496
497	unlink "$path.cfperl";
498	};
499
500	*cf::mapsupport::on_swapin =
501	*cf::mapsupport::on_load = sub {
502	my ($map) = @_;
503
504	my $path = $map->tmpname;
505	$path = $map->path unless defined $path;
506
507	open my $fh, "<:raw", "$path.cfperl"
508	or return; # no perl data
509
510	my $data = Storable::thaw do { local $/; <$fh> };
511
512	$data->{version} <= 1
513	or return; # too new
514
515	$map->_set_obs ($data->{obs});
516	};
517
518	*cf::mapsupport::on_swapout = sub {
519	my ($map) = @_;
520
521	my $path = $map->tmpname;
522	$path = $map->path unless defined $path;
523
524	my $obs = $map->_get_obs;
525
526	if (defined $obs) {
527	open my $fh, ">:raw", "$path.cfperl"
528	or die "$path.cfperl: $!";
529
530	stat $path;
531
532	print $fh Storable::nfreeze {
533	size => (stat _)[7],
534	time => (stat _)[9],
535	version => 1,
536	obs => $obs,
537	};
538
539	chmod SAVE_MODE, "$path.cfperl"; # very racy, but cf-compatible g
540	} else {
541	unlink "$path.cfperl";
542	}
543	};
544
545	attach_to_maps prio => -10000, package => cf::mapsupport::;
546
547	#############################################################################
548	# load/save perl data associated with player->ob objects
549
550	sub all_objects(@) {
551	@_, map all_objects ($_->inv), @_
552	}
553
554	attach_to_players
555	on_load => sub {
556	my ($pl, $path) = @_;
557
558	for my $o (all_objects $pl->ob) {
559	if (my $value = $o->get_ob_key_value ("_perl_data")) {
560	$o->set_ob_key_value ("_perl_data");
561
562	%$o = %{ Storable::thaw pack "H*", $value };
563	}
564	}
565	},
566	on_save => sub {
567	my ($pl, $path) = @_;
568
569	$_->set_ob_key_value (_perl_data => unpack "H*", Storable::nfreeze $_)
570	for grep %$_, all_objects $pl->ob;
571	},
572	;
573
574	#############################################################################
575	# core extensions - in perl
576
577	=item cf::player::exists $login
578
579	Returns true when the given account exists.
580
581	=cut
582
583	sub cf::player::exists($) {
584	cf::player::find $_[0]
585	or -f sprintf "%s/%s/%s/%s.pl", cf::localdir, cf::playerdir, ($_[0]) x 2;
586	}
587
588	=item $player->reply ($npc, $msg[, $flags])
589
590	Sends a message to the player, as if the npc C<$npc> replied. C<$npc>
591	can be C<undef>. Does the right thing when the player is currently in a
592	dialogue with the given NPC character.
593
594	=cut
595
596	# rough implementation of a future "reply" method that works
597	# with dialog boxes.
598	sub cf::object::player::reply($$$;$) {
599	my ($self, $npc, $msg, $flags) = @_;
600
601	$flags = cf::NDI_BROWN \| cf::NDI_UNIQUE unless @_ >= 4;
602
603	if ($self->{record_replies}) {
604	push @{ $self->{record_replies} }, [$npc, $msg, $flags];
605	} else {
606	$msg = $npc->name . " says: $msg" if $npc;
607	$self->message ($msg, $flags);
608	}
609	}
610
611	=item $player->ext_reply ($msgid, $msgtype, %msg)
612
613	Sends an ext reply to the player.
614
615	=cut
616
617	sub cf::player::ext_reply($$$%) {
618	my ($self, $id, %msg) = @_;
619
620	$msg{msgid} = $id;
621
622	$self->send ("ext " . to_json \%msg);
623	}
624
625	#############################################################################
626	# map scripting support
627
628	our $safe = new Safe "ext";
629	our $safe_hole = new Safe::Hole;
630
631	$SIG{FPE} = 'IGNORE';
632
633	$safe->permit_only (Opcode::opset qw(:base_core :base_mem :base_orig :base_math sort time));
634
635	# here we export the classes and methods available to script code
636
637	for (
638	["cf::object" => qw(contr pay_amount pay_player)],
639	["cf::object::player" => qw(player)],
640	["cf::player" => qw(peaceful)],
641	) {
642	no strict 'refs';
643	my ($pkg, @funs) = @$_;
644	*{"ext::$pkg\::$_"} = $safe_hole->wrap (\&{"$pkg\::$_"})
645	for @funs;
646	}
647
648	sub safe_eval($;@) {
649	my ($code, %vars) = @_;
650
651	my $qcode = $code;
652	$qcode =~ s/"/‟/g; # not allowed in #line filenames
653	$qcode =~ s/\n/\\n/g;
654
655	local $_;
656	local @ext::cf::_safe_eval_args = values %vars;
657
658	$code =
659	"do {\n"
660	. "my (" . (join ",", map "\$$_", keys %vars) . ") = \@cf::_safe_eval_args;\n"
661	. "#line 0 \"{$qcode}\"\n"
662	. $code
663	. "\n}"
664	;
665
666	sub_generation_inc;
667	my @res = wantarray ? $safe->reval ($code) : scalar $safe->reval ($code);
668	sub_generation_inc;
669
670	wantarray ? @res : $res[0]
671	}
672
673	sub register_script_function {
674	my ($fun, $cb) = @_;
675
676	no strict 'refs';
677	*{"ext::$fun"} = $safe_hole->wrap ($cb);
678	}
679
680	#############################################################################
681	# the server's main()
682
683	sub main {
684	Event::loop;
685	}
686
687	#############################################################################
688	# initialisation
689
690	register "<global>", __PACKAGE__;
691
692	unshift @INC, $LIBDIR;
693
694	load_extensions;
695
696	$TICK_WATCHER = Event->timer (
697	prio => 1,
698	at => $NEXT_TICK \|\| 1,
699	cb => sub {
700	cf::server_tick; # one server iteration
701
702	my $NOW = Event::time;
703	$NEXT_TICK += $TICK;
704
705	# if we are delayed by four ticks, skip them all
706	$NEXT_TICK = $NOW if $NOW >= $NEXT_TICK + $TICK * 4;
707
708	$TICK_WATCHER->at ($NEXT_TICK);
709	$TICK_WATCHER->start;
710	},
711	);
712
713	1
714