[ViewVC] Annotation of: cvs/rxvt-unicode/src/perl/searchable-scrollback

#! perl

# this extension implements scrollback buffer search

#:META:RESOURCE:%:string:activation hotkey keysym
#:META:BINDING:M-s:start

=head1 NAME

searchable-scrollback - incremental scrollback search (enabled by default)

=head1 DESCRIPTION

Adds regex search functionality to the scrollback buffer, triggered by
the C<searchable-scrollback:start> action (bound to C<M-s> by
default). While in search mode, normal terminal input/output is
suspended and a regex is displayed at the bottom of the screen.

Inputting characters appends them to the regex and continues incremental
search. C<BackSpace> removes a character from the regex, C<Up> and C<Down>
search upwards/downwards in the scrollback buffer, C<End> jumps to the
bottom. C<Escape> leaves search mode and returns to the point where search
was started, while C<Enter> or C<Return> stay at the current position and
additionally stores the first match in the current line into the primary
selection if the C<Shift> modifier is active.

The regex defaults to "(?i)", resulting in a case-insensitive search. To
get a case-sensitive search you can delete this prefix using C<BackSpace>
or simply use an uppercase character which removes the "(?i)" prefix.

See L<perlre> for more info about perl regular expression syntax.

=cut

sub on_init {
   my ($self) = @_;

   # only for backwards compatibility
   my $hotkey = $self->{argv}[0]
                || $self->x_resource ("%")
                || return;

   $self->bind_action ($hotkey, "searchable-scrollback:start") # ugh
      or warn "unable to register '$hotkey' as scrollback search start hotkey\n";

   ()
}

sub on_action {
   my ($self, $action) = @_;

   $action eq "start"
      and $self->enter;

   ()
}

sub msg {
   my ($self, $msg) = @_;

   $self->{overlay} = $self->overlay (0, -1, $self->ncol, 1, urxvt::OVERLAY_RSTYLE, 0);
   $self->{overlay}->set (0, 0, $self->special_encode ($msg));
}

sub enter {
   my ($self) = @_;

   return if $self->{overlay};

   $self->{view_start} = $self->view_start;
   $self->{pty_ev_events} = $self->pty_ev_events (urxvt::EV_NONE);
   $self->{row} = $self->nrow - 1;
   $self->{search} = "(?i)";

   $self->enable (
      key_press     => \&key_press,
      tt_write      => \&tt_write,
      refresh_begin => \&refresh,
      refresh_end   => \&refresh,
   );

   $self->{manpage_overlay} = $self->overlay (0, -2, $self->ncol, 1, urxvt::OVERLAY_RSTYLE, 0);
   $self->{manpage_overlay}->set (0, 0, "scrollback search, see the ${urxvt::RXVTNAME}perl manpage for details");

   $self->idle;
}

sub leave {
   my ($self) = @_;

   $self->disable ("key_press", "tt_write", "refresh_begin", "refresh_end");
   $self->pty_ev_events ($self->{pty_ev_events});

   delete $self->{manpage_overlay};
   delete $self->{overlay};
   delete $self->{search};
}

sub idle {
   my ($self) = @_;

   $self->msg ("(escape cancels) /$self->{search}█");
}

sub search {
   my ($self, $dir) = @_;

   delete $self->{found};
   my $row = $self->{row};

   my $search = $self->special_encode ($self->{search});

   no re 'eval'; # just to be sure
   if (my $re = eval { qr/$search/ }) {
      while ($self->nrow > $row && $row >= $self->top_row) {
         my $line = $self->line ($row)
            or last;

         my $text = $line->t;
         if ($text =~ /$re/g) {
            do {
               push @{ $self->{found} }, [$line->coord_of ($-[0]), $line->coord_of ($+[0])];
            } while $text =~ /$re/g;

            $self->{row} = $row;
            $self->view_start (List::Util::min 0, $row - ($self->nrow >> 1));
            $self->want_refresh;
            last;
         }

         $row = $dir < 0 ? $line->beg - 1 : $line->end + 1;
      }
   }

   $self->scr_bell unless $self->{found};
}

sub refresh {
   my ($self) = @_;

   return unless $self->{found};

   my $xor = urxvt::RS_RVid | urxvt::RS_Blink;
   for (@{ $self->{found} }) {
      $self->scr_xor_span (@$_, $xor);
      $xor = urxvt::RS_RVid;
   }

   ()
}

sub key_press {
   my ($self, $event, $keysym, $string) =  @_;

   delete $self->{manpage_overlay};

   if ($keysym == 0xff0d || $keysym == 0xff8d) { # enter
      if ($self->{found} && $event->{state} & urxvt::ShiftMask) {
         my ($br, $bc, $er, $ec) = @{ $self->{found}[0] };
         $self->selection_beg ($br, $bc);
         $self->selection_end ($er, $ec);
         $self->selection_make ($event->{time});
      }
      $self->leave;
   } elsif ($keysym == 0xff1b) { # escape
      $self->view_start ($self->{view_start});
      $self->leave;
   } elsif ($keysym == 0xff57) { # end
      $self->{row} = $self->nrow - 1;
      $self->view_start (0);
   } elsif ($keysym == 0xff52) { # up
      $self->{row}-- if $self->{row} > $self->top_row;
      $self->search (-1);
   } elsif ($keysym == 0xff54) { # down
      $self->{row}++ if $self->{row} < $self->nrow;
      $self->search (+1);
   } elsif ($keysym == 0xff08) { # backspace
      substr $self->{search}, -1, 1, "";
      $self->search;
      $self->idle;
   } elsif ($string !~ /[\x00-\x1f\x80-\xaf]/) {
      return; # pass to tt_write
   }

   1
}

sub tt_write {
   my ($self, $data) = @_;

   $self->{search} .= $self->locale_decode ($data);

   $self->{search} =~ s/^\(\?i\)//
      if $self->{search} =~ /^\(.*[[:upper:]]/;

   $self->search (-1);
   $self->idle;

   1
}


Revision:	1.36
Committed:	Sat May 31 08:33:47 2014 UTC (9 years, 11 months ago) by sf-exg
Branch:	MAIN
Changes since 1.35:	+5 -5 lines
Log Message:	Doc fixes.
#	User	Rev	Content
1	root	1.1	#! perl
2
3			# this extension implements scrollback buffer search
4
5	root	1.32	#:META:RESOURCE:%:string:activation hotkey keysym
6	root	1.33	#:META:BINDING:M-s:start
7	root	1.27
8	root	1.29	=head1 NAME
9
10	sf-exg	1.36	searchable-scrollback - incremental scrollback search (enabled by default)
11	root	1.29
12			=head1 DESCRIPTION
13
14	sf-exg	1.36	Adds regex search functionality to the scrollback buffer, triggered by
15			the C<searchable-scrollback:start> action (bound to C<M-s> by
16			default). While in search mode, normal terminal input/output is
17			suspended and a regex is displayed at the bottom of the screen.
18	root	1.29
19			Inputting characters appends them to the regex and continues incremental
20			search. C<BackSpace> removes a character from the regex, C<Up> and C<Down>
21			search upwards/downwards in the scrollback buffer, C<End> jumps to the
22			bottom. C<Escape> leaves search mode and returns to the point where search
23			was started, while C<Enter> or C<Return> stay at the current position and
24			additionally stores the first match in the current line into the primary
25			selection if the C<Shift> modifier is active.
26
27			The regex defaults to "(?i)", resulting in a case-insensitive search. To
28			get a case-sensitive search you can delete this prefix using C<BackSpace>
29			or simply use an uppercase character which removes the "(?i)" prefix.
30
31			See L<perlre> for more info about perl regular expression syntax.
32
33			=cut
34
35	root	1.1	sub on_init {
36			my ($self) = @_;
37
38	root	1.33	# only for backwards compatibility
39	root	1.12	my $hotkey = $self->{argv}[0]
40	root	1.28	\|\| $self->x_resource ("%")
41	root	1.34	\|\| return;
42	root	1.1
43	root	1.33	$self->bind_action ($hotkey, "searchable-scrollback:start") # ugh
44	root	1.4	or warn "unable to register '$hotkey' as scrollback search start hotkey\n";
45	root	1.1
46			()
47			}
48
49	root	1.33	sub on_action {
50			my ($self, $action) = @_;
51	root	1.1
52	root	1.33	$action eq "start"
53	root	1.8	and $self->enter;
54	root	1.1
55			()
56			}
57
58			sub msg {
59			my ($self, $msg) = @_;
60
61			$self->{overlay} = $self->overlay (0, -1, $self->ncol, 1, urxvt::OVERLAY_RSTYLE, 0);
62			$self->{overlay}->set (0, 0, $self->special_encode ($msg));
63			}
64
65			sub enter {
66			my ($self) = @_;
67
68			return if $self->{overlay};
69
70	root	1.8	$self->{view_start} = $self->view_start;
71	root	1.24	$self->{pty_ev_events} = $self->pty_ev_events (urxvt::EV_NONE);
72	root	1.13	$self->{row} = $self->nrow - 1;
73	root	1.22	$self->{search} = "(?i)";
74	root	1.1
75			$self->enable (
76	root	1.2	key_press => \&key_press,
77	root	1.7	tt_write => \&tt_write,
78	root	1.2	refresh_begin => \&refresh,
79			refresh_end => \&refresh,
80	root	1.1	);
81
82	root	1.8	$self->{manpage_overlay} = $self->overlay (0, -2, $self->ncol, 1, urxvt::OVERLAY_RSTYLE, 0);
83	root	1.11	$self->{manpage_overlay}->set (0, 0, "scrollback search, see the ${urxvt::RXVTNAME}perl manpage for details");
84	root	1.8
85	root	1.1	$self->idle;
86			}
87
88			sub leave {
89			my ($self) = @_;
90
91	root	1.7	$self->disable ("key_press", "tt_write", "refresh_begin", "refresh_end");
92	root	1.8	$self->pty_ev_events ($self->{pty_ev_events});
93	root	1.1
94	root	1.8	delete $self->{manpage_overlay};
95			delete $self->{overlay};
96	root	1.13	delete $self->{search};
97	root	1.1	}
98
99			sub idle {
100			my ($self) = @_;
101
102	root	1.13	$self->msg ("(escape cancels) /$self->{search}█");
103	root	1.1	}
104
105			sub search {
106	root	1.13	my ($self, $dir) = @_;
107	root	1.1
108			delete $self->{found};
109	root	1.13	my $row = $self->{row};
110	root	1.1
111	root	1.7	my $search = $self->special_encode ($self->{search});
112
113	root	1.1	no re 'eval'; # just to be sure
114	root	1.16	if (my $re = eval { qr/$search/ }) {
115	sf-exg	1.25	while ($self->nrow > $row && $row >= $self->top_row) {
116	root	1.16	my $line = $self->line ($row)
117			or last;
118
119			my $text = $line->t;
120			if ($text =~ /$re/g) {
121			do {
122			push @{ $self->{found} }, [$line->coord_of ($-[0]), $line->coord_of ($+[0])];
123			} while $text =~ /$re/g;
124
125			$self->{row} = $row;
126	root	1.20	$self->view_start (List::Util::min 0, $row - ($self->nrow >> 1));
127	root	1.16	$self->want_refresh;
128			last;
129			}
130	root	1.1
131	root	1.16	$row = $dir < 0 ? $line->beg - 1 : $line->end + 1;
132	root	1.1	}
133			}
134
135			$self->scr_bell unless $self->{found};
136			}
137
138	root	1.2	sub refresh {
139			my ($self) = @_;
140
141	root	1.18	return unless $self->{found};
142
143	root	1.15	my $xor = urxvt::RS_RVid \| urxvt::RS_Blink;
144	root	1.13	for (@{ $self->{found} }) {
145			$self->scr_xor_span (@$_, $xor);
146			$xor = urxvt::RS_RVid;
147			}
148	root	1.2
149			()
150			}
151
152			sub key_press {
153	root	1.1	my ($self, $event, $keysym, $string) = @_;
154
155	root	1.13	delete $self->{manpage_overlay};
156
157	root	1.14	if ($keysym == 0xff0d \|\| $keysym == 0xff8d) { # enter
158	ayin	1.23	if ($self->{found} && $event->{state} & urxvt::ShiftMask) {
159	root	1.13	my ($br, $bc, $er, $ec) = @{ $self->{found}[0] };
160			$self->selection_beg ($br, $bc);
161			$self->selection_end ($er, $ec);
162			$self->selection_make ($event->{time});
163			}
164			$self->leave;
165	root	1.14	} elsif ($keysym == 0xff1b) { # escape
166	root	1.13	$self->view_start ($self->{view_start});
167			$self->leave;
168	root	1.14	} elsif ($keysym == 0xff57) { # end
169	root	1.13	$self->{row} = $self->nrow - 1;
170			$self->view_start (0);
171	root	1.14	} elsif ($keysym == 0xff52) { # up
172	root	1.20	$self->{row}-- if $self->{row} > $self->top_row;
173	root	1.13	$self->search (-1);
174	root	1.14	} elsif ($keysym == 0xff54) { # down
175	root	1.13	$self->{row}++ if $self->{row} < $self->nrow;
176			$self->search (+1);
177	root	1.14	} elsif ($keysym == 0xff08) { # backspace
178	root	1.13	substr $self->{search}, -1, 1, "";
179			$self->search;
180			$self->idle;
181	root	1.19	} elsif ($string !~ /[\x00-\x1f\x80-\xaf]/) {
182	root	1.13	return; # pass to tt_write
183	root	1.1	}
184
185			1
186			}
187
188	root	1.7	sub tt_write {
189			my ($self, $data) = @_;
190
191			$self->{search} .= $self->locale_decode ($data);
192	root	1.22
193			$self->{search} =~ s/^\(\?i\)//
194			if $self->{search} =~ /^\(.*[[:upper:]]/;
195	sf-exg	1.26
196	root	1.13	$self->search (-1);
197			$self->idle;
198	root	1.7
199			1
200			}
201
202	root	1.1