[ViewVC] Annotation of: cvs/rxvt-unicode/src/perl/matcher

#! perl

# Author: Tim Pope <rxvt-unicodeNOSPAM@tpope.org>
#         Bob Farrell <robertanthonyfarrell@gmail.com>

#:META:RESOURCE:%.launcher:string:default launcher command
#:META:RESOURCE:%.button:string:the button, yeah
#:META:RESOURCE:%.pattern.:string:extra pattern to match
#:META:RESOURCE:%.launcher.:string:custom launcher for pattern
#:META:RESOURCE:%.rend.:string:custom rednition for pattern

=head1 NAME

matcher - match strings in terminal output and change their rendition

=head1 DESCRIPTION

Uses per-line display filtering (C<on_line_update>) to underline text
matching a certain pattern and make it clickable. When clicked with the
mouse button specified in the C<matcher.button> resource (default 2, or
middle), the program specified in the C<matcher.launcher> resource
(default, the C<url-launcher> resource, C<sensible-browser>) will be started
with the matched text as first argument.  The default configuration is
suitable for matching URLs and launching a web browser, like the
former "mark-urls" extension.

The default pattern to match URLs can be overridden with the
C<matcher.pattern.0> resource, and additional patterns can be specified
with numbered patterns, in a manner similar to the "selection" extension.
The launcher can also be overridden on a per-pattern basis.

It is possible to activate the most recently seen match or a list of matches
from the keyboard.  Simply bind a keysym to "matcher:last" or
"matcher:list" as seen in the example below.

Example: load and use the matcher extension with defaults.

    URxvt.perl-ext:           default,matcher

Example: use a custom configuration.

    URxvt.url-launcher:       sensible-browser
    URxvt.keysym.C-Delete:    matcher:last
    URxvt.keysym.M-Delete:    matcher:list
    URxvt.matcher.button:     1
    URxvt.matcher.pattern.1:  \\bwww\\.[\\w-]+\\.[\\w./?&@#-]*[\\w/-]
    URxvt.matcher.pattern.2:  \\B(/\\S+?):(\\d+)(?=:|$)
    URxvt.matcher.launcher.2: gvim +$2 $1

=cut

my $url =
   qr{
      (?:https?://|ftp://|news://|mailto:|file://|\bwww\.)
      [\w\-\@;\/?:&=%\$.+!*\x27,~#]*
      (
         \([\w\-\@;\/?:&=%\$.+!*\x27,~#]*\)| # Allow a pair of matched parentheses
         [\w\-\@;\/?:&=%\$+*~]  # exclude some trailing characters (heuristic)
      )+
   }x;

sub on_key_press {
   my ($self, $event, $keysym, $octets) = @_;

   return unless $self->{overlay};

   delete $self->{overlay};

   my $i = ($keysym == 96 ? 0 : $keysym - 48);
   if ($i >= 0 && $i < @{ $self->{matches} }) {
      my @exec = @{ $self->{matches}[$i] };
      shift @exec;
      $self->exec_async (@exec);
   }

   1
}

# backwards compat
sub on_user_command {
   my ($self, $cmd) = @_;

   if ($cmd =~ s/^matcher:list\b//) {
      $self->matchlist;
   } else {
      if ($cmd =~ s/^matcher:last\b//) {
         $self->most_recent;
      } elsif ($cmd =~ s/^matcher\b//) {
         # for backward compatibility
         $self->most_recent;
      }
   }

   ()
}

sub on_action {
   my ($self, $action) = @_;

   if ($action eq "list") {
      $self->matchlist;
   } elsif ($action eq "last") {
      $self->most_recent;
   }

   ()
}

sub matchlist {
   my ($self) = @_;

   @{ $self->{matches} } = ();
   my $row = $self->nrow - 1;
   while ($row >= 0 && @{ $self->{matches} } < 10) {
      my $line = $self->line ($row);
      my @matches = $self->find_matches ($row, 0);

      for (sort { $b->[0] <=> $a->[0] } @matches) {
         shift @$_;
         push @{ $self->{matches} }, $_;
         last if @{ $self->{matches} } == 10;
      }

      $row = $line->beg - 1;
   }

   return unless @{ $self->{matches} };

   my $width = 0;

   my $i = 0;
   for my $match (@{ $self->{matches} }) {
      my $text = $match->[0];
      my $w = $self->strwidth ("$i-$text");

      $width = $w if $w > $width;
      $i++;
   }

   $width = $self->ncol - 2 if $width > $self->ncol - 2;

   $self->{overlay} = $self->overlay (0, 0, $width, scalar (@{ $self->{matches} }), urxvt::OVERLAY_RSTYLE, 2);
   my $i = 0;
   for my $match (@{ $self->{matches} }) {
      my $text = $match->[0];

      $self->{overlay}->set (0, $i, "$i-$text");
      $i++;
   }

}

sub most_recent {
   my ($self) = shift;
   my $row = $self->nrow;
   my @exec;
   while($row-- > $self->top_row) {
      @exec = $self->command_for($row);
      last if(@exec);
   }
   if(@exec) {
      return $self->exec_async (@exec);
   }
   ()
}

sub my_resource {
   $_[0]->x_resource ("%.$_[1]")
}

# turn a rendition spec in the resource into a sub that implements it on $_
sub parse_rend {
   my ($self, $str) = @_;
   my ($mask, $fg, $bg, $failed) = $str ? urxvt::rend2mask($str)
                                        : (urxvt::RS_Uline, undef, undef, []);
   warn "Failed to parse rendition string: " . join(',', @$failed) if @$failed;
   my @rend;
   push @rend, sub { $_ |= $mask } if $mask;
   push @rend, sub { $_ = urxvt::SET_FGCOLOR($_, $fg) } if defined $fg;
   push @rend, sub { $_ = urxvt::SET_BGCOLOR($_, $bg) } if defined $bg;
   sub {
      for my $s ( @rend ) { &$s };
   }
}

sub on_start {
   my ($self) = @_;

   $self->{launcher} = $self->my_resource ("launcher") || $self->x_resource("url-launcher") || "sensible-browser";

   $self->{matches} = [];
   $self->{button}  = 2;
   $self->{state}   = 0;
   if($self->{argv}[0] || $self->my_resource ("button")) {
      my @mods = split '', $self->{argv}[0] || $self->my_resource ("button");
      for my $mod (@mods) {
         if($mod =~ /^\d+$/) {
            $self->{button} = $mod;
         } elsif($mod eq "C") {
            $self->{state} |= urxvt::ControlMask;
         } elsif($mod eq "S") {
            $self->{state} |= urxvt::ShiftMask;
         } elsif($mod eq "M") {
            $self->{state} |= $self->ModMetaMask;
         } elsif($mod ne "-" && $mod ne " ") {
            warn("$mod is invalid in $self->{_name}<$self->{argv}[0]>\n");
         }
      }
   }

   my @defaults = ($url);
   my @matchers;
   for (my $idx = 0; defined (my $res = $self->my_resource ("pattern.$idx") || $defaults[$idx]); $idx++) {
      $res = $self->locale_decode ($res);
      utf8::encode $res;
      my $launcher = $self->my_resource ("launcher.$idx");
      $launcher =~ s/\$&|\$\{&\}/\${0}/g if $launcher;
      my $rend = $self->parse_rend($self->my_resource ("rend.$idx"));
      unshift @matchers, [qr($res)x,$launcher,$rend];
   }
   $self->{matchers} = \@matchers;

   ()
}

sub on_line_update {
   my ($self, $row) = @_;

   # fetch the line that has changed
   my $line = $self->line ($row);
   my $text = $line->t;
   my $i = 0;

   # find all urls (if any)
   for my $matcher (@{$self->{matchers}}) {
      while ($text =~ /$matcher->[0]/g) {
         #print "$&\n";
         my $rend = $line->r;

         # mark all characters as underlined. we _must_ not toggle underline,
         # as we might get called on an already-marked url.
         &{$matcher->[2]}
         for @{$rend}[ $-[0] .. $+[0] - 1];

         $line->r ($rend);
      }
   }

   ()
}

sub valid_button {
   my ($self, $event) = @_;
   my $mask = $self->ModLevel3Mask | $self->ModMetaMask
   | urxvt::ShiftMask | urxvt::ControlMask;
   return ($event->{button} == $self->{button} &&
      ($event->{state} & $mask) == $self->{state});
}

sub find_matches {
   my ($self, $row, $col) = @_;
   my $line = $self->line ($row);
   my $text = $line->t;

   my @matches;
   for my $matcher (@{$self->{matchers}}) {
      my $launcher = $matcher->[1] || $self->{launcher};
      while ($text =~ /$matcher->[0]/g) {
         my $match = substr $text, $-[0], $+[0] - $-[0];
         my @begin = @-;
         my @end = @+;
         my @exec;

         if (!defined($col) || ($-[0] <= $col && $+[0] >= $col)) {
            if ($launcher !~ /\$/) {
               @exec = ($launcher, $match);
            } else {
               # It'd be nice to just access a list like ($&,$1,$2...),
               # but alas, m//g behaves differently in list context.
               @exec = map { s/\$(\d+)|\$\{(\d+)\}/
                  substr $text, $begin[$1 || $2], $end[$1 || $2] - $begin[$1 || $2]
                  /egx; $_ } split /\s+/, $launcher;
            }

            push @matches, [ $begin[0], $match, @exec ];
         }
      }
   }

   @matches;
}

sub command_for {
   my ($self, $row, $col) = @_;

   my @matches = $self->find_matches ($row, $col);
   if (@matches) {
      my @match = @{ $matches[0] };
      return @match[2 .. $#match];
   }

   ()
}

sub on_button_press {
   my ($self, $event) = @_;
   if($self->valid_button($event)
      && (my @exec = $self->command_for($event->{row},$event->{col}))) {
      $self->{row} = $event->{row};
      $self->{col} = $event->{col};
      $self->{cmd} = \@exec;
      return 1;
   } else {
      delete $self->{row};
      delete $self->{col};
      delete $self->{cmd};
   }

   ()
}

sub on_button_release {
   my ($self, $event) = @_;

   my $row = delete $self->{row};
   my $col = delete $self->{col};
   my $cmd = delete $self->{cmd};

   return if !defined $row;

   if($row == $event->{row} && abs($col-$event->{col}) < 2
      && join("\x00", @$cmd) eq join("\x00", $self->command_for($row,$col))) {
      if($self->valid_button($event)) {

         $self->exec_async (@$cmd);

      }
   }

   1;
}

# vim:set sw=3 sts=3 et:
Revision:	1.23
Committed:	Thu Jun 12 12:19:09 2014 UTC (9 years, 11 months ago) by sf-exg
Branch:	MAIN
Changes since 1.22:	+1 -1 lines
Log Message:	Fix fix style.
#	User	Rev	Content
1	root	1.1	#! perl
2
3	sf-tpope	1.7	# Author: Tim Pope <rxvt-unicodeNOSPAM@tpope.org>
4	root	1.14	# Bob Farrell <robertanthonyfarrell@gmail.com>
5	root	1.1
6	root	1.15	#:META:RESOURCE:%.launcher:string:default launcher command
7			#:META:RESOURCE:%.button:string:the button, yeah
8			#:META:RESOURCE:%.pattern.:string:extra pattern to match
9			#:META:RESOURCE:%.launcher.:string:custom launcher for pattern
10			#:META:RESOURCE:%.rend.:string:custom rednition for pattern
11	root	1.8
12	root	1.10	=head1 NAME
13
14	root	1.13	matcher - match strings in terminal output and change their rendition
15	root	1.10
16	root	1.11	=head1 DESCRIPTION
17	root	1.10
18			Uses per-line display filtering (C<on_line_update>) to underline text
19			matching a certain pattern and make it clickable. When clicked with the
20			mouse button specified in the C<matcher.button> resource (default 2, or
21			middle), the program specified in the C<matcher.launcher> resource
22	sf-exg	1.16	(default, the C<url-launcher> resource, C<sensible-browser>) will be started
23	root	1.10	with the matched text as first argument. The default configuration is
24			suitable for matching URLs and launching a web browser, like the
25			former "mark-urls" extension.
26
27			The default pattern to match URLs can be overridden with the
28			C<matcher.pattern.0> resource, and additional patterns can be specified
29			with numbered patterns, in a manner similar to the "selection" extension.
30			The launcher can also be overridden on a per-pattern basis.
31
32			It is possible to activate the most recently seen match or a list of matches
33	sf-exg	1.20	from the keyboard. Simply bind a keysym to "matcher:last" or
34			"matcher:list" as seen in the example below.
35	root	1.10
36	root	1.14	Example: load and use the matcher extension with defaults.
37	root	1.10
38			URxvt.perl-ext: default,matcher
39	root	1.14
40			Example: use a custom configuration.
41
42	root	1.10	URxvt.url-launcher: sensible-browser
43	sf-exg	1.20	URxvt.keysym.C-Delete: matcher:last
44			URxvt.keysym.M-Delete: matcher:list
45	root	1.10	URxvt.matcher.button: 1
46			URxvt.matcher.pattern.1: \\bwww\\.[\\w-]+\\.[\\w./?&@#-]*[\\w/-]
47			URxvt.matcher.pattern.2: \\B(/\\S+?):(\\d+)(?=:\|$)
48			URxvt.matcher.launcher.2: gvim +$2 $1
49
50			=cut
51
52	root	1.1	my $url =
53			qr{
54	tpope	1.2	(?:https?://\|ftp://\|news://\|mailto:\|file://\|\bwww\.)
55	sf-tpope	1.12	[\w\-\@;\/?:&=%\$.+!\x27,~#]
56	tpope	1.2	(
57	sf-tpope	1.12	\([\w\-\@;\/?:&=%\$.+!\x27,~#]\)\| # Allow a pair of matched parentheses
58			[\w\-\@;\/?:&=%\$+*~] # exclude some trailing characters (heuristic)
59	tpope	1.2	)+
60	root	1.1	}x;
61
62	sf-tpope	1.6	sub on_key_press {
63			my ($self, $event, $keysym, $octets) = @_;
64
65	sf-exg	1.18	return unless $self->{overlay};
66
67			delete $self->{overlay};
68	sf-tpope	1.6
69			my $i = ($keysym == 96 ? 0 : $keysym - 48);
70	sf-exg	1.18	if ($i >= 0 && $i < @{ $self->{matches} }) {
71			my @exec = @{ $self->{matches}[$i] };
72			shift @exec;
73			$self->exec_async (@exec);
74	sf-tpope	1.6	}
75
76	sf-exg	1.18	1
77	sf-tpope	1.6	}
78
79	root	1.14	# backwards compat
80	tpope	1.4	sub on_user_command {
81			my ($self, $cmd) = @_;
82	sf-tpope	1.6
83	root	1.14	if ($cmd =~ s/^matcher:list\b//) {
84			$self->matchlist;
85	sf-tpope	1.6	} else {
86	root	1.14	if ($cmd =~ s/^matcher:last\b//) {
87	sf-tpope	1.6	$self->most_recent;
88	root	1.14	} elsif ($cmd =~ s/^matcher\b//) {
89			# for backward compatibility
90	sf-tpope	1.6	$self->most_recent;
91			}
92	tpope	1.4	}
93	root	1.14
94	tpope	1.4	()
95			}
96
97	sf-exg	1.20	sub on_action {
98			my ($self, $action) = @_;
99
100			if ($action eq "list") {
101			$self->matchlist;
102			} elsif ($action eq "last") {
103			$self->most_recent;
104			}
105
106			()
107			}
108
109	sf-tpope	1.6	sub matchlist {
110			my ($self) = @_;
111	sf-exg	1.17
112	sf-exg	1.18	@{ $self->{matches} } = ();
113			my $row = $self->nrow - 1;
114			while ($row >= 0 && @{ $self->{matches} } < 10) {
115			my $line = $self->line ($row);
116	sf-exg	1.21	my @matches = $self->find_matches ($row, 0);
117	sf-exg	1.17
118	sf-exg	1.19	for (sort { $b->[0] <=> $a->[0] } @matches) {
119			shift @$_;
120			push @{ $self->{matches} }, $_;
121			last if @{ $self->{matches} } == 10;
122			}
123
124	sf-exg	1.18	$row = $line->beg - 1;
125			}
126	sf-exg	1.17
127	sf-exg	1.18	return unless @{ $self->{matches} };
128	sf-exg	1.17
129	sf-exg	1.18	my $width = 0;
130	sf-exg	1.17
131	sf-exg	1.18	my $i = 0;
132			for my $match (@{ $self->{matches} }) {
133			my $text = $match->[0];
134			my $w = $self->strwidth ("$i-$text");
135	sf-exg	1.17
136	sf-exg	1.18	$width = $w if $w > $width;
137			$i++;
138	sf-exg	1.17	}
139
140	sf-exg	1.18	$width = $self->ncol - 2 if $width > $self->ncol - 2;
141	sf-exg	1.17
142	sf-exg	1.18	$self->{overlay} = $self->overlay (0, 0, $width, scalar (@{ $self->{matches} }), urxvt::OVERLAY_RSTYLE, 2);
143	sf-exg	1.17	my $i = 0;
144	sf-exg	1.18	for my $match (@{ $self->{matches} }) {
145			my $text = $match->[0];
146
147			$self->{overlay}->set (0, $i, "$i-$text");
148	sf-exg	1.17	$i++;
149			}
150	sf-tpope	1.6
151			}
152
153	tpope	1.4	sub most_recent {
154			my ($self) = shift;
155			my $row = $self->nrow;
156			my @exec;
157			while($row-- > $self->top_row) {
158			@exec = $self->command_for($row);
159			last if(@exec);
160			}
161			if(@exec) {
162			return $self->exec_async (@exec);
163			}
164			()
165			}
166	tpope	1.2
167	root	1.1	sub my_resource {
168	root	1.9	$_[0]->x_resource ("%.$_[1]")
169	root	1.1	}
170
171	tpope	1.2	# turn a rendition spec in the resource into a sub that implements it on $_
172			sub parse_rend {
173			my ($self, $str) = @_;
174	sf-tpope	1.6	my ($mask, $fg, $bg, $failed) = $str ? urxvt::rend2mask($str)
175	tpope	1.2	: (urxvt::RS_Uline, undef, undef, []);
176			warn "Failed to parse rendition string: " . join(',', @$failed) if @$failed;
177			my @rend;
178			push @rend, sub { $_ \|= $mask } if $mask;
179			push @rend, sub { $_ = urxvt::SET_FGCOLOR($_, $fg) } if defined $fg;
180			push @rend, sub { $_ = urxvt::SET_BGCOLOR($_, $bg) } if defined $bg;
181			sub {
182			for my $s ( @rend ) { &$s };
183			}
184			}
185
186	root	1.1	sub on_start {
187			my ($self) = @_;
188
189	root	1.8	$self->{launcher} = $self->my_resource ("launcher") \|\| $self->x_resource("url-launcher") \|\| "sensible-browser";
190	root	1.1
191	sf-exg	1.18	$self->{matches} = [];
192	root	1.1	$self->{button} = 2;
193			$self->{state} = 0;
194	root	1.8	if($self->{argv}[0] \|\| $self->my_resource ("button")) {
195			my @mods = split '', $self->{argv}[0] \|\| $self->my_resource ("button");
196	root	1.1	for my $mod (@mods) {
197			if($mod =~ /^\d+$/) {
198			$self->{button} = $mod;
199			} elsif($mod eq "C") {
200			$self->{state} \|= urxvt::ControlMask;
201			} elsif($mod eq "S") {
202			$self->{state} \|= urxvt::ShiftMask;
203			} elsif($mod eq "M") {
204			$self->{state} \|= $self->ModMetaMask;
205			} elsif($mod ne "-" && $mod ne " ") {
206	root	1.9	warn("$mod is invalid in $self->{_name}<$self->{argv}[0]>\n");
207	root	1.1	}
208			}
209			}
210
211			my @defaults = ($url);
212			my @matchers;
213	root	1.8	for (my $idx = 0; defined (my $res = $self->my_resource ("pattern.$idx") \|\| $defaults[$idx]); $idx++) {
214	root	1.1	$res = $self->locale_decode ($res);
215			utf8::encode $res;
216	root	1.8	my $launcher = $self->my_resource ("launcher.$idx");
217			$launcher =~ s/\$&\|\$\{&\}/\${0}/g if $launcher;
218			my $rend = $self->parse_rend($self->my_resource ("rend.$idx"));
219	tpope	1.2	unshift @matchers, [qr($res)x,$launcher,$rend];
220	root	1.1	}
221			$self->{matchers} = \@matchers;
222
223			()
224			}
225
226			sub on_line_update {
227			my ($self, $row) = @_;
228
229			# fetch the line that has changed
230			my $line = $self->line ($row);
231			my $text = $line->t;
232			my $i = 0;
233
234			# find all urls (if any)
235			for my $matcher (@{$self->{matchers}}) {
236			while ($text =~ /$matcher->[0]/g) {
237	tpope	1.2	#print "$&\n";
238	root	1.1	my $rend = $line->r;
239
240			# mark all characters as underlined. we _must_ not toggle underline,
241			# as we might get called on an already-marked url.
242	tpope	1.2	&{$matcher->[2]}
243	root	1.1	for @{$rend}[ $-[0] .. $+[0] - 1];
244
245			$line->r ($rend);
246			}
247			}
248
249			()
250			}
251
252			sub valid_button {
253			my ($self, $event) = @_;
254			my $mask = $self->ModLevel3Mask \| $self->ModMetaMask
255			\| urxvt::ShiftMask \| urxvt::ControlMask;
256			return ($event->{button} == $self->{button} &&
257			($event->{state} & $mask) == $self->{state});
258			}
259
260	sf-exg	1.21	sub find_matches {
261	root	1.1	my ($self, $row, $col) = @_;
262			my $line = $self->line ($row);
263			my $text = $line->t;
264
265	sf-exg	1.21	my @matches;
266	root	1.1	for my $matcher (@{$self->{matchers}}) {
267			my $launcher = $matcher->[1] \|\| $self->{launcher};
268	sf-exg	1.22	while ($text =~ /$matcher->[0]/g) {
269	sf-exg	1.21	my $match = substr $text, $-[0], $+[0] - $-[0];
270	root	1.1	my @begin = @-;
271			my @end = @+;
272	sf-exg	1.21	my @exec;
273
274	tpope	1.2	if (!defined($col) \|\| ($-[0] <= $col && $+[0] >= $col)) {
275	root	1.1	if ($launcher !~ /\$/) {
276	sf-exg	1.21	@exec = ($launcher, $match);
277	root	1.1	} else {
278			# It'd be nice to just access a list like ($&,$1,$2...),
279			# but alas, m//g behaves differently in list context.
280	sf-exg	1.21	@exec = map { s/\$(\d+)\|\$\{(\d+)\}/
281	sf-exg	1.23	substr $text, $begin[$1 \|\| $2], $end[$1 \|\| $2] - $begin[$1 \|\| $2]
282	sf-exg	1.22	/egx; $_ } split /\s+/, $launcher;
283	root	1.1	}
284	sf-exg	1.21
285			push @matches, [ $begin[0], $match, @exec ];
286	root	1.1	}
287			}
288			}
289
290	sf-exg	1.21	@matches;
291			}
292
293			sub command_for {
294			my ($self, $row, $col) = @_;
295
296			my @matches = $self->find_matches ($row, $col);
297			if (@matches) {
298			my @match = @{ $matches[0] };
299			return @match[2 .. $#match];
300			}
301
302	root	1.1	()
303			}
304
305			sub on_button_press {
306			my ($self, $event) = @_;
307	sf-tpope	1.5	if($self->valid_button($event)
308			&& (my @exec = $self->command_for($event->{row},$event->{col}))) {
309	root	1.1	$self->{row} = $event->{row};
310			$self->{col} = $event->{col};
311	sf-tpope	1.5	$self->{cmd} = \@exec;
312			return 1;
313	root	1.1	} else {
314			delete $self->{row};
315			delete $self->{col};
316	sf-tpope	1.5	delete $self->{cmd};
317	root	1.1	}
318
319			()
320			}
321
322			sub on_button_release {
323			my ($self, $event) = @_;
324
325			my $row = delete $self->{row};
326			my $col = delete $self->{col};
327	sf-tpope	1.5	my $cmd = delete $self->{cmd};
328	root	1.1
329	sf-tpope	1.5	return if !defined $row;
330
331			if($row == $event->{row} && abs($col-$event->{col}) < 2
332			&& join("\x00", @$cmd) eq join("\x00", $self->command_for($row,$col))) {
333	root	1.1	if($self->valid_button($event)) {
334
335	sf-exg	1.17	$self->exec_async (@$cmd);
336	root	1.1
337			}
338			}
339
340	sf-tpope	1.5	1;
341	root	1.1	}
342
343			# vim:set sw=3 sts=3 et: