[ViewVC] Annotation of: cvs/rxvt-unicode/src/perl/tabbed

#! perl

sub refresh {
   my ($self) = @_;

   my $ncol = $self->ncol;

   my $text = " " x $ncol;
   my $rend = [($self->{rs_tabbar}) x $ncol];

   my @ofs;

   substr $text, 0, 7, "[NEW] |";
   @$rend[0 .. 5] = ($self->{rs_tab}) x 6;
   push @ofs, [0, 6, sub { $_[0]->new_tab }];

   my $ofs = 7;
   my $idx = 0;

   for my $tab (@{ $self->{tabs} }) {
      $idx++;

      my $act = $tab->{activity} && $tab != $self->{cur}
                ? "*" : " ";

      my $txt = "$act$idx$act";
      my $len = length $txt;

      substr $text, $ofs, $len + 1, "$txt|";
      @$rend[$ofs .. $ofs + $len - 1] = ($self->{rs_tab}) x $len
         if $tab == $self->{cur};

      push @ofs, [ $ofs, $ofs + $len, sub { $_[0]->make_current ($tab) } ];

      $ofs += $len + 1;
   }

   $self->{tabofs} = \@ofs;

   $self->ROW_t (0, $text, 0, 0, $ncol);
   $self->ROW_r (0, $rend, 0, 0, $ncol);

   $self->want_refresh;
}

sub new_tab {
   my ($self, @argv) = @_;

   # save a backlink to us, make sure tabbed is inactive
   push @urxvt::TERM_INIT, sub {
      my ($term) = @_;
      $term->{parent} = $self;

      for (0 .. urxvt::NUM_RESOURCES - 1) {
         my $value = $self->{resource}[$_];

         $term->resource ("+$_" => $value)
            if defined $value;
      }

      $term->resource (perl_ext_2 => $term->resource ("perl_ext_2") . ",-tabbed");
   };

   push @urxvt::TERM_EXT, urxvt::ext::tabbed::tab::;

   my $term = new urxvt::term
      $self->env, $urxvt::RXVTNAME,
      -embed => $self->parent,
      @argv,
   ;
}

sub configure {
   my ($self) = @_;

   my $tab = $self->{cur};

   # this is an extremely dirty way to force a configurenotify, but who cares
   $tab->XMoveResizeWindow (
      $tab->parent,
      0, $self->{tabheight} + 1,
      $self->width,
      $self->height - $self->{tabheight} + 2 * $tab->int_bwidth
   );
   $tab->XMoveResizeWindow (
      $tab->parent,
      0, $self->{tabheight},
      $self->width,
      $self->height - $self->{tabheight} + 2 * $tab->int_bwidth
   );
}

sub on_resize_all_windows {
   my ($self, $width, $height) = @_;

   1
}

sub copy_properties {
   my ($self) = @_;
   my $tab = $self->{cur};

   my $wm_normal_hints = $self->XInternAtom ("WM_NORMAL_HINTS");

   my $current = delete $self->{current_properties};

   # pass 1: copy over properties different or nonexisting
   for my $atom ($tab->XListProperties ($tab->parent)) {
      my ($type, $format, $items) = $self->XGetWindowProperty ($tab->parent, $atom);

      # fix up size hints
      if ($atom == $wm_normal_hints) {
         my (@hints) = unpack "l!*", $items;

         $hints[$_] += $self->{tabheight} for (4, 6, 16);

         $items = pack "l!*", @hints;
      }

      my $cur = delete $current->{$atom};

      # update if changed, we assume empty items and zero type and format will not happen
      $self->XChangeProperty ($self->parent, $atom, $type, $format, $items)
         if $cur->[0] != $type or $cur->[1] != $format or $cur->[2] ne $items;

      $self->{current_properties}{$atom} = [$type, $format, $items];
   }

   # pass 2, delete all extraneous properties
   $self->XDeleteProperty ($self->parent, $_) for keys %$current;
}

sub make_current {
   my ($self, $tab) = @_;

   if (my $cur = $self->{cur}) {
      delete $cur->{activity};
      $cur->XUnmapWindow ($cur->parent) if $cur->mapped;
      $cur->focus_out;
   }

   $self->{cur} = $tab;

   $self->configure;
   $self->copy_properties;

   $tab->focus_out; # just in case, should be a nop
   $tab->focus_in if $self->focus;

   $tab->XMapWindow ($tab->parent);
   delete $tab->{activity};
   $self->refresh;

   ()
}

sub on_focus_in {
   my ($self, $event) = @_;

   $self->{cur}->focus_in;

   ()
}

sub on_focus_out {
   my ($self, $event) = @_;

   $self->{cur}->focus_out;

   ()
}

sub on_tt_write {
    my ($self, $octets) = @_;

    $self->{cur}->tt_write ($octets);

    1
}

sub on_key_press {
   my ($self, $event) = @_;

   $self->{cur}->key_press ($event->{state}, $event->{keycode}, $event->{time});

   1
}

sub on_key_release {
   my ($self, $event) = @_;

   $self->{cur}->key_release ($event->{state}, $event->{keycode}, $event->{time});

   1
}

sub on_button_press {
   1
}

sub on_button_release {
   my ($self, $event) = @_;

   if ($event->{row} == 0) {
      for my $button (@{ $self->{tabofs} }) {
         $button->[2]->($self, $event)
            if $event->{col} >= $button->[0]
               && $event->{col} < $button->[1];
      }
   }

   1
}

sub on_motion_notify {
   1
}

sub on_init {
   my ($self) = @_;

   $self->{resource} = [map $self->resource ("+$_"), 0 .. urxvt::NUM_RESOURCES - 1];

   $self->resource (int_bwidth => 0);
   $self->resource (name => "URxvt.tabbed");
   $self->resource (pty_fd => -1);

   $self->option ($urxvt::OPTION{scrollBar}, 0);

   my $fg    = $self->x_resource ("tabbar-fg");
   my $bg    = $self->x_resource ("tabbar-bg");
   my $tabfg = $self->x_resource ("tab-fg");
   my $tabbg = $self->x_resource ("tab-bg");

   defined $fg    or $fg    = 3;
   defined $bg    or $bg    = 0;
   defined $tabfg or $tabfg = 0;
   defined $tabbg or $tabbg = 1;

   $self->{rs_tabbar} = urxvt::SET_COLOR (urxvt::DEFAULT_RSTYLE, $fg    + 2, $bg    + 2);
   $self->{rs_tab}    = urxvt::SET_COLOR (urxvt::DEFAULT_RSTYLE, $tabfg + 2, $tabbg + 2);

   ()
}

sub on_start {
   my ($self) = @_;

   $self->{tabheight} = $self->int_bwidth + $self->fheight + $self->lineSpace;

   $self->cmd_parse ("\033[?25l");

   my @argv = $self->argv;

   do {
      shift @argv;
   } while @argv && $argv[0] ne "-e";

   $self->new_tab (@argv);

   ()
}

sub on_configure_notify {
   my ($self, $event) = @_;

   $self->configure;
   $self->refresh;

   ()
}

sub on_wm_delete_window {
   my ($self) = @_;

   $_->destroy for @{ $self->{tabs} };

   1
}

sub tab_start {
   my ($self, $tab) = @_;

   $tab->XChangeInput ($tab->parent, urxvt::PropertyChangeMask);

   push @{ $self->{tabs} }, $tab;

#   $tab->{name} ||= scalar @{ $self->{tabs} };
   $self->make_current ($tab);

   ()
}

sub tab_destroy {
   my ($self, $tab) = @_;

   $self->{tabs} = [ grep $_ != $tab, @{ $self->{tabs} } ];

   if (@{ $self->{tabs} }) {
      if ($self->{cur} == $tab) {
         delete $self->{cur};
         $self->make_current ($self->{tabs}[-1]);
      } else {
         $self->refresh;
      }
   } else {
      # delay destruction a tiny bit
      $self->{destroy} = urxvt::iw->new->start->cb (sub { $self->destroy });
   }

   ()
}

sub tab_key_press {
   my ($self, $tab, $event, $keysym, $str) = @_;

   if ($event->{state} & urxvt::ShiftMask) {
      if ($keysym == 0xff51 || $keysym == 0xff53) {
         my ($idx) = grep $self->{tabs}[$_] == $tab, 0 .. $#{ $self->{tabs} };

         --$idx if $keysym == 0xff51;
         ++$idx if $keysym == 0xff53;

         $self->make_current ($self->{tabs}[$idx % @{ $self->{tabs}}]);

         return 1;
      } elsif ($keysym == 0xff54) {
         $self->new_tab;

         return 1;
      }
   }
   elsif ($event->{state} & urxvt::ControlMask) {
      if ($keysym == 0xff51 || $keysym == 0xff53) {
         my ($idx1) = grep $self->{tabs}[$_] == $tab, 0 .. $#{ $self->{tabs} };
         my  $idx2  = ($idx1 + ($keysym == 0xff51 ? -1 : +1)) % @{ $self->{tabs} };

         ($self->{tabs}[$idx1], $self->{tabs}[$idx2]) =
            ($self->{tabs}[$idx2], $self->{tabs}[$idx1]);

         $self->make_current ($self->{tabs}[$idx2]);

         return 1;
      }
   }

   ()
}

sub tab_property_notify {
   my ($self, $tab, $event) = @_;

   $self->copy_properties
      if $event->{window} == $tab->parent;

   ()
}

sub tab_activity {
   my ($self, $tab) = @_;

   $self->refresh;
}

package urxvt::ext::tabbed::tab;

# helper extension implementing the subwindows of a tabbed terminal.
# simply proxies all interesting calls back to the tabbed class.

{
   for my $hook qw(start destroy key_press property_notify) {
      eval qq{
         sub on_$hook {
            my \$parent = \$_[0]{term}{parent}
               or return;
            \$parent->tab_$hook (\@_)
         }
      };
      die if $@;
   }
}

sub on_add_lines {
  $_[0]->{activity}++
     or $_[0]{term}{parent}->tab_activity ($_[0]);
  ()
}


Revision:	1.29
Committed:	Mon Jan 9 17:49:00 2012 UTC (12 years, 4 months ago) by mikachu
Branch:	MAIN
Changes since 1.28:	+4 -2 lines
Log Message:	bugfixes
#	User	Rev	Content
1	root	1.1	#! perl
2
3			sub refresh {
4			my ($self) = @_;
5
6	root	1.6	my $ncol = $self->ncol;
7
8			my $text = " " x $ncol;
9	root	1.15	my $rend = [($self->{rs_tabbar}) x $ncol];
10	root	1.6
11			my @ofs;
12	root	1.1
13	root	1.7	substr $text, 0, 7, "[NEW] \|";
14	root	1.15	@$rend[0 .. 5] = ($self->{rs_tab}) x 6;
15	root	1.7	push @ofs, [0, 6, sub { $_[0]->new_tab }];
16
17			my $ofs = 7;
18			my $idx = 0;
19
20	root	1.1	for my $tab (@{ $self->{tabs} }) {
21	root	1.7	$idx++;
22
23	root	1.9	my $act = $tab->{activity} && $tab != $self->{cur}
24			? "*" : " ";
25
26			my $txt = "$act$idx$act";
27	root	1.6	my $len = length $txt;
28
29			substr $text, $ofs, $len + 1, "$txt\|";
30	root	1.15	@$rend[$ofs .. $ofs + $len - 1] = ($self->{rs_tab}) x $len
31	root	1.7	if $tab == $self->{cur};
32	root	1.6
33	root	1.7	push @ofs, [ $ofs, $ofs + $len, sub { $_[0]->make_current ($tab) } ];
34	root	1.1
35	root	1.6	$ofs += $len + 1;
36	root	1.1	}
37
38			$self->{tabofs} = \@ofs;
39
40	root	1.7	$self->ROW_t (0, $text, 0, 0, $ncol);
41			$self->ROW_r (0, $rend, 0, 0, $ncol);
42
43			$self->want_refresh;
44	root	1.1	}
45
46			sub new_tab {
47	root	1.21	my ($self, @argv) = @_;
48	root	1.1
49			# save a backlink to us, make sure tabbed is inactive
50			push @urxvt::TERM_INIT, sub {
51			my ($term) = @_;
52			$term->{parent} = $self;
53
54	root	1.25	for (0 .. urxvt::NUM_RESOURCES - 1) {
55			my $value = $self->{resource}[$_];
56
57			$term->resource ("+$_" => $value)
58			if defined $value;
59			}
60	root	1.1
61			$term->resource (perl_ext_2 => $term->resource ("perl_ext_2") . ",-tabbed");
62			};
63
64			push @urxvt::TERM_EXT, urxvt::ext::tabbed::tab::;
65
66			my $term = new urxvt::term
67			$self->env, $urxvt::RXVTNAME,
68			-embed => $self->parent,
69	root	1.21	@argv,
70	root	1.1	;
71			}
72
73			sub configure {
74			my ($self) = @_;
75
76	root	1.5	my $tab = $self->{cur};
77
78	root	1.14	# this is an extremely dirty way to force a configurenotify, but who cares
79	root	1.5	$tab->XMoveResizeWindow (
80			$tab->parent,
81	root	1.14	0, $self->{tabheight} + 1,
82	mikachu	1.29	$self->width,
83			$self->height - $self->{tabheight} + 2 * $tab->int_bwidth
84	root	1.13	);
85			$tab->XMoveResizeWindow (
86			$tab->parent,
87	root	1.4	0, $self->{tabheight},
88	mikachu	1.29	$self->width,
89			$self->height - $self->{tabheight} + 2 * $tab->int_bwidth
90	root	1.1	);
91	root	1.11	}
92
93	root	1.19	sub on_resize_all_windows {
94			my ($self, $width, $height) = @_;
95
96			1
97			}
98
99	root	1.11	sub copy_properties {
100			my ($self) = @_;
101			my $tab = $self->{cur};
102	root	1.5
103			my $wm_normal_hints = $self->XInternAtom ("WM_NORMAL_HINTS");
104
105	root	1.24	my $current = delete $self->{current_properties};
106	root	1.16
107	root	1.24	# pass 1: copy over properties different or nonexisting
108	root	1.5	for my $atom ($tab->XListProperties ($tab->parent)) {
109			my ($type, $format, $items) = $self->XGetWindowProperty ($tab->parent, $atom);
110	sf-exg	1.27
111	root	1.24	# fix up size hints
112	root	1.5	if ($atom == $wm_normal_hints) {
113			my (@hints) = unpack "l!*", $items;
114	sf-exg	1.27
115	root	1.19	$hints[$_] += $self->{tabheight} for (4, 6, 16);
116	sf-exg	1.27
117	root	1.19	$items = pack "l!*", @hints;
118			}
119	root	1.5
120	root	1.24	my $cur = delete $current->{$atom};
121	root	1.6
122	root	1.24	# update if changed, we assume empty items and zero type and format will not happen
123			$self->XChangeProperty ($self->parent, $atom, $type, $format, $items)
124			if $cur->[0] != $type or $cur->[1] != $format or $cur->[2] ne $items;
125
126			$self->{current_properties}{$atom} = [$type, $format, $items];
127	root	1.5	}
128	root	1.6
129	root	1.24	# pass 2, delete all extraneous properties
130			$self->XDeleteProperty ($self->parent, $_) for keys %$current;
131	root	1.1	}
132
133			sub make_current {
134			my ($self, $tab) = @_;
135
136			if (my $cur = $self->{cur}) {
137	root	1.9	delete $cur->{activity};
138	root	1.7	$cur->XUnmapWindow ($cur->parent) if $cur->mapped;
139			$cur->focus_out;
140	root	1.1	}
141	sf-exg	1.27
142	root	1.1	$self->{cur} = $tab;
143
144			$self->configure;
145	root	1.11	$self->copy_properties;
146	sf-exg	1.27
147	root	1.20	$tab->focus_out; # just in case, should be a nop
148			$tab->focus_in if $self->focus;
149	sf-exg	1.27
150	root	1.1	$tab->XMapWindow ($tab->parent);
151	root	1.10	delete $tab->{activity};
152	root	1.1	$self->refresh;
153
154			()
155			}
156
157	root	1.15	sub on_focus_in {
158			my ($self, $event) = @_;
159
160			$self->{cur}->focus_in;
161
162			()
163			}
164
165			sub on_focus_out {
166			my ($self, $event) = @_;
167
168			$self->{cur}->focus_out;
169
170			()
171			}
172
173	sf-exg	1.26	sub on_tt_write {
174			my ($self, $octets) = @_;
175
176			$self->{cur}->tt_write ($octets);
177
178			1
179			}
180
181	root	1.15	sub on_key_press {
182			my ($self, $event) = @_;
183
184			$self->{cur}->key_press ($event->{state}, $event->{keycode}, $event->{time});
185
186			1
187			}
188
189			sub on_key_release {
190			my ($self, $event) = @_;
191
192			$self->{cur}->key_release ($event->{state}, $event->{keycode}, $event->{time});
193
194			1
195			}
196
197	root	1.1	sub on_button_press {
198			1
199			}
200
201			sub on_button_release {
202			my ($self, $event) = @_;
203
204			if ($event->{row} == 0) {
205	root	1.6	for my $button (@{ $self->{tabofs} }) {
206			$button->[2]->($self, $event)
207			if $event->{col} >= $button->[0]
208			&& $event->{col} < $button->[1];
209	root	1.1	}
210			}
211
212			1
213			}
214
215			sub on_motion_notify {
216			1
217			}
218
219			sub on_init {
220			my ($self) = @_;
221
222	root	1.25	$self->{resource} = [map $self->resource ("+$_"), 0 .. urxvt::NUM_RESOURCES - 1];
223	root	1.1
224			$self->resource (int_bwidth => 0);
225	root	1.15	$self->resource (name => "URxvt.tabbed");
226	root	1.1	$self->resource (pty_fd => -1);
227
228			$self->option ($urxvt::OPTION{scrollBar}, 0);
229
230	root	1.15	my $fg = $self->x_resource ("tabbar-fg");
231			my $bg = $self->x_resource ("tabbar-bg");
232			my $tabfg = $self->x_resource ("tab-fg");
233			my $tabbg = $self->x_resource ("tab-bg");
234
235			defined $fg or $fg = 3;
236			defined $bg or $bg = 0;
237			defined $tabfg or $tabfg = 0;
238			defined $tabbg or $tabbg = 1;
239
240			$self->{rs_tabbar} = urxvt::SET_COLOR (urxvt::DEFAULT_RSTYLE, $fg + 2, $bg + 2);
241			$self->{rs_tab} = urxvt::SET_COLOR (urxvt::DEFAULT_RSTYLE, $tabfg + 2, $tabbg + 2);
242
243	root	1.1	()
244			}
245
246			sub on_start {
247			my ($self) = @_;
248
249	root	1.4	$self->{tabheight} = $self->int_bwidth + $self->fheight + $self->lineSpace;
250
251	root	1.15	$self->cmd_parse ("\033[?25l");
252
253	root	1.21	my @argv = $self->argv;
254
255			do {
256			shift @argv;
257			} while @argv && $argv[0] ne "-e";
258
259			$self->new_tab (@argv);
260	root	1.1
261			()
262			}
263
264			sub on_configure_notify {
265			my ($self, $event) = @_;
266
267			$self->configure;
268	root	1.12	$self->refresh;
269	root	1.1
270			()
271			}
272
273			sub on_wm_delete_window {
274			my ($self) = @_;
275
276			$_->destroy for @{ $self->{tabs} };
277
278			1
279			}
280
281			sub tab_start {
282			my ($self, $tab) = @_;
283
284	root	1.11	$tab->XChangeInput ($tab->parent, urxvt::PropertyChangeMask);
285
286	root	1.1	push @{ $self->{tabs} }, $tab;
287
288	root	1.7	# $tab->{name} \|\|= scalar @{ $self->{tabs} };
289	root	1.1	$self->make_current ($tab);
290
291			()
292			}
293
294			sub tab_destroy {
295			my ($self, $tab) = @_;
296
297			$self->{tabs} = [ grep $_ != $tab, @{ $self->{tabs} } ];
298
299			if (@{ $self->{tabs} }) {
300			if ($self->{cur} == $tab) {
301			delete $self->{cur};
302			$self->make_current ($self->{tabs}[-1]);
303	root	1.7	} else {
304			$self->refresh;
305	root	1.1	}
306			} else {
307			# delay destruction a tiny bit
308			$self->{destroy} = urxvt::iw->new->start->cb (sub { $self->destroy });
309			}
310
311			()
312			}
313
314	root	1.8	sub tab_key_press {
315			my ($self, $tab, $event, $keysym, $str) = @_;
316
317	root	1.10	if ($event->{state} & urxvt::ShiftMask) {
318			if ($keysym == 0xff51 \|\| $keysym == 0xff53) {
319			my ($idx) = grep $self->{tabs}[$_] == $tab, 0 .. $#{ $self->{tabs} };
320
321			--$idx if $keysym == 0xff51;
322			++$idx if $keysym == 0xff53;
323
324			$self->make_current ($self->{tabs}[$idx % @{ $self->{tabs}}]);
325	sf-exg	1.27
326	root	1.10	return 1;
327			} elsif ($keysym == 0xff54) {
328			$self->new_tab;
329
330			return 1;
331			}
332	root	1.8	}
333	root	1.22	elsif ($event->{state} & urxvt::ControlMask) {
334			if ($keysym == 0xff51 \|\| $keysym == 0xff53) {
335			my ($idx1) = grep $self->{tabs}[$_] == $tab, 0 .. $#{ $self->{tabs} };
336			my $idx2 = ($idx1 + ($keysym == 0xff51 ? -1 : +1)) % @{ $self->{tabs} };
337
338			($self->{tabs}[$idx1], $self->{tabs}[$idx2]) =
339			($self->{tabs}[$idx2], $self->{tabs}[$idx1]);
340
341			$self->make_current ($self->{tabs}[$idx2]);
342
343			return 1;
344			}
345			}
346	root	1.8
347			()
348			}
349
350	root	1.11	sub tab_property_notify {
351			my ($self, $tab, $event) = @_;
352
353			$self->copy_properties
354			if $event->{window} == $tab->parent;
355
356			()
357			}
358
359	root	1.9	sub tab_activity {
360			my ($self, $tab) = @_;
361
362			$self->refresh;
363			}
364
365	root	1.1	package urxvt::ext::tabbed::tab;
366
367			# helper extension implementing the subwindows of a tabbed terminal.
368			# simply proxies all interesting calls back to the tabbed class.
369
370			{
371	root	1.11	for my $hook qw(start destroy key_press property_notify) {
372	root	1.1	eval qq{
373			sub on_$hook {
374			my \$parent = \$_[0]{term}{parent}
375			or return;
376			\$parent->tab_$hook (\@_)
377			}
378			};
379			die if $@;
380			}
381			}
382
383	root	1.9	sub on_add_lines {
384			$_[0]->{activity}++
385			or $_[0]{term}{parent}->tab_activity ($_[0]);
386			()
387			}
388	root	1.1
389