| 1 |
package cf; |
| 2 |
|
| 3 |
use Symbol; |
| 4 |
use List::Util; |
| 5 |
use Storable; |
| 6 |
use Opcode; |
| 7 |
use Safe; |
| 8 |
use Safe::Hole; |
| 9 |
|
| 10 |
use Time::HiRes; |
| 11 |
use Event; |
| 12 |
$Event::Eval = 1; # no idea why this is required, but it is |
| 13 |
|
| 14 |
use strict; |
| 15 |
|
| 16 |
our %COMMAND = (); |
| 17 |
our @EVENT; |
| 18 |
our @PLUGIN_EVENT; |
| 19 |
our %PROP_TYPE; |
| 20 |
our %PROP_IDX; |
| 21 |
our $LIBDIR = maps_directory "perl"; |
| 22 |
|
| 23 |
our $TICK = MAX_TIME * 1e-6; |
| 24 |
our $TICK_WATCHER; |
| 25 |
our $NEXT_TICK; |
| 26 |
|
| 27 |
BEGIN { |
| 28 |
@PLUGIN_EVENT = map lc, @PLUGIN_EVENT; |
| 29 |
|
| 30 |
*CORE::GLOBAL::warn = sub { |
| 31 |
my $msg = join "", @_; |
| 32 |
$msg .= "\n" |
| 33 |
unless $msg =~ /\n$/; |
| 34 |
|
| 35 |
print STDERR "cfperl: $msg"; |
| 36 |
LOG llevError, "cfperl: $msg"; |
| 37 |
}; |
| 38 |
} |
| 39 |
|
| 40 |
my %ignore_set = (MAP_PROP_PATH => 1); # I hate the plug-in api. Deeply! |
| 41 |
|
| 42 |
# generate property mutators |
| 43 |
sub prop_gen { |
| 44 |
my ($prefix, $class) = @_; |
| 45 |
|
| 46 |
no strict 'refs'; |
| 47 |
|
| 48 |
for my $prop (keys %PROP_TYPE) { |
| 49 |
$prop =~ /^\Q$prefix\E_(.*$)/ or next; |
| 50 |
my $sub = lc $1; |
| 51 |
|
| 52 |
my $type = $PROP_TYPE{$prop}; |
| 53 |
my $idx = $PROP_IDX {$prop}; |
| 54 |
|
| 55 |
*{"$class\::get_$sub"} = *{"$class\::$sub"} = sub { |
| 56 |
$_[0]->get_property ($type, $idx) |
| 57 |
}; |
| 58 |
|
| 59 |
*{"$class\::set_$sub"} = sub { |
| 60 |
$_[0]->set_property ($type, $idx, $_[1]); |
| 61 |
} unless $ignore_set{$prop}; |
| 62 |
} |
| 63 |
} |
| 64 |
|
| 65 |
# auto-generate most of the API |
| 66 |
|
| 67 |
prop_gen OBJECT_PROP => "cf::object"; |
| 68 |
# CFAPI_OBJECT_ANIMATION? |
| 69 |
prop_gen PLAYER_PROP => "cf::object::player"; |
| 70 |
|
| 71 |
prop_gen MAP_PROP => "cf::map"; |
| 72 |
prop_gen ARCH_PROP => "cf::arch"; |
| 73 |
|
| 74 |
# guessed hierarchies |
| 75 |
|
| 76 |
@safe::cf::object::player::ISA = @cf::object::player::ISA = 'cf::object'; |
| 77 |
@safe::cf::object::map::ISA = @cf::object::map::ISA = 'cf::object'; |
| 78 |
|
| 79 |
# we bless all objects into (empty) derived classes to force a method lookup |
| 80 |
# within the Safe compartment. |
| 81 |
for my $pkg (qw(cf::object cf::object::map cf::object::player cf::player cf::map cf::party cf::region cf::arch)) { |
| 82 |
no strict 'refs'; |
| 83 |
@{"safe::$pkg\::wrap::ISA"} = @{"$pkg\::wrap::ISA"} = $pkg; |
| 84 |
} |
| 85 |
|
| 86 |
$Event::DIED = sub { |
| 87 |
warn "error in event callback: @_"; |
| 88 |
}; |
| 89 |
|
| 90 |
my %ext_pkg; |
| 91 |
my @exts; |
| 92 |
my @hook; |
| 93 |
my %command; |
| 94 |
my %extcmd; |
| 95 |
|
| 96 |
############################################################################# |
| 97 |
# "new" plug-in system |
| 98 |
|
| 99 |
=item cf::object::attach ... # NYI |
| 100 |
|
| 101 |
=item cf::attach_global ... |
| 102 |
|
| 103 |
=item cf::attach_to_type ... |
| 104 |
|
| 105 |
=item cf::attach_to_objects ... |
| 106 |
|
| 107 |
=item cf::attach_to_players ... |
| 108 |
|
| 109 |
=item cf::attach_to_maps ... |
| 110 |
|
| 111 |
prio => $number, # lower is earlier |
| 112 |
on_xxx => \&cb, |
| 113 |
package => package::, |
| 114 |
|
| 115 |
=cut |
| 116 |
|
| 117 |
# the following variables are defined in .xs and must not be re-created |
| 118 |
our @CB_GLOBAL = (); # registry for all global events |
| 119 |
our @CB_OBJECT = (); |
| 120 |
our @CB_PLAYER = (); |
| 121 |
our @CB_TYPE = (); # registry for type (cf-object class) based events |
| 122 |
our @CB_MAP = (); |
| 123 |
|
| 124 |
sub _attach_cb($\%$$$) { |
| 125 |
my ($registry, $undo, $event, $prio, $cb) = @_; |
| 126 |
|
| 127 |
use sort 'stable'; |
| 128 |
|
| 129 |
$cb = [$prio, $cb]; |
| 130 |
|
| 131 |
@{$registry->[$event]} = sort |
| 132 |
{ $a->[0] cmp $b->[0] } |
| 133 |
@{$registry->[$event] || []}, $cb; |
| 134 |
|
| 135 |
push @{$undo->{cb}}, [$event, $cb]; |
| 136 |
} |
| 137 |
|
| 138 |
# attach handles attaching event callbacks |
| 139 |
# the only thing the caller has to do is pass the correct |
| 140 |
# registry (== where the callback attaches to). |
| 141 |
sub _attach(\@$\@) { |
| 142 |
my ($registry, $klass, $arg) = @_; |
| 143 |
|
| 144 |
my $prio = 0; |
| 145 |
|
| 146 |
my %undo = ( |
| 147 |
registry => $registry, |
| 148 |
cb => [], |
| 149 |
); |
| 150 |
|
| 151 |
my %cb_id = map +("on_" . lc $EVENT[$_][0], $_) , grep $EVENT[$_][1] == $klass, 0 .. $#EVENT; |
| 152 |
|
| 153 |
while (@$arg) { |
| 154 |
my $type = shift @$arg; |
| 155 |
|
| 156 |
if ($type eq "prio") { |
| 157 |
$prio = shift @$arg; |
| 158 |
|
| 159 |
} elsif ($type eq "package") { |
| 160 |
my $pkg = shift @$arg; |
| 161 |
|
| 162 |
while (my ($name, $id) = each %cb_id) { |
| 163 |
if (my $cb = $pkg->can ($name)) { |
| 164 |
_attach_cb $registry, %undo, $id, $prio, $cb; |
| 165 |
} |
| 166 |
} |
| 167 |
|
| 168 |
} elsif (exists $cb_id{$type}) { |
| 169 |
_attach_cb $registry, %undo, $cb_id{$type}, $prio, shift @$arg; |
| 170 |
|
| 171 |
} elsif (ref $type) { |
| 172 |
warn "attaching objects not supported, ignoring.\n"; |
| 173 |
|
| 174 |
} else { |
| 175 |
shift @$arg; |
| 176 |
warn "attach argument '$type' not supported, ignoring.\n"; |
| 177 |
} |
| 178 |
} |
| 179 |
|
| 180 |
\%undo |
| 181 |
} |
| 182 |
|
| 183 |
sub cf::object::attach { |
| 184 |
die; |
| 185 |
} |
| 186 |
|
| 187 |
sub attach_global { |
| 188 |
_attach @CB_GLOBAL, KLASS_GLOBAL, @_ |
| 189 |
} |
| 190 |
|
| 191 |
sub attach_to_type { |
| 192 |
my $type = shift; |
| 193 |
_attach @{$CB_TYPE[$type]}, KLASS_OBJECT, @_ |
| 194 |
} |
| 195 |
|
| 196 |
sub attach_to_objects { |
| 197 |
_attach @CB_OBJECT, KLASS_OBJECT, @_ |
| 198 |
} |
| 199 |
|
| 200 |
sub attach_to_players { |
| 201 |
_attach @CB_PLAYER, KLASS_PLAYER, @_ |
| 202 |
} |
| 203 |
|
| 204 |
sub attach_to_maps { |
| 205 |
_attach @CB_MAP, KLASS_MAP, @_ |
| 206 |
} |
| 207 |
|
| 208 |
our $override; |
| 209 |
|
| 210 |
sub override() { |
| 211 |
$override = 1 |
| 212 |
} |
| 213 |
|
| 214 |
sub invoke { |
| 215 |
my $event = shift; |
| 216 |
my $callbacks = shift; |
| 217 |
|
| 218 |
local $override; |
| 219 |
|
| 220 |
for (@$callbacks) { |
| 221 |
eval { &{$_->[1]} }; |
| 222 |
|
| 223 |
if ($@) { |
| 224 |
warn "$@"; |
| 225 |
warn "... while processing $EVENT[$event][0] event, skipping processing altogether.\n"; |
| 226 |
override; |
| 227 |
} |
| 228 |
|
| 229 |
return 1 if $override; |
| 230 |
} |
| 231 |
|
| 232 |
0 |
| 233 |
} |
| 234 |
|
| 235 |
############################################################################# |
| 236 |
# old plug-in events |
| 237 |
|
| 238 |
sub inject_event { |
| 239 |
my $extension = shift; |
| 240 |
my $event_code = shift; |
| 241 |
|
| 242 |
my $cb = $hook[$event_code]{$extension} |
| 243 |
or return; |
| 244 |
|
| 245 |
&$cb |
| 246 |
} |
| 247 |
|
| 248 |
sub inject_global_event { |
| 249 |
my $event = shift; |
| 250 |
|
| 251 |
my $cb = $hook[$event] |
| 252 |
or return; |
| 253 |
|
| 254 |
List::Util::max map &$_, values %$cb |
| 255 |
} |
| 256 |
|
| 257 |
sub inject_command { |
| 258 |
my ($name, $obj, $params) = @_; |
| 259 |
|
| 260 |
for my $cmd (@{ $command{$name} }) { |
| 261 |
$cmd->[1]->($obj, $params); |
| 262 |
} |
| 263 |
|
| 264 |
-1 |
| 265 |
} |
| 266 |
|
| 267 |
sub register_command { |
| 268 |
my ($name, $time, $cb) = @_; |
| 269 |
|
| 270 |
my $caller = caller; |
| 271 |
#warn "registering command '$name/$time' to '$caller'"; |
| 272 |
|
| 273 |
push @{ $command{$name} }, [$time, $cb, $caller]; |
| 274 |
$COMMAND{"$name\000"} = List::Util::max map $_->[0], @{ $command{$name} }; |
| 275 |
} |
| 276 |
|
| 277 |
sub register_extcmd { |
| 278 |
my ($name, $cb) = @_; |
| 279 |
|
| 280 |
my $caller = caller; |
| 281 |
#warn "registering extcmd '$name' to '$caller'"; |
| 282 |
|
| 283 |
$extcmd{$name} = [$cb, $caller]; |
| 284 |
} |
| 285 |
|
| 286 |
sub register { |
| 287 |
my ($base, $pkg) = @_; |
| 288 |
|
| 289 |
for my $idx (0 .. $#PLUGIN_EVENT) { |
| 290 |
if (my $ref = $pkg->can ("on_$PLUGIN_EVENT[$idx]")) { |
| 291 |
#warn "registering $PLUGIN_EVENT[$idx] hook to '$pkg'\n"; |
| 292 |
$hook[$idx]{$base} = $ref; |
| 293 |
} |
| 294 |
} |
| 295 |
} |
| 296 |
|
| 297 |
sub load_extension { |
| 298 |
my ($path) = @_; |
| 299 |
|
| 300 |
$path =~ /([^\/\\]+)\.ext$/ or die "$path"; |
| 301 |
my $base = $1; |
| 302 |
my $pkg = $1; |
| 303 |
$pkg =~ s/[^[:word:]]/_/g; |
| 304 |
$pkg = "ext::$pkg"; |
| 305 |
|
| 306 |
warn "loading '$path' into '$pkg'\n"; |
| 307 |
|
| 308 |
open my $fh, "<:utf8", $path |
| 309 |
or die "$path: $!"; |
| 310 |
|
| 311 |
my $source = |
| 312 |
"package $pkg; use strict; use utf8;\n" |
| 313 |
. "#line 1 \"$path\"\n{\n" |
| 314 |
. (do { local $/; <$fh> }) |
| 315 |
. "\n};\n1"; |
| 316 |
|
| 317 |
eval $source |
| 318 |
or die "$path: $@"; |
| 319 |
|
| 320 |
push @exts, $pkg; |
| 321 |
$ext_pkg{$base} = $pkg; |
| 322 |
|
| 323 |
# no strict 'refs'; |
| 324 |
# @{"$pkg\::ISA"} = ext::; |
| 325 |
|
| 326 |
register $base, $pkg; |
| 327 |
} |
| 328 |
|
| 329 |
sub unload_extension { |
| 330 |
my ($pkg) = @_; |
| 331 |
|
| 332 |
warn "removing extension $pkg\n"; |
| 333 |
|
| 334 |
# remove hooks |
| 335 |
for my $idx (0 .. $#PLUGIN_EVENT) { |
| 336 |
delete $hook[$idx]{$pkg}; |
| 337 |
} |
| 338 |
|
| 339 |
# remove commands |
| 340 |
for my $name (keys %command) { |
| 341 |
my @cb = grep $_->[2] ne $pkg, @{ $command{$name} }; |
| 342 |
|
| 343 |
if (@cb) { |
| 344 |
$command{$name} = \@cb; |
| 345 |
$COMMAND{"$name\000"} = List::Util::max map $_->[0], @cb; |
| 346 |
} else { |
| 347 |
delete $command{$name}; |
| 348 |
delete $COMMAND{"$name\000"}; |
| 349 |
} |
| 350 |
} |
| 351 |
|
| 352 |
# remove extcmds |
| 353 |
for my $name (grep $extcmd{$_}[1] eq $pkg, keys %extcmd) { |
| 354 |
delete $extcmd{$name}; |
| 355 |
} |
| 356 |
|
| 357 |
if (my $cb = $pkg->can ("on_unload")) { |
| 358 |
eval { |
| 359 |
$cb->($pkg); |
| 360 |
1 |
| 361 |
} or warn "$pkg unloaded, but with errors: $@"; |
| 362 |
} |
| 363 |
|
| 364 |
Symbol::delete_package $pkg; |
| 365 |
} |
| 366 |
|
| 367 |
sub load_extensions { |
| 368 |
my $LIBDIR = maps_directory "perl"; |
| 369 |
|
| 370 |
for my $ext (<$LIBDIR/*.ext>) { |
| 371 |
next unless -r $ext; |
| 372 |
eval { |
| 373 |
load_extension $ext; |
| 374 |
1 |
| 375 |
} or warn "$ext not loaded: $@"; |
| 376 |
} |
| 377 |
} |
| 378 |
|
| 379 |
sub _perl_reload(&) { |
| 380 |
my ($msg) = @_; |
| 381 |
|
| 382 |
$msg->("reloading..."); |
| 383 |
|
| 384 |
eval { |
| 385 |
# 1. cancel all watchers |
| 386 |
$_->cancel for Event::all_watchers; |
| 387 |
|
| 388 |
# 2. unload all extensions |
| 389 |
for (@exts) { |
| 390 |
$msg->("unloading <$_>"); |
| 391 |
unload_extension $_; |
| 392 |
} |
| 393 |
|
| 394 |
# 3. unload all modules loaded from $LIBDIR |
| 395 |
while (my ($k, $v) = each %INC) { |
| 396 |
next unless $v =~ /^\Q$LIBDIR\E\/.*\.pm$/; |
| 397 |
|
| 398 |
$msg->("removing <$k>"); |
| 399 |
delete $INC{$k}; |
| 400 |
|
| 401 |
$k =~ s/\.pm$//; |
| 402 |
$k =~ s/\//::/g; |
| 403 |
|
| 404 |
if (my $cb = $k->can ("unload_module")) { |
| 405 |
$cb->(); |
| 406 |
} |
| 407 |
|
| 408 |
Symbol::delete_package $k; |
| 409 |
} |
| 410 |
|
| 411 |
# 4. get rid of safe::, as good as possible |
| 412 |
Symbol::delete_package "safe::$_" |
| 413 |
for qw(cf::object cf::object::map cf::object::player cf::player cf::map cf::party cf::region); |
| 414 |
|
| 415 |
# 5. remove register_script_function callbacks |
| 416 |
# TODO |
| 417 |
|
| 418 |
# 6. unload cf.pm "a bit" |
| 419 |
delete $INC{"cf.pm"}; |
| 420 |
|
| 421 |
# don't, removes xs symbols, too, |
| 422 |
# and global variables created in xs |
| 423 |
#Symbol::delete_package __PACKAGE__; |
| 424 |
|
| 425 |
# 7. reload cf.pm |
| 426 |
$msg->("reloading cf.pm"); |
| 427 |
require cf; |
| 428 |
}; |
| 429 |
$msg->($@) if $@; |
| 430 |
|
| 431 |
$msg->("reloaded"); |
| 432 |
}; |
| 433 |
|
| 434 |
sub perl_reload() { |
| 435 |
_perl_reload { |
| 436 |
warn $_[0]; |
| 437 |
print "$_[0]\n"; |
| 438 |
}; |
| 439 |
} |
| 440 |
|
| 441 |
register_command "perl-reload", 0, sub { |
| 442 |
my ($who, $arg) = @_; |
| 443 |
|
| 444 |
if ($who->flag (FLAG_WIZ)) { |
| 445 |
_perl_reload { |
| 446 |
warn $_[0]; |
| 447 |
$who->message ($_[0]); |
| 448 |
}; |
| 449 |
} |
| 450 |
}; |
| 451 |
|
| 452 |
############################################################################# |
| 453 |
# utility functions |
| 454 |
|
| 455 |
use JSON::Syck (); # TODO# replace by JSON::PC once working |
| 456 |
|
| 457 |
sub from_json($) { |
| 458 |
$JSON::Syck::ImplicitUnicode = 1; # work around JSON::Syck bugs |
| 459 |
JSON::Syck::Load $_[0] |
| 460 |
} |
| 461 |
|
| 462 |
sub to_json($) { |
| 463 |
$JSON::Syck::ImplicitUnicode = 0; # work around JSON::Syck bugs |
| 464 |
JSON::Syck::Dump $_[0] |
| 465 |
} |
| 466 |
|
| 467 |
############################################################################# |
| 468 |
# extcmd framework, basically convert ext <msg> |
| 469 |
# into pkg::->on_extcmd_arg1 (...) while shortcutting a few |
| 470 |
|
| 471 |
sub on_extcmd { |
| 472 |
my ($pl, $buf) = @_; |
| 473 |
|
| 474 |
my $msg = eval { from_json $buf }; |
| 475 |
|
| 476 |
if (ref $msg) { |
| 477 |
if (my $cb = $extcmd{$msg->{msgtype}}) { |
| 478 |
if (my %reply = $cb->[0]->($pl, $msg)) { |
| 479 |
$pl->ext_reply ($msg->{msgid}, %reply); |
| 480 |
} |
| 481 |
} |
| 482 |
} else { |
| 483 |
warn "player " . ($pl->ob->name) . " sent unparseable ext message: <$buf>\n"; |
| 484 |
} |
| 485 |
|
| 486 |
1 |
| 487 |
} |
| 488 |
|
| 489 |
############################################################################# |
| 490 |
# load/save/clean perl data associated with a map |
| 491 |
|
| 492 |
*cf::mapsupport::on_clean = sub { |
| 493 |
my ($map) = @_; |
| 494 |
|
| 495 |
my $path = $map->tmpname; |
| 496 |
defined $path or return; |
| 497 |
|
| 498 |
unlink "$path.cfperl"; |
| 499 |
}; |
| 500 |
|
| 501 |
*cf::mapsupport::on_swapin = |
| 502 |
*cf::mapsupport::on_load = sub { |
| 503 |
my ($map) = @_; |
| 504 |
|
| 505 |
my $path = $map->tmpname; |
| 506 |
$path = $map->path unless defined $path; |
| 507 |
|
| 508 |
open my $fh, "<:raw", "$path.cfperl" |
| 509 |
or return; # no perl data |
| 510 |
|
| 511 |
my $data = Storable::thaw do { local $/; <$fh> }; |
| 512 |
|
| 513 |
$data->{version} <= 1 |
| 514 |
or return; # too new |
| 515 |
|
| 516 |
$map->_set_obs ($data->{obs}); |
| 517 |
}; |
| 518 |
|
| 519 |
*cf::mapsupport::on_swapout = sub { |
| 520 |
my ($map) = @_; |
| 521 |
|
| 522 |
my $path = $map->tmpname; |
| 523 |
$path = $map->path unless defined $path; |
| 524 |
|
| 525 |
my $obs = $map->_get_obs; |
| 526 |
|
| 527 |
if (defined $obs) { |
| 528 |
open my $fh, ">:raw", "$path.cfperl" |
| 529 |
or die "$path.cfperl: $!"; |
| 530 |
|
| 531 |
stat $path; |
| 532 |
|
| 533 |
print $fh Storable::nfreeze { |
| 534 |
size => (stat _)[7], |
| 535 |
time => (stat _)[9], |
| 536 |
version => 1, |
| 537 |
obs => $obs, |
| 538 |
}; |
| 539 |
|
| 540 |
chmod SAVE_MODE, "$path.cfperl"; # very racy, but cf-compatible *g* |
| 541 |
} else { |
| 542 |
unlink "$path.cfperl"; |
| 543 |
} |
| 544 |
}; |
| 545 |
|
| 546 |
attach_to_maps prio => -10000, package => cf::mapsupport::; |
| 547 |
|
| 548 |
############################################################################# |
| 549 |
# load/save perl data associated with player->ob objects |
| 550 |
|
| 551 |
sub all_objects(@) { |
| 552 |
@_, map all_objects ($_->inv), @_ |
| 553 |
} |
| 554 |
|
| 555 |
attach_to_players |
| 556 |
on_load => sub { |
| 557 |
my ($pl, $path) = @_; |
| 558 |
|
| 559 |
for my $o (all_objects $pl->ob) { |
| 560 |
if (my $value = $o->get_ob_key_value ("_perl_data")) { |
| 561 |
$o->set_ob_key_value ("_perl_data"); |
| 562 |
|
| 563 |
%$o = %{ Storable::thaw pack "H*", $value }; |
| 564 |
} |
| 565 |
} |
| 566 |
}, |
| 567 |
on_save => sub { |
| 568 |
my ($pl, $path) = @_; |
| 569 |
|
| 570 |
$_->set_ob_key_value (_perl_data => unpack "H*", Storable::nfreeze $_) |
| 571 |
for grep %$_, all_objects $pl->ob; |
| 572 |
}, |
| 573 |
; |
| 574 |
|
| 575 |
############################################################################# |
| 576 |
# core extensions - in perl |
| 577 |
|
| 578 |
=item cf::player::exists $login |
| 579 |
|
| 580 |
Returns true when the given account exists. |
| 581 |
|
| 582 |
=cut |
| 583 |
|
| 584 |
sub cf::player::exists($) { |
| 585 |
cf::player::find $_[0] |
| 586 |
or -f sprintf "%s/%s/%s/%s.pl", cf::localdir, cf::playerdir, ($_[0]) x 2; |
| 587 |
} |
| 588 |
|
| 589 |
=item $player->reply ($npc, $msg[, $flags]) |
| 590 |
|
| 591 |
Sends a message to the player, as if the npc C<$npc> replied. C<$npc> |
| 592 |
can be C<undef>. Does the right thing when the player is currently in a |
| 593 |
dialogue with the given NPC character. |
| 594 |
|
| 595 |
=cut |
| 596 |
|
| 597 |
# rough implementation of a future "reply" method that works |
| 598 |
# with dialog boxes. |
| 599 |
sub cf::object::player::reply($$$;$) { |
| 600 |
my ($self, $npc, $msg, $flags) = @_; |
| 601 |
|
| 602 |
$flags = cf::NDI_BROWN | cf::NDI_UNIQUE unless @_ >= 4; |
| 603 |
|
| 604 |
if ($self->{record_replies}) { |
| 605 |
push @{ $self->{record_replies} }, [$npc, $msg, $flags]; |
| 606 |
} else { |
| 607 |
$msg = $npc->name . " says: $msg" if $npc; |
| 608 |
$self->message ($msg, $flags); |
| 609 |
} |
| 610 |
} |
| 611 |
|
| 612 |
=item $player->ext_reply ($msgid, $msgtype, %msg) |
| 613 |
|
| 614 |
Sends an ext reply to the player. |
| 615 |
|
| 616 |
=cut |
| 617 |
|
| 618 |
sub cf::player::ext_reply($$$%) { |
| 619 |
my ($self, $id, %msg) = @_; |
| 620 |
|
| 621 |
$msg{msgid} = $id; |
| 622 |
|
| 623 |
$self->send ("ext " . to_json \%msg); |
| 624 |
} |
| 625 |
|
| 626 |
############################################################################# |
| 627 |
# map scripting support |
| 628 |
|
| 629 |
our $safe = new Safe "safe"; |
| 630 |
our $safe_hole = new Safe::Hole; |
| 631 |
|
| 632 |
$SIG{FPE} = 'IGNORE'; |
| 633 |
|
| 634 |
$safe->permit_only (Opcode::opset qw(:base_core :base_mem :base_orig :base_math sort time)); |
| 635 |
|
| 636 |
# here we export the classes and methods available to script code |
| 637 |
|
| 638 |
for ( |
| 639 |
["cf::object" => qw(contr pay_amount pay_player)], |
| 640 |
["cf::object::player" => qw(player)], |
| 641 |
["cf::player" => qw(peaceful)], |
| 642 |
) { |
| 643 |
no strict 'refs'; |
| 644 |
my ($pkg, @funs) = @$_; |
| 645 |
*{"safe::$pkg\::$_"} = $safe_hole->wrap (\&{"$pkg\::$_"}) |
| 646 |
for @funs; |
| 647 |
} |
| 648 |
|
| 649 |
sub safe_eval($;@) { |
| 650 |
my ($code, %vars) = @_; |
| 651 |
|
| 652 |
my $qcode = $code; |
| 653 |
$qcode =~ s/"/‟/g; # not allowed in #line filenames |
| 654 |
$qcode =~ s/\n/\\n/g; |
| 655 |
|
| 656 |
local $_; |
| 657 |
local @safe::cf::_safe_eval_args = values %vars; |
| 658 |
|
| 659 |
my $eval = |
| 660 |
"do {\n" |
| 661 |
. "my (" . (join ",", map "\$$_", keys %vars) . ") = \@cf::_safe_eval_args;\n" |
| 662 |
. "#line 0 \"{$qcode}\"\n" |
| 663 |
. $code |
| 664 |
. "\n}" |
| 665 |
; |
| 666 |
|
| 667 |
sub_generation_inc; |
| 668 |
my @res = wantarray ? $safe->reval ($eval) : scalar $safe->reval ($eval); |
| 669 |
sub_generation_inc; |
| 670 |
|
| 671 |
if ($@) { |
| 672 |
warn "$@"; |
| 673 |
warn "while executing safe code '$code'\n"; |
| 674 |
warn "with arguments " . (join " ", %vars) . "\n"; |
| 675 |
} |
| 676 |
|
| 677 |
wantarray ? @res : $res[0] |
| 678 |
} |
| 679 |
|
| 680 |
sub register_script_function { |
| 681 |
my ($fun, $cb) = @_; |
| 682 |
|
| 683 |
no strict 'refs'; |
| 684 |
*{"safe::$fun"} = $safe_hole->wrap ($cb); |
| 685 |
} |
| 686 |
|
| 687 |
############################################################################# |
| 688 |
# the server's main() |
| 689 |
|
| 690 |
sub main { |
| 691 |
Event::loop; |
| 692 |
} |
| 693 |
|
| 694 |
############################################################################# |
| 695 |
# initialisation |
| 696 |
|
| 697 |
register "<global>", __PACKAGE__; |
| 698 |
|
| 699 |
unshift @INC, $LIBDIR; |
| 700 |
|
| 701 |
load_extensions; |
| 702 |
|
| 703 |
$TICK_WATCHER = Event->timer ( |
| 704 |
prio => 1, |
| 705 |
at => $NEXT_TICK || 1, |
| 706 |
cb => sub { |
| 707 |
cf::server_tick; # one server iteration |
| 708 |
|
| 709 |
my $NOW = Event::time; |
| 710 |
$NEXT_TICK += $TICK; |
| 711 |
|
| 712 |
# if we are delayed by four ticks, skip them all |
| 713 |
$NEXT_TICK = $NOW if $NOW >= $NEXT_TICK + $TICK * 4; |
| 714 |
|
| 715 |
$TICK_WATCHER->at ($NEXT_TICK); |
| 716 |
$TICK_WATCHER->start; |
| 717 |
}, |
| 718 |
); |
| 719 |
|
| 720 |
1 |
| 721 |
|
