[ViewVC] Annotation of: cvs/rxvt-unicode/src/perl/matcher

#! perl

# Author: Tim Pope <rxvt-unicodeNOSPAM@tpope.org>
#         Bob Farrell <robertanthonyfarrell@gmail.com>

#:META:RESOURCE:%.launcher:string:default launcher command
#:META:RESOURCE:%.button:string:the button, yeah
#:META:RESOURCE:%.pattern.:string:extra pattern to match
#:META:RESOURCE:%.launcher.:string:custom launcher for pattern
#:META:RESOURCE:%.rend.:string:custom rednition for pattern

=head1 NAME

matcher - match strings in terminal output and change their rendition

=head1 DESCRIPTION

Uses per-line display filtering (C<on_line_update>) to underline text
matching a certain pattern and make it clickable. When clicked with the
mouse button specified in the C<matcher.button> resource (default 2, or
middle), the program specified in the C<matcher.launcher> resource
(default, the C<url-launcher> resource, C<sensible-browser>) will be started
with the matched text as first argument.  The default configuration is
suitable for matching URLs and launching a web browser, like the
former "mark-urls" extension.

The default pattern to match URLs can be overridden with the
C<matcher.pattern.0> resource, and additional patterns can be specified
with numbered patterns, in a manner similar to the "selection" extension.
The launcher can also be overridden on a per-pattern basis.

It is possible to activate the most recently seen match or a list of matches
from the keyboard.  Simply bind a keysym to "matcher:last" or
"matcher:list" as seen in the example below.

Example: load and use the matcher extension with defaults.

    URxvt.perl-ext:           default,matcher

Example: use a custom configuration.

    URxvt.url-launcher:       sensible-browser
    URxvt.keysym.C-Delete:    matcher:last
    URxvt.keysym.M-Delete:    matcher:list
    URxvt.matcher.button:     1
    URxvt.matcher.pattern.1:  \\bwww\\.[\\w-]+\\.[\\w./?&@#-]*[\\w/-]
    URxvt.matcher.pattern.2:  \\B(/\\S+?):(\\d+)(?=:|$)
    URxvt.matcher.launcher.2: gvim +$2 $1

=cut

my $url =
   qr{
      (?:https?://|ftp://|news://|mailto:|file://|\bwww\.)
      [\w\-\@;\/?:&=%\$.+!*\x27,~#]*
      (
         \([\w\-\@;\/?:&=%\$.+!*\x27,~#]*\)| # Allow a pair of matched parentheses
         [\w\-\@;\/?:&=%\$+*~]  # exclude some trailing characters (heuristic)
      )+
   }x;

sub matchlist_key_press {
   my ($self, $event, $keysym, $octets) = @_;

   delete $self->{overlay};
   $self->disable ("key_press");

   my $i = ($keysym == 96 ? 0 : $keysym - 48);
   if ($i >= 0 && $i < @{ $self->{matches} }) {
      my @exec = @{ $self->{matches}[$i] };
      $self->exec_async (@exec[5 .. $#exec]);
   }

   1
}

# backwards compat
sub on_user_command {
   my ($self, $cmd) = @_;

   if ($cmd =~ s/^matcher:list\b//) {
      $self->matchlist;
   } else {
      if ($cmd =~ s/^matcher:last\b//) {
         $self->most_recent;
      } elsif ($cmd =~ s/^matcher\b//) {
         # for backward compatibility
         $self->most_recent;
      }
   }

   ()
}

sub on_action {
   my ($self, $action) = @_;

   if ($action eq "list") {
      $self->matchlist;
   } elsif ($action eq "last") {
      $self->most_recent;
   }

   ()
}

sub matchlist {
   my ($self) = @_;

   $self->{matches} = [];
   my $row = $self->nrow - 1;
   while ($row >= 0 && @{ $self->{matches} } < 10) {
      my $line = $self->line ($row);
      my @matches = $self->find_matches ($row);

      for (sort { $b->[0] <=> $a->[0] or $b->[1] <=> $a->[1] } @matches) {
         push @{ $self->{matches} }, $_;
         last if @{ $self->{matches} } == 10;
      }

      $row = $line->beg - 1;
   }

   return unless @{ $self->{matches} };

   my $width = 0;

   my $i = 0;
   for my $match (@{ $self->{matches} }) {
      my $text = $match->[4];
      my $w = $self->strwidth ("$i-$text");

      $width = $w if $w > $width;
      $i++;
   }

   $width = $self->ncol - 2 if $width > $self->ncol - 2;

   $self->{overlay} = $self->overlay (0, 0, $width, scalar (@{ $self->{matches} }), urxvt::OVERLAY_RSTYLE, 2);
   my $i = 0;
   for my $match (@{ $self->{matches} }) {
      my $text = $match->[4];

      $self->{overlay}->set (0, $i, "$i-$text");
      $i++;
   }

   $self->enable (key_press => \&matchlist_key_press);
}

sub most_recent {
   my ($self) = shift;
   my $row = $self->nrow;
   my @exec;
   while($row-- > $self->top_row) {
      @exec = $self->command_for($row);
      last if(@exec);
   }
   if(@exec) {
      return $self->exec_async (@exec);
   }
   ()
}

sub my_resource {
   $_[0]->x_resource ("%.$_[1]")
}

# turn a rendition spec in the resource into a sub that implements it on $_
sub parse_rend {
   my ($self, $str) = @_;
   my ($mask, $fg, $bg, $failed) = $str ? urxvt::rend2mask($str)
                                        : (urxvt::RS_Uline, undef, undef, []);
   warn "Failed to parse rendition string: " . join(',', @$failed) if @$failed;
   my @rend;
   push @rend, sub { $_ |= $mask } if $mask;
   push @rend, sub { $_ = urxvt::SET_FGCOLOR($_, $fg) } if defined $fg;
   push @rend, sub { $_ = urxvt::SET_BGCOLOR($_, $bg) } if defined $bg;
   sub {
      for my $s ( @rend ) { &$s };
   }
}

sub on_start {
   my ($self) = @_;

   $self->{launcher} = $self->my_resource ("launcher") || $self->x_resource("url-launcher") || "sensible-browser";

   $self->{button}  = 2;
   $self->{state}   = 0;
   if($self->{argv}[0] || $self->my_resource ("button")) {
      my @mods = split '', $self->{argv}[0] || $self->my_resource ("button");
      for my $mod (@mods) {
         if($mod =~ /^\d+$/) {
            $self->{button} = $mod;
         } elsif($mod eq "C") {
            $self->{state} |= urxvt::ControlMask;
         } elsif($mod eq "S") {
            $self->{state} |= urxvt::ShiftMask;
         } elsif($mod eq "M") {
            $self->{state} |= $self->ModMetaMask;
         } elsif($mod ne "-" && $mod ne " ") {
            warn("$mod is invalid in $self->{_name}<$self->{argv}[0]>\n");
         }
      }
   }

   my @defaults = ($url);
   my @matchers;
   for (my $idx = 0; defined (my $res = $self->my_resource ("pattern.$idx") || $defaults[$idx]); $idx++) {
      $res = $self->locale_decode ($res);
      utf8::encode $res;
      my $launcher = $self->my_resource ("launcher.$idx");
      $launcher =~ s/\$&|\$\{&\}/\${0}/g if $launcher;
      my $rend = $self->parse_rend($self->my_resource ("rend.$idx"));
      unshift @matchers, [qr($res)x,$launcher,$rend];
   }
   $self->{matchers} = \@matchers;

   ()
}

sub on_line_update {
   my ($self, $row) = @_;

   # fetch the line that has changed
   my $line = $self->line ($row);
   my $text = $line->t;

   # find all urls (if any)
   for my $matcher (@{$self->{matchers}}) {
      while ($text =~ /$matcher->[0]/g) {
         #print "$&\n";
         my $rend = $line->r;

         # mark all characters as underlined. we _must_ not toggle underline,
         # as we might get called on an already-marked url.
         &{$matcher->[2]}
         for @{$rend}[ $-[0] .. $+[0] - 1];

         $line->r ($rend);
      }
   }

   ()
}

sub valid_button {
   my ($self, $event) = @_;
   my $mask = $self->ModLevel3Mask | $self->ModMetaMask
   | urxvt::ShiftMask | urxvt::ControlMask;
   return ($event->{button} == $self->{button} &&
      ($event->{state} & $mask) == $self->{state});
}

sub find_matches {
   my ($self, $row, $col) = @_;
   my $line = $self->line ($row);
   my $text = $line->t;
   my $off = $line->offset_of ($row, $col) if $col;

   my @matches;
   for my $matcher (@{$self->{matchers}}) {
      my $launcher = $matcher->[1] || $self->{launcher};
      while ($text =~ /$matcher->[0]/g) {
         my $match = substr $text, $-[0], $+[0] - $-[0];
         my @begin = @-;
         my @end = @+;
         my @exec;

         if (!defined($off) || ($-[0] <= $off && $+[0] >= $off)) {
            if ($launcher !~ /\$/) {
               @exec = ($launcher, $match);
            } else {
               # It'd be nice to just access a list like ($&,$1,$2...),
               # but alas, m//g behaves differently in list context.
               @exec = map { s/\$(\d+)|\$\{(\d+)\}/
                  substr $text, $begin[$1 || $2], $end[$1 || $2] - $begin[$1 || $2]
                  /egx; $_ } split /\s+/, $launcher;
            }

            push @matches, [ $line->coord_of ($begin[0]), $line->coord_of ($end[0]), $match, @exec ];
         }
      }
   }

   @matches;
}

sub command_for {
   my ($self, $row, $col) = @_;

   my @matches = $self->find_matches ($row, $col);
   if (@matches) {
      my @match = @{ $matches[0] };
      return @match[5 .. $#match];
   }

   ()
}

sub on_button_press {
   my ($self, $event) = @_;
   if($self->valid_button($event)
      && (my @exec = $self->command_for($event->{row},$event->{col}))) {
      $self->{row} = $event->{row};
      $self->{col} = $event->{col};
      $self->{cmd} = \@exec;
      return 1;
   } else {
      delete $self->{row};
      delete $self->{col};
      delete $self->{cmd};
   }

   ()
}

sub on_button_release {
   my ($self, $event) = @_;

   my $row = delete $self->{row};
   my $col = delete $self->{col};
   my $cmd = delete $self->{cmd};

   return if !defined $row;

   if($row == $event->{row} && abs($col-$event->{col}) < 2
      && join("\x00", @$cmd) eq join("\x00", $self->command_for($row,$col))) {
      if($self->valid_button($event)) {

         $self->exec_async (@$cmd);

      }
   }

   1;
}

# vim:set sw=3 sts=3 et:
Revision:	1.27
Committed:	Sun Jun 15 11:38:00 2014 UTC (9 years, 10 months ago) by sf-exg
Branch:	MAIN
Changes since 1.26:	+0 -1 lines
Log Message:	Remove unused variable.
#	User	Rev	Content
1	root	1.1	#! perl
2
3	sf-tpope	1.7	# Author: Tim Pope <rxvt-unicodeNOSPAM@tpope.org>
4	root	1.14	# Bob Farrell <robertanthonyfarrell@gmail.com>
5	root	1.1
6	root	1.15	#:META:RESOURCE:%.launcher:string:default launcher command
7			#:META:RESOURCE:%.button:string:the button, yeah
8			#:META:RESOURCE:%.pattern.:string:extra pattern to match
9			#:META:RESOURCE:%.launcher.:string:custom launcher for pattern
10			#:META:RESOURCE:%.rend.:string:custom rednition for pattern
11	root	1.8
12	root	1.10	=head1 NAME
13
14	root	1.13	matcher - match strings in terminal output and change their rendition
15	root	1.10
16	root	1.11	=head1 DESCRIPTION
17	root	1.10
18			Uses per-line display filtering (C<on_line_update>) to underline text
19			matching a certain pattern and make it clickable. When clicked with the
20			mouse button specified in the C<matcher.button> resource (default 2, or
21			middle), the program specified in the C<matcher.launcher> resource
22	sf-exg	1.16	(default, the C<url-launcher> resource, C<sensible-browser>) will be started
23	root	1.10	with the matched text as first argument. The default configuration is
24			suitable for matching URLs and launching a web browser, like the
25			former "mark-urls" extension.
26
27			The default pattern to match URLs can be overridden with the
28			C<matcher.pattern.0> resource, and additional patterns can be specified
29			with numbered patterns, in a manner similar to the "selection" extension.
30			The launcher can also be overridden on a per-pattern basis.
31
32			It is possible to activate the most recently seen match or a list of matches
33	sf-exg	1.20	from the keyboard. Simply bind a keysym to "matcher:last" or
34			"matcher:list" as seen in the example below.
35	root	1.10
36	root	1.14	Example: load and use the matcher extension with defaults.
37	root	1.10
38			URxvt.perl-ext: default,matcher
39	root	1.14
40			Example: use a custom configuration.
41
42	root	1.10	URxvt.url-launcher: sensible-browser
43	sf-exg	1.20	URxvt.keysym.C-Delete: matcher:last
44			URxvt.keysym.M-Delete: matcher:list
45	root	1.10	URxvt.matcher.button: 1
46			URxvt.matcher.pattern.1: \\bwww\\.[\\w-]+\\.[\\w./?&@#-]*[\\w/-]
47			URxvt.matcher.pattern.2: \\B(/\\S+?):(\\d+)(?=:\|$)
48			URxvt.matcher.launcher.2: gvim +$2 $1
49
50			=cut
51
52	root	1.1	my $url =
53			qr{
54	tpope	1.2	(?:https?://\|ftp://\|news://\|mailto:\|file://\|\bwww\.)
55	sf-tpope	1.12	[\w\-\@;\/?:&=%\$.+!\x27,~#]
56	tpope	1.2	(
57	sf-tpope	1.12	\([\w\-\@;\/?:&=%\$.+!\x27,~#]\)\| # Allow a pair of matched parentheses
58			[\w\-\@;\/?:&=%\$+*~] # exclude some trailing characters (heuristic)
59	tpope	1.2	)+
60	root	1.1	}x;
61
62	sf-exg	1.26	sub matchlist_key_press {
63	sf-tpope	1.6	my ($self, $event, $keysym, $octets) = @_;
64
65	sf-exg	1.18	delete $self->{overlay};
66	sf-exg	1.26	$self->disable ("key_press");
67	sf-tpope	1.6
68			my $i = ($keysym == 96 ? 0 : $keysym - 48);
69	sf-exg	1.18	if ($i >= 0 && $i < @{ $self->{matches} }) {
70			my @exec = @{ $self->{matches}[$i] };
71	sf-exg	1.26	$self->exec_async (@exec[5 .. $#exec]);
72	sf-tpope	1.6	}
73
74	sf-exg	1.18	1
75	sf-tpope	1.6	}
76
77	root	1.14	# backwards compat
78	tpope	1.4	sub on_user_command {
79			my ($self, $cmd) = @_;
80	sf-tpope	1.6
81	root	1.14	if ($cmd =~ s/^matcher:list\b//) {
82			$self->matchlist;
83	sf-tpope	1.6	} else {
84	root	1.14	if ($cmd =~ s/^matcher:last\b//) {
85	sf-tpope	1.6	$self->most_recent;
86	root	1.14	} elsif ($cmd =~ s/^matcher\b//) {
87			# for backward compatibility
88	sf-tpope	1.6	$self->most_recent;
89			}
90	tpope	1.4	}
91	root	1.14
92	tpope	1.4	()
93			}
94
95	sf-exg	1.20	sub on_action {
96			my ($self, $action) = @_;
97
98			if ($action eq "list") {
99			$self->matchlist;
100			} elsif ($action eq "last") {
101			$self->most_recent;
102			}
103
104			()
105			}
106
107	sf-tpope	1.6	sub matchlist {
108			my ($self) = @_;
109	sf-exg	1.17
110	sf-exg	1.26	$self->{matches} = [];
111	sf-exg	1.18	my $row = $self->nrow - 1;
112			while ($row >= 0 && @{ $self->{matches} } < 10) {
113			my $line = $self->line ($row);
114	sf-exg	1.24	my @matches = $self->find_matches ($row);
115	sf-exg	1.17
116	sf-exg	1.26	for (sort { $b->[0] <=> $a->[0] or $b->[1] <=> $a->[1] } @matches) {
117	sf-exg	1.19	push @{ $self->{matches} }, $_;
118			last if @{ $self->{matches} } == 10;
119			}
120
121	sf-exg	1.18	$row = $line->beg - 1;
122			}
123	sf-exg	1.17
124	sf-exg	1.18	return unless @{ $self->{matches} };
125	sf-exg	1.17
126	sf-exg	1.18	my $width = 0;
127	sf-exg	1.17
128	sf-exg	1.18	my $i = 0;
129			for my $match (@{ $self->{matches} }) {
130	sf-exg	1.26	my $text = $match->[4];
131	sf-exg	1.18	my $w = $self->strwidth ("$i-$text");
132	sf-exg	1.17
133	sf-exg	1.18	$width = $w if $w > $width;
134			$i++;
135	sf-exg	1.17	}
136
137	sf-exg	1.18	$width = $self->ncol - 2 if $width > $self->ncol - 2;
138	sf-exg	1.17
139	sf-exg	1.18	$self->{overlay} = $self->overlay (0, 0, $width, scalar (@{ $self->{matches} }), urxvt::OVERLAY_RSTYLE, 2);
140	sf-exg	1.17	my $i = 0;
141	sf-exg	1.18	for my $match (@{ $self->{matches} }) {
142	sf-exg	1.26	my $text = $match->[4];
143	sf-exg	1.18
144			$self->{overlay}->set (0, $i, "$i-$text");
145	sf-exg	1.17	$i++;
146			}
147	sf-tpope	1.6
148	sf-exg	1.26	$self->enable (key_press => \&matchlist_key_press);
149	sf-tpope	1.6	}
150
151	tpope	1.4	sub most_recent {
152			my ($self) = shift;
153			my $row = $self->nrow;
154			my @exec;
155			while($row-- > $self->top_row) {
156			@exec = $self->command_for($row);
157			last if(@exec);
158			}
159			if(@exec) {
160			return $self->exec_async (@exec);
161			}
162			()
163			}
164	tpope	1.2
165	root	1.1	sub my_resource {
166	root	1.9	$_[0]->x_resource ("%.$_[1]")
167	root	1.1	}
168
169	tpope	1.2	# turn a rendition spec in the resource into a sub that implements it on $_
170			sub parse_rend {
171			my ($self, $str) = @_;
172	sf-tpope	1.6	my ($mask, $fg, $bg, $failed) = $str ? urxvt::rend2mask($str)
173	tpope	1.2	: (urxvt::RS_Uline, undef, undef, []);
174			warn "Failed to parse rendition string: " . join(',', @$failed) if @$failed;
175			my @rend;
176			push @rend, sub { $_ \|= $mask } if $mask;
177			push @rend, sub { $_ = urxvt::SET_FGCOLOR($_, $fg) } if defined $fg;
178			push @rend, sub { $_ = urxvt::SET_BGCOLOR($_, $bg) } if defined $bg;
179			sub {
180			for my $s ( @rend ) { &$s };
181			}
182			}
183
184	root	1.1	sub on_start {
185			my ($self) = @_;
186
187	root	1.8	$self->{launcher} = $self->my_resource ("launcher") \|\| $self->x_resource("url-launcher") \|\| "sensible-browser";
188	root	1.1
189			$self->{button} = 2;
190			$self->{state} = 0;
191	root	1.8	if($self->{argv}[0] \|\| $self->my_resource ("button")) {
192			my @mods = split '', $self->{argv}[0] \|\| $self->my_resource ("button");
193	root	1.1	for my $mod (@mods) {
194			if($mod =~ /^\d+$/) {
195			$self->{button} = $mod;
196			} elsif($mod eq "C") {
197			$self->{state} \|= urxvt::ControlMask;
198			} elsif($mod eq "S") {
199			$self->{state} \|= urxvt::ShiftMask;
200			} elsif($mod eq "M") {
201			$self->{state} \|= $self->ModMetaMask;
202			} elsif($mod ne "-" && $mod ne " ") {
203	root	1.9	warn("$mod is invalid in $self->{_name}<$self->{argv}[0]>\n");
204	root	1.1	}
205			}
206			}
207
208			my @defaults = ($url);
209			my @matchers;
210	root	1.8	for (my $idx = 0; defined (my $res = $self->my_resource ("pattern.$idx") \|\| $defaults[$idx]); $idx++) {
211	root	1.1	$res = $self->locale_decode ($res);
212			utf8::encode $res;
213	root	1.8	my $launcher = $self->my_resource ("launcher.$idx");
214			$launcher =~ s/\$&\|\$\{&\}/\${0}/g if $launcher;
215			my $rend = $self->parse_rend($self->my_resource ("rend.$idx"));
216	tpope	1.2	unshift @matchers, [qr($res)x,$launcher,$rend];
217	root	1.1	}
218			$self->{matchers} = \@matchers;
219
220			()
221			}
222
223			sub on_line_update {
224			my ($self, $row) = @_;
225
226			# fetch the line that has changed
227			my $line = $self->line ($row);
228			my $text = $line->t;
229
230			# find all urls (if any)
231			for my $matcher (@{$self->{matchers}}) {
232			while ($text =~ /$matcher->[0]/g) {
233	tpope	1.2	#print "$&\n";
234	root	1.1	my $rend = $line->r;
235
236			# mark all characters as underlined. we _must_ not toggle underline,
237			# as we might get called on an already-marked url.
238	tpope	1.2	&{$matcher->[2]}
239	root	1.1	for @{$rend}[ $-[0] .. $+[0] - 1];
240
241			$line->r ($rend);
242			}
243			}
244
245			()
246			}
247
248			sub valid_button {
249			my ($self, $event) = @_;
250			my $mask = $self->ModLevel3Mask \| $self->ModMetaMask
251			\| urxvt::ShiftMask \| urxvt::ControlMask;
252			return ($event->{button} == $self->{button} &&
253			($event->{state} & $mask) == $self->{state});
254			}
255
256	sf-exg	1.21	sub find_matches {
257	root	1.1	my ($self, $row, $col) = @_;
258			my $line = $self->line ($row);
259			my $text = $line->t;
260	sf-exg	1.25	my $off = $line->offset_of ($row, $col) if $col;
261	root	1.1
262	sf-exg	1.21	my @matches;
263	root	1.1	for my $matcher (@{$self->{matchers}}) {
264			my $launcher = $matcher->[1] \|\| $self->{launcher};
265	sf-exg	1.22	while ($text =~ /$matcher->[0]/g) {
266	sf-exg	1.21	my $match = substr $text, $-[0], $+[0] - $-[0];
267	root	1.1	my @begin = @-;
268			my @end = @+;
269	sf-exg	1.21	my @exec;
270
271	sf-exg	1.25	if (!defined($off) \|\| ($-[0] <= $off && $+[0] >= $off)) {
272	root	1.1	if ($launcher !~ /\$/) {
273	sf-exg	1.21	@exec = ($launcher, $match);
274	root	1.1	} else {
275			# It'd be nice to just access a list like ($&,$1,$2...),
276			# but alas, m//g behaves differently in list context.
277	sf-exg	1.21	@exec = map { s/\$(\d+)\|\$\{(\d+)\}/
278	sf-exg	1.23	substr $text, $begin[$1 \|\| $2], $end[$1 \|\| $2] - $begin[$1 \|\| $2]
279	sf-exg	1.22	/egx; $_ } split /\s+/, $launcher;
280	root	1.1	}
281	sf-exg	1.21
282	sf-exg	1.26	push @matches, [ $line->coord_of ($begin[0]), $line->coord_of ($end[0]), $match, @exec ];
283	root	1.1	}
284			}
285			}
286
287	sf-exg	1.21	@matches;
288			}
289
290			sub command_for {
291			my ($self, $row, $col) = @_;
292
293			my @matches = $self->find_matches ($row, $col);
294			if (@matches) {
295			my @match = @{ $matches[0] };
296	sf-exg	1.26	return @match[5 .. $#match];
297	sf-exg	1.21	}
298
299	root	1.1	()
300			}
301
302			sub on_button_press {
303			my ($self, $event) = @_;
304	sf-tpope	1.5	if($self->valid_button($event)
305			&& (my @exec = $self->command_for($event->{row},$event->{col}))) {
306	root	1.1	$self->{row} = $event->{row};
307			$self->{col} = $event->{col};
308	sf-tpope	1.5	$self->{cmd} = \@exec;
309			return 1;
310	root	1.1	} else {
311			delete $self->{row};
312			delete $self->{col};
313	sf-tpope	1.5	delete $self->{cmd};
314	root	1.1	}
315
316			()
317			}
318
319			sub on_button_release {
320			my ($self, $event) = @_;
321
322			my $row = delete $self->{row};
323			my $col = delete $self->{col};
324	sf-tpope	1.5	my $cmd = delete $self->{cmd};
325	root	1.1
326	sf-tpope	1.5	return if !defined $row;
327
328			if($row == $event->{row} && abs($col-$event->{col}) < 2
329			&& join("\x00", @$cmd) eq join("\x00", $self->command_for($row,$col))) {
330	root	1.1	if($self->valid_button($event)) {
331
332	sf-exg	1.17	$self->exec_async (@$cmd);
333	root	1.1
334			}
335			}
336
337	sf-tpope	1.5	1;
338	root	1.1	}
339
340			# vim:set sw=3 sts=3 et: