kgsueme/kgsueme/game.pl

use utf8;

package game::goclock;

# Lo and Behold! I admit it! The rounding stuff etc.. in goclock
# is completely borked.

use Time::HiRes ();

use KGS::Constants;

use base gtk::widget;

sub new {
   my $class = shift;
   my $self = $class->SUPER::new(@_);

   $self->{widget} = new Gtk2::Label;

   $self->{set}    = sub { };
   $self->{format} = sub { "ERROR" };

   $self;
}

sub configure {
   my ($self, $timesys, $main, $interval, $count) = @_;

   if ($timesys == TIMESYS_ABSOLUTE) {
      $self->{set}    = sub { $self->{time} = $_[0] };
      $self->{format} = sub { util::format_time $_[0] };

   } elsif ($timesys == TIMESYS_BYO_YOMI) {
      my $low = $interval * $count;

      $self->{set}    = sub { $self->{time} = $_[0] };

      $self->{format} = sub {
         if ($_[0] > $low) {
            util::format_time $_[0] - $low;
         } else {
            sprintf "%s (%d)",
                    util::format_time int (($_[0] - 1) % $interval + 1),
                    ($_[0] - 1) / $interval;
         }
      };

   } elsif ($timesys == TIMESYS_CANADIAN) {
      $self->{set}    = sub { $self->{time} = $_[0]; $self->{moves} = $_[1] };

      $self->{format} = sub {
         if (!$self->{moves}) {
            util::format_time $_[0] - $low;
         } else {
            my $time = int (($_[0] - 1) % $interval + 1);

            sprintf "%s/%d {%d}",
                    util::format_time $time,
                    $self->{moves},
                    $time / ($self->{moves} || 1);

         }
      };

   } else {
      # none, or unknown
      $self->{set}    = sub { };
      $self->{format} = sub { "---" }
   }
}

sub refresh {
   my ($self, $timestamp) = @_;
   my $timer = $self->{time} + $self->{start} - $timestamp;
 
   # we round the timer value slightly... the protocol isn't exact anyways,
   # and this gives smoother timers ;)
   my @format = $self->{format}->(int ($timer + 0.4));
   $self->{widget}->set_text ($self->{format}->(int ($timer + 0.4)));

   $timer - int $timer;
}

sub set_time {
   my ($self, $time) = @_;

   # we ignore requests to re-set the time of a running clock.
   # this is the easiest way to ensure that commentary etc.
   # doesn't re-set the clock. yes, this is frickle design,
   # but I think the protocol is to blame here, which gives
   # very little time information. (cgoban2 also has had quite
   # a lot of small time update problems...)
   unless ($self->{timeout}) {
      $self->{set}->($time->[0], $time->[1]);
      $self->refresh ($self->{start});
   }
}

sub start {
   my ($self, $when) = @_;

   $self->stop;

   $self->{start} = $when;

   my $timeout; $timeout = sub {
      my $next = $self->refresh (Time::HiRes::time) * 1000;
      $next += 1000 if $next < 0;
      $self->{timeout} = add Glib::Timeout $next, $timeout;
      0;
   };

   $timeout->();
}

sub stop {
   my ($self) = @_;

   remove Glib::Source delete $self->{timeout} if $self->{timeout};
}

sub destroy {
   my ($self) = @_;
   $self->stop;
   $self->SUPER::destroy;
}

package game::userpanel;

use base gtk::widget;

sub new {
   my $class = shift;
   my $self = $class->SUPER::new(@_);

   $self->{widget} = new Gtk2::HBox;

   $self->{widget}->add (my $vbox = new Gtk2::VBox);

   $vbox->add ($self->{name} = new Gtk2::Label $self->{name});
   $vbox->add ($self->{info} = new Gtk2::Label "");
   $vbox->add (($self->{clock} = new game::goclock)->widget);

   $vbox->add ($self->{imagebox} = new Gtk2::VBox);

   $self;
}

sub configure {
   my ($self, $user, $rules) = @_;

   if ($self->{name}->get_text ne $user->as_string) {
      $self->{name}->set_text ($user->as_string);

      $self->{imagebox}->remove ($_) for $self->{imagebox}->get_children;
      $self->{imagebox}->add (gtk::image_from_data undef);
      $self->{imagebox}->show_all;

      # the big picture...
      appwin::userpic ($user->{name}, sub {
         return unless $self->{imagebox};
         if ($_[0]) {
            $self->{imagebox}->remove ($_) for $self->{imagebox}->get_children;
            $self->{imagebox}->add (gtk::image_from_data $_[0]);
            $self->{imagebox}->show_all;
         }
      });
   }
   
   $self->{clock}->configure (@{$rules}{qw(timesys time interval count)});
}

sub set_state {
   my ($self, $captures, $timer, $when) = @_;

   $self->{clock}->stop unless $when;
   $self->{clock}->set_time ($timer);
   $self->{clock}->start ($when) if $when;

   $self->{info}->set_text ("$captures pris.");
}

package game;

use KGS::Constants;
use KGS::Game::Board;

use base KGS::Listener::Game;
use base KGS::Game;

use base gtk::widget;

use POSIX qw(ceil);

sub new {
   my $self = shift;
   $self = $self->SUPER::new(@_);

   $self->listen($self->{conn});

   $self->{window} = new Gtk2::Window 'toplevel';
   my $title = $self->{channel} ? $self->owner->as_string." ".$self->opponent_string : "Game Window";
   $self->{window}->set_title("KGS Game $title");
   gtk::state $self->{window}, "game::window", undef, window_size => [600, 500];

   $self->{window}->signal_connect(delete_event => sub {
      $self->part;
      $self->destroy;
      1;
   });

   $self->{window}->add($self->{hpane} = new Gtk2::HPaned);
   gtk::state $self->{hpane}, "game::hpane", undef, position => 500;

   # LEFT PANE

   $self->{hpane}->pack1(($self->{left} = new Gtk2::VBox), 1, 0);
   
   $self->{boardbox} = new Gtk2::VBox;

   $self->{hpane}->pack1((my $vbox = new Gtk2::VBox), 1, 1);

   # challenge

   $self->{challenge} = new challenge channel => $self->{channel};
   
   # board box (aspect/canvas)
   
   $self->{boardbox}->pack_start((my $frame = new Gtk2::Frame), 0, 1, 0);

   {
      $frame->add(my $vbox = new Gtk2::VBox);
      $vbox->add($self->{title} = new Gtk2::Label $title);

      $self->{moveadj} = new Gtk2::Adjustment 0, 0, 0, 1, 1, 0;

      $vbox->add(my $scale = new Gtk2::HScale $self->{moveadj});
      $scale->set_draw_value (0);
      $scale->set_digits (0);

      $self->{moveadj}->signal_connect (value_changed => sub { $self->update_board });
   }

   $self->{boardbox}->pack_start((my $aspect_frame = new Gtk2::AspectFrame "", 0.5, 0.5, 1, 0), 1, 1, 0);
   $aspect_frame->set (border_width => 0, shadow_type => 'none', label_xalign => 0.5);
   $self->{board_label} = $aspect_frame->get_label_widget;

   $aspect_frame->add($self->{canvas} = new Gtk2::DrawingArea);
   $self->{canvas}->double_buffered (0) if $::config->{conserve_memory};

   $self->{canvas}->signal_connect(configure_event => \&configure_event, $self);
   $self->{canvas}->signal_connect(expose_event    => \&expose_event,    $self);

   # RIGHT PANE

   $self->{hpane}->pack2(($self->{vpane} = new Gtk2::VPaned), 1, 1);
   $self->{hpane}->set(position_set => 1);
   gtk::state $self->{vpane}, "game::vpane", $self->{name}, position => 80;

   $self->{vpane}->add(my $sw = new Gtk2::ScrolledWindow);
   $sw->set_policy("automatic", "always");

   $sw->add(($self->{userlist} = new userlist)->widget);

   $self->{vpane}->add(my $vbox = new Gtk2::VBox);

   $vbox->pack_start((my $hbox = new Gtk2::HBox 1), 0, 1, 0);
   $hbox->add (($self->{userpanel}[WHITE] = new game::userpanel colour => WHITE)->widget);
   $hbox->add (($self->{userpanel}[BLACK] = new game::userpanel colour => BLACK)->widget);
   
   $vbox->pack_start(($self->{text} = new gtk::text)->widget, 1, 1, 0);

   $vbox->pack_start(($self->{entry} = new Gtk2::Entry), 0, 1, 0);
   $self->{entry}->signal_connect(activate => sub {
      my $text = $self->{entry}->get_text;
      $self->say($text) if $text =~ /\S/;
      $self->{entry}->set_text("");
   });

   $self->event_update_game;
   $self;
}

sub event_update_users {
   my ($self, $add, $update, $remove) = @_;

   $self->{userlist}->update ($add, $update, $remove);
}

sub join {
   my ($self) = @_;
   return if $self->{joined};

   $self->SUPER::join;

   $self->{window}->show_all;
}

sub part {
   my ($self) = @_;

   $self->SUPER::part;
   $self->destroy;
}

sub configure_event {
   my ($widget, $event, $self) = @_;
   delete $self->{stack};
   delete $self->{pixbuf};
   delete $self->{board_shown};
   delete $self->{background};
   $self->repaint_board;
   0;
}

sub expose_event {
   my ($widget, $event, $self) = @_;

   $self->{pixbuf} or return;

   my $area = $event->area;

   $self->redraw ($area);

   0;
}

# something Gtk2 fixed
sub INTERP_NEAREST  (){ 'nearest'  }
sub INTERP_TILES    (){ 'tiles'    }
sub INTERP_BILINEAR (){ 'bilinear' }
sub INTERP_HYPER    (){ 'hyper'    }

sub new_pixbuf {
   my ($w, $h, $alpha, $fill) = @_;

   my $pixbuf = new Gtk2::Gdk::Pixbuf 'rgb', $alpha, 8, $w, $h;
   $pixbuf->fill ($fill) if defined $fill;

   $pixbuf;
}

sub scale_pixbuf {
   my ($src, $w, $h, $mode) = @_;

   my $dst = new_pixbuf $w, $h, 1;

   $src->scale(
      $dst, 0, 0, $w, $h, 0, 0,
      $w / $src->get_width, $h / $src->get_height,
      $mode,
   );

   $dst;
}

# create a stack of stones
sub create_stack {
   my ($self, $mark, $size, $rand) = @_;

   my $shadow = $size * 0.05;

   my $c = \$self->{stack}{$mark};
   unless ($$c) {
      for my $stone ($mark & (MARK_W | MARK_GRAY_W) ? @::white_img : @::black_img) {
         my $base = new_pixbuf $size + $shadow, $size + $shadow, 1, 0x00000000;

         # zeroeth the shadow
         if ($mark & (MARK_B | MARK_W)) {
            # the -0.5's are a mystery to me
            $::shadow_img->composite (
               $base, $shadow, $shadow, $size, $size, $shadow - 0.5, $shadow - 0.5,
               $size / $::shadow_img->get_width, $size / $::shadow_img->get_height,
               $::config->{speed} ? INTERP_NEAREST : INTERP_BILINEAR, 192
            );
         }

         # first the big stones (handicap stones could be different)
         for ([MARK_B,      $mark & MARK_MOVE ? 255 : 255],
              [MARK_W,      $mark & MARK_MOVE ? 255 : 255],
              [MARK_GRAY_B, 128],
              [MARK_GRAY_W, 128]) {
            my ($mask, $alpha) = @$_;
            if ($mark & $mask) {
               $stone->composite (
                  $base, 0, 0, $size, $size, 0, 0,
                  $size / $stone->get_width, $size / $stone->get_height,
                  $::config->{speed} ? INTERP_NEAREST : INTERP_BILINEAR, $alpha
               );
            }
         }

         # then the small stones
         for ([MARK_SMALL_B, $::black_img[$rand % @::black_img]],
              [MARK_SMALL_W, $::white_img[$rand % @::white_img]]) {
            my ($mask, $img) = @$_;
            if ($mark & $mask) {
               $img->composite (
                  $base, (int ($size / 4)) x2, (ceil ($size / 2 + 1)) x2, ($size / 4) x2,
                  $size / $img->get_width / 2, $size / $img->get_height / 2,
                  $::config->{speed} ? INTERP_NEAREST : INTERP_BILINEAR, 224
               );
            }
         }

         # and lastly any markers
         my $dark_bg = ! ! ($mark & (MARK_B | MARK_GRAY_B));

         for ([MARK_CIRCLE,   $::circle_img[$dark_bg]],
              [MARK_TRIANGLE, $::triangle_img[$dark_bg]],
              [MARK_SQUARE,   $::square_img[$dark_bg]]) {
           my ($mask, $img) = @$_;
           if ($mark & $mask) {
              $img->composite (
                 $base, 0, 0, $size, $size, 0, 0,
                 $size / $img->get_width, $size / $img->get_height,
                 $::config->{speed} ? INTERP_NEAREST : INTERP_BILINEAR, 192
              );
           }
         }

         push @$$c, $base;
      }
   }

   $$c->[$rand % @$$c];
}

sub pixbuf_text {
   my ($pixbuf, $colour, $x, $y, $height, $text) = @_;

   my @c = grep $_,
              map $::font[$colour][$::fontmap{$_}],
                 split //, $text;

   if (@c) {
      my $spacing = $height * 0.1;
      my $s = $height / List::Util::max map $_->get_height, @c;
      my $W = List::Util::sum map $_->get_width, @c;

      $x -= ($W * $s + $spacing * (@c - 1)) * 0.5;
      $y -= $height * 0.5;

      for (@c) {
         my $w = $_->get_width * $s;
         # +2 == don't fight the rounding
         $_->composite ($pixbuf,
               $x, $y, $w+2, $height+2, $x, $y, $s, $s,
               $::config->{speed} ? INTERP_NEAREST : INTERP_BILINEAR, 255);

         $x += $w + $spacing;
      }
   }
}

sub pixbuf_rect {
   my ($pb, $colour, $x1, $y1, $x2, $y2, $alpha) = @_;
   # we fake lines by... a horrible method :/
   my $colour_pb = new_pixbuf 1, 1, 0, $colour;
   $colour_pb->composite ($pb, $x1, $y1, $x2 - $x1 + 1, $y2 - $y1 + 1, $x1, $y1, $x2 + 1, $y2 + 1,
                          INTERP_NEAREST, $alpha);
}

sub repaint_board {
   my ($self) = @_;
   my $canvas = $self->{canvas};
   my $expose_area = undef;

   return $expose_area unless $self->{board};

   my ($w, $h) = ($canvas->allocation->values)[2,3];

   die "FATAL: board aspect ratio != 1" unless $w == $h;
   
   my $s = $w;

   return unless $s >= 200;
   
   my $size = $self->{size};

   # we leave enough space for the shadows.. I like smaller stones, and we
   # do no need to do the nifty recursive screen updates that goban2 does
   my $border = int ($s / ($size + 3) * 0.5);
   my $s2     = $s - $border * 2;
   my $edge   = int ($s2 / ($size + 1) * 0.96) - ($::config->{randomize} ? 3 : 0);
   my $ofs    = int ($edge / 2);

   my @k = map int ($s2 * $_ / ($size+1) + $border + 0.5), 0 .. $size;

   my $pixbuf;

   my $oldboard;

   if ($self->{background}) {
      if ($oldboard = $self->{board_shown}) {
         $pixbuf = $self->{pixbuf};
      } else {
         $pixbuf = $self->{background}->copy;
         $expose_area = new Gtk2::Gdk::Rectangle 0, 0, $s, $s;
      }
   } else {
      $expose_area = new Gtk2::Gdk::Rectangle 0, 0, $s, $s;

      my ($bw, $bh) = ($::board_img->get_width, $::board_img->get_height);

      if ($s < $bw && $s < $bh) {
         $pixbuf = new_pixbuf $s, $s, 0;
         $::board_img->copy_area (0, 0, $s, $s, $pixbuf, 0, 0);
      } else {
         $pixbuf = scale_pixbuf $::board_img, $s, $s, $::config->{speed} ? INTERP_NEAREST : INTERP_TILES;
      }

      my $linew = int ($s / 40 / $size);

      # ornamental border... we have time to waste :/
      pixbuf_rect $pixbuf, 0xffcc7700, 0, 0,           $s-1, $linew, 255;
      pixbuf_rect $pixbuf, 0xffcc7700, 0, 0,           $linew, $s-1, 255;
      pixbuf_rect $pixbuf, 0xffcc7700, $s-$linew-1, 0, $s-1, $s-1,   255;
      pixbuf_rect $pixbuf, 0xffcc7700, 0, $s-$linew-1, $s-1, $s-1,   255;

      for my $i (1 .. $size) {
         pixbuf_rect $pixbuf, 0x44111100, $k[$i] - $linew, $k[1] - $linew, $k[$i] + $linew, $k[$size] + $linew, 192;
         pixbuf_rect $pixbuf, 0x44111100, $k[1] - $linew, $k[$i] - $linew, $k[$size] + $linew, $k[$i] + $linew, 192;

         # 38 max, but we allow a bit more
         my $label = (qw(- A  B  C  D  E  F  G  H  J  K  L  M  N  O  P  Q  R  S  T  U  V  W  X  Y  Z
                           AA BB CC DD EE FF GG HH JJ KK LL MM NN OO PP QQ RR SS TT UU VV WW XX YY ZZ))[$i];

         pixbuf_text $pixbuf, 0, $k[$i], $border,       $ofs, $label;
         pixbuf_text $pixbuf, 0, $k[$i], $s2 + $border, $ofs, $label;
         pixbuf_text $pixbuf, 0, $border, $k[$i],       $ofs, $size - $i + 1;
         pixbuf_text $pixbuf, 0, $s2 + $border, $k[$i], $ofs, $size - $i + 1;

         $a++;
         $a++ if $a eq "I"; # not correct, instead of AA AB, we should get HH JJ KK...
      }

      # hoshi points
      my $hoshi = sub {
         my ($x, $y) = @_;
         my $hs = int ($edge / 4) | 1;
         $x = $k[$x] - $hs / 2; $y = $k[$y] - $hs / 2;

         # we use the shadow mask... not perfect, but I want to finish this
         $::shadow_img->composite ($pixbuf,
               $x, $y, $hs + 1, $hs + 1, $x, $y,
               $hs / $::shadow_img->get_width, $hs / $::shadow_img->get_height,
               $::config->{speed} ? INTERP_NEAREST : INTERP_BILINEAR, 255);
      };

      my $h1 = $size < 10 ? 3 : 4; # corner / edge offset
      $hoshi->($h1, $h1);
      $hoshi->($size - $h1 + 1, $h1);
      $hoshi->($h1, $size - $h1 + 1);
      $hoshi->($size - $h1 + 1, $size - $h1 + 1);

      if ($size % 2) { # on odd boards, also the remaining 5
         my $h2 = ($size + 1) / 2;
         if ($size > 10) {
            $hoshi->($h1, $h2);
            $hoshi->($size - $h1 + 1, $h2);
            $hoshi->($h2, $size - $h1 + 1);
            $hoshi->($h2, $h1);
         }
         # the tengen
         $hoshi->($h2, $h2);
      }

      unless ($::config->{conserve_memory} > 1) {
         $self->{background} = $pixbuf;
         $pixbuf = $pixbuf->copy;
      }
   }

   $self->{pixbuf} = $pixbuf;

   for my $x (1 .. $size) {
      for my $y (1 .. $size) {
         my $rand = ($x ^ $y ^ 0x5555);

         my ($dx, $dy) = ($k[$x] - $ofs, $k[$y] - $ofs);

         if ($::config->{randomize}) {
            $dx += ($rand     % 7) - 3;
            $dy += ($rand / 3 % 7) - 3;
         }

         my $shadow = $edge * 0.05;
         my $area = [$dx, $dy, $edge + $shadow, $edge + $shadow];
         
         my $mark = $self->{board}{board}[$x-1][$y-1];
         my $old = $oldboard ? $oldboard->{board}[$x-1][$y-1] : 0;

         if ($oldboard) {
            next if $old == $mark; # no change

            $self->{background}->copy_area (@$area, $pixbuf, $dx, $dy);
            $expose_area = $expose_area
                              ? $expose_area->union (new Gtk2::Gdk::Rectangle @$area)
                              : new Gtk2::Gdk::Rectangle @$area;
         }

         if ($mark) {
            my $pb = $self->create_stack($mark, $edge, $rand);

            $pb->composite ($pixbuf, @$area,
                            $dx, $dy, 1, 1, $::config->{speed} ? INTERP_NEAREST : INTERP_NEAREST, 255);

            # labels are handled here because they are quite rare
            if ($mark & MARK_LABEL) {
               my $white = $mark & (MARK_W | MARK_GRAY_W) ? 0 : 1;

               if ($white) {
                  pixbuf_text $pixbuf, 0,
                              $k[$x] + $ofs * 0.1, $k[$y] + $ofs * 0.1, $ofs * 0.7,
                              $self->{board}{label}[$x-1][$y-1];
               }
               pixbuf_text $pixbuf, $white,
                           $k[$x], $k[$y], $ofs * 0.7,
                           $self->{board}{label}[$x-1][$y-1];
            }
         }
      }
   }

   $self->{board_shown} = Storable::dclone $self->{board};
   #d# save
   #Storable::nstore { board => $self->{board}, size => $self->{size}, path => $self->{path}}, "testboard.storable";

   $expose_area;
}

sub redraw {
   my ($self, $area) = @_;

   if ($area && $self->{pixbuf}) {
      my ($x, $y, $w, $h) = $area->values;

      $self->{canvas}->window->draw_pixbuf ($self->{canvas}->style->white_gc, $self->{pixbuf},
            $x, $y, $x, $y, $w, $h,
            "normal", 0, 0);
      $self->{canvas}->window->draw_rectangle ($self->{canvas}->style->black_gc, 0,
                         $x - 1, $y - 1, $w + 2, $h + 2) if $::DEBUG_EXPOSE;
   }
}

sub update_board {
   my ($self) = @_;
   return unless $self->{path};

   my $move = int $self->{moveadj}->get_value;

   warn "update_board called $move\n";#d#

   my $running = $move == @{$self->{path}};

   $self->{board_label}->set_text ("Move $move");

   $self->{board} = new KGS::Game::Board $self->{size};
   $self->{board}->interpret_path ([@{$self->{path}}[0 .. $move - 1]]);

   for my $colour (WHITE, BLACK) {
      $self->{userpanel}[$colour]->set_state (
         $self->{board}{captures}[$colour],
         $self->{board}{timer}[$colour],
         ($running && $self->{lastmove_colour} == $colour)
            ? $self->{lastmove_time} : 0
      );
   }

   $self->redraw ($self->repaint_board);
}

sub event_update_tree {
   my ($self) = @_;

   $self->{path} = $self->get_path;

   if ($self->{moveadj}) {
      my $upper = $self->{moveadj}->upper;
      my $pos = $self->{moveadj}->get_value;

      $self->{moveadj}->upper (scalar @{$self->{path}});
      
      warn "UPDATE_TREE $pos,$upper";#d#
      $self->{moveadj}->changed;
      if ($pos == $upper) {
         $self->{moveadj}->set_value (scalar @{$self->{path}});
      } else {
         $self->update_board;
      }
   }
}

sub event_update_comments {
   my ($self, $node, $comment, $newnode) = @_;
   $self->SUPER::event_update_comments($node, $comment, $newnode);

   my $text;

   $text .= "\n<header>Move <move>$node->{move}</move>, Node <node>$node->{id}</node></header>"
      if $newnode;

   for (split /\n/, $comment) {
      $text .= "\n";
      if (s/^([0-9a-zA-Z]+ \[[0-9dkp\?\-]+\])://) {
         $text .= "<user>" . (util::toxml $1) . "</user>:";
      }
      
      # coords only for 19x19 so far
      $_ = util::toxml $_;
      s{
         (
            \b
            (?:[bw])?
            [, ]{0,2}
            [a-hj-t] # valid for upto 19x19
            \s?
            [1-9]?[0-9]
            \b
         )
      }{
         "<coord>$1</coord>";
      }sgexi;

      $text .= $_;
   }

   $self->{text}->append_text ($text);
}

sub event_join {
   my ($self) = @_;
   $self->SUPER::event_join;
}

sub event_part {
   my ($self) = @_;
   $self->SUPER::event_part;
}

sub event_move {
   my ($self, $pass) = @_;
   sound::play 1, $pass ? "pass" : "move";
}

sub event_update_game {
   my ($self) = @_;
   $self->SUPER::event_update_game;

   $self->{user}[BLACK] = $self->{user1};
   $self->{user}[WHITE] = $self->{user2};

   # show board

   $self->{left}->remove ($_) for $self->{left}->get_children;
   if ($self->is_valid) {
      $self->{left}->add ($self->{boardbox});
      (delete $self->{challenge})->destroy if $self->{challenge};
   } else {
      $self->{left}->add ($self->{challenge}->widget);
   }
   $self->{left}->show_all;

   # view text
   
   $text = "\n<header>Game Update</header>";
   
   $text .= "\nType: " . (util::toxml $gametype{$self->type})
          . " (" . (util::toxml $gameopt{$self->option}) . ")";
   $text .= "\nFlags:";
   $text .= " valid"     if $self->is_valid;
   $text .= " adjourned" if $self->is_adjourned;
   $text .= " scored"    if $self->is_scored;
   $text .= " saved"     if $self->is_saved;

   $text .= "\nWhite: <user>" . (util::toxml $self->{user2}->as_string) . "</user>";
   $text .= "\nBlack: <user>" . (util::toxml $self->{user1}->as_string) . "</user>";
   $text .= "\nOwner: <user>" . (util::toxml $self->{user3}->as_string) . "</user>" if $self->{user3}->is_valid;

   if ($self->is_valid) {
      $text .= "\nHandicap: " . $self->{handicap};
      $text .= "\nKomi: " . $self->{komi};
      $text .= "\nSize: " . $self->size_string;
   }

   $self->{text}->append_text ("<infoblock>$text</infoblock>");
}

sub event_update_rules {
   my ($self, $rules) = @_;

   $self->{userpanel}[$_]->configure ($self->{user}[$_], $rules)
      for BLACK, WHITE;

   my $text = "\n<header>Game Rules</header>";

   $text .= "\nRuleset: " . $ruleset{$rules->{ruleset}};

   $text .= "\nTime: ";

   if ($rules->{timesys} == TIMESYS_NONE) {
      $text .= "UNLIMITED";
   } elsif ($rules->{timesys} == TIMESYS_ABSOLUTE) {
      $text .= util::format_time $rules->{time};
      $text .= " ABS";
   } elsif ($rules->{timesys} == TIMESYS_BYO_YOMI) {
      $text .= util::format_time $rules->{time} - $rules->{interval} * $rules->{count};
      $text .= sprintf " + %s (%d) BY", util::format_time $rules->{interval}, $rules->{count};
   } elsif ($rules->{timesys} == TIMESYS_CANADIAN) {
      $text .= util::format_time $rules->{time};
      $text .= sprintf " + %s/%d CAN", util::format_time $rules->{interval}, $rules->{count};
   }
   
   $self->{text}->append_text ("<infoblock>$text</infoblock>");
}

sub inject_resign_game {
   my ($self, $msg) = @_;

   $self->{text}->append_text ("\n<infoblock><header>Resign</header>"
                               . "\n<user>"
                               . (util::toxml $self->{user}[$msg->{player}]->as_string)
                               . "</user> resigned.</infoblock>");
}

sub inject_final_result {
   my ($self, $msg) = @_;

   $self->{text}->append_text ("<infoblock>\n<header>Game Over</header>"
                               . "\nWhite Score " . (util::toxml $msg->{whitescore}->as_string)
                               . "\nBlack Score " . (util::toxml $msg->{blackscore}->as_string)
                               . "</infoblock>"
                              );
}

sub destroy {
   my ($self) = @_;
   $self->{userpanel}[$_] && (delete $self->{userpanel}[$_])->destroy
      for BLACK, WHITE;
   $self->SUPER::destroy;
   delete $appwin::gamelist->{game}{$self->{channel}};
}

1;

Revision:	1.46
Committed:	Thu Jun 5 06:01:01 2003 UTC (20 years, 11 months ago) by pcg
Content type:	text/plain
Branch:	MAIN
Changes since 1.45:	+4 -3 lines
Log Message:	* empty log message *